# booty_call_sms

!=====   Reply example here ==================================================================================!

!	gs 'SMStext_builder', 'add_reply', [$text], [$location], [$args0], [$args1], [$args2], ...
!	examples:
!		gs 'SMStext_builder', 'add_reply', 'No, I do''t want to come over', 'booty_call_sms', 'Choice_a', $ARGS[1], $ARGS[2]
!		gs 'SMStext_builder', 'add_reply', 'Good luck!', 'band_tour_anushka_SMS', 'Week1', 'Choice_a'

!=============================================================================================================!


!=====   Adding Images to SMS ================================================================================!

!	You can add images at the end of the text by using:
!		gs 'SMStext_builder', 'add_end_img', [$imagepath]
!	Up to 4 images can be added this way.

!	You can also always add a picture to the text, scaling is an issue though:
!		gs 'SMStext_builder', 'send_img', [$imagepath], [$alt_text]
!	alt_text is an optional variable which displays the alternative text if the image does not load.
!	examples:
!		gs 'SMStext_builder', 'send_img', 'images/characters/shared/headshots_main/144.jpg', 'Anushka''s Face'

!=============================================================================================================!




if $ARGS[0] = 'start':
	$booty_call_daily_id[i] = $ARGS[1]

	if npc_booty_call[$ARGS[1]] = daystart:
		gs 'booty_call_sms', 'Add SMS2', 'pre_planned_booty_call', $ARGS[1]
	elseif sugar_daddy_call[$ARGS[1]] = 1:
		gs 'booty_call_sms', 'Add SMS', 'sugar_daddy_booty_call', $ARGS[1]
		!gs 'booty_call_sms', 'Add SMS3', 'new_booty_call', $ARGS[1]
	elseif npc_std_test[$ARGS[1]] = 1:
		gs 'booty_call_sms', 'Add SMS', 'std_free', $ARGS[1]
	else
		gs 'booty_call_sms', 'Add SMS', 'default_booty_call', $ARGS[1]
		!gs 'booty_call_sms', 'Add SMS3', 'new_booty_call', $ARGS[1]
	end
end




	!!===============================================================!!
	!!                                                               !!
	!!                            SMSTREE                            !!
	!!                                                               !!
	!!===============================================================!!


