# traits

if $ARGS[0] = 'menu':
	*clr & cla
	gs 'obj_din', 'chartabs'
	'<center><h1>Traits</h1></center>'
	'<center><table cellspacing="0" cellpadding="20" valign="top"><tr>'
	'<td>'
	'<center><b>Bimbo</b></center>'
	if bimbolevel = 0:
		'You do not have this trait.'
		'To gain this trait you must wear bimbo clothing / shoes for a few days.'
		'You have <<bimbo>> out of 10 points towards level 1.'
	elseif bimbolevel = 1:
		'You have this trait at level 1.'
		'To maintain this trait you must wear bimbo clothing / shoes and/or have regular sex.'
		'Due to this trait you gain a very small bonus to appearance and a very small penalty to intelligence.'
		'You have <<bimbo>> out of 20 points towards level 2.'
		if bimbowithdrawal = 0:
			'You are not in withdrawal.'
		else
			'You have <<bimbowithdrawal>> out of 30 points towards losing this trait.'
		end
	elseif bimbolevel = 2:
		'You have this trait at level 2.'
		'To maintain this trait you must wear bimbo clothing / shoes and/or have regular sex.'
		'Due to this trait you gain a small bonus to appearance and a small penalty to intelligence.'
		'You have <<bimbo>> out of 30 points towards level 3.'
		if bimbowithdrawal = 0:
			'You are not in withdrawal.'
		else
			'You have <<bimbowithdrawal>> out of 30 points towards losing this trait.'
		end
	else
		'You have this trait at level 3.'
		'To maintain this trait you must wear bimbo clothing / shoes and/or have regular sex.'
		'Due to this trait you gain a moderate bonus to appearance and a moderate penalty to intelligence.'
		if bimbowithdrawal = 0:
			'You are not in withdrawal.'
		else
			'You have <<bimbowithdrawal>> out of 30 points towards losing this trait.'
		end
	end
	
	*nl
	
	'<center><b>Exhibitionist</b></center>'
	if Exhibitionist_lvl = 0 and exhib_cheat = 0:
		'You do not have this trait.'
		'To gain this trait you must have low enough inhibition and choose to expose your breasts in public.'
		'You have <<pcs_exhib>> out of 10 points towards level 1. This will slowly decrease each day unless you expose yourself.'
	elseif Exhibitionist_lvl = 1:
		'You have this trait at level 1.'
		'To increase this trait you must choose to expose your breasts and/or bare bottom in public.'
		'This trait grants you a small amount of excitement from exposing yourself.'
		'You have <<pcs_exhib>> out of 50 points towards level 2.'
	elseif Exhibitionist_lvl = 2:
		'You have this trait at level 2.'
		'To increase this trait you must choose to expose your breasts, bare bottom and/or pussy in public.'
		'This trait grants you a moderate amount of excitement from exposing yourself.'
		if pcs_exhib < 100:
			'You have <<pcs_exhib>> out of 100 points towards level 3.'
		elseif pcs_exhib >= 100 and exhibitionQW < 3:
			'You must trigger an event in the park to gain level 3.'
		elseif pcs_exhib >= 100 and exhibitionQW > 2:
			'You will have to wait until the end of the day for the trait level to update.'
		end
	else
		'You have this trait at level 3.'
		'This is the highest level of this trait.'
		'This trait grants you a large amount of excitement from exposing yourself.'
	end
	
	*nl
	
	'<center><b>Addictive Personality</b></center>'
	if addictive_trait_lvl = 0 and addictive_cheat = 0:
		'You do not have this trait.'
		'To gain this trait you have to use 2 different types of drugs several times. At the moment you have <<addictive_exp>> out of 2 points towards level 1.'
	elseif addictive_trait_lvl = 1:
		'You have this trait at level 1.'
		'You have some experience with taking drugs and it becomes harder for you to refuse to take them.'
		'To increase this trait you have to use 3 different types of drugs several times. At the moment you have <<addictive_exp>> out of 3 points towards level 2.'
	elseif addictive_trait_lvl = 2:
		'You have this trait at level 2.'
		'Taking drugs has become something normal and that makes it even harder for you to refuse to take them.'
		'To increase this trait you have to use 4 different types of drugs several times. At the moment you have <<addictive_exp>> out of 4 points towards level 3.'
	elseif addictive_trait_lvl = 3:
		'You have this trait at level 3.'
		'Taking drugs is a normal part of your life which makes it difficult for you to refuse to take them.'
		'This is the highest level of this trait.'
	end
	
	*nl
	
	'<center><b>Cumeater</b></center>'
	if trt_cumeater = 0 and cumeater_cheat = 0:
		'You do not have this trait.'
		'To gain this trait you must swallow cum 10 times.'
		'You have swallowed cum <<swallow>> times.'
	elseif trt_cumeater = 0 and cumeater_cheat = 1:
		'You do not have this trait.'
	else
		'You have this trait.'
		'It allows you to remove cum from certain locations and eat it'
		'This trait cannot be lost.'
	end
	
	*nl
	
	if alko_trait = -1:
		'<center><b>Lightweight</b></center>'
		'It doesn''t take much for you to get drunk. You don''t have to drink as much to feel the affects of alcohol.'
	elseif alko_trait = 1:
		'<center><b>Heavyweight</b></center>'
		'You''ve built up a tolerance, making it harder for you to feel the affects of alcohol.'
	end

	act 'Exit the menu': gt $loc, $metka
	'</td></tr></table></center>'
