# pharmacy

if $ARGS[0] = 'start':
	*clr & cla
	menu_off = 1
	minut += 5
	gs 'stat' & ! Update the information about the past tense
	!a time limit of work pharmacies in Pavlovo
	people = rand(1,15) & !We define the size of the queue in the pharmacy
	if people <= 5:
		*pl '<center><b><font color="maroon">Pharmacy</font></b></center>'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/pharmacy/aptekabusy<<people>>.jpg"></center>'
		*nl
		'When you go up to check out their is <<people>> ' + iif(people < 2 or people > 4, 'people' , 'man' ) + ' in line before you.'
		act 'Leave the pharmacy': minut += 5 & gt 'street'
		act 'Wait for your turn' :
			minut += rand(1,4) * people
			people = 0
			gs 'stat'
			gt 'pharmacy', 'shop'
		end
	else
		gt 'pharmacy', 'shop'
	end
end

if $ARGS[0] = 'shop' or $ARGS[0] = '':
	*clr & cla
	$location_type = 'public_indoors'
	$loc = 'pharmacy'
	$metka = 'shop'
	$menu_loc = 'pharmacy'
	$menu_arg = 'shop'
	menu_off = 0
	gs 'stat'
	*pl '<center><b><font color="maroon">Pharmacy</font></b></center>'
	if pharma_day ! daystart: pharma_day = daystart & pharma_picrand = rand(1,4)
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/pharmacy/apteka_worker_'+pharma_picrand+'.jpg"></center>'
	*nl
	if $message ! '':
		$message
		killvar '$message'
		'<center>"Do you need anything else?"</center>'
	else
		'<center>Their is a young woman behind the counter in a white coat,as you approach she asks. "Hello, what can I help you with?"</center>'
	end

	act 'Leave the pharmacy': minut += 5 & gt 'street'

	!! output for purchased item
	iif($ARGS[1] = '', '', '<center><<$ARGS[1]>></center>')
	*nl
	*pl '<center><table align="center" width=80%>'
	if preziktype = 0: *P func ('$stock_item', 5, 'Condoms', 500, 'prezik', $curloc, $ARGS[0])
	if preziktype = 1 or preziktype = 2: *P func ('$stock_item', 5, 'Condoms', 500, 'prezikcount', $curloc, $ARGS[0])
	*P func ('$stock_item', 1, 'Pregnancy test', 530, 'pregtest', $curloc, $ARGS[0])
	*P func ('$stock_item', 1, 'Birth control pills', 1870, 'tabletki', $curloc, $ARGS[0])
	*P func ('$stock_item', 10, 'Antibiotics', 580, 'lekarstvo', $curloc, $ARGS[0])
	*P func ('$stock_item', 30, 'Vitamins', 130, 'vitamin', $curloc, $ARGS[0])
	*P func ('$stock_item', 50, 'Painkillers', 435, 'painkiller', $curloc, $ARGS[0])
	*P func ('$stock_item', 10, 'Ointments for chafing', 372, 'mosolmaz', $curloc, $ARGS[0])
	*P func ('$stock_item', 20, 'Lubricant', 145, 'lubri', $curloc, $ARGS[0])
	!!tube of 5 uses as far as I can tell, price is set to that
	*P func ('$stock_item', 30, 'Lip balm', 127, 'lipbalm', $curloc, $ARGS[0])
	*P func ('$stock_item', 12, 'Weight loss pill', 248, 'fatdel', $curloc, $ARGS[0])
	*P func ('$stock_item', 20, 'Tampons', 200, 'tampon', $curloc, $ARGS[0])
	*P func ('$stock_item', 20, 'Sanitary napkins', 100, 'sanpad', $curloc, $ARGS[0])
	*P func ('$single_stock_item', 1, 'Enema kit', 1250, 'klisma', $curloc, $ARGS[0])
	*P func ('$single_stock_item', 1, 'Breast pump', 2200, 'breastpump', $curloc, $ARGS[0])
	*P func ('$stock_item', 3, 'Breastmilk bottle S', 930, 'bpbottles', $curloc, $ARGS[0])
	*P func ('$stock_item', 2, 'Breastmilk bottle M', 930, 'bpbottlem', $curloc, $ARGS[0])
	if pcs_knows_nipplecream > 0:
		*P func ('$stock_item', 20, 'Nipplebalm', 600, 'bpnipplebalm', $curloc, $ARGS[0])
	end
	if KandidNapr = 1: *P func ('$single_stock_item', 1, 'Antifungal medication', 1050, 'Kandidoz', $curloc, $ARGS[0], StoryLine, '(you have 0)',''+iif(money >= 1050,'<a href="exec:gs ''pharmacy'', ''buy_antifungal''">buy</a>','')+'')
	*P '</table></center>'
end

if $ARGS[0] = 'buy_antifungal':
	if Kandidoz >= 30:
		money -= 1050
		Kandidoz = 0
		gs 'stat'
		$gardmess = '<center><font color="green">You bought 1 <b>Antifungal medication</b>.</font></center><br>You put the money on the counter and immediately open the package and swallow the tablet. A while later, you feel better.'
		gt 'pharmacy', 'shop'
	elseif Kandidoz < 30 and KandidozOnce > 0:
		'You don''t need the medication right now. Your thrush is currently in remission, taking vitamins will ensure that it stays that way.'
	else
		msg '<center>You don''t need any antifungal medication right now.</center>'
		*nl
		gt 'pharmacy', 'shop'
	end
end

--- pharmacy ---------------------------------