if $ARGS[0] = 'default_booty_call':
!!	Structure:
!!		0: boy
!!			1: player
!!				2: boy
!!					a3: player - 1st reply, choice A
!!						a4: boy
!!							aa5: player - 2nd reply, choice A: decline booty call
!!								aa6: boy
!!							ab5: player - 2nd reply, choice B: accept booty call
!!								ab6: boy
!!					b3: player - 1st reply, choice B
!!						b4: boy
!!							ba5: player - 2nd reply, choice A: decline booty call
!!								ba6: boy
!!							bb5: player - 2nd reply, choice B: accept booty call
!!								bb6: boy


		!! boy
	$SMSTree['0'] = dyneval('$result=''hey <<$pcs_nickname>>'' ')
			!! player
		$SMSTree['1'] = dyneval('$result=''hey <<$npc_nickname[$ARGS[1]]>>'' ')
				!! boy
			$SMSTree['2'] = 'ive been thinking about you'

					!! player response 1 option 1
				$SMSTree['a3'] = 'what were you thinking about?'
						!! boy response 1
					if npc_finance[$ARGS[1]] = 2 and func('homes_properties_attr', 'get_property_attribute', '$town', $home['current']) ! 'city' and npc_residence[$ARGS[1]] >= 3:
						$SMSTree['a4'] = 'i booked a hotel room in Pav. why dont you come by?'
					else
						if $npc_fav_pos[$ARGS[1]] = 'blowjob' and rand(0, 2) = 0:
							$SMSTree['a4'] = 'your mouth around my cock'
						elseif npc_know_virgin[$ARGS[1]] ! 1:
							if $npc_cum_pref[$ARGS[1]] = 'creampie' and (npc_condom_conscious[$ARGS[1]] = 0 or npc_bareback[$ARGS[1]] = 1) and rand(0, 2) = 0:
								$SMSTree['a4'] = 'your pussy filled with my cum'
							elseif npc_sex_speed[$ARGS[1]] = 3 and rand(0, 2) = 0:
								$SMSTree['a4'] = 'fucking you bowlegged'
							elseif $npc_cum_pref[$ARGS[1]] = 'facial' and rand(0, 2) = 0:
								$SMSTree['a4'] = 'your pretty face covered in my cum'
							elseif $npc_cum_pref[$ARGS[1]] = 'mouth' and rand(0, 2) = 0:
								$SMSTree['a4'] = 'watching you swallow my cum'
							elseif $npc_cum_pref[$ARGS[1]] = 'tits' and rand(0, 2) = 0:
								$SMSTree['a4'] = 'my cum all over your tits'
							elseif $npc_fav_pos[$ARGS[1]] = 'doggy' and rand(0, 2) = 0:
								$SMSTree['a4'] = 'pounding you on all fours'
							elseif $npc_fav_pos[$ARGS[1]] = 'cowgirl' and rand(0, 2) = 0:
								$SMSTree['a4'] = 'you riding my cock like crazy'
							else
								if rand(0, 1) = 0:
									$SMSTree['a4'] = 'you naked on my bed'
								else
									$SMSTree['a4'] = 'want to come over and have some fun?'
								end
							end
						end
					end

									!! player response 2 option 1
							if hour < 21:
								$SMSTree['aa5'] = 'sorry, i cant. i have stuff to do'
							else
								$SMSTree['aa5'] = 'its late. text me sooner if you want me to come over.'
							end
										!! boy response 2 option 1
									$SMSTree['aa6'] = 'shit, maybe next time then'

									!! player response 2 option 2
								$SMSTree['ab5'] = 'ill come right now ;)'
										!! boy response 2 option 1
									if npc_humor[$ARGS[1]] <= 1 and rand(0,1) = 0:
										$SMSTRee['ab6'] = 'im already hard'
									elseif npc_humor[$ARGS[1]] = 2 and rand(0,1) = 0:
										if rand(0,1) = 1:
											$SMSTRee['ab6'] = 'in the street?? damn! keep it in your pants till you get here!'
										else
											$SMSTRee['ab6'] = 'as long as you make me cum later'
										end
									elseif npc_humor[$ARGS[1]] = 3 and rand(0, 1) = 0:
										$SMSTRee['ab6'] = 'phrasing'
									else
										$SMSTRee['ab6'] = 'cant wait'
									end


					!! player response 1 option 2
				$SMSTree['b3'] = 'me too'
						!! boy response 2
					if npc_finance[$ARGS[1]] = 2 and func('homes_properties_attr', 'get_property_attribute', '$town', $home['current']) ! 'city' and npc_residence[$ARGS[1]] >= 3: 
						$SMSTree['b4'] = 'i booked a hotel room in Pav. why dont you come by?'
					else
						if $npc_fav_pos[$ARGS[1]] = 'blowjob' and rand(0, 2) = 0:
							$SMSTree['b4'] = 'i want to feel your mouth around my cock'
						elseif npc_know_virgin[$ARGS[1]] ! 1:
							if $npc_cum_pref[$ARGS[1]] = 'creampie' and (npc_condom_conscious[$ARGS[1]] = 0 or npc_bareback[$ARGS[1]] = 1) and rand(0, 2) = 0:
								$SMSTree['b4'] = 'i want to pump you full of cum'
							elseif npc_sex_speed[$ARGS[1]] = 3 and rand(0, 2) = 0:
								$SMSTree['b4'] = 'come over i want to hear you screaming my name'
							elseif $npc_cum_pref[$ARGS[1]] = 'facial' and rand(0, 2) = 0:
								$SMSTree['b4'] = 'i want to cum all over your face'
							elseif $npc_cum_pref[$ARGS[1]] = 'mouth' and rand(0, 2) = 0:
								$SMSTree['b4'] = 'i want to watch you swallow my cum'
							elseif $npc_cum_pref[$ARGS[1]] = 'tits' and rand(0, 2) = 0:
								$SMSTree['b4'] = 'let me glaze your tits with my cum'
							elseif $npc_fav_pos[$ARGS[1]] = 'doggy' and rand(0, 2) = 0:
								$SMSTree['b4'] = 'i want to pound you on all fours'
							elseif $npc_fav_pos[$ARGS[1]] = 'cowgirl' and rand(0, 2) = 0:
								$SMSTree['b4'] = 'i want you to ride my cock like theres no tomorrow'
							else
								if rand(0, 1) = 0:
									$SMSTree['b4'] = 'lets fuck like bunnies today'
								else
									$SMSTree['b4'] = 'come over lets have some fun today'
								end
							end
						end
					end

								!! player response 2 option 1
							$SMSTree['ba5'] = $SMSTree['aa5']
									!! boy response 2 option 1
								$SMSTree['ba6'] = $SMSTree['aa6']
								!! player response 2 option 2
							$SMSTree['bb5'] = $SMSTree['ab5']
									!! boy response 2 option 2
								$SMSTree['bb6'] = $SMSTree['ab6']
end


if $ARGS[0] = 'pre_planned_booty_call':
!!	Structure:
!!		0: boy
!!			a1: player - 1st reply, choice A: cancel booty call
!!			b1: player - 1st reply, choice B
!!				b2: boy
!!					ba3: player - 2nd reply, choice A: cancel booty call
!!						ba4: boy
!!					bb3: player - 2nd reply, choice B: confirm booty call
!!						bb4: boy


		!! boy
	$SMSTree['0'] = 'hey <<$pcs_nickname>>, you coming over?'
			!! player choice 1 option 1
		$SMSTree['a1'] = 'sorry, something came up'
			!! player choice 1 option 2
		$SMSTree['b1'] = 'on my way now'

				! boy
			temp_rand = rand(0, 2)
			if temp_rand = 0:
				$SMSTree['b2'] = 'come over to my place lets fuck like bunnies'
			elseif temp_rand = 1:
				$SMSTree['b2'] = 'come over to my place i want to hear you screaming my name'
			else
				$SMSTree['b2'] = 'come over to my place lets have some fun today'
			end
			killvar 'temp_rand'

				! player choice 2 option 1
				$SMSTree['ba3'] = 'sorry, i cant. i have stuff to do'
					! boy
					$SMSTree['ba4'] = 'shit, maybe next time then'


				! player choice 2 opiton 2
				$SMSTree['bb3'] = 'ill come right now ;)'

					! boy
					if npc_humor[$ARGS[1]] <= 1:
						$SMSTree['bb4'] = 'im already hard'
					elseif npc_humor[$ARGS[1]] = 2:
						if rand(0,1) = 1:
							$SMSTree['bb4'] = 'in the street?? damn! keep it in your pants till you get here!'
						else
							$SMSTree['bb4'] = 'as long as you make me cum later'
						end
					elseif npc_humor[$ARGS[1]] = 3:
						if rand(0,1) = 1:
							$SMSTree['bb4'] = 'phrasing'
						else
							$SMSTree['bb4'] = 'as long as you make me cum later'
						end
					end
