glife/locations/pushkin_sq.qsrc

# pushkin_sq
!!2021/05/14
*clr & cla
gs 'shortgs', 'setloc', 'pushkin_sq', $ARGS[0]
$region = 'pushkin'
$location_type = 'public_outdoors'
menu_off = 0
gs'stat'

'<center><B>Okhlopkov Square</B></center>'
'<center><img <<$set_imgh>> src="images/locations/pushkin/liames.jpg" ></center>'
'Okhlopkov Square serves as the main intersection of several smaller streets.'  
'There are many small cafes and shops also a flourishing nightlife and entertainment activities.'

'Another street runs straight back to the <a href="exec:minut += 5 & gt ''pushkin''">Pushkin Town Center</a>.'
'Okhlopkov Square itself leads to the <a href="exec:minut += 5 & gt ''pushkin_parks'',''start''">Pushkin Park</a>.'
if hour >= 8 and hour <= 20:
	'A small <a href="exec:gt ''larek'',''start''">grocery store</a> is currently open.'
else
	'There is a small whole foods store that is open from 8:00 - 20:00 everyday. It is currently closed.'
end

if hour >= 10 and hour <= 22:
	'A quaint little restaurant has put a sign outside of its door, reading, "<a href="exec:gt ''pushkin_cafe'',''start''">Liamel Cafe</a>."'
else
	'Liamel Cafe is current closed, it is open every day 10:00 - 22:00'
end

if week < 7 and hour >= 9 and hour <= 17:
	'The long standing alternative clothing shop <a href="exec:gt ''shop_tsar_bomba'',''start''">Tsar Bomba</a> is unmistakable amongst the tourist shops on the main square.'
	'Clothing for younger women is catered for in <a href="exec:gt ''shop_flamingos'',''start''">Flamingos</a>.'
	'Catering for the burlesque club here there is the <a href="exec:gt ''shop_fancy_pancy'',''start''">Fancy Pancy</a> boutique clothing store.'
	else
	'Tsar Bomba, Flamingos and Fansy Pansy,  are all current closed, they are open open Mon - Sat day 9:00 - 18:00'
end
if week < 7 and hour >= 9 and hour <= 17:
	'<a href="exec:gt ''ballet_secrets'',''init''">Ballet Secrets</a> is located at the end of a well maintained alleyway with a flamboyant ballet shop display and despite it''s name the premises offers a wide range of services for dancers and athletes. '
elseif 	week = 7 and (hour >= 10 and hour <=16):
	'The dance shop is closed, but you can still access the <a href="exec:gt ''ballet_secrets'',''init''">Members Area</a> with your card.'
else
	'Ballet Secrets is currently closed. The shop opens 09:00-17:00 Monday to Saturday, and members only access for class is open on Sunday from 10:00 - 17:00.'
end
if exhibitionQW > 3:
	if week < 7 and hour >= 8 and hour <= 17:
		'<a href="exec:gt ''exhibitionistshop'',''start''">Simply Salacious</a> is just down a small side street from here.'
	else
		'<b>Simply Salacious,</b> is open Mon - Sat, 8:00 - 18:00'
	end
end

if hour >= 12 or hour < 2:
	if pcs_inhib > 30:
		'Club <a href="exec:gt ''Rasputin_entrance''">Rasputin</a> provides both burlesque and exotic variety shows every evening except on Mondays.'
		'The new members of the Pushkin Burlesque Troupe also perform there to hone their skills.'
	else
		'There is a burlesque club in an old theatre here. Such perversion is unhealthy and you cannot bring yourself to go there.'
	end
else
	'The old theatre that houses a burlesque club is closed now. It is open every day 18:00 - 23:00'
end

if mother['kickedout_timer'] ! 0 and mother['kickedout_timer'] + 3 <= daystart and hour > 6 and hour <= 15 and cumloc[11] = 0:
	gs 'mother_chats', 'reconciliation_talk'
exit
end

if func('homes_properties', 'is_property_of_status', 'rented', 'old_town_apartment'): act '<b>Go home</b>':gt'korr2x'

act 'Walk to the Town Center (0:05)':minut += 5 & gt 'pushkin'

if hour >= 8 and hour <= 17 and exhibitionQW = 3: act 'Search for the shop on the card from Kseniya': gt 'exhibitionistshop', 'start'

act 'Wait':gs 'obj_din', 'wait'