end

if $ARGS[0] = 'hourly':
	if swallow >= 10 and trt_cumeater = 0 and cumeater_cheat = 0:
		trt_cumeater = 1
		msg 'You have gained the trait "Cumeater"'
	end
end

if $ARGS[0] = 'overnight':
	!!alko_trait: light weight (-1), normal (0), heavy weight (+1)
	!!alko_trait_counter: between -100 and 100, tracks if sveta is a light or heavy wight
	!!alko_trait_day: amount of alko sveta has drunk today
	
	!!Gains/Decay
	if alko_trait_day > 0:
		if alko_trait_day > 9:
			alko_trait_counter += 9
		else
			alko_trait_counter += alko_trait_day
		end
	elseif alko_trait_day = 0:
		alko_trait_counter -= 2
	end
	
	!!Trait selection
	if alko_trait_counter > 50 and alko_trait < 1:
		alko_trait = 1
		msg 'You have gained the trait ''Heavyweight''.'
	elseif alko_trait_counter < -50 and alko_trait > -1:
		alko_trait = -1	
		msg 'You have gained the trait ''Lightweight''.'
	elseif alko_trait = -1 and alko_trait_counter > 0:
		alko_trait = 0
		msg 'You have lost the trait ''Lightweight''.'
	elseif alko_trait = 1 and alko_trait_counter < 0:
		alko_trait = 0
		msg 'You have lost the trait ''Heavyweight''.'
	end
	
	!!Cleanup
	alko_trait_day = 0
	if alko_trait_counter > 100: 
		alko_trait_counter = 100
	elseif alko_trait_counter < -100: 
		alko_trait_counter = -100
	end
end

if $ARGS[0] = 'addictive_personality':
	!!Addictive Personality Trait
	if addictive_cheat = 0:
		addictive_exp = smoke_exp + joint_exp + heroin_exp + cocaine_exp + alcohol_exp + amphetamine_exp

		if addictive_exp = 2 and addictive_trait_lvl < 1:
			addictive_trait_lvl = 1
			if add_trait_msg_1 = 0: add_trait_msg_1 = 1 & msg 'You have gained the trait ''Addictive Personality''.'
		elseif addictive_exp = 3 and addictive_trait_lvl < 2:
			addictive_trait_lvl = 2
			if add_trait_msg_2 = 0: add_trait_msg_2 = 1 & msg 'You have increased the level of your ''Addictive Personality'' trait to 2.'
		elseif addictive_exp >= 4 or (heroin_exp = 1 and cocaine_exp = 1) and addictive_trait_lvl < 3:
			addictive_trait_lvl = 3
			if add_trait_msg_3 = 0: add_trait_msg_3 = 1 & msg 'You have increased the level of your ''Addictive Personality'' trait to 3.'
		end
	end
end

--- traits ---------------------------------