end


if $ARGS[0] = 'std_free':
!!	Structure:
!!		0: boy
!!			1: player
!!				2: boy
!!					a3: player - 1st reply, choice A
!!						a4: boy
!!							aa5: player - 2nd reply, choice A: decline booty call
!!								aa6: boy
!!							ab5: player - 2nd reply, choice B: accept booty call
!!								ab6: boy
!!					b3: player - 1st reply, choice B
!!						b4: boy
!!							ba5: player - 2nd reply, choice A: decline booty call
!!								ba6: boy
!!							bb5: player - 2nd reply, choice B: accept booty call
!!								bb6: boy

		!! boy
	$SMSTree['0'] = 'hey <<$pcs_nickname>>'
			!! player
		$SMSTree['1'] = 'hey <<$npc_nickname[$ARGS[1]]>>'
				!! boy
			$SMSTree['2'] = 'got some good news'
					!! player response 1 option 1
				$SMSTree['a3'] = 'oh?'
						!! boy response 1
					$SMSTree['a4'] = 'my std test came back clean. why dont we celebrate tog'
							!! player response 2 option 1
						if hour < 21:
							$SMSTree['aa5'] = 'sorry, i cant. i have stuff to do'
						else
							$SMSTree['aa5'] = 'its late. text me sooner if you want me to come over.'
						end
									!! boy response 2 option 1
								$SMSTree['aa6'] = 'shit, maybe next time then'

							!! player response 2 option 2
						$SMSTree['ab5'] = 'ill come right now ;)'
								!! boy response 2 option 2
							if npc_humor[$ARGS[1]] <= 1 and rand(0, 1) = 0:
								$SMSTree['ab6'] = 'im already hard'
							elseif npc_humor[$ARGS[1]] = 2 and rand(0, 1) = 0:
								if rand(0, 1) = 0:
									$SMSTree['ab6'] = 'in the street?? damn! keep it in your pants till you get here!'
								else
									$SMSTree['ab6'] = 'as long as you make me cum later'
								end
							elseif npc_humor[$ARGS[1]] = 3 and rand(0, 1) = 0:
								$SMSTree['ab6'] = 'phrasing'
							else
								$SMSTree['ab6'] = 'cant wait'
							end

					!! player response 1 option 2
				$SMSTree['b3'] = 'what is it?'
						!! boy response 2
					$SMSTree['b4'] = 'my std test came back clean'
							!! player response 2 option 1
						$SMSTree['ba5'] = $SMSTree['aa5']
								!! boy response 2 option 1
							$SMSTree['ba6'] = $SMSTree['aa6']
							!! player response 2 option 2
						$SMSTree['bb5'] = $SMSTree['ab5']
								!! boy response 2 option 2
							$SMSTree['bb6'] = $SMSTree['ab6']


end


if $ARGS[0] = 'sugar_daddy_booty_call':
!!	Structure:
!!		0: boy
!!			1: player
!!				2: boy
!!					a3: player - 1st reply, choice A
!!						a4: boy
!!							aa5: player - 2nd reply, choice A: decline booty call
!!								aa6: boy
!!							ab5: player - 2nd reply, choice B: accept booty call
!!								ab6: boy
!!					b3: player - 1st reply, choice B
!!						b4: boy
!!							ba5: player - 2nd reply, choice A: decline booty call
!!								ba6: boy
!!							bb5: player - 2nd reply, choice B: accept booty call
!!								bb6: boy

		!! boy
	$SMSTree['0'] = 'hey <<$pcs_nickname>>'
			!! player
		$SMSTree['1'] = 'hey <<$npc_nickname[$ARGS[1]]>>'
				!! boy
			$SMSTree['2'] = 'ive been thinking about you'
					!! player 1st reply, choice A
				$SMSTree['a3'] = 'what were you thinking about?'
	
						!! boy response to 1st reply, choice A
					if ($home['current'] ! 'city_apartment' and $home['current'] ! 'niko_apartment' and $home['current'] ! 'university_dorm' and $home['current'] ! 'city_house' and $home['current'] ! 'maid_bedroom') and npc_residence[$ARGS[1]] >= 3:
						$SMSTree['a4'] = 'i booked a hotel room in Pav. why dont you come by?'
					else
						$SMSTree['a4'] = 'i want to see you. why dont you come by my apartment?'
					end
							!! player 2nd reply, choice A
						if hour < 21:
							$SMSTree['aa5'] = 'sorry, i cant. i have stuff to do'
						else
							$SMSTree['aa5'] = 'its late. text me sooner if you want me to come over.'
						end
								!! boy response to 2nd reply, choice A
							$SMSTRee['aa6'] = 'damn scheduling conflicts'

							!! player 2nd reply, choice B
						$SMSTree['ab5'] = 'ill come right now ;)'
								!! boy response to 2nd reply, choice B
							if ($home['current'] = 'parents_home' or $home['current'] = 'meynold_household' or $home['current'] = 'shared_apartment') and npc_residence[$ARGS[1]] >= 3:
								$SMSTree['ab6'] = 'room <<rand(1,3)>><<rand(10,19)>>'
							else
								if npc_humor[$ARGS[1]] <= 1 and rand(0,1) = 1:
									$SMSTree['ab6'] = 'im already hard'
								elseif npc_humor[$ARGS[1]] = 2 and rand(0,1) = 1:
									$SMSTree['ab6'] = 'as long as you make me cum later'
								elseif npc_humor[$ARGS[1]] = 3 and rand(0,1) = 1:
									$SMSTree['ab6'] = 'phrasing'
								else
									$SMSTree['ab6'] = 'cant wait'
								end
							end

					!! player 1st Reply, choice B
				$SMSTree['b3'] = 'me too'
					$SMSTree['b4'] = $SMSTree['a4']
						$SMSTree['ba5'] = $SMSTree['aa5']
							$SMSTree['ba6'] = $SMSTree['aa6']
						$SMSTree['bb5'] = $SMSTree['ab5']
							$SMSTree['bb6'] = $SMSTree['ab6']

