# clener
if $ARGS[0] = 'start':
	$menu_loc = 'clener'
	$menu_arg = 'start'
	menu_off = 0
	CLOSE ALL
	if sound = 0 and hour >= 8 and hour < 17:PLAY 'sound/office.mp3',30 & PLAY 'sound/office2.mp3',30
	*clr & cla
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Office building</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener.jpg"></center>'
	'You notice several ads on one of the walls. As you look through them you see a notice that someone is searching for cleaners.'

	if svQW >= 1:
		if hour >= 8 and hour <= 16 and week < 6:
			'The door to the<a href="exec:gt ''torgpred''">Trade Mission</a> is open.'
		else
			'The door of the trade mission is closed. There''s a note on the door, Open hours: Saturday and Sunday 8:00--16:00'
		end
	end

	act 'Leave': minut += 5 & gt 'street'
	
	if jouryQwNo = 1 and hour = 17:
		'You see Yuri walking down the corridor, you remember him making a move on you but you refused him. He looks at you, smiles and approaches you.'

		act 'Talk to Yuri':
			cla
			menu_off = 1
			minut += 5
			gs 'stat'
			'Still smiling he says, "<<$pcs_nickname>>, want to grab a cup of coffee?"'

			act 'Decline': jouryQwNo = 1 & gt 'clener', 'start'

			act 'Accept':
				*clr & cla
				minut += 30
				gs 'stat'
				'You nod and the two of you head off to the café, where Yuri orders coffee. You sit down at the table and begin to sip on your coffee. Yuri is painfully quiet, he has no sense of humor and is very stiff.'
				'It''s pretty clear that he likes you, but he does not know how to put a move on you. As you finish the coffee Yuri finally suggests if you want to follow him to his home.'

				act 'No': jouryQwNo = 1 & gt 'clener', 'start'

				act 'Go with Yuri': gt 'youry', 'quest'
			end
		end
	end

	if borodachQW > 0 and borodachSex = 0 and hour >= 19:'The security guard, Sasha, greets you.'
	if borodachQW > 0 and borodachSex > 0 and hour >= 19:'The security guard, Sasha, smiles and says, "Hi <<$pcs_nickname>>!"'

	if borodachQW > 0 and hour >= 19:
		act 'Approach Sasha':
			*clr & cla
			menu_off = 1
			minut += 5
			gs 'stat'

			if borodachSexDay = daystart:'You approach the security guard and greet him. You chat with him for a while. After some time Sasha tells you that he has to go on patrol and hurries off.'

			if borodachSexDay ! daystart:
				'You approach the security guard and greet him. He winks at you, "I stashed a bottle here, I''m sure we''ve both earnt a little break."'

				act 'Join him':
					cla
					minut += 5
					gs 'stat'
					'Sasha takes you to his cubbyhole and pulls out a bottle of vodka from under the table. He then reaches into a drawer and pulls out a piece of liver sausage and some cheese. He pours some of the vodka out into two glasses.'

					act 'Have a drink':
						cla
						gs 'drugs', 'alcohol', 'vodka'
						pcs_energy += 10
						fat += 2
						gs 'stat'
						'You drink the shitty vodka and it burns your throat. Your throat is on fire and you quickly grab some cheese to help soothe it. Sasha casually downs the glass and doesn''t even blink. "Ah, good one."'
						'While you are leaning over to eat the sausage, you feel a light touch as the guard pats you on the buttocks.'

						act 'Smile':
							cla
							minut += 10
							pcs_horny += 10
							gs 'drugs', 'alcohol', 'vodka'
							gs 'stat'
							'You smile and Sasha pours more vodka, not stopping his caressing of your buttocks.'

							if pcs_horny < 50: gs 'clener', 'borodachNo2'

							gs 'clener', 'borodachDrink'
						end

						gs 'willpower', 'hj', 'self'
						if will_cost <= pcs_willpwr:
							act 'Put your hand on his pants (<<will_cost>> Willpower)':
								*clr & cla
								gs 'willpower', 'pay', 'self'
								borodachTimes += 1
								gs 'stat'

								picrand = rand(0, 2)

								if picrand = 0:'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/hj.jpg"></center>'
								if picrand = 1:'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/hj1.jpg"></center>'
								if picrand = 2:'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/hj2.jpg"></center>'

								'You put your hand on his crotch and feel his erection harden. Your thin fingers slide over his hardon and find the zipper. You unzip him and get his cock out of his pants. Sasha relaxes on the couch waiting for you to continue what you started.'
								
								gs 'arousal', 'foreplay', 5
								gs 'stat'
								
								
								gs 'clener', 'ohrhj'
								gs 'clener', 'ohrbj'
							end
						else
							act 'Put your hand on his pants (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
						end
					end
				end
			end

			gs 'arousal', 'end'
			gs 'stat'
							
			act 'Leave':gt 'clener', 'start'
		end
	end

	if clenerT >= 3 and borodachQW = 0 and hour >= 19:
		'You see a crossword placed on a chair in front of the guard as he''s deeply sighs. He looks up to you and asks, "I''m looking for another word for pleasure, the second letter is u."'

		act 'Reply':
			*clr & cla
			menu_off = 1
			borodachQW = 1
			'"Fulfilment?" you reply.'
			'The guard smiles, "You''re right, the only word that came up in my head was fucking."'

			act 'Leave':gt 'clener', 'start'

			act 'Laugh out loud':
				cla
				borodachQW = 2
				'You laugh at him, he smiles and puts aside the crossword. "You must be new, I haven''t seen you before. Are you the new cleaning lady?"'
				'You nod, "Yes, the pay is pretty bad but I need the job..."'
				'"By the way, I''m Sasha, and you''re?"'
				'"<<$pcs_nickname>>." you politely answer.'
				'"Nice name... I was just thinking about heading on a break, would you like to join me for a drink?"'

				gs 'willpower', 'drink', 'resist'
				if will_cost <= pcs_willpwr:
					act 'Sorry, I have to go (<<will_cost>> Willpower)': gs 'willpower', 'pay', 'resist' & gt 'clener', 'start'
				else
					act 'Sorry, I have to go (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
				end

				act 'Why not':
					cla
					minut += 5
					gs 'stat'
					'Sasha takes you into his cubbyhole and takes out a bottle of vodka from under the table, at the same he reaches into the drawer and pulls out a piece of liver sausage and some cheese. He pours some of the vodka out into two glasses.'

					act 'Have a drink':
						cla
						gs 'drugs', 'alcohol', 'vodka'
						pcs_energy += 10
						fat += 2
						gs 'stat'
						'You drink the shitty vodka and it burns your throat. Your throat is on fire and you quickly grab some cheese to help soothe it. Sasha casually downs the glass and doesn''t even blink. "Ah, good one."'
						'While you are leaning over to eat the sausage, you feel a light touch as the guard pats you on the buttocks.'

						gs 'willpower', 'foreplay', 'self'
						if will_cost <= pcs_willpwr:
							act 'React (<<will_cost>> Willpower)':
								cla
								gs 'willpower', 'pay', 'self'
								minut += 10
								pcs_horny += 10
								gs 'stat'
								'"Hey! What are you doing?" you ask.'
								'"Relax, it was merely an accident." Sasha starts muttering as he pours another shot, "Let''s have a drink."'

								if pcs_horny < 50: gs 'clener', 'borodachNo'

								gs 'clener', 'borodachDrink'
							end
						else
							act 'React (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
						end

						act 'Pretend not to notice':
							cla
							minut += 10
							pcs_horny += 15
							gs 'stat'
							'You continue on as usual, trying not to pay attention to it, since it was only a casual touch. Sasha pours more vodka and says, "The second shot always tastes better." as he takes another quaff.'
							if pcs_horny < 50: gs 'clener', 'borodachNo'
							gs 'clener', 'borodachDrink'
						end
					end
				end
			end
		end
	end

	if clener >= 10 and clenerT = 0:
		act 'Ask for more work':
			cla
			menu_off = 1
			'You ask Boris Ivanovich whether he has more work for you. He says that he needs a cleaner to clean the toilets. You''ll be almost able to work every day. Cleaning toilets for an hour earns you 65 <b>₽</b> upfront.'

			act 'Refuse and leave': minut += 5 & gt 'street'

			act 'Accept':
				cla
				clenerT = 1
				'You agree to work as a cleaner.'

				act 'Leave':gt 'clener', 'start'
			end
		end
	end

	if clener = 1:
		act 'Ask about available jobs':
			cla
			menu_off = 1
			'You head into the office that advertised the job. You see a large man in a jacket sitting there. He tells you can clean the Office for 65 <b>₽</b> per hour, payed upfront.'

			act 'Refuse and leave': minut += 5 & gt 'street'

			act 'Accept':
				cla
				clener = 2
				'You agree to work as a cleaner.'

				act 'Leave': gt 'clener', 'start'
			end
		end
	end

	if clener > 1 and clenday ! daystart:
		act 'Mop the floor in the office for 65 <b>₽</b> (1:00)':
			*clr & cla
			menu_off = 1
			clenday = daystart
			minut += 60
			clener += 1
			pcs_mood -= 15
			money += 65
			gs 'sweat', 'add', 20
			'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener1.jpg"></center>'

			if clener < 5:
				if hour >= 9 and hour <= 16: 'You fill a bucket of water and head over to the office with a mop. The office staff keeps out of the way while you clean the floor.'
			elseif clener >= 5 and clener < 10:
				if hour >= 9 and hour <= 16:
					jouryQw += 1
					'You fill a bucket of water and head over to the office with a mop. The office staff keeps out of the way while you clean the floor. One of the office workers, a man with blond hair and a red face looks at you and tries to hide it, but you can feel his burning gaze.'
				end
			elseif clener >= 10:
				if hour >= 9 and hour <= 16 and jouryQw < 7:
					jouryQw += 1
					'You fill a bucket of water and head over  to the office with a mop. The office staff keeps out of the way while you clean the floor. One of the office workers, a man with blond hair and a red face looks at you and tries to hide it, but you can feel his burning gaze.'
				elseif jouryQw = 7 and hour >= 9 and hour <= 16:
					*clr & cla
					gs 'stat'
					jouryQw += 1
					'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener1.jpg"></center>'
					'You fill a bucket of water and head over to the office with a mop. All the staff are out of the office, except for a red faced blond man. He walks up to you visibly nervous and quietly says, "Hi. My name Yuri. And I think I''m in love with you... Can we meet and do something after work?"'

					act 'No':
						cla
						jouryQwNo = 1
						'You look angrily at him, "No, I don''t mix business with pleasure..." Yuri looks dejected as he moves away from you.'
						'As you''ve finished, you head over to Boris Ivanovich''s office. He gives you 65 <b>₽</b> for the work.'

						act 'Leave': gt 'clener', 'start'
					end

					act 'Yes':
						cla
						minut += 15
						gs 'stat'
						'You smile and nod. Yuri says that he''s just about to finish and will meet you at the entrance of the building.'
						'As you''ve finished, you head over to Boris Ivanovich''s office. He gives you 65 <b>₽</b> for the work.'
						'As you leave, you notice Yuri awiting you. He''s pretty nervous and it seems as if he doesn''t know what to do. Not knowing what to say, he blurts out, "How about we head over to my place, watch some movies, drink champagne and talk."'

						act 'No': jouryQwNo = 1 & gt 'clener', 'start'

						act 'Go with Yuri': gt 'youry', 'quest'
					end

					exit
				end

				if jouryQw > 7 and hour >= 9 and hour <= 16 and jourySex = 0: 'You fill a bucket of water and head over to the office with a mop. The office staff keeps out of the way while you clean the floor. Yuri looks at you studying every inch of your figure.'
				if jouryQw > 7 and hour >= 9 and hour <= 16 and jourySex > 0: 'You fill a bucket of water and head over to the office with a mop. The office staff keeps out of the way while you clean the floor. Yuri pretends not to notice you in the office.'
			end

			if hour < 9 or hour > 16: 'The office is empty of people, you quietly wash the floor and wipe the floor in the office.'

			'As you''ve finished, you head over to Boris Ivanovich''s office. He gives you 65 <b>₽</b> for the work.'

			act 'Leave':gt 'clener', 'start'
		end
	end

	if clenerT >= 1 and clendayT ! daystart:
		act 'Clean toilets for 65 <b>₽</b> (1:00)':
			*clr & cla
			menu_off = 1
			clendayT = daystart
			minut += 60
			clenerT += 1
			pcs_mood -= 25
			money += 65
			gs 'sweat', 'add', 30
			'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener2.jpg"></center>'

			if jouryQw > 7 and hour >= 9 and hour <= 16 and jourySex > 0 and jouryResult = 0:
				'You enter a booth and begin scrubbing the toilet bowl. The toilet door slams as somebody comes in, you turn around and see Yuri standing there. He, quickly comes over to you, "<<$pcs_nickname>>, don''t approach me at the office, well, you know, I don''t want the rest of the office to gossip about me seeing the cleaner."'

				act 'You''re ashamed of me?':
					cla
					'You let go off your cleaning stuff and look straight into Yuri''s eyes, asking him, "Are you ashamed of me?"'
					'Yuri stammers, "I-I''m not embarrassed by you being a cleaner, but you must understand, I''m a manager, and you''re the cleaning lady. We must not be seen together. But I want you to keep seeing you. You know where I live, come by my place after 16:00."'

					gs 'willpower', 'misc', 'self'
					if will_cost <= pcs_willpwr:
						act 'Fuck you (<<will_cost>> Willpower)':
							cla
							gs 'willpower', 'pay', 'self'
							jouryResult = 1
							'You''re offended by his behaviour and without any hesitation you tell Yuri to go to hell. He quickly turns and walks away.'
							'You continue on by mopping the floor and polish the toilets and urinals. You are given 65 <b>₽</b> for your work.'

							act 'Leave':gt 'clener', 'start'
						end
					else
						act 'Fuck you (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
					end

					act 'Okay.':
						cla
						jouryResult = 10
						'Yuri only sees you as a simple fuck whore. But you''re willing to put up with it and agree to visit him afterwards. Yuri nods in satisfaction and leaves the toilet.'
						'You continue on by mopping the floor and polish the toilets and urinals. You are given 65 <b>₽</b> for your work.'

						act 'Leave':gt 'clener', 'start'
					end
				end

				exit
			end

			if StasikValera > 0 and SVqw = 0:
				'You clean the toilet and all of a sudden you hear the toilet door as someone walks in, as you turn around you see a man. To your surprise, it is Stasik, with him is his friend Valera that you''ve met at the beach. Stasik also apparently recognizes you, walking up to you, "Hi <<$pcs_nickname>>, you work here as a cleaner?"'

				act 'Explain':
					*clr & cla
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener2.jpg"></center>'
					'Shrugging, you say, "I need the money. So I''ll do whatever it takes."'
					'Stasik smiles, "Well, an attractive girl as you shouldn''t work a job like this, I can find a decent part-time job instead."'

					act 'Further':
						*clr & cla
						SVqw = 1
						gs 'stat'
						'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener2.jpg"></center>'
						'You ask him about the details. Stasik tells you, "It''s very simple. In the northern, central and residential areas there are supermarkets. You come to our office to find out what your assignment is, then you visit all the three stores and arrange our products there, making changes according to the assignment. At the checkout you take a receipt confirming that you''ve been to work."' 
						'"Afterwards, you head back to our office and we will pay you. How does 500 <b>₽</b> sound for a few hours work? No hard labour, what do you say?"'

						act 'Not interested':gt 'clener', 'start'

						act 'Accept':
							*clr & cla
							SVqw = 2
							gs 'stat'
							'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener2.jpg"></center>'
							'You grin and nod acceptingly, Stas nods confirming the deal, and after that walks out of the toilet.'

							act 'Leave':gt 'clener', 'start'
						end
					end
				end

				exit
			end

			'You wash the floor and polish all the booths and urinals. You are given 65 <b>₽</b> for your work.'

			act 'Leave':gt 'clener', 'start'
		end
	end
