# clothing
!!2021/05/06
menu_off = 1

$clothing_list_line = {
	!! a single line in a clothing list (wardrobe, etc)
	!! ARGS 0 - action type (wardrobe, sell, resize, store, forsale)
	!! ARGS 1 - clothing type
	!! ARGS 2 - clothing index

	gs 'themes', 'clothing', 1

	$RESULT = '<TR bgcolor='+$bgcolor+'>'

	if Enable_clothwidth > 0:
		clothing_temp = Enable_clothwidth - 1
	else
		clothing_temp = 150 & !clothing widdefault to 150
	end
	$RESULT +='<TD><a href="exec:gt ''clothing'', ''view_clothing_item'', ''<<$ARGS[0]>>'', ''<<$ARGS[1]>>'', <<ARGS[2]>>"><img src="<<FUNC(''$clothing_image'', $ARGS[1], ARGS[2])>>" width="<<clothing_temp>>"><p><<$ARGS[1]>> outfit</p></a></TD>'
	killvar 'clothing_temp'
	$swimwear_description = ''
	gs 'clothing_attributes', $ARGS[1], ARGS[2]

	if $ARGS[1] ! 'gm_school' or ARGS[2] ! 6:
		$RESULT += '<TD>' + dyneval '$RESULT += <<$ARGS[1]>>_h[<<ARGS[2]>>]' + '</TD>'

		if $ARGS[1] ! 'danilovich' and $ARGS[1] ! 'coat' and CloStyle ! 5:
			$RESULT += '<TD>' + dyneval '$RESULT += <<$ARGS[1]>>_b[<<ARGS[2]>>]' + '</TD>'
		else
			$RESULT += '<TD></TD>'
		end
	else
		$RESULT += '<TD colspan="2"></TD>'
	end

	if $ARGS[1] = 'misc_outfits' and ARGS[2] = 1:
		$RESULT += '<TD>A hessian sack the hunters gave you.</TD>'
	elseif $swimwear_description = '':
		gs 'clothing_descriptions'
		$RESULT += '<TD><<FUNC(''$short_description'', $ARGS[1])>> <<ARGS[2]>><br/><br/><<$description>></TD>'
	else
		$RESULT += '<TD>' + $swimwear_description + '</TD>'
	end

	if CloBimbo = 1:
		$RESULT += '<TD>Yes</TD>'
	else
		$RESULT += '<TD>No</TD>'
	end

	if CloStyle = 4:
		$RESULT += '<TD>Yes</TD>'
	else
		$RESULT += '<TD>No</TD>'
	end

	$RESULT += '<TD><a href="exec:gt ''clothing'', ''view_clothing_item'', ''<<$ARGS[0]>>'', ''<<$ARGS[1]>>'', <<ARGS[2]>>">View</a>'

	if $ARGS[0] ! 'sell' and $ARGS[0] ! 'resize':
		if StoryLine = 1 and SchoolAtestat = 0 and SchoolBlock = 0 and $ARGS[1] = 'gm_school' and ARGS[2] = 6:
			$RESULT += ' <a href="exec:gs ''clothing'', ''wear'', ''<<$ARGS[1]>>'', <<ARGS[2]>> & gt ''clothing'', ''view_clothing_list'', ''wardrobe'', ''<<$ward_list_store>>''">Wear</a></TD>'
		elseif $ARGS[2] ! 'danilovich_swimsuit' and $ARGS[2] ! 'scandalicious_bikinis' and $ARGS[2] ! 'scandalicious_swimsuit' and $ARGS[2] ! 'allure_bikinis' and $ARGS[2] ! 'allure_bikinis' and dyneval('RESULT = <<$ARGS[1]>>_h[<<ARGS[2]>>]') > 0:
			if $ARGS[1] ! 'danilovich' and CloStyle ! 5 and (dyneval('RESULT = <<$ARGS[1]>>_b[<<ARGS[2]>>]') < (pcs_hips - 8) or dyneval('RESULT = <<$ARGS[1]>>_b[<<ARGS[2]>>]') > (pcs_hips + 8)) or (ARRPOS('$CloLosTyp', $ARGS[1]) ! -1 and ARRPOS('CloLosNum',ARGS[2]) ! -1):
				$RESULT += '</TD>'
			else
				$RESULT += ' <a href="exec:gs ''clothing'', ''wear'', ''<<$ARGS[1]>>'', <<ARGS[2]>> & gt ''clothing'', ''view_clothing_list'', ''wardrobe'', ''<<$ward_list_store>>''">Wear</a></TD>'
			end
		else
			$RESULT += '</TD>'
		end

		$RESULT += '<TD>'
		if cloc ! 1:$RESULT += ' <a href="exec:gt ''clothing'', ''dest1'', ''<<$ARGS[0]>>'', ''<<$ARGS[1]>>'', <<ARGS[2]>> ">Storage</a><BR>'
		if cloc ! 0:$RESULT += ' <a href="exec:gt ''clothing'', ''dest0'', ''<<$ARGS[0]>>'', ''<<$ARGS[1]>>'', <<ARGS[2]>> ">Wardrobe</a><BR>'
		if $ARGS[1] ! 'gm_school' or ARGS[2] ! 6:
			if cloc ! 2:$RESULT += ' <a href="exec:gt ''clothing'', ''dest2'', ''<<$ARGS[0]>>'', ''<<$ARGS[1]>>'', <<ARGS[2]>> ">Unwanted</a>'
		end
		$RESULT += '</TD>'
	end
}

!!cloc, 0 = wardrobe, 1 = storage, 2 = unwanted


if $ARGS[0] = 'dest0':
	*clr
	dynamic '<<$ARGS[2]>>_s[<<ARGS[3]>>] = 0'
	gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
end

if $ARGS[0] = 'dest1':
	*clr
	dynamic '<<$ARGS[2]>>_s[<<ARGS[3]>>] = 1'
	gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
end

if $ARGS[0] = 'dest2':
	*clr
	dynamic '<<$ARGS[2]>>_s[<<ARGS[3]>>] = 2'
	gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
end