end


if $ARGS[0] = 'new_booty_call':
!!	Structure:
!!		0: boy
!!			1: player
!!				2: player
!!					3: player
!!
!!


	!!==============   PART 1   ==============!!

	$SMSTree['0'] = 'hey <<$pcs_nickname>>'
		$SMSTree['1'] = 'hey <<$npc_nickname[$ARGS[1]]>>'
			$SMSTree['a2'] = 'what''s up?'
			$SMSTree['b2'] = 'hey sexy'

			!! hour > 20 or hour < 4
			$SMSTree['c2'] = 'its late. but ive always got time for you :)'
			$SMSTree['d2'] = 'its late. what do you want?'
			$SMSTree['e2'] = 'its late. text me earlier next time.'

			!! hour - message_received_hour >= 3
			$SMSTree['f2'] = 'sorry'
				$SMSTree['fa3'] = 'didn''t see your message until now'
					$SMSTree['fa4'] = 'whatsup?'
				$SMSTree['fb3'] = 'i was doing something'
					$SMSTree['fb4'] = $SMSTree['fa3']
				$SMSTree['fc3'] = 'i was at the gym'
					$SMSTree['fc4'] = $SMSTree['fa3']
				$SMSTree['fd3'] = 'i was in class'
					$SMSTree['fd4'] = $SMSTree['fa3']


	!!==============   PART 2   ==============!!

	if 0:
		! Date invite

	elseif $npc_rel_type[$ARGS[1]] = 'sugar_daddy':
		$SMSTree['10'] = 'i want to see you'
			$SMSTree['11'] = 'ive booked a hotel room'

	elseif $npc_rel_type[$ARGS[1]] = 'casual_date' or $npc_rel_type[$ARGS[2]] = 'fuckbuddy':
		$SMSTree['10'] = 'ive been thinking about you'
				!! player response 1 option 1
			$SMSTree['a11'] = 'what were you thinking about?'
					!! boy response 1
				if npc_finance[$ARGS[1]] = 2 and func('homes_properties_attr', 'get_property_attribute', '$town', $home['current']) ! 'city' and npc_residence[$ARGS[1]] >= 3:
					$SMSTree['a12'] = 'i booked a hotel room in Pav. why dont you come by?'
				else
					if $npc_fav_pos[$ARGS[1]] = 'blowjob' and rand(0, 2) = 0:
						$SMSTree['a12'] = 'your mouth around my cock'
					elseif npc_know_virgin[$ARGS[1]] ! 1:
						if $npc_cum_pref[$ARGS[1]] = 'creampie' and (npc_condom_conscious[$ARGS[1]] = 0 or npc_bareback[$ARGS[1]] = 1) and rand(0, 2) = 0:
							$SMSTree['a12'] = 'your pussy filled with my cum'
						elseif npc_sex_speed[$ARGS[1]] = 3 and rand(0, 2) = 0:
							$SMSTree['a12'] = 'fucking you bowlegged'
						elseif $npc_cum_pref[$ARGS[1]] = 'facial' and rand(0, 2) = 0:
							$SMSTree['a12'] = 'your pretty face covered in my cum'
						elseif $npc_cum_pref[$ARGS[1]] = 'mouth' and rand(0, 2) = 0:
							$SMSTree['a12'] = 'watching you swallow my cum'
						elseif $npc_cum_pref[$ARGS[1]] = 'tits' and rand(0, 2) = 0:
							$SMSTree['a12'] = 'my cum all over your tits'
						elseif $npc_fav_pos[$ARGS[1]] = 'doggy' and rand(0, 2) = 0:
							$SMSTree['a12'] = 'pounding you on all fours'
						elseif $npc_fav_pos[$ARGS[1]] = 'cowgirl' and rand(0, 2) = 0:
							$SMSTree['a12'] = 'you riding my cock like crazy'
						else
							if rand(0, 1) = 0:
								$SMSTree['a12'] = 'you naked on my bed'
							else
								$SMSTree['a12'] = 'want to come over and have some fun?'
							end
						end
					end
				end

				!! player response 1 option 2
			$SMSTree['b11'] = 'me too'
					!! boy response 2
				if npc_finance[$ARGS[1]] = 2 and func('homes_properties_attr', 'get_property_attribute', '$town', $home['current']) ! 'city' and npc_residence[$ARGS[1]] >= 3: 
					$SMSTree['b12'] = 'i booked a hotel room in Pav. why dont you come by?'
				else
					if $npc_fav_pos[$ARGS[1]] = 'blowjob' and rand(0, 2) = 0:
						$SMSTree['b12'] = 'i want to feel your mouth around my cock'
					elseif npc_know_virgin[$ARGS[1]] ! 1:
						if $npc_cum_pref[$ARGS[1]] = 'creampie' and (npc_condom_conscious[$ARGS[1]] = 0 or npc_bareback[$ARGS[1]] = 1) and rand(0, 2) = 0:
							$SMSTree['b12'] = 'i want to pump you full of cum'
						elseif npc_sex_speed[$ARGS[1]] = 3 and rand(0, 2) = 0:
							$SMSTree['b12'] = 'come over i want to hear you screaming my name'
						elseif $npc_cum_pref[$ARGS[1]] = 'facial' and rand(0, 2) = 0:
							$SMSTree['b12'] = 'i want to cum all over your face'
						elseif $npc_cum_pref[$ARGS[1]] = 'mouth' and rand(0, 2) = 0:
							$SMSTree['b12'] = 'i want to watch you swallow my cum'
						elseif $npc_cum_pref[$ARGS[1]] = 'tits' and rand(0, 2) = 0:
							$SMSTree['b12'] = 'let me glaze your tits with my cum'
						elseif $npc_fav_pos[$ARGS[1]] = 'doggy' and rand(0, 2) = 0:
							$SMSTree['b12'] = 'i want to pound you on all fours'
						elseif $npc_fav_pos[$ARGS[1]] = 'cowgirl' and rand(0, 2) = 0:
							$SMSTree['b12'] = 'i want you to ride my cock like theres no tomorrow'
						else
							if rand(0, 1) = 0:
								$SMSTree['b12'] = 'lets fuck like bunnies today'
							else
							end
						end
					end
				end

	elseif strpos('boyfriend|girlfriend|husband|wife', $npc_rel_type[$ARGS[1]]) > 0:
		if 0:
			!living with husband/wife
			if npc_dirty_lover[$ARGS[1]] = 1:
				$SMSTree['10'] = 'come home'
					$SMSTree['11'] = 'i want to fuck you senseless'
			elseif npc_sensual_lover[$ARGS[1]] = 1:
				$SMSTree['10'] = 'are you coming home soon'
					$SMSTree['11'] = 'lets make love'
			else
				$SMSTree['10'] = 'are you coming home soon'
					$SMSTree['11'] = 'lets get naughty'
			end
		else
			if npc_dirty_lover[$ARGS[1]] = 1:
				$SMSTree['10'] = 'come over'
					$SMSTree['11'] = 'i want to fuck you senseless'
			elseif npc_sensual_lover[$ARGS[1]] = 1:
				$SMSTree['10'] = 'i want to see you'
					$SMSTree['11'] = 'lets make love'
			else
				$SMSTree['10'] = 'you should come over'
					$SMSTree['11'] = 'lets get naughty'
			end
		end
	end



	!!==============   PART 3   ==============!!

	!! Final Choice
			!! player response 2 option 1
	if hour < 21:
		$SMSTree['a20'] = 'sorry, i cant. i have stuff to do'
	else
		$SMSTree['a20'] = 'its late. text me sooner if you want me to come over.'
	end
				!! boy response 2 option 1
			$SMSTree['a21'] = 'shit, maybe next time then'

			!! player response 2 option 2
		$SMSTree['b20'] = 'ill come right now ;)'
				!! boy response 2 option 1
			if npc_humor[$ARGS[1]] <= 1 and rand(0, 1) = 0:
				$SMSTRee['b21'] = 'im already hard'
			elseif npc_humor[$ARGS[1]] = 2 and rand(0, 1) = 0:
				if rand(0, 1) = 0:
					$SMSTRee['b21'] = 'in the street?? damn! keep it in your pants till you get here!'
				else
					$SMSTRee['b21'] = 'as long as you make me cum later'
				end
			elseif npc_humor[$ARGS[1]] = 3 and rand(0, 1) = 0:
				$SMSTRee['b21'] = 'phrasing'
			else
				$SMSTRee['b21'] = 'cant wait'
			end
	
	$SMSTree['c20'] = 'its kind of late'
		$SMSTree['c21'] = 'sorry'
			$SMSTree['c22'] = 'maybe another time?'