end

if $ARGS[0] = 'borodachNo':
	menu_off = 1
	act 'I''ve had enough':
		cla
		minut += 5
		gs 'stat'
		'You refuse to drink and start to leave. The guard tries to persuade you to stay with him and continue.'

		gs 'willpower', 'drink', 'resist'
		if will_cost <= pcs_willpwr:
			act 'Leave (<<will_cost>> Willpower)': gs 'willpower', 'pay', 'resist' & gt 'clener', 'start'
		else
			act 'Leave (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
		gs 'clener', 'borodachDrink'
	end
end

if $ARGS[0] = 'borodachNo2':
	menu_off = 1
	act 'I have to go now':
		cla
		minut += 5
		gs 'stat'
		'You gather your things and start to leave, Sasha tries to persuade you to stay with him and continue.'

		gs 'willpower', 'sex', 'resist', 'easy'
		if will_cost <= pcs_willpwr:
			act 'Leave (<<will_cost>> Willpower)': gs 'willpower', 'pay', 'resist' & gt 'clener', 'start'
		else
			act 'Leave (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
		gs 'clener', 'borodachSex'
	end
end

if $ARGS[0] = 'borodachDrink':
	menu_off = 1
	act 'Another drink':
		cla
		minut += 15
		pcs_horny += 20
		gs 'stat'
		'You drink and eat some more cheese, you realize that you are happily drunk. The guard''s hand does not stop caressing your ass.'
		gs 'clener', 'borodachNo2'
		gs 'clener', 'borodachSex'
	end