if $ARGS[0] = 'view_clothing_list':
	!! ARGS 0 - view_clothing_list
	!! ARGS 1 - action type (wardrobe, sell, resize, store, unwanted)
	!! ARGS 2 - Shop name (kats, moncheri, gm, fashionista, sexshop, exhibitshop, dolls, sports)
	
	if $pursepantytype ! '' or $pursebratype ! '' and $ARGS[1] ! 'resize' and $ARGS[1] ! 'sell':
		'<center><b>You put the '+iif($pursepantytype ! '','panties','')+iif($pursepantytype ! '' and $pursebratype ! '',' and ','')+iif($pursebratype ! '','bra','')+' from your purse back in the wardrobe.</b></center><br>'
		killvar '$pursepantytype' & killvar 'pursepantynumber'
		killvar '$pursebratype' & killvar 'pursebranumber'
	end
	
	if $ARGS[1] = 'wardrobe':
		$ward_list_page = $ARGS[1]
		'<h3><center><b><font color="maroon">Wardrobe list</font></b></center></h3>'
	elseif $ARGS[1] = 'store':
		$ward_list_page = $ARGS[1]
		'<h3><center><b><font color="maroon">Stored clothing list</font></b></center></h3>'
	elseif $ARGS[1] = 'unwanted':
		$ward_list_page = $ARGS[1]
		'<h3><center><b><font color="maroon">Unwanted clothing list</font></b></center></h3>'
	elseif $ARGS[1] = 'sell':
		$ward_list_page = $ARGS[1]
		'<h3><center><b><font color="maroon">Choose an item to sell</font></b></center></h3>'
	end

	if $ARGS[2] = 'gm' or $ARGS[2] = 'gm_outfits' or $ARGS[2] = 'gm_dress' or $ARGS[2] = 'gm_office' or $ARGS[2] = 'gm_school' or $ARGS[2] = 'gm_maid' or $ARGS[2] = 'gm_server':
		!'<center><b><font color="maroon">Viewing clothes from G&M</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/gm.png"></center>'
	elseif $ARGS[2] = 'kats':
		!'<center><b><font color="maroon">Viewing clothes from PussyKats</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/pussycat.png"></center>'
	elseif $ARGS[2] = 'fashionista':
		!'<center><b><font color="maroon">Viewing clothes from Fashionista</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/fashionista.png"></center>'
	elseif $ARGS[2] = 'moncheri':
		!'<center><b><font color="maroon">Viewing clothes from Mon Cheri</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/moncheri.png"></center>'
	elseif $ARGS[2] = 'sexshop':
		!'<center><b><font color="maroon">Viewing clothes from the sex shop</font></b></center>'
		'<center><img src="images/locations/city/redlight/erotomaniac/shop_name.png"></center>'
	elseif $ARGS[2] = 'exhibitshop':
		!'<center><b><font color="maroon">Viewing clothes from the Exhibitionist shop</font></b></center>'
		'<center><img src="images/locations/pushkin/exhibitshop/shop_name.png"></center>'
	elseif $ARGS[2] = 'dolls':
		!'<center><b><font color="maroon">Viewing clothes from Patchwork Dolls</font></b></center>'
		'<center><img src="images/locations/city/island/dolls/shop_name.png"></center>'
	elseif $ARGS[2] = 'sports':
		!'<center><b><font color="maroon">Viewing sportswear from Danilovich</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/sports.png"></center>'
	elseif $ARGS[2] = 'scandalicious':
		!'<center><b><font color="maroon">Viewing clothes from Scandalicious</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/scandalicious.png"></center>'
	elseif $ARGS[2] = 'scandalicious_swimwear':
		!'<center><b><font color="maroon">Viewing Swimwear from scandalicious</font></b></center>'
		'<center><img src="images/locations/city/citycenter/mall/scandalicious_swimwear.png"></center>'
	elseif $ARGS[2] = 'allure':
		!'<center><b><font color="maroon">Viewing Swimwear from allure</font></b></center>'
		'<center><img src="images/locations/pavlovsk/commercial/allure/shop_name.png"></center>'
	elseif $ARGS[2] = 'market':
		!'<center><b><font color="maroon">Viewing Swimwear from allure</font></b></center>'
		'<center>Clothing from the market</center>'
		*nl
	else
		'<center><b><font color="maroon">Click on a shop name to view clothes from that shop</font></b></center>'

		if $wloc = 'wardrobe':
			act 'Return': killvar '$ward_list_store' & gt 'wardrobe', 'start'
		elseif $ARGS[1] = 'sell' or $ARGS[1] = 'resize':
			act 'Leave': killvar '$ward_list_store' & gt $loc, $loc_arg
		else
			act 'Leave': killvar '$ward_list_store' & gt $loc, $loc_arg			
		end
	end
	*nl

	if $ARGS[1] ! 'sell':
		$clothing_header = '<center><table border=1>'
		if $ARGS[1] ! 'wardrobe': $clothing_header += '<TH><a href="exec:gt ''clothing'', ''view_clothing_list'', ''wardrobe'', ''<<$ward_list_store>>''">Switch to wardrobe list</a></TH>'
		$clothing_header += '<TH><a href="exec:gt ''clothing_QV'', ''list'', ''<<$ward_list_store>>''">Switch to icons</a></TH>'
		if $ARGS[1] ! 'store': $clothing_header += '<TH><a href="exec:gt ''clothing'', ''view_clothing_list'', ''store'', ''<<$ward_list_store>>''">Switch to stored clothing list</a></TH>'
		if $ARGS[1] ! 'unwanted': $clothing_header += '<TH><a href="exec:gt ''clothing'', ''view_clothing_list'', ''unwanted'', ''<<$ward_list_store>>''">Switch to unwanted clothing list</a></TH></center>'

		$clothing_header
		if $ARGS[1] = 'wardrobe':
			'<center>These are the clothes that are currently available for you to wear.</center><br>'
		elseif $ARGS[1] = 'store':
			'<center>These are the clothes you have stored that do not show up in your wardrobe list and cannot be sold at the market.</center><br>'
		elseif $ARGS[1] = 'unwanted':
			'<center>These are the clothes you''ve marked to be sold at the market.</center><br>'
		end
	end

	if $ARGS[2] = '':
		if ARRSIZE('gm_outfits') > 0 or ARRSIZE('gm_dress') > 0:'<center><a href="exec:$ward_list_store = ''gm'' & gt ''clothing'', ''view_clothing_list'', ''<<$ARGS[1]>>'', ''gm''"><img src="images/locations/city/citycenter/mall/gm.png"></a></center>'

		if ARRSIZE('gm_school') > 0:'<center><a href="exec:$ward_list_store = ''gm_school'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''gm_school''"><img src="images/pc/items/gm/school.png"></a></center>'

		if ARRSIZE('gm_office') > 0:'<center><a href="exec:$ward_list_store = ''gm_office'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''gm_office''"><img src="images/pc/items/gm/officewear.png"></a></center>'

		if ARRSIZE('gm_maid') > 0:'<center><a href="exec:$ward_list_store = ''gm_maid'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''gm_maid''"><img src="images/pc/items/gm/maid.png"></a></center>'

		if ARRSIZE('gm_server') > 0:'<center><a href="exec:$ward_list_store = ''gm_server'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''gm_server''"><img src="images/pc/items/gm/server.png"></a></center>'

		if ARRSIZE('misc_outfits') > 0:'<center><a href="exec:$ward_list_store = ''misc'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''misc''"><img src="images/pc/items/misc/misc.png"></a></center>'

		if ARRSIZE('cats_outfits') > 0 or ARRSIZE('cats_dress') > 0:'<center><a href="exec:$ward_list_store = ''kats'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''kats''"><img src="images/locations/city/citycenter/mall/pussycat.png"></a></center>'

		if ARRSIZE('flamingos_outfits') > 0 or ARRSIZE('flamingos_dress') > 0:'<center><a href="exec:$ward_list_store = ''flamingos'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''flamingos''"><img src="images/locations/city/island/flamingos/shop_name.png"></a></center>'

		if ARRSIZE('coco_outfits') > 0 or ARRSIZE('coco_dress') > 0:'<center><a href="exec:$ward_list_store = ''coco'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''coco''"><img src="images/locations/pavlovsk/coco/shop_name.png"></a></center>'

		if ARRSIZE('fashionista') > 0:'<center><a href="exec:$ward_list_store = ''fashionista'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''fashionista''"><img src="images/locations/city/citycenter/mall/fashionista.png"></a></center>'

		if ARRSIZE('moncheri_gown') > 0 or ARRSIZE('moncheri_dress') > 0:'<center><a href="exec:$ward_list_store = ''moncheri'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''moncheri''"><img src="images/locations/city/citycenter/mall/moncheri.png"></a></center>'

		if ARRSIZE('scandalicious_outfits') > 0 or ARRSIZE('scandalicious_dress') > 0:'<center><a href="exec:$ward_list_store = ''scandalicious'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''scandalicious''"><img src="images/locations/city/citycenter/mall/scandalicious.png"></a></center>'

		if ARRSIZE('scandalicious_bikinis') > 0 or ARRSIZE('scandalicious_swimsuit') > 0:'<center><a href="exec:$ward_list_store = ''scandalicious_swimwear'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''scandalicious_swimwear''"><img src="images/locations/city/citycenter/mall/scandalicious_swimwear.png"></a></center>'

		if ARRSIZE('allure_bikinis') > 0 or ARRSIZE('allure_swimsuit') > 0:'<center><a href="exec:$ward_list_store = ''allure'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''allure''"><img src="images/locations/pavlovsk/commercial/allure/shop_name.png"></a></center>'

		if ARRSIZE('fancy_burlesque') > 0:'<center><a href="exec:$ward_list_store = ''fancypancy'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''fancypancy''"><img src="images/locations/pushkin/fancypancy/shop_name.png"></a></center>'

		if ARRSIZE('eroto_dress') > 0 or ARRSIZE('eroto_outfits') > 0 or ARRSIZE('eroto_strip') > 0:'<center><a href="exec:$ward_list_store = ''sexshop'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''sexshop''"><img src="images/locations/city/redlight/erotomaniac/shop_name.png"></a></center>'

		if ARRSIZE('salacious_outfits') > 0 or ARRSIZE('salacious_dress') > 0:'<center><a href="exec:$ward_list_store = ''exhibitshop'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''exhibitshop''"><img src="images/locations/pushkin/exhibitshop/shop_name.png"></a></center>'

		if ARRSIZE('dolls_outfits') > 0 or ARRSIZE('dolls_dress') > 0:'<center><a href="exec:$ward_list_store = ''dolls'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''dolls''"><img src="images/locations/city/island/dolls/shop_name.png"></a></center>'

		if ARRSIZE('bomba_outfits') > 0 or ARRSIZE('bomba_dress') > 0:'<center><a href="exec:$ward_list_store = ''bomba'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''bomba''"><img src="images/locations/pushkin/bomba/shop_name.png"></a></center>'

		if ARRSIZE('danilovich') > 0:'<center><a href="exec:$ward_list_store = ''sports'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''sports''"><img src="images/locations/city/citycenter/mall/sports.png"></a></center>'

		if ARRSIZE('materinstvo_dress') > 0:'<center><a href="exec:$ward_list_store = ''materinstvo'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''materinstvo''"><img src="images/locations/city/citycenter/mall/mommy.png"></a></center>'

		if ARRSIZE('market_outfits') > 0:'<center><a href="exec:$ward_list_store = ''market'' & gt ''clothing'', ''view_clothing_list'', ''<<$ward_list_page>>'', ''market''">Clothes from the market</a></center>'
	else


		$bgcolor='#f3f4ee'

		if $ARGS[1] = 'sell':
			'<table border=0 cellspacing=0 cellpadding=5><TH></TH><TH>Strength</TH><TH>Hip size</TH><TH>Description</TH><TH>Bimbo</TH><TH>Prostitute</TH><TH>Actions</TH>'
		else
			'<table border=0 cellspacing=0 cellpadding=5><TH></TH><TH>Strength</TH><TH>Hip size</TH><TH>Description</TH><TH>Bimbo</TH><TH>Prostitute</TH><TH>Actions</TH><TH>Move to</TH>'
		end

		if $ARGS[1] = 'store':
			cloc = 1
		elseif $ARGS[1] = 'unwanted':
			cloc = 2
		else
			cloc = 0
		end

		if $ARGS[2] = 'gm':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopgm_outfits
				if gm_outfits[i] = 1 and gm_outfits_s[i] = cloc and ($clothingworntype ! 'gm_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'gm_outfits', i)
				i += 1
			if i <= ARRSIZE('gm_outfits'):jump 'loopgm_outfits'

			$ward_list_store = $ARGS[2]
			i = 1
			:loopgm_dress
				if gm_dress[i] = 1 and gm_dress_s[i] = cloc and ($clothingworntype ! 'gm_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'gm_dress', i)
				i += 1
			if i <= ARRSIZE('gm_dress'):jump 'loopgm_dress'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'gm_office':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopoffice
				if gm_office[i] = 1 and gm_office_s[i] = cloc and ($clothingworntype ! 'gm_office' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'gm_office', i)
				i += 1
			if i <= ARRSIZE('gm_office'):jump 'loopoffice'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'gm_school':
			$ward_list_store = $ARGS[2]

			if StoryLine = 1 and SchoolAtestat = 0 and SchoolBlock = 0 and gm_school_s[6] = cloc and ($clothingworntype ! 'gm_school' or clothingwornnumber ! 6):*P dyneval($clothing_list_line, $ARGS[1], 'gm_school', 6)

			i = 1
			:loopschool
				if gm_school[i] = 1 and gm_school_s[i] = cloc and ($clothingworntype ! 'gm_school' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'gm_school', i)
				i += 1
				if i = 6: i = 7
			if i <= ARRSIZE('gm_school'):jump 'loopschool'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'gm_maid':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopgm_maid
				if gm_maid[i] = 1 and gm_maid_s[i] = cloc and ($clothingworntype ! 'gm_maid' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'gm_maid', i)
				i += 1
			if i <= ARRSIZE('gm_maid'):jump 'loopgm_maid'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'gm_server':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopgm_server
				if gm_server[i] = 1 and gm_server_s[i] = cloc and ($clothingworntype ! 'gm_server' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'gm_server', i)
				i += 1
			if i <= ARRSIZE('gm_server'):jump 'loopgm_server'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'misc':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopmisc_outfits
				if misc_outfits[i] = 1 and misc_outfits_s[i] = cloc and ($clothingworntype ! 'misc_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'misc_outfits', i)
				i += 1
			if i <= ARRSIZE('misc_outfits'):jump 'loopmisc_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'kats':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopcats_dress
				if cats_dress[i] = 1 and cats_dress_s[i] = cloc and ($clothingworntype ! 'cats_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'cats_dress', i)
				i += 1
			if i <= ARRSIZE('cats_dress'):jump 'loopcats_dress'

			i = 1
			:loopcats_outfits
				if cats_outfits[i] = 1 and cats_outfits_s[i] = cloc and ($clothingworntype ! 'cats_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'cats_outfits', i)
				i += 1
			if i <= ARRSIZE('cats_outfits'):jump 'loopcats_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'flamingos':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopflamingos_dress
				if flamingos_dress[i] = 1 and flamingos_dress_s[i] = cloc and ($clothingworntype ! 'flamingos_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'flamingos_dress', i)
				i += 1
			if i <= ARRSIZE('flamingos_dress'):jump 'loopflamingos_dress'

			i = 1
			:loopflamingos_outfits
				if flamingos_outfits[i] = 1 and flamingos_outfits_s[i] = cloc and ($clothingworntype ! 'flamingos_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'flamingos_outfits', i)
				i += 1
			if i <= ARRSIZE('flamingos_outfits'):jump 'loopflamingos_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'coco':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopcoco_dress
				if coco_dress[i] = 1 and coco_dress_s[i] = cloc and ($clothingworntype ! 'coco_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'coco_dress', i)
				i += 1
			if i <= ARRSIZE('coco_dress'):jump 'loopcoco_dress'

			i = 1
			:loopcoco_outfits
				if coco_outfits[i] = 1 and coco_outfits_s[i] = cloc and ($clothingworntype ! 'coco_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'coco_outfits', i)
				i += 1
			if i <= ARRSIZE('coco_outfits'):jump 'loopcoco_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'fashionista':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopfashionista
				if fashionista[i] = 1 and fashionista_s[i] = cloc and ($clothingworntype ! 'fashionista' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'fashionista', i)
				i += 1
			if i <= ARRSIZE('fashionista'):jump 'loopfashionista'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'moncheri':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopmoncheri_dress
				if moncheri_dress[i] = 1 and moncheri_dress_s[i] = cloc and ($clothingworntype ! 'moncheri_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'moncheri_dress', i)
				i += 1
			if i <= ARRSIZE('moncheri_dress'):jump 'loopmoncheri_dress'

			i = 1
			:loopmoncheri_gown
				if moncheri_gown[i] = 1 and moncheri_gown_s[i] = cloc and ($clothingworntype ! 'moncheri_gown' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'moncheri_gown', i)
				i += 1
			if i <= ARRSIZE('moncheri_gown'):jump 'loopmoncheri_gown'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'scandalicious':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopscandalicious_dress
				if scandalicious_dress[i] = 1 and scandalicious_dress_s[i] = cloc and ($clothingworntype ! 'scandalicious_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'scandalicious_dress', i)
				i += 1
			if i <= ARRSIZE('scandalicious_dress'):jump 'loopscandalicious_dress'

			i = 1
			:loopscandalicious_outfits
				if scandalicious_outfits[i] = 1 and scandalicious_outfits_s[i] = cloc and ($clothingworntype ! 'scandalicious_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'scandalicious_outfits', i)
				i += 1
			if i <= ARRSIZE('scandalicious_outfits'):jump 'loopscandalicious_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'scandalicious_swimwear':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopscandalicious_bikinis
				if scandalicious_bikinis[i] = 1 and scandalicious_bikinis_s[i] = cloc and ($clothingworntype ! 'scandalicious_bikinis' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'scandalicious_bikinis', i)
				i += 1
			if i <= ARRSIZE('scandalicious_bikinis'):jump 'loopscandalicious_bikinis'

			$ward_list_store = $ARGS[2]
			i = 1
			:loopscandalicious_swimsuit
				if scandalicious_swimsuit[i] = 1 and scandalicious_swimsuit_s[i] = cloc and ($clothingworntype ! 'scandalicious_swimsuit' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'scandalicious_swimsuit', i)
				i += 1
			if i <= ARRSIZE('scandalicious_swimsuit'):jump 'loopscandalicious_swimsuit'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'allure':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopallure_bikinis
				if allure_bikinis[i] = 1 and allure_bikinis_s[i] = cloc and ($clothingworntype ! 'allure_bikinis' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'allure_bikinis', i)
				i += 1
			if i <= ARRSIZE('allure_bikinis'):jump 'loopallure_bikinis'

			$ward_list_store = $ARGS[2]
			i = 1
			:loopallure_swimsuit
				if allure_swimsuit[i] = 1 and allure_swimsuit_s[i] = cloc and ($clothingworntype ! 'allure_swimsuit' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'allure_swimsuit', i)
				i += 1
			if i <= ARRSIZE('allure_swimsuit'):jump 'loopallure_swimsuit'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'sexshop':
			$ward_list_store = $ARGS[2]
			i = 1
			:looperoto_dress
				if eroto_dress[i] = 1 and eroto_dress_s[i] = cloc and ($clothingworntype ! 'eroto_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'eroto_dress', i)
				i += 1
			if i <= ARRSIZE('eroto_dress'):jump 'looperoto_dress'

			$ward_list_store = $ARGS[2]
			i = 1
			:looperoto_outfits
				if eroto_outfits[i] = 1 and eroto_outfits_s[i] = cloc and ($clothingworntype ! 'eroto_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'eroto_outfits', i)
				i += 1
			if i <= ARRSIZE('eroto_outfits'):jump 'looperoto_outfits'

			$ward_list_store = $ARGS[2]
			i = 1
			:looperoto_strip
				if eroto_strip[i] = 1 and eroto_strip_s[i] = cloc and ($clothingworntype ! 'eroto_strip' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'eroto_strip', i)
				i += 1
			if i <= ARRSIZE('eroto_strip'):jump 'looperoto_strip'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'exhibitshop':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopsalacious_dress
				if salacious_dress[i] = 1 and salacious_dress_s[i] = cloc and ($clothingworntype ! 'salacious_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'salacious_dress', i)
				i += 1
			if i <= ARRSIZE('salacious_dress'):jump 'loopsalacious_dress'

			$ward_list_store = $ARGS[2]
			i = 1
			:loopsalacious_outfits
				if salacious_outfits[i] = 1 and salacious_outfits_s[i] = cloc and ($clothingworntype ! 'salacious_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'salacious_outfits', i)
				i += 1
			if i <= ARRSIZE('salacious_outfits'):jump 'loopsalacious_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'fancypancy':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopfancy_burlesque
				if fancy_burlesque[i] = 1 and fancy_burlesque_s[i] = cloc and ($clothingworntype ! 'fancy_burlesque' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'fancy_burlesque', i)
				i += 1
			if i <= ARRSIZE('fancy_burlesque'):jump 'loopfancy_burlesque'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'dolls':
			cla
			$ward_list_store = $ARGS[2]
			i = 1
			:loopdolls_outfits
				if dolls_outfits[i] = 1 and dolls_outfits_s[i] = cloc and ($clothingworntype ! 'dolls_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'dolls_outfits', i)
				i += 1
			if i <= ARRSIZE('dolls_outfits'):jump 'loopdolls_outfits'

			$ward_list_store = $ARGS[2]
			i = 1
			:loopdolls_dress
				if dolls_dress[i] = 1 and dolls_dress_s[i] = cloc and ($clothingworntype ! 'dolls_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'dolls_dress', i)
				i += 1
			if i <= ARRSIZE('dolls_dress'):jump 'loopdolls_dress'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'bomba':
			cla
			$ward_list_store = $ARGS[2]
			i = 1
			:loopbomba_outfits
				if bomba_outfits[i] = 1 and bomba_outfits_s[i] = cloc and ($clothingworntype ! 'bomba_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'bomba_outfits', i)
				i += 1
			if i <= ARRSIZE('bomba_outfits'):jump 'loopbomba_outfits'

			i = 1
			:loopbomba_dress
				if bomba_dress[i] = 1 and bomba_dress_s[i] = cloc and ($clothingworntype ! 'bomba_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'bomba_dress', i)
				i += 1
			if i <= ARRSIZE('bomba_dress'):jump 'loopbomba_dress'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'sports':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopdanilovich
				if danilovich[i] = 1 and danilovich_s[i] = cloc and ($clothingworntype ! 'danilovich' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'danilovich', i)
				i += 1
			if i <= ARRSIZE('danilovich'):jump 'loopdanilovich'

			i = 1
			:loopdanilovich_swimsuit
				if danilovich_swimsuit[i] = 1 and danilovich_swimsuit_s[i] = cloc :*P dyneval($clothing_list_line, $ARGS[1], 'danilovich_swimsuit', i)
				i += 1
			if i <= ARRSIZE('danilovich_swimsuit'):jump 'loopdanilovich_swimsuit'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'market':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopmarket_outfits
				if market_outfits[i] = 1 and market_outfits_s[i] = cloc and ($clothingworntype ! 'market_outfits' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'market_outfits', i)
				i += 1
			if i <= ARRSIZE('market_outfits'):jump 'loopmarket_outfits'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		if $ARGS[2] = 'materinstvo':
			$ward_list_store = $ARGS[2]
			i = 1
			:loopmaterinstvo_dress
				if materinstvo_dress[i] = 1 and materinstvo_dress_s[i] = cloc and ($clothingworntype ! 'materinstvo_dress' or clothingwornnumber ! i):*P dyneval($clothing_list_line, $ARGS[1], 'materinstvo_dress', i)
				i += 1
			if i <= ARRSIZE('materinstvo_dress'):jump 'loopmaterinstvo_dress'

			act 'Return': killvar '$ward_list_store' & gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
			gs 'clothing', 'clothwidth'
		end

		'</table>'
	end
end

if $ARGS[0] = 'clothwidth':
	act 'Set image size for this view': 
		Enable_clothwidth = input("Enter height in pixels you want for images on this page <br>(Default 150, min 50, max 500)")
		if Enable_clothwidth < 50:
			Enable_clothwidth = 50
		elseif Enable_clothwidth > 500:
			Enable_clothwidth = 500
		end
		gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
	end
end

if $ARGS[0] = 'view_clothing_item':
	!! ARGS 0 - view_clothing_item
	!! ARGS 1 = action type (wardrobe, shop, sell, resize)
	!! ARGS 2 - clothing type
	!! ARGS 3 - clothing index
	!! ARGS 4 - price for shop

	$swimwear_description = ''

	cla
	'<center><img src="<<FUNC(''$clothing_image'',  $ARGS[2], ARGS[3])>>"></center>'
	gs 'clothing_attributes', $ARGS[2], ARGS[3]
	$RESULT = FUNC('$short_description', $ARGS[2], CloStyle2)
	$RESULT += '<<ARGS[3]>>'
	'<<$RESULT>>'
	if $ARGS[2] = 'misc_outfits' and ARGS[3] = 1:
		'A hessian sack the hunters gave you.'
	elseif $swimwear_description = '':
		gs 'clothing_descriptions'
		'<<$description>>'
	else
		$swimwear_description
	end

	if CloBimbo = 1 and cheatbimbo = 0:'This item is considered bimbo clothing.'

	if CloStyle = 4:'This outfit can be used for prostitution.'

	if CloInhibit > 10:
		if CloInhibit + 10 > pcs_inhib and CloInhibit <= pcs_inhib: 'You find this outfit more revealing than you are completely comfortable with but that makes it quite exciting too.'
	end

!!CloStyle2: 1 Maid, 2 Server, 3 Stripper, 4 School
	if CloStyle2 = 1: 'This is a maid outfit.'
	if CloStyle2 = 2: 'This outfit is a server uniform.'
	if CloStyle2 = 3: 'This outfit is a stripper uniform, suitable for jobs that require one.'

	if CloStyle2 = 4:
		if CloInhibit <= 10:
			'<font color="blue">This uniform is very conservative. Only the nerds would approve of you wearing it.</font>'
		elseif CloSkirtShortness < 5 and CloThinness < 5 and CloBra = 0:
			if CloQuality = 4:
				'<font color="blue">This uniform complies with the regulations and is of good quality. It would certainly help you with your standing with the cool kids and jocks.</font>'
			else
				'<font color="blue">This uniform complies with the school regulations on skirt length. Nobody in school would be offended by you wearing it.</font>'
			end
		elseif CloSkirtShortness = 5 and CloThinness < 5 and CloBra = 0:
			if CloQuality = 4:
				'<font color="blue">This uniform slightly breaches the school regulations on skirt length and is of good quality. Everybody apart from the nerds would approve of you wearing it.</font>'
			else
				'<font color="blue">This uniform slightly breaches the school regulations on skirt length. The gopnik would approve of you wearing it.</font>'
			end
		else
			'<font color="red">This uniform makes a mockery of the school uniform regulations. Everybody in school apart from the gopniks will think that you''re a slut.</font>'
		end
	end

	if $ARGS[1] ! 'shop' and ($ARGS[2] ! 'gm_school' or ARGS[3] ! 6):
		$RESULT = '(strength '
		dynamic '$RESULT += <<$ARGS[2]>>_h[<<ARGS[3]>>]'
		if $ARGS[2] ! 'danilovich' and $ARGS[2] ! 'coat' and CloStyle ! 5:
			$RESULT += ', hip size '
			dynamic '$RESULT += <<$ARGS[2]>>_b[<<ARGS[3]>>]'
		end
		$RESULT += ')'
		'<<$RESULT>>'
	end

	if $ARGS[1] = 'shop':
		if dyneval('RESULT = <<$ARGS[2]>>[<<ARGS[3]>>]') = 1:
			'You already own this item.'
			act 'Leave': gt $loc, $loc_arg
		else
			if $ARGS[2] = 'coat' and ARGS[3] = 5:
				price = ARGS[4]
			else
				price = ('<<ARGS[4]>>' * ((5 * CloQuality) + 100) / 100) * 1000 / (1250 - Clothingstock[ARGS[3]]) * 3 / 2
				price = price / 50 * 50
			end
			'Price: <<price>> <b>₽</b>'
			act 'Leave': gt $loc, $loc_arg
			if CloInhibit > pcs_inhib:
				'You don''t feel daring enough to wear an outfit this revealing and can''t bring yourself to buy it.'
			elseif karta + bankDebtLimit < Price and money < Price:
				'You cannot afford this outfit.'
			else
				if money >= Price:
					act 'Buy (cash)':
						h = 0
						if CloStyle = 2:h = 10
						if CloStyle = 5:h = 20
						h += (3 * CloQuality)
						money -= price
						gs 'clothing', 'view_clothing_item_buy', $ARGS[1], $ARGS[2], ARGS[3], ARGS[4]
					end
				end
				if karta + bankDebtLimit >= Price:
					act 'Buy (card)':
						h = 0
						if CloStyle = 2:h = 10
						if CloStyle = 5:h = 20
						h += (3 * CloQuality)
						karta -= price
						gs 'clothing', 'view_clothing_item_buy', $ARGS[1], $ARGS[2], ARGS[3], ARGS[4]
					end
				end
			end
		end
	elseif $ARGS[1] = 'wardrobe':
		act 'Return':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'

		if $ARGS[2] ! 'gm_school' or ARGS[3] ! 6:
			!! if the clothing is worn out
			if dyneval('RESULT = <<$ARGS[2]>>_h[<<ARGS[3]>>]') <= 0:
				'This item is worn and is not suitable for further wear.'
				if pcs_sewng >= 60 and tkan > 0:
					cla
					'You can repair this thanks to your sewing skill.'
					act 'Repair item':
						if rand (1, 100) < 30:
							*clr
							cla
							tkan -= 1
							minut += 30
							dynamic $ARGS[2] + '_h[<<ARGS[3]>>] += 30'
							'<center><img <<$set_imgh>> src="images/pc/activities/sewing/fix' + rand(1,2) + '.jpg"></center>'
							'You spend 30 minutes fixing the outfit.'
							act 'Return':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
						else
							*clr
							cla
							tkan += 3
							minut += 30
							dynamic $ARGS[2] + '[<<ARGS[3]>>] = 0'
							'<center><img <<$set_imgh>> src="images/pc/activities/sewing/fix' + rand(1,2) + '.jpg"></center>'
							'Despite your skill with a needle, this outfit has proved beyond repair. All that is left of it is only good for your cloth pile.'
							act 'Return':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>'
						end
					end
					act 'Return': gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
				end
			exit

			end

			!! if the clothing is a type that checks for hip size
			if $ARGS[2] ! 'danilovich' and CloStyle ! 5:
				!! if the hipsize is too far from your hipsize
				dynamic 'RESULT = <<$ARGS[2]>>_b[<<ARGS[3]>>]'
				if RESULT < pcs_hips - 8 or RESULT > pcs_hips + 8:
					if RESULT < pcs_hips:
						'This item is too small for you to wear.'
					else
						'This item is too large for you to wear.'
					end

					if (pcs_sewng >= 50 and tkan > 0) or $loc_arg = 'tailor':
						cla & *nl
						if $loc_arg = 'tailor':
							'You can pay to have this resized for (500 <b>₽</b>).'
						else
							'You can resize this thanks to your sewing skill.'
						end
						
						act 'Return': gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
						
						act 'Resize item':
							cla
							if $loc_arg = 'tailor':
								minut += 15
								money -= 500
								dynamic $ARGS[2] + '_b[<<ARGS[3]>>] = pcs_hips'
								*nl
								'You hand the clothing over to the tailor who takes it into the back. Fifteen minutes later, he presents your clothing back to you, adjusted to fit you perfectly.'
							else
								tkan -= 1
								minut += 30
								dynamic $ARGS[2] + '_b[<<ARGS[3]>>] = pcs_hips'
								'You spend 30 minutes resizing the outfit.'
							end
							act 'Return':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
						end
					end
				exit

				end
			end
		end

		if $ARGS[2] ! 'danilovich_swimsuit' and $ARGS[2] ! 'scandalicious_bikinis' and $ARGS[2] ! 'scandalicious_swimsuit' and $ARGS[2] ! 'allure_bikinis' and $ARGS[2] ! 'allure_bikinis':

			if CloInhibit > pcs_inhib:
				'You don''t feel daring enough to wear an outfit this revealing.'
			elseif ARRPOS('$CloLosTyp', $ARGS[2]) ! -1 and ARRPOS('CloLosNum',ARGS[3]) ! -1 :
				'You lost these clothes somewhere, maybe you can find them again?.'
			else
				act 'Wear':
					gs 'clothing', 'wear', $ARGS[2], ARGS[3]

					gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
				end
			end
		end
	elseif $ARGS[1] = 'store' or $ARGS[1] = 'unwanted':
		act 'Return':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'

		if $ARGS[2] ! 'coat':
			act 'Move back to wardrobe':
				dynamic $ARGS[2] + '_s[<<ARGS[3]>>] = 0'
				gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
			end
		end

	elseif $ARGS[1] = 'sell':
		$ward_list_page = $ARGS[1]
		act 'Keep item':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'

		!! value is based on the strength remaining
		dynamic 'RESULT = <<$ARGS[2]>>_h[<<ARGS[3]>>]'
		if RESULT > 45:
			'You can sell this item for 500 <b>₽</b>.'
			act 'Sell':
				dynamic '<<$ARGS[2]>>[<<ARGS[3]>>] = 0'
				money += 500
				gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
			end
		elseif RESULT > 30:
			'You can sell this item for 300 <b>₽</b>.'
			act 'Sell':
				dynamic '<<$ARGS[2]>>[<<ARGS[3]>>] = 0'
				money += 300
				gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
			end
		elseif RESULT > 0:
			'You can sell this item for 100 <b>₽</b>.'
			act 'Sell':
				dynamic '<<$ARGS[2]>>[<<ARGS[3]>>] = 0'
				money += 100
				gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
			end
		else
			'This item is too worn to have any sale value.'
			act 'Throw it away':
				dynamic '<<$ARGS[2]>>[<<ARGS[3]>>] = 0'
				gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'
			end
		end
	elseif $ARGS[1] = 'resize':
		act 'Leave item alone':gt 'clothing', 'view_clothing_list', '<<$ward_list_page>>', '<<$ward_list_store>>'

		if $ARGS[2] ! 'danilovich' and $ARGS[2] ! 'coat' and CloStyle ! 5:
			if dyneval('RESULT = <<$ARGS[2]>>_b[<<ARGS[3]>>]') ! pcs_hips and money >= 500:
				'You can have this resized for 500 <b>₽</b>.'
				act 'Resize':
					money -= 500
					dynamic '<<$ARGS[2]>>_b[<<ARGS[3]>>] = pcs_hips'
					gt 'clothing', 'view_clothing_list', 'resize'
				end
			end
		end
	end
end

if $ARGS[0] = 'view_clothing_item_buy':
	dynamic $ARGS[2] + '[<<ARGS[3]>>] = 1'
	if $ARGS[2] = 'gm_outfits' or $ARGS[2] = 'gm_dress' or $ARGS[2] = 'gm_office':
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 70 + <<h>>'
	elseif $ARGS[2] = 'cats_dress' or $ARGS[2] = 'cats_outfits' or $ARGS[2] = 'flamingos_dress' or $ARGS[2] = 'flamingos_outfits' or $ARGS[2] = 'coco_dress' or $ARGS[2] = 'coco_outfits':
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 90 + <<h>>'
	elseif $ARGS[2] = 'moncheri_gown' or $ARGS[2] = 'moncheri_dress':
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 25 + <<h>>'
	elseif $ARGS[2] = 'eroto_dress' or $ARGS[2] = 'eroto_outfits' or $ARGS[2] = 'eroto_strip' or $ARGS[2] = 'salacious_outfits' or $ARGS[2] = 'salacious_dress' or $ARGS[2] = 'fancy_burlesque':
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 40 + <<h>>'
	elseif $ARGS[2] = 'gm_school' or $ARGS[2] = 'gm_maid' or $ARGS[2] = 'gm_server':
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 120 + <<h>>'
	elseif $ARGS[2] = 'danilovich':
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 100 + <<h>>'
	else
		dynamic $ARGS[2] + '_h[<<ARGS[3]>>] = 60 + <<h>>'
	end
	dynamic $ARGS[2] + '_b[<<ARGS[3]>>] = pcs_hips'
	dynamic $ARGS[2] + '_s[<<ARGS[3]>>] = 0'
	gs 'stat'
	gt $loc, $loc_arg
end

if $ARGS[0] = 'strip_all':
	$strip_loc = $ARGS[1]
	gs 'underwear', 'remove'
	gs 'clothing', 'strip', $strip_loc
end

if $ARGS[0] = 'strip':
	!$strip_loc = location when stripping outdoors
	$strip_loc = $ARGS[1]
	if $clothingworntype = 'nude': exit
	cumspclnt = 6
	gs 'cum_cleanup'
	if cloth_vid = 1:
		last_vid = 1
	else
		last_vid = 0
	end

	if PCloStyle2 = 4:
		$schbrand = $clothingworntype
		schtype = clothingwornnumber
	end

	if $strip_loc ! '' :
		DYNAMIC '$CloLos<<$clothingworntype>>[<<clothingwornnumber>>]=<<$strip_loc>>'
		$CloLosLoc[] = $strip_loc
		$CloLosTyp[$strip_loc] = $clothingworntype
		CloLosNum[$strip_loc] = clothingwornnumber
		CloLosDay[$strip_loc] = daystart
		KILLVAR '$lastwornclothingtype'
		KILLVAR 'lastwornclothingnumber'
	else
		$lastwornclothingtype = $clothingworntype
		lastwornclothingnumber = clothingwornnumber
	end

	killvar '$strip_loc'

	$clothingworntype = 'nude'
	clothingwornnumber = 0
	CloQuality = 0
	CloThinness = 0
	CloTopCut = 0
	CloBra = 0
	CloPantsShortness = 0
	CloSkirtShortness = 0
	CloPanties = 0
	CloStyle = 0
	CloStyle2 = 0
	CloBimbo = 0
	CloOnePiece = 0
	PShoQuaility = 0
	PShoCut = 0
	PShoHeels = 0
	PShoStyle = 0
	PCloQuality = 0
	PCloThinness = 0
	PCloTopCut = 0
	PCloPants = 0
	PCloSkirt = 0
	PCloStyle = 0
	PCloStyle2 = 0
	PCloBimbo = 0
	PCloInhibit = 0
	PCloOnePiece = 0
	PCloswimwear = 0
	PXCloThinness = 0
	PXCloTopCut = 0
	PXCloBottomShortness = 0
	glamur = 0
	sport = 0
	ski = 0
	ofclo = 0
	sexual = 0
	odevnesh = 0
	! WD: Bimbo look
	cloth_vid = 0
	exhibiHideNewCloth = 0
end


if $ARGS[0] = 'recover_lost_clothes':
	!$ARGS[1] = location
	!ARGS[2] = 1 : wear the clothes, ARGS[2] = 2 : Return to shop (lost FOREVAH!)
	$cloLoc = $ARGS[1]
	cloAction = ARGS[2]

	$clothType = $CloLosTyp[$cloLoc]
	clothNumber = CloLosNum[$cloLoc]
	dayLost = CloLosDay[$cloLoc]

	DYNAMIC 'KILLVAR ''$CloLos<<$clothingworntype>>'', <<clothingwornnumber>>'
	findLocInd = ARRPOS('$CloLosTyp', $clothType)
	KILLVAR '$CloLosTyp', findLocInd
	findLocInd = ARRPOS('CloLosNum', clothNumber)
	KILLVAR 'CloLosNum', findLocInd
	findLocInd = ARRPOS('CloLosDay', CloLosDay[$cloLoc])
	KILLVAR 'CloLosDay', findLocInd
	findLocInd = ARRPOS('$CloLosLoc', $cloLoc)
	KILLVAR '$CloLosLoc', findLocInd
	KILLVAR 'findLocInd'

	if cloAction = 1:
		gs 'clothing', 'wear', $clothType, clothNumber
	elseif cloAction = 2 :
		dynamic $clothType + '_s[<<clothNumber>>] = 1'
	end

	KILLVAR '$cloLoc'
	KILLVAR 'cloAction'
	KILLVAR '$clothType'
	KILLVAR 'clothNumber'
end

if $ARGS[0] = 'wear':
	!! ARGS 0 - action
	!! ARGS 1 - clothing type name
	!! ARGS 2 - clothing index

	gs 'clothing', 'strip'

	$clothingworntype = $ARGS[1]
	clothingwornnumber = ARGS[2]

	dynamic $ARGS[1] + '_w[<<ARGS[2]>>] = 1'

	gs 'clothing_attributes', $ARGS[1], ARGS[2]

	dynamic '<<$ARGS[1]>>_s[<<ARGS[2]>>] = 0'

	if CloStyle2 = 4:
		$schbrand = $clothingworntype
		schtype = clothingwornnumber
	end

	PCloQuality = CloQuality
	PCloThinness = CloThinness
	PCloTopCut = CloTopCut
	PCloBra = CloBra
	PCloOnePiece = CloOnePiece
	PCloPants = CloPantsShortness
	PCloSkirt = CloSkirtShortness
	PCloPanties = CloPanties
	PCloStyle = CloStyle
	PCloStyle2 = CloStyle2
	PCloInhibit = CloInhibit
	if cheatbimbo = 0:
		PCloBimbo = CloBimbo
		!! This is counter for setting bimbo points overnight, don''t change bimbocl setting unless changing that
		if CloBimbo = 1: bimbocl = 1
	else
		PCloBimbo = 0
		CloBimbo = 0
		bimbocl = 0
	end

	if PCloTopCut > 1:
		if tits = 2 or tits = 3: PCloTopCut += 1
		if tits >= 4: PCloTopCut += 2
		if PCloTopCut > 2 and tits >=6: PCloTopCut += 1
	end

!Calculations for clothing beauty, multiplied by natural beauty
	if PCloThinness > 0:
		if PCloThinness = 1:
			PXCloThinness = 150
		elseif PCloThinness = 2:
			PXCloThinness = 200
		elseif PCloThinness = 3:
			PXCloThinness = 250
		elseif PCloThinness = 4:
			PXCloThinness = 300
		elseif PCloThinness = 5:
			PXCloThinness = 350
		elseif PCloThinness = 6:
			PXCloThinness = 400
		end
	end

	if PCloTopCut > 0:
		if PCloTopCut = 1:
			PXCloTopCut = 100
		elseif PCloTopCut = 2:
			PXCloTopCut = 150
		elseif PCloTopCut = 3:
			PXCloTopCut = 200
		elseif PCloTopCut = 4:
			PXCloTopCut = 250
		elseif PCloTopCut = 5:
			PXCloTopCut = 300
		elseif PCloTopCut = 6:
			PXCloTopCut = 350
		elseif PCloTopCut >= 7:
			PXCloTopCut = 400
		end
	end

	if PCloBra = 1:
		PXCloTopCut = 400
		$braworntype = 'none'
	elseif PCloBra = 2:
		PXCloTopCut = 500
	end

	if PCloSkirt > 0:
		if PCloSkirt = 1:
			PXCloBottomShortness = 100
		elseif PCloSkirt = 2:
			PXCloBottomShortness = 150
		elseif PCloSkirt = 3:
			PXCloBottomShortness = 200
		elseif PCloSkirt = 4:
			PXCloBottomShortness = 250
		elseif PCloSkirt = 5:
			PXCloBottomShortness = 300
		elseif PCloSkirt = 6:
			PXCloBottomShortness = 350
		elseif PCloSkirt >= 7:
			PXCloBottomShortness = 400
		end
	end

	if PCloPants > 0:
		if PCloPants = 1:
			PXCloBottomShortness = 100
		elseif PCloPants = 2:
			PXCloBottomShortness = 150
		elseif PCloPants = 3:
			PXCloBottomShortness = 200
		elseif PCloPants = 4:
			PXCloBottomShortness = 250
		elseif PCloPants = 5:
			PXCloBottomShortness = 300
		elseif PCloPants = 6:
			PXCloBottomShortness = 350
		elseif PCloPants >= 7:
			PXCloBottomShortness = 400
		end
	end

	if PCloPanties = 1: PXCloBottomShortness = 400

	if $clothingworntype = 'danilovich_swimsuit' or $clothingworntype = 'scandalicious_swimsuit' or $clothingworntype = 'scandalicious_bikinis' or $clothingworntype = 'allure_swimsuit' or $clothingworntype = 'allure_bikinis': PCloswimwear = 1
end

if $ARGS[0] = 'wear_last_worn':
	!!contingency
	if $lastwornclothingtype = '': $lastwornclothingtype = 'nude'
	gs 'clothing', 'wear', $lastwornclothingtype, lastwornclothingnumber
end

if $ARGS[0] = 'swamp_clothes':
	if ARGS[1] = 1:
	!hessian clothing to owned, sets size and equipped.
		misc_outfits[1] = 1
		misc_outfits_s[1] = 0
		misc_outfits_h[1] = 100
		misc_outfits_b[1] = pcs_hips
		swamp_clothes = 1
		gs 'clothing', 'wear', 'misc_outfits', 1
	end
	if ARGS[1] = 0:
	!hessian clothing no longer owned, but not unequipped.
		misc_outfits[1] = 0
		swamp_clothes = 0
	end
end
--- clothing ---------------------------------