end

if $ARGS[0] = 'new_sexting':
	$SMSTree['0'] = 'send me a pic then?'
		$SMSTree['a1'] = 'refuse'
			$SMSTree['a2'] = 'no'
		$SMSTree['b1'] = 'next time tiger'
		$SMSTree['c1'] = 'im not at home!'
			if npc_dirty_lover[$ARGS[1]] = 1:
				if rand(0, 1) = 0:
					$SMSTree['c2'] = 'hot'
				else
					$SMSTree['c2'] = 'so?'
				end
			else
				$SMSTree['c2'] = 'ill use my imagination then'
			end
		$SMSTree['s1'] = 'Send a selfie from your gallery'
end




	!!===============================================================!!
	!!                                                               !!
	!!                           BUILD SMS                           !!
	!!                                                               !!
	!!===============================================================!!


!Does not work with pre-planned?
if $ARGS[0] = 'Add SMS':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]

	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'receive', $SMSTree['0']
		gs 'SMStext_builder', 'add_reply', $SMSTree['1'], 'booty_call_sms', 'SMS_Base', $ARGS[1], $ARGS[2]
		gs 'SMStext_builder', 'add_sms', $ARGS[2]
	gs 'SMStext_builder', 'end'
end


if $ARGS[0] = 'SMS_Base':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree['1']
		gs 'SMStext_builder', 'show_sms', ARGS[3]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree['2']
		gs 'SMStext_builder', 'add_reply', $SMSTree['a3'], 'booty_call_sms', 'bc_choice1', $ARGS[1], $ARGS[2], 'a'
		gs 'SMStext_builder', 'add_reply', $SMSTree['b3'], 'booty_call_sms', 'bc_choice1', $ARGS[1], $ARGS[2], 'b'
		gs 'SMStext_builder', 'show_sms', ARGS[3]
	gs 'SMStext_builder', 'end'
end