end

if $ARGS[0] = 'borodachSex':
	menu_off = 1
	act 'Relax':
		cla

		if borodachSex = 0:borodachSex = 1 & guy += 1
		'You calm down and begin to enjoy the hands caressing you. Sasha has openly embraced and started kissing you.'
		'His hands slide under your clothes, unbuttoning and removing them. Soon he has exposed your chest and begins to suck your nipples.'

		gs 'arousal', 'foreplay', 5 
		gs 'stat'
		
		act 'Lie down on the sofa':
			*clr & cla
			gs 'stat'
			borodachSexDay = daystart
			pose = 0
			gs 'boyStat', 'A39'
			'<center><img <<$set_imgh>> src="images/shared/sex/vag/miss/vag.jpg"></center>'
			'<<$boydesc>> lays you on the sofa, spreads your legs and pulls out his <<dick>> cm dick, his fingers begin to caress your pussy, preparing it for entry.'
			
			gs 'dinsex', 'boy_puts_condom'
			gs 'arousal', 'vaginal_finger', 5
			gs 'dinsex', 'vaginal_sex', 15
			gs 'dinsex', 'sexcum'
			gs 'arousal', 'end'
			gs 'stat'

			act 'Leave':gt 'street'
		end
	end
end

if $ARGS[0] = 'ohrhj':
	menu_off = 1
	act 'Masturbate him':
		cla
		'You start stroking his cock with your delicate hands. Quickly Sasha groans, "I can''t hold on much longer."'
		
		gs 'arousal', 'hj', 5, 'dom'
		gs 'stat'
		
		gs 'clener', 'ohrbj'
		gs 'clener', 'ohrhjcum'
		gs 'clener', 'ohrsex'
	end
