glife/locations/Nord

# Nord
$metka = $ARGS[0]
$loc = $CURLOC
$metkaStreet = $ARGS[0]
$locStreet = $CURLOC
gs 'dinam'
'<center><b>Northern region</b></center>'
'<center><img src="images/etogame/nord.jpg"></center>'
clr
gs 'stat'
gs 'time'

!!act 'Exit to the northern highway':minut += 15 & nroad = 0 & gt 'road'
act 'Wait':
	cla
	waiting = input ("How long would you like to wait? (Not more than 120 minutes)")

	if waiting <= 0 or waiting > 120:set minut += 15
	if waiting > 0 and waiting <= 120:set minut += waiting

	act 'Take a look at the clock':gt curloc
end

act 'Take a cab':
	cla
	*clr
	'<center><img src="images/etogame/taxi1.jpg"></center>'
	'You caught a passing taxi.'
	'"The drive will cost you <b>250 rubles</b>", the driver says.'
	set minut += 5

	if $loc ! 'street':
		act 'Go to the Residential Area':
			set $loc = 'street'
			dynamic $taxi
		end
	end

	if $loc ! 'down':
		act 'Go to the City Center':
			set $loc = 'down'
			dynamic $taxi
		end
	end

	if $loc ! 'Nord':
		act 'Go to the Northern Area':
			set $loc = 'Nord'
			dynamic $taxi
		end
	end

	act 'Turn him down and leave':gt '<<$loc>>'
end

if car > 0:
	if cardrive = 3 or cardrive >= 6 and cardrive <= 9:'In the parking stands your <a href="exec:GS ''carF'', ''start''"><<$car>></a>.'
end

if hour >= 8 and hour <= 22:'A kiosk is selling <a href="exec:dynamic $kiosksig">cigarettes</a>.'

'<a href="exec:minut += 15 & gt ''vokzal''">Train Station</a> to get to the small Town.'

if slavaQW >= 1:'<a href="exec:gt ''qwBarPolet''">Bar "Flight"</a>.'

litltown = 0
'There is a <a href="exec:gt ''zaprF'', ''start''">Gas</a> Station near the street'

if hour >= 5 and hour <= 23:'The <a href="exec:gt ''metro'', ''start''">Metro</a> Station is within a 5 minute walk from here.'
if hour >= 9 and hour <= 17 and week > 1:'<a href="exec:gt ''autosalonF'', ''start''">Car Dealership</a>'
if hour >= 9 and hour <= 20 and week < 7:'<a href="exec:gt ''autoservisF'', ''start''">Repair Shop</a>'
if hour >= 9 and hour <= 17 and week > 1:'Used <a href="exec:gt ''autotraidF'', ''start''">Car Dealership</a>'
if hour >= 9 and hour <= 17 and week < 6:'<a href="exec:gt ''dk'', ''start''">The House of Culture named after Lenin</a>'
if hour >= 8 and hour <= 20:'The parking lot, which is engulfed in bright lights, belongs to a <a href="exec:gt ''shop'', ''start''">Supermarket</a>'
if hour >= 12 and hour < 20:'Above the door to a basement room is a bright neon sign for a <a href="exec:gt ''pirsingsalon''">piercing parlor</a>'
if tobiQW >= 1:'The old mansion, home to <a href="exec:gt ''kakuzu'', ''start''">Kakuzu</a>'
'There is a huge building, with bright lights, which houses a <a href="exec:gt ''casino''">Casino</a> and a hotel.'
if hour >= 14 or hour < 4:'Located far away from the buildings <a href="exec:gt ''lakecafe'', ''main''">barbecue</a>.'
if jouryResult = 10:'In one of the building you can find <a href="exec:gt ''youry''">Georges</a> flat'
if IvanKvartira > 0:'In one of these building is <a href="exec:gt ''ivanRoom''">Manager Ivans</a> apartment'

'A long and high fence, which is build around the <a href="exec:gt ''Terminal''">storage terminal</a>'
dynamic $din_street_cum

--- Nord ---------------------------------