if $ARGS[0] = 'bc_choice1':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3] + '3']
		gs 'SMStext_builder', 'show_sms', ARGS[4]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree[$ARGS[3] + '4']
		gs 'SMStext_builder', 'add_reply', $SMSTree[$ARGS[3] + 'a5'], 'booty_call_sms', 'bc_choice2', $ARGS[1], $ARGS[2], $ARGS[3] + 'a', 'decline_booty_call'
		gs 'SMStext_builder', 'add_reply', $SMSTree[$ARGS[3] + 'b5'], 'booty_call_sms', 'bc_choice2', $ARGS[1], $ARGS[2], $ARGS[3] + 'b', 'accept_booty_call'
		gs 'SMStext_builder', 'show_sms', ARGS[4]
	gs 'SMStext_builder', 'end'

elseif $ARGS[0] = 'bc_choice2':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3] + '5']
		gs 'SMStext_builder', 'show_sms', ARGS[5]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree[$ARGS[3] + '6']
		gs 'SMStext_builder', 'show_sms', ARGS[5]
	gs 'SMStext_builder', 'end'

	gs 'booty_call_sms', $ARGS[4], $ARGS[2], ARGS[5]
end





! For pre-planned
if $ARGS[0] = 'Add SMS2':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'receive', $SMSTree['0']
		gs 'SMStext_builder', 'add_reply', $SMSTree['a1'], 'booty_call_sms', 'Choice2_a', $ARGS[1], $ARGS[2]
		gs 'SMStext_builder', 'add_reply', $SMSTree['b1'], 'booty_call_sms', 'Choice2_b', $ARGS[1], $ARGS[2]
		gs 'SMStext_builder', 'add_sms', $ARGS[2]
	gs 'SMStext_builder', 'end'
end


if $ARGS[0] = 'Choice2_a':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree['a1']
		gs 'SMStext_builder', 'show_sms', ARGS[3]
	gs 'SMStext_builder', 'end'
end



if $ARGS[0] = 'Choice2_b':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree['b1']
		gs 'SMStext_builder', 'show_sms', ARGS[3]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree['b2']
		gs 'SMStext_builder', 'add_reply', $SMSTree['ba3'], 'booty_call_sms', 'Choice2_b2', $ARGS[1], $ARGS[2], 'ba', 'decline_booty_call'
		gs 'SMStext_builder', 'add_reply', $SMSTree['bb3'], 'booty_call_sms', 'Choice2_b2', $ARGS[1], $ARGS[2], 'bb', 'accept_booty_call'
		gs 'SMStext_builder', 'show_sms', ARGS[3]
	gs 'SMStext_builder', 'end'

elseif $ARGS[0] = 'Choice2_b2':
	!! booty call is declined

	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3] + '3']
		gs 'SMStext_builder', 'show_sms', ARGS[5]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree[$ARGS[3] + '4']
		gs 'SMStext_builder', 'show_sms', ARGS[5]
	gs 'SMStext_builder', 'end'

	gs 'booty_call_sms', $ARGS[4], $ARGS[2], ARGS[5]
end




	!!=====================================================================!!
	!!                                                                     !!
	!!                           NEW BOOTY CALLS                           !!
	!!                                                                     !!
	!!=====================================================================!!


! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
if $ARGS[0] = 'Add SMS3':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'receive', $SMSTree['0']
		gs 'SMStext_builder', 'add_reply', $SMSTree['1'], 'booty_call_sms', 'new_routing1', $ARGS[1], $ARGS[2], '<<totminut>>'
		gs 'SMStext_builder', 'add_sms', $ARGS[2]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
! $ARGS[3] = totminut string
!  ARGS[4] = smsID
if $ARGS[0] = 'new_routing1':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree['1']
		if totminut >= val($ARGS[3]) + 180:
			gs 'SMStext_builder', 'add_reply', $SMSTree['f2'], 'booty_call_sms', 'new_delayed', '1', $ARGS[1], $ARGS[2]
		elseif hour > 20 or hour < 4:
			gs 'SMStext_builder', 'add_reply', $SMSTree['c2'], 'booty_call_sms', 'new_routing2', $ARGS[1], $ARGS[2], 'c2', 'npc_rel[''''<<$ARGS[2]>>''''] += 1'
			gs 'SMStext_builder', 'add_reply', $SMSTree['d2'], 'booty_call_sms', 'new_routing2', $ARGS[1], $ARGS[2], 'd2', 'npc_rel[''''<<$ARGS[2]>>''''] -= 2'
			gs 'SMStext_builder', 'add_reply', $SMSTree['e2'], 'booty_call_sms', 'end', $ARGS[1], $ARGS[2], 'e2', 'decline_booty_call', ''
		else
			gs 'SMStext_builder', 'add_reply', $SMSTree['a2'], 'booty_call_sms', 'new_routing2', $ARGS[1], $ARGS[2], 'a2', ''
			gs 'SMStext_builder', 'add_reply', $SMSTree['b2'], 'booty_call_sms', 'new_routing2', $ARGS[1], $ARGS[2], 'b2', ''
		end
		gs 'SMStext_builder', 'show_sms', ARGS[4]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = '1' or '2'