if $home['current'] = 'old_town_apartment':
	if vladimirQW['day'] = daystart and vladimirQW['stage'] = 30 and hour >= 16 and week = 6:'<a href="exec:gt ''vladimirQW_meet'',''2''">There''s an Audi parked in front of your apartment, and standing beside it, you notice Vladimir</a>.'
	if vladimirQW['day'] = daystart and vladimirQW['stage'] = 40 and hour >= 16 and week = 6:'<a href="exec:gt ''vladimirQW_meet'',''3''">There''s an Audi parked in front of your apartment, and standing beside it, you notice Vladimir</a>.'

	if hour = meethour[0]:
		if svidanie[0] = 1:'<b><a href="exec:lover_number = 0 & gt ''lover_meet'', ''start''"><<$loverdesc[0]>></a> is waiting at the entrance to your apartment building.</b>'
	end
	if hour = meethour[1]:
		if svidanie[1] = 1:'<b><a href="exec:lover_number = 1 & gt ''lover_meet'', ''start''"><<$loverdesc[1]>></a> is waiting at the entrance to your apartment building.</b>'
	end
	if hour = meethour[2]:
		if svidanie[2] = 1:'<b><a href="exec:lover_number = 2 & gt ''lover_meet'', ''start''"><<$loverdesc[2]>></a> is waiting at the entrance to your apartment building.</b>'
	end
end

if rand(0,50) = 50 and fame['event_day'] ! daystart and hour > 8 and hour < 21:
	gs 'fame_events', 'select', 'pushkin'
end

if rand(0,100) >= 60 and pcs_lover < 3 and rand(0,1200) <= pcs_apprnc:
	gs 'boygirl', 0
	'You are approached by <<$boybody_pref>>, <<$boybod>> guy with <<$boyface>> hair. He is <<$boyClo>>'
	'The guy introduced himself as <<$boydesc>> and asks you for your telephone number.'

	act 'Walk away': gt 'pushkin_sq'
	act 'Tell him your telephone number.':
		cla
		gs'boyfrend', 'start'
		stopboy = 0
		'<<$boydesc>> saved your phone number and left.'
		act 'Continue': gt 'pushkin_sq'
	end
end

if rand(1,100) >= 95:
	*clr & cla
	minut += 5
	gs'stat'
	'<center><img <<$set_imgh>> src="images/locations/pushkin/liamhud1.jpg"></center>'

	'Making your way down Okhlopkov Square, you see a woman waiting patiently while an artist paints her portrait.'

	act 'Continue': gt'pushkin_sq'
end

gs 'music_actions', 'music_icon'

if hour >= 15 and hour <= 22 and tusa = 0:
	act 'Go to the local hangout':
		*clr & cla
		menu_off = 1
		minut += 20
		tusa = 1
		gs 'dibodi'
		gs'stat'
		'<center><img <<$set_imgh>> src="images/locations/pushkin/photo.jpg"></center>'
		'Local youth get-together.'
		act 'Explore it': gt 'dibodi', 'sgtusa'
	end
elseif hour >= 15 and hour <= 22 and tusa = 1 and tusnyakday ! daystart:
	act 'Go to the local hangout':
		*clr & cla
		menu_off = 1
		minut += 20
		gs'dibodi'
		gs'stat'
		'<center><img <<$set_imgh>> src="images/locations/pushkin/photo.jpg"></center>'
		'The girls and boys at the local hangout happily greet you.'

		act'Leave': gt 'pushkin_sq'
		
		if $pantyworntype = 'none' and sttan = 0:
			cla
			'"Hey guys, <<$pcs_nickname>> is going commando," one of the boys says.'
			act 'Continue':gt 'dibodi', 'sotusa'
		end

!!		if sttan = 1 and $pantyworntype = 'none':
!!			'- <<$pcs_nickname>>, and again without panties, - said one of the boys - Pussy pokezh?'
!!			'- And yet to show? - you said - How do I want and go.'
!!			act 'Further':gt'etoexhib','pos2'
!!		end

!!		if sttan = 1 and $pantyworntype ! 'none':
!!			'- Vav <<$pcs_nickname>> truselya put.'
!!			act 'Answer':gt'etoexhib','pos3'
!!		end
	end
end

if stallionQ = 3:
	*clr & cla
	'There is a rumbling in your stomach, you need to use the restroom. There appears to be a public restroom tucked into the corner of a building. Unfortunately, the female one has a sign reading, "Out of order."'
	gs 'willpower', 'misc', 'resist', 'easy'
	if will_cost <= pcs_willpwr:
		act 'Hold it (<<will_cost>> Willpower)':
			gs 'willpower', 'pay', 'resist'
			stallionQ = 1
			gt 'pushkin_sq'
		end
	else
		act 'Hold it (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end
	act 'Use the Men''s Restroom': gt 'stallion','start'
end

--- pushkin_sq ---------------------------------