end

if $ARGS[0] = 'ohrhjcum':
	menu_off = 1
	act 'Masturbate him more':
		*clr & cla
		borodachSexDay = daystart
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/hjcum.jpg"></center>'
		'Sasha groans and his cock enthusiastically paints your hand white.'

		gs 'arousal', 'hj', 5, 'dom'
		gs 'stat'
		
		act 'Leave':gt 'street'
	end
end

if $ARGS[0] = 'ohrbj':
	menu_off = 1
	act 'Suck him':
		*clr & cla
		picrand = rand(1, 4)
		'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/bj<<picrand>>.jpg"></center>'

		'You wrap your <<$liptalk>> around his strong and warm 15 cm cock and quickly begin by sucking the head, caressing it with your tongue and lips. Sasha groans, "I''m going to come."'
		
		gs 'arousal', 'bj', 5, 'sub'
		gs 'stat'
		
		gs 'clener', 'ohrbjcum'
		gs 'clener', 'ohrsex'
	end
end

if $ARGS[0] = 'ohrbjcum':
	menu_off = 1
	act 'Suck harder':
		*clr & cla
		spafinloc = 12
		gs 'cum_manage'
		gs 'stat'
		picrand = rand(1, 4)
		'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/bjcum<<picrand>>.jpg"></center>'
		'You redouble your efforts, sucking his hard cock with your <<$liptalk>>. Hot sperm hits your mouth, again and again. You continue to suck, ignoring your mouth full of viscous sperm. Until he finally nothing left.'
		
		gs 'arousal', 'bj', 5, 'sub'
		gs 'stat'

		act 'Swallow sperm':
			*clr & cla
			borodachSexDay = daystart
			gs 'stat'
			picrand = rand(1, 3)
			'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/swallow<<picrand>>.jpg"></center>'
			'You open your sperm filled mouth and show off your hard work, then swallow it.'

			gs 'arousal', 'bj', 1, 'sub'
			gs 'arousal', 'end'
			gs 'stat'
		
			act 'Leave':gt 'street'
		end

		act 'Spit it out':
			*clr & cla
			borodachSexDay = daystart
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/residential/office/sex/guard/spit.jpg"></center>'
			'You open your sperm filled mouth and show off your hard work, then quickly find the sink and spit it out.'

			gs 'arousal', 'bj', 1, 'sub'
			gs 'arousal', 'end'
			gs 'stat'
			
			act 'Leave':gt 'street'
		end
	end
end

if $ARGS[0] = 'ohrsex':
	menu_off = 1
	act 'Sex':
		*clr & cla
		gs 'stat'
		borodachSexDay = daystart
		pose = 0
		gs 'boyStat', 'A39'
		'<center><img <<$set_imgh>> src="images/shared/sex/vag/miss/vag.jpg"></center>'
		'<<$boydesc>> lays you on the sofa, spreads your legs and pulls out his <<dick>> centimeter dick. His fingers begin to caress your pussy, preparing it for entry.'

		gs 'arousal', 'vaginal_finger', 5
		gs 'arousal', 'vaginal', 15, 'sub'
		gs 'arousal', 'end'
		gs 'stat'
			
		act 'Leave':gt 'street'
	end
end
--- clener ---------------------------------