! $ARGS[2] = SMSTree argloc
! $ARGS[3] = npc_code
!  ARGS[4] = smsID
if $ARGS[0] = 'new_delayed':
	gs 'booty_call_sms', $ARGS[2], $ARGS[3]
	gs 'SMStext_builder', 'start'
		if $ARGS[1] = '1':
			gs 'SMStext_builder', 'send', $SMSTree['f2']
			gs 'SMStext_builder', 'add_reply', $SMSTree['f3'], 'booty_call_sms', 'new_delayed', '2', $ARGS[2], $ARGS[3]
		elseif $ARGS[2] = '2':
			gs 'SMStext_builder', 'send', $SMSTree['f3']
			gs 'SMStext_builder', 'add_reply', $SMSTree['fa4'], 'booty_call_sms', 'new_routing2', $ARGS[2], $ARGS[3], 'fa4', ''
			gs 'SMStext_builder', 'add_reply', $SMSTree['fb4'], 'booty_call_sms', 'new_routing2', $ARGS[2], $ARGS[3], 'fb4', ''
			gs 'SMStext_builder', 'add_reply', $SMSTree['fc4'], 'booty_call_sms', 'new_routing2', $ARGS[2], $ARGS[3], 'fc4', ''
			gs 'SMStext_builder', 'add_reply', $SMSTree['fd4'], 'booty_call_sms', 'new_routing2', $ARGS[2], $ARGS[3], 'fd4', ''
		end
		gs 'SMStext_builder', 'show_sms', ARGS[4]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
! $ARGS[3] = code reply send
! $ARGS[4] = dynamic code to be executed
!  ARGS[5] = smsID
if $ARGS[0] = 'new_routing2':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	dynamic $ARGS[4]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3]]
		gs 'SMStext_builder', 'show_sms', ARGS[5]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree['10']
		gs 'SMStext_builder', 'show_sms', ARGS[5]

		if $npc_rel_type[$ARGS[2]] = 'casual_date' or $npc_rel_type[$ARGS[2]] = 'fuckbuddy':
			gs 'SMStext_builder', 'add_reply', $SMSTree['a11'], 'booty_call_sms', 'new_bootycall', $ARGS[1], $ARGS[2], 'a'
			gs 'SMStext_builder', 'add_reply', $SMSTree['b11'], 'booty_call_sms', 'new_bootycall', $ARGS[1], $ARGS[2], 'b'
		else
			wait 250
			gs 'SMStext_builder', 'receive', $SMSTree['11']

			if 1:
				! not living together
				! sugar daddy, or boy/girlfriend, or husband/wife (not living together) or date invite
				gs 'SMStext_builder', 'add_reply', $SMSTree['a20'], 'booty_call_sms', 'new_routing3', $ARGS[1], $ARGS[2], 'a', 'decline_booty_call', 'npc_rel[''''<<$ARGS[2]>>''''] -= 2'
				gs 'SMStext_builder', 'add_reply', $SMSTree['b20'], 'booty_call_sms', 'new_routing3', $ARGS[1], $ARGS[2], 'b', 'accept_booty_call', ''
				if hour > 20 or hour <= 4: gs 'SMStext_builder', 'add_reply', $SMSTree['c20'], 'booty_call_sms', 'late_apology', '1', $ARGS[1], $ARGS[2], 'c20'
			end
		end
		gs 'SMStext_builder', 'show_sms', ARGS[5]
	gs 'SMStext_builder', 'end'
	if 0:
		! living together
		if rand(0, 1) = 0: wait 250 & gs 'booty_call_sms', 'sexting1', 'new_sexting', $ARGS[1], ARGS[2]
	end
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
! $ARGS[3] = code reply send
!  ARGS[4] = smsID
if $ARGS[0] = 'new_bootycall':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3] + '11']
		gs 'SMStext_builder', 'show_sms', ARGS[4]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree[$ARGS[3] + '12']
		gs 'SMStext_builder', 'add_reply', $SMSTree['a20'], 'booty_call_sms', 'new_routing3', $ARGS[1], $ARGS[2], 'a', 'decline_booty_call', ''
		gs 'SMStext_builder', 'add_reply', $SMSTree['b20'], 'booty_call_sms', 'new_routing3', $ARGS[1], $ARGS[2], 'b', 'accept_booty_call', ''
		gs 'SMStext_builder', 'show_sms', ARGS[4]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = '1' or '2'
! $ARGS[2] = SMSTree argloc
! $ARGS[3] = npc_code
! $ARGS[4] = code reply send
!  ARGS[5] = smsID
if $ARGS[0] = 'late apology':
	gs 'booty_call_sms', $ARGS[2], $ARGS[3]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[4]]

		if $ARGS[1] = '1':
			gs 'SMStext_builder', 'add_reply', $SMSTree['c22'], 'booty_call_sms', 'late_apology', '2', $ARGS[2], $ARGS[3], 'c22'
		elseif $ARGS[1] = '2':
			gs 'SMStext_builder', 'add_reply', $SMSTree['c23'], 'booty_call_sms', 'new_routing3', $ARGS[2], $ARGS[3], 'c23'
		end
		gs 'SMStext_builder', 'show_sms', ARGS[5]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
! $ARGS[3] = code reply send
! $ARGS[4] = 'accept_booty_call' or 'decline_booty_call'
! $ARGS[5] = dynamic code to be executed
!  ARGS[6] = smsID
if $ARGS[0] = 'new_routing3':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	dynamic $ARGS[5]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3] + '20']
		gs 'SMStext_builder', 'show_sms', ARGS[6]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree[$ARGS[3] + '21']
		gs 'SMStext_builder', 'show_sms', ARGS[6]
	gs 'SMStext_builder', 'end'
	gs 'booty_call_sms', $ARGS[4], $ARGS[2], ARGS[6]
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
! $ARGS[3] = code reply send
! $ARGS[4] = 'accept_booty_call' or 'decline_booty_call'
! $ARGS[5] = dynamic code to be executed
!  ARGS[6] = smsID
if $ARGS[0] = 'end':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	dynamic $ARGS[5]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree[$ARGS[3]]
		gs 'SMStext_builder', 'show_sms', ARGS[6]
	gs 'SMStext_builder', 'end'
	gs 'booty_call_sms', $ARGS[4], $ARGS[2], ARGS[6]
end

! $ARGS[1] = npc_code
!  ARGS[2] = smsID
if $ARGS[0] = 'accept_booty_call':
	booty_call_invite[$ARGS[1]] = daystart
	if npc_finance[$ARGS[1]] = 2 and npc_residence[$ARGS[1]] >= 3:
		if func('homes_properties_attr', 'get_property_attribute', '$town', $home['current']) = 'city':
			$booty_call_hotel[$ARGS[1]] = 'city'
		else
			$booty_call_hotel[$ARGS[1]] = 'pav'
		end
	end

! $ARGS[1] = npc_code
!  ARGS[2] = smsID
elseif $ARGS[0] = 'decline_booty_call':
	if sugar_daddy_call[$ARGS[1]] = 1:
		npc_rel[$ARGS[1]] -= 2
		sugar_daddy_call[$ARGS[1]] = 0
	end

	if rand(0, 1) = 0: wait 250 & gs 'booty_call_sms', 'sexting1', 'new_sexting', $ARGS[1], ARGS[2]
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
!  ARGS[3] = smsID
if $ARGS[0] = 'sexting1':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'receive', $SMSTree['0']
		gs 'SMStext_builder', 'add_reply', $SMSTree['a1'], 'booty_call_sms', 'sexting_refuse', $ARGS[1], $ARGS[2], 'refuse'
		gs 'SMStext_builder', 'add_reply', $SMSTree['b1'], 'booty_call_sms', 'sexting_refuse', $ARGS[1], $ARGS[2], 'next'
		if strpos($location_type, 'outdoors') > 0 or strpos($location_type, 'public') > 0:
			gs 'SMStext_builder', 'add_reply', $SMSTree['c1'], 'booty_call_sms', 'sexting_public', $ARGS[1], $ARGS[2]
		end
		gs 'SMStext_builder', 'send_selfie', $SMSTree['s1'], 'n|b|sh|ft|fa|fp', 'booty_call_sms', 'sexting_send', $ARGS[1], $ARGS[2]
		gs 'SMStext_builder', 'show_sms', ARGS[3]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
!  ARGS[3] = smsID
if $ARGS[0] = 'sexting_public':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send', $SMSTree['c1']
		gs 'SMStext_builder', 'show_sms', ARGS[3]

		wait 250

		gs 'SMStext_builder', 'receive', $SMSTree['c2']
		if npc_dirty_lover[$ARGS[2]] = 1:
			gs 'SMStext_builder', 'add_reply', $SMSTree['a1'], 'booty_call_sms', 'sexting_refuse', $ARGS[1], $ARGS[2], 'refuse'
			gs 'SMStext_builder', 'add_reply', $SMSTree['b1'], 'booty_call_sms', 'sexting_refuse', $ARGS[1], $ARGS[2], 'next'
			gs 'SMStext_builder', 'send_selfie', $SMSTree['s1'], 'n|b|sh|ft|fa|fp', 'booty_call_sms', 'sexting_send', $ARGS[1], $ARGS[2]
		end
		gs 'SMStext_builder', 'show_sms', ARGS[3]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
! $ARGS[3] = 'refuse' or 'next'
!  ARGS[4] = smsID
if $ARGS[0] = 'sexting_refuse':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		if $ARGS[3] = 'refuse':
			gs 'SMStext_builder', 'send', $SMSTree['a2']
			npc_rel[$ARGS[2]] -= 1
		else
			gs 'SMStext_builder', 'send', $SMSTree['b1']
		end
		gs 'SMStext_builder', 'show_sms', ARGS[4]
	gs 'SMStext_builder', 'end'
end

! $ARGS[1] = SMSTree argloc
! $ARGS[2] = npc_code
!  ARGS[3] = smsID
! $ARGS[4] = image path
! $ARGS[5] = location
! $ARGS[6] = state of dress (clothed, nude, etc)
!  ARGS[7] = is the index of the location in $selfieLoc[] and $selfieFilePrefix
!  ARGS[8] = the selfie number
if $ARGS[0] = 'sexting_send':
	gs 'booty_call_sms', $ARGS[1], $ARGS[2]
	gs 'SMStext_builder', 'start'
		gs 'SMStext_builder', 'send_img', $ARGS[4]
		gs 'SMStext_builder', 'show_sms', ARGS[3]

		wait 250

		gs 'SMStext_builder', 'receive', 'damn!!'
		npc_rel[$ARGS[2]] += 3
		gs 'SMStext_builder', 'show_sms', ARGS[3]

		wait 250

		gs 'SMStext_builder', 'send', ':)'
		! Add responses based on the result??
		!{
		if $ARGS[6] = 'clothed':
		elseif $ARGS[6] = 'nude' or $ARGS[6] = 'pussyflash':
		end
		}
		gs 'SMStext_builder', 'show_sms', ARGS[3]
	gs 'SMStext_builder', 'end'
end




if $ARGS[0] ! 'default_booty_call' and $ARGS[0] ! 'pre_planned_booty_call' and $ARGS[0] ! 'std_free' and $ARGS[0] ! 'sugar_daddy_booty_call' and $ARGS[0] ! 'new_booty_call' and $ARGS[0] ! 'new_sexting':
	killvar '$SMSTree'
end

--- hookup_sms ---------------------------------