glife-arm/locations/gdksport.qsrc

# gdksport
!2021/05/02

if $ARGS[0] = 'start':
	CLOSE ALL
	*clr & cla
	$loc_arg ='start'
	$locM_arg = 'start'
	$loc = 'gdksport'
	$locM = 'gdksport'
	$menu_loc = 'gdksport'
	$menu_arg = 'start'
	menu_off = 0
	$location_type = 'public_indoors'
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">community center</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/gdksport.jpg"></center>'
	'The community center sports club offers lessons in <a href="exec: gt ''gdksport'',''racing1''">Racing</a>, <a href="exec: gt ''gdksport'',''dance1''">Dance</a> and <a href="exec: gt ''gdksport'',''vball1''">Volleyball</a>. All lessons start before 18:00'
	*nl
	'In the locker room is a <a href="exec: gt ''mirror'',''start''">mirror</a>, where you can ' + iif(pcs_hairbsh = 0,'<a href="exec: gt ''mirror'',''brush''">brush</a>','brush') + ' your hair.'
	*nl
	'You can access your <a href="exec: quick_dress = 1 & gt ''wardrobe'', ''default''">default clothing</a> options directly.'
	*nl
	if AlbinaQW['StarletsJoined'] > 0 and AlbinaQW['StarletsShutDown'] = 0 and npc_pregtalk['A23'] = 0 and cheerleaders_on = 1: 'Albina is at cheerleading, so there is no Starlets training today.'

	if kotovLoveQW > 0 and hour = 16:
		'You see <a href="exec:minut += 3 & gt ''kotovEv''">Vitek Kotov</a> with a large sports bag entering the sports club.'
	elseif npc_rel['A3'] >= 80 and hour = 17 and ivansportday ! daystart:
		'You see <a href="exec:minut += 3 & gt ''IvanEv''">Ivan Prokhorov</a> with a large sports bag entering the sports club.'
	end

	if npc_rel['A5'] >= 80 and fedorKozlovQW = 0 and hotcat >= 5 and fedorkozbreak < 2 and pav_slut <= 75: gt 'gdksport', 'Fedor First Date'

	if week <= 5 and hour >= 16 and hour < 18 and fedorKozlovQW >= 20:
		'You can see <a href="exec: gt ''FedorMisc'', ''Fedor Workout''">Fedor</a> on his phone next to some punching bags.'
	end
	
	if (temper < 15 or sunWeather ! 1) and hour > 8 and hour < 12 and week = 6 and bbpickupDay + 14 <= daystart and fbpickupDay ! daystart:
		*nl
		'As you pass by the sports field you notice that most of the ''jocks'' have gathered around the <a href="exec:gt ''bbgamein'', ''start''">basketball court</a>.'
	end

	*nl
	if $clothingworntype ! 'danilovich': 'You are not dressed in sports clothes.'
	if $shoeworntype ! 'danilovich': 'You are not wearing training shoes.'

	act 'Go outside':
		if $clothingworntype = 'nude':
			msg'<b><font color = red>You need to get dressed before leaving.</font></b>'
			gt 'gdksport', 'start'
		elseif lariskaQwestStart <= daystart and lariskaQwestStart ! 0 and LariskaQW['LariskaHelp'] = 0:
			LariskaQW['LariskaHelp'] = 1
			gt 'LariskaStart', 'start'
		elseif LariskaQW['LariskaHelp'] = 1 and LariskaQW['LariskaHelpEnd'] = 0 and lariskaQwestDay <= daystart:
			LariskaQW['LariskaHelpEnd'] = 1
			gt 'LariskaStart', 'end'
		else
			gt 'pav_commcenter'
		end
	end

	act 'Go to the toilets':
		if $clothingworntype = 'nude':
			msg'<b><font color = red>You need to get dressed before leaving.</font></b>'
			gt 'gdksport', 'start'
		elseif lariskaQwestStart <= daystart and lariskaQwestStart ! 0 and LariskaQW['LariskaHelp'] = 0:
			LariskaQW['LariskaHelp'] = 1
			gt 'LariskaStart', 'start'
		elseif LariskaQW['LariskaHelp'] = 1 and LariskaQW['LariskaHelpEnd'] = 0 and lariskaQwestDay <= daystart:
			LariskaQW['LariskaHelpEnd'] = 1
			gt 'LariskaStart', 'end'
		else
			gt 'gdktoilet', 'start'
		end
	end

	act 'Change outfit in the locker room':
		cla
		gt 'wardrobe', 'start'
	end

	gs 'wardrobe', 'sports_outfit'

	if shampoo > 0 or (StoryLine = 1 and (SchoolAtestat = 0 or SchoolBlock = 0)):
		act 'Take a shower': gt 'gdksport', 'shower'
	else
		'<font color="red">You''ve run out of shampoo and will have to buy some more before you can wash yourself.</font>'
	end

	*nl

	if pcs_stam > 20 and $clothingworntype = 'danilovich' and $shoeworntype = 'danilovich' and hour < 18:
		if gsAboBeg > 0 and npc_pregtalk['A131'] = 0:
			act 'Take a track lesson. You have <<gsAboBeg>> lessons remaining': gt 'gdksport', 'racing2'
		end
		if gsAboVolley > 0 and volleysostav = 0 and npc_pregtalk['A69'] = 0:
			if week ! 5:
				act 'Take a volleyball lesson. You have <<gsAboVolley>> lessons remaining': gt 'gdksport', 'vball2'
			else
				act 'Take a volleyball lesson. You have <<gsAboVolley>> lessons remaining': gt 'gdksport', 'vball3'
			end
		end
		if volleysostav > 0:
			if week ! 6 and volkomday ! daystart:
				act 'Play with the team': gt 'gdksport', 'vball4'
			elseif week = 6 and sorevday ! daystart and hour <= 18:
				act 'Play in Tournament': gt 'gdksport', 'vball5'
			elseif week = 6 and sorevday ! daystart and hour > 18:
				'As you look around, you don''t see anyone from the team. You suddenly realize that there was a tournament game today and you were supposed to be here at 18:00! You missed the bus and the coach is going to be furious!'
				npc_rel['A69'] -= 20
				sorevday = daystart
				act 'Back': gt 'gdksport', 'start'
			elseif pregtime >= 90:
				act 'Play with the team': gt 'gdksport', 'vballreact'
			end
		end
		if gsAboDance > 0 and AlbinaQW['StarletsJoined'] = 0 and npc_pregtalk['A23'] = 0:
			act 'Take a dance lesson. You have <<gsAboDance>> lessons remaining':
				if rand(0, 5) = 0:
					gt 'danceGev'
				else
					gt 'gdksport', 'dance2'
				end
			end
		elseif AlbinaQW['StarletsJoined'] > 0 and AlbinaQW['StarletsShutDown'] = 0 and npc_pregtalk['A23'] = 0 and AlbinaQW['startletsday'] ! daystart:
			if hour = 15 and starlets_on = 1:
				if pregtime >= 90 or grupTipe = 5 or starlets_missed = 1:
					if pregtime >= 90: act 'Train with Starlets': gt 'AlbStars', 'Starletsreact'
					if grupTipe = 5: act 'Train with Starlets': gt 'AlbStars', 'StarletsEnd'
					if starlets_missed = 1:
						act 'Train with Starlets': 
							starlets_missed = 0
							starlet_practice_skipped += 1
							gt 'AlbStars', 'StarletsPracticeMissed'
						end
					end
				else
					act 'Train with Starlets': gt 'AlbStars', 'starlets'
				end
				act 'Quit the Starlets' : gt 'AlbStars', 'Quit' 
			end
		end
	elseif pcs_stam <= 20:
		*nl
		'You are too tired to do any exercise. You need to rest and replenish your stamina.'
	end
	
	if deodorant > 0 and deodorant_on = 0:
		'Your deodorant will last you for <b><<deodorant>></b> more '+iif(deodorant = 1, 'application.', 'applications.')
		act 'Apply deodorant (0:01)':
			*clr & cla
			menu_off = 1
			minut += 1
			deodorant -= 1
			gs 'sweat', 'deo'
			iif(func('body_din','pregnancyVisibility') = 1, '<center><img <<$set_imgh>> src="images/shared/home/bathroom/deodorant_preg.jpg"></center>', '<center><img <<$set_imgh>> src="images/shared/home/bathroom/deodorant.jpg"></center>')
			'You apply deodorant to your armpits. It will keep you feeling fresh and clean for longer.'
			act 'Continue': menu_off = 0 & gt $loc, $loc_arg
		end
	end
end

if $ARGS[0] = 'racing1':
	menu_off = 1
	*clr & cla
	gs 'stat'
	'Race training cost 300 <b>₽</b> for 30 lessons.'

	act 'Leave': gt 'gdksport', 'start'

	if money >= 300 and gsAboBeg <= 0:
		act 'Buy 30 racing lessons (300 <b>₽</b>)':
			*clr & cla
			money -= 300
			gsAboBeg = 30
			gs 'stat'
			'You paid for 30 racing lessons.'
			act 'Leave': gt 'gdksport', 'start'
		end
	end
end

if $ARGS[0] = 'dance1':
	menu_off = 1
	*clr & cla
	gs 'stat'
	'Dance lessons cost 300 <b>₽</b> for 30 lessons.'

	act 'Leave': gt 'gdksport', 'start'

	if money >= 300 and gsAboDance <= 0:
		act 'Buy 30 dance lessons (300 <b>₽</b>)':
			*clr & cla
			money -= 300
			gsAboDance = 30
			gs 'stat'
			'You paid for 30 dance lessons.'
			act 'Leave': gt 'gdksport', 'start'
		end
	end
end

if $ARGS[0] = 'vball1':
	menu_off = 1
	*clr & cla
	gs 'stat'
	'Volleyball lessons cost 300 <b>₽</b> for 30 visits.'

	act 'Leave': gt 'gdksport', 'start'

	if money >= 300 and gsAboVolley <= 0:
		act 'Buy 30 volleyball lessons (300 <b>₽</b>)':
			*clr & cla
			money -= 300
			gsAboVolley = 30
			gs 'stat'
			'You paid for 30 volleyball lessons.'
			act 'Leave': gt 'gdksport', 'start'
		end
	end
end

if $ARGS[0] = 'dance2':
	cla & *clr
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/dance_studio/fit1.jpg"></center>'

	act 'Leave': gt 'gdksport', 'start'

	if pcs_danc < 50:
		gsAboDance -= 1
		timemult = 8
		loopcount = 1
		:dancetimeloop
		gs 'exercise', 'tier2', 0, 'agil_exp', 'danc_exp'
		if loopcount < timemult: loopcount += 1 & jump 'dancetimeloop'
		loopcount = 0
		timemult = 0
		if pcs_inhib < 40:inhib_exp += rand(1,2)

		'You take a lesson in modern dance, which is very popular with people your age.'

		if pcs_danc < pcs_agil:
			'Your skill still has a ways to go, but your agility helps you pull off some of the dance moves.'
		else
			'Your body lacks the agility to perform the dance moves that you are being taught.'
		end
		!place for use in events
		gs 'stat'
	else
		'There is nothing you can learn from this dance class with your current skill. You need to find a new teacher or travel to the city to find better dance classes if you wish to improve further.'

		if AlbinaQW['StarletsJoined'] = 0 and StoryLine ! 0 and ( month < 10 or ( month = 10 and day < 18 )):
			if alterstrtimg = 13:
				gt 'AlbStars', 'albina3'
			elseif grupTipe = 1 or grupTipe = 2:
				gt 'AlbStars', 'albina2'
			else
				gt 'AlbStars', 'albina1'
			end
		end
	end
end

if $ARGS[0] = 'racing2':
	*clr & cla
	menu_off = 1
	gsAboBeg -= 1
	timemult = 8
	loopcount = 1
	:runtimeloop
	gs 'exercise', 'tier2', 0, 'run_exp'
	if loopcount < timemult: loopcount += 1 & jump 'runtimeloop'
	loopcount = 0
	timemult = 0

	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/park/parkbeg.jpg"></center>'
	'You spend 20 minutes on warm up, run for 90 minutes then spend 10 minutes on your cool down.'

	act 'Leave': gt 'gdksport', 'start'
end

if $ARGS[0] = 'vball2':
	*clr & cla
	menu_off = 1
	gsAboVolley -= 1
	if alko < 2:
		npc_rel['A69'] += rand(0,2)
		timemult = 8
		loopcount = 1
		:vballtimeloop1
		gs 'exercise', 'tier2', 0, 'vball_exp', 'run_exp', 'agil_exp', 'stren_exp', 'vital_exp'
		if loopcount < timemult: loopcount += 1 & jump 'vballtimeloop1'
		loopcount = 0
		timemult = 0
	else
		timemult = 8
		loopcount = 1
		:vballtimeloop2
		gs 'exercise', 'tier1', 0, 'run_exp'
		if loopcount < timemult: loopcount += 1 & jump 'vballtimeloop2'
		loopcount = 0
		timemult = 0
		if pcs_inhib < 40:inhib_exp += rand(0,1)
	end
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/gdksport.jpg"></center>'
	if alko < 2:
		'At the beginning of the workout you ran a few laps around the gym. After some sprints, you did abdominal exercises. Afterwards, you practiced volleying and serving the ball.'
	else
		npc_rel['A69'] -= rand(0,2)
		'You tried to train, but your level of intoxication doesn''t let you focus. The coach sent you to spend the lesson doing laps.'
	end

	act 'Leave': gt 'gdksport', 'start'
	act 'Talk to the coach': gt 'Voltrener', 'start'
end

if $ARGS[0] = 'vball3':
	*clr & cla
	menu_off = 1
	gsAboVolley -= 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/gdksport.jpg"></center>'
	'On Fridays they hold intramural competitions. Scouts for professional teams sometime come to see who the stronger and more talented players are.'

	if alko < 2:
		timemult = 8
		loopcount = 1
		:vballtimeloop3
		gs 'exercise', 'tier2', 0, 'vball_exp', 'run_exp', 'agil_exp', 'stren_exp', 'vital_exp'
		if loopcount < timemult: loopcount += 1 & jump 'vballtimeloop3'
		loopcount = 0
		timemult = 0
		if pcs_vball < 25:
			'You were an absolutely lousy player and made constant mistakes. Eventually, the coach had enough and he removed you from the court.'
		elseif pcs_vball < 50:
			'You did not play very well. Sometimes you made some blunders. The coach was angry, but tolerated your antics.'
		elseif pcs_vball < 75:
			'You played well on the court and rarely made any mistakes. The coach looked pleased with you.'
		else
			'You played great on the court, and easily defeated your rivals. The coach looked pleased with your game.'
			if rand(0, 1) = 0:
				if andGevknow = 0:$nameAndGev = 'some guy'
				if andGevknow > 0:$nameAndGev = 'Andrei'

				'During the game you got pushed by <a href="exec: gt ''volAndGev'', ''start''"><<$nameAndGev>></a>.'
			end
		end
	else
		minut += 120
		'You took to the court, but kept missing plays because you were too drunk to focus. The coach noticed your state and removed you from the game.'
	end
	act 'Leave': gt 'gdksport', 'start'
	act 'Talk to the coach': gt 'Voltrener', 'start'
end

if $ARGS[0] = 'vball4':
	*clr & cla
	menu_off = 1
	volkomday = daystart
	timemult = 8
	loopcount = 1
	:vballtimeloop4
	gs 'exercise', 'tier2', 0, 'vball_exp', 'run_exp', 'agil_exp', 'stren_exp', 'vital_exp'
	if loopcount < timemult: loopcount += 1 & jump 'vballtimeloop4'
	loopcount = 0
	timemult = 0
	npc_rel['A69'] += 1
	if pcs_inhib < 40:inhib_exp += rand(0,1)
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/gdksport.jpg"></center>'
	'Number of games <<volsesongame>>, Win - <<volsesonwin>>, lesions - <<volsesonloss>>.'
	'At the beginning of the workout you ran a few laps around the room. Afterwards the coach has you do push-ups and crunches. Then you practiced receiving and setting up plays and serving the ball. At the end of the workout you had a practice game.'
	act 'Leave': gt 'gdksport', 'start'
	if $pantyworntype = 'none' and rand(0,1) = 1 and (volleytanga = 1 or VoltrenerVoyeur >= 5):
		gs 'willpower', 'exhib', 'self'
		if will_cost <= pcs_willpwr:
			act 'Correct clothing (<<will_cost>> Willpower)':
				*clr & cla
				inhib_exp += rand(1,5)
				TrenerLust += 3
				Voltrenersee += 1 & ! setcheck on gg without panties
				gs 'willpower', 'exhib', 'self'
				gs 'willpower', 'pay', 'self'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/event/game'+rand(1,2)+'.jpg"></center>'
				'It seems the coach noticed you weren''t wearing any panties, his eyes lit up and he said turning away: "<<$pcs_lastname>>. Come see me after training. I need to show you UH... a few things" '
				act 'Leave':gs'stat'& gt 'gdksport', 'start'
				act 'Go to the coach''s office': gt 'Voltrenersex', 'start'
			end
		else
			act 'Correct clothing (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	else
		act 'Talk to the coach': gt 'Voltrener', 'start'
	end
end

if $ARGS[0] = 'vball5':
	*clr & cla
	menu_off = 1
	timemult = 8
!	loopcount = 1
!	:vballtimeloop5
!	gs 'exercise', 'tier2', 0, 'vball_exp', 'run_exp', 'agil_exp', 'stren_exp', 'vital_exp'
!	if loopcount < timemult: loopcount += 1 & jump 'vballtimeloop5'
!	loopcount = 0
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/gdksport.jpg"></center>'
	'The tournament starts at 19:00. Your bus departs at 18:00. You gather your things together with the rest of the team and get on a bus that takes you to the out of town match.'
	act 'Leave': gt 'gdksport', 'start'
	act 'Get on bus and go to play':
		volltime = 0
		sorevday = daystart
		if hour < 18: hour = 18 & minut = 0
		timemult = 0
		npc_rel['A69'] += 2
		minut += 60 & !total time should be 4 hours, 2 hours for the game and 2 hours travel
		gt 'gdksport', 'volley'
	end
end

if $ARGS[0] = 'volley':
	menu_off = 1
	gs 'exercise', 'tier2', 0, 'vball_exp', 'run_exp', 'agil_exp', 'stren_exp', 'vital_exp'
	gs 'exercise', 'tier2', 0, 'vball_exp', 'run_exp', 'agil_exp', 'stren_exp', 'vital_exp'
!	minut += 30
	gs 'stat'

	if volltime = 0:
		!! reset the scores
		volpoint = 0
		volpointv = 0

	'The teams take to the court and start playing.'

		!! reserve player or you were caught drinking by the coach and he forbid you from playing
		if trener_Speak < 8 or seealko = 1:
			volleysostav = 1
			poverkomand = 50
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game3.jpg"></center>'
			'You sit on the bench watching your team play.'

		!! starter
		else
			volleysostav = 2
			!! between 0 and 200 dependent on player skills
			poverkomand = ((pcs_vball*2) + ((pcs_stren + pcs_vital + pcs_agil + pcs_react)/2))/2
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game4.jpg"></center>'
			'After warming up you run out on the court to join your teammates.'
		end

		!! opponent skill - between 0 and 200. A perfect player should be able to win every match.
		poverkomandV = rand(0, 200)

		if poverkomand > poverkomandV:
			volpoint = 1
			'Your team plays better than your opponents.'
		elseif poverkomand < poverkomandV:
			volpointv = 1
			'Your opponents play better than your team.'
		else
			'The scoring varies one way, then the other, obviously the teams are evenly matched.'
		end

		act 'Continue':volltime = 1 & gt 'gdksport', 'volley'

	!! halftime
	elseif volltime = 1:
		'During the break, both teams have a rest.'

		if volpointv = 0:
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/teacher/mikhail/volleytrener6.jpg"></center>'
			'Coach tells the team that you can''t relax. "Although we''re winning, you still need to be focused! Don''t let the enemy back into the game!"'
		elseif volpoint = 0:
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/teacher/mikhail/volleytrener2.jpg"></center>'
			'Coach tells the team that losing the first half is bad, but it''s not a disaster. "You pick yourselves up and go out and kick their asses. You can still win this game in the second half."'
		else
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/teacher/mikhail/volleytrener1.jpg"></center>'
			'Coach tells the team that there is no draws in volleyball, he expects you to keep doing the things that you are doing well, but increase pressure. "With more discipline and toughness, you can win this game!"'
		end

		if volleysostav = 1:
			'You are sitting on the bench.'

			act 'Ask to play':
				if seealko = 1:
					*clr & cla
					'The coach refuses to let you play because he caught you drinking.'
					act 'Continue':volltime = 2 & gt 'gdksport', 'volley'
				else
					*clr & cla
					gs 'stat'

					if npc_rel['A69'] >= rand(0, 80):
						volleysostav = 2
						poverkomand = ((pcs_vball*2) + ((pcs_stren + pcs_vital + pcs_agil + pcs_react)/2))/2
						'The coach agrees to let you play the second half.'

						act 'Continue':volltime = 2 & gt 'gdksport', 'volley'
					else
						'You ask the coach to play, but he shakes his head and explains that it is not strategically right for the team.'

						act 'Continue':volltime = 2 & gt 'gdksport', 'volley'
					end
				end
			end
		end

		act 'Continue':volltime = 2 & gt 'gdksport', 'volley'

	!! 2nd half
	elseif volltime = 2:
		*clr & cla
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game5.jpg"></center>'
		'Break is over and the team starts the second half.'

		if volleysostav = 1:'You sit on the bench watching your team play.'


		!! change the opponent skill a bit so both halves are not an entirely static affair.
		poverkomandV += rand(-50, 50)

		if poverkomand > poverkomandV:
			volpoint += 1
			'Your team plays better than your opponents.'

			!! you came in and your team scored when they would not have without you
			if volleysostav = 2 and volpointv = 1:npc_rel['A69'] += 10
		elseif poverkomand < poverkomandV:
			volpointv += 1
			'Your opponents play better than your team.'

			!! you came in and your team gave up a point they would not have without you
			if volleysostav = 2 and volpoint = 1:npc_rel['A69'] -= 5
		else
			'The scoring varies one way, then the other. The teams are obviously evenly matched.'

			!! you came in and your team tied when they would have lost without you
			if volleysostav = 2 and volpointv = 1:npc_rel['A69'] += 5
		end

		act 'Continue':volltime = 3 & gt 'gdksport', 'volley'

	!! end of game
	elseif volltime = 3:
		*clr
		cla
		volsesongame += 1
		if rand (1, 100) < 3:
			if volpointv = 2:
				volpoint = 0
				volpointv = 2
			elseif volpoint = 2:
				volpoint = 2
				volpointv = 0
			end
		end

		'Final whistle.'
		seealko = 0
		if volpoint > volpointv:
			volsesonwin += 1
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game6.jpg"></center>'
			'Your team wins.'
		elseif volpoint < volpointv:
			volsesonloss += 1
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game8.jpg"></center>'
			'Your team loses.'
		else
			if rand (0, 1) = 0:
				volsesonwin += 1
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game7.jpg"></center>'
				'The match was very close, but in the end your team pulls off a win.'
			else
				volsesonloss += 1
				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/gym/volley/game7.jpg"></center>'
				'The match was very close, but in the end your team still loses.'
			end
		end
		minut += 60 & !total time should be 4 hours, 2 hours for the game and 2 hours travel
		act 'Leave': gt 'gdksport', 'start'
		act 'Talk to the coach': gt 'Voltrener', 'start'
	end
end

if $ARGS[0] = 'shower':
	menu_off = 1
	*clr & cla
	$location_type = 'bathroom'
	if StoryLine = 1 and (SchoolAtestat = 0 or SchoolBlock = 0): noShampoo = 1
	dynamic $showerdin
	minut += 15
	pcs_horny += 1
	pcs_makeup = 1
	if frost > 0:frost = 0
	gs 'stat'
	'<center><video autoplay loop src="images/shared/home/bathroom/dush.mp4"></video></center>'

	if IvanShowerYes = 1 and rand(0,3) = 1 and ShowerIvan < 3:
		if ShowerIvan = 1: ShowerIvan = 2
		'You enter the women''s shower, and turning the water on, you begin to lather up your body with a washcloth. Suddenly, you hear the door creak open and you remember that you agreed not to lock it for Ivan.'
		'You look around and see Ivan standing there looking at you. "Hello <<$pcs_nickname>>. The men''s shower is full, so I thought I would join you instead." He smiles.'
		act 'Shower with Ivan': gt 'gdksport', 'ShowerWithIvan'
		gs 'willpower', 'bj', 'resist'
		if will_cost <= pcs_willpwr:
			act 'Not today (<<will_cost>> Willpower)':
				*clr & cla
				gs 'willpower', 'bj', 'resist'
				gs 'willpower', 'pay', 'resist'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/community/shower1.jpg"></center>'
				'You cover your breasts with one hand and turn sideways crossing your legs while flashing Ivan your best smile.'
				'"How about another time Ivan? I''m not feeling it right now." Ivan just laughs and walk out of the shower room.'
				'You quickly lock the door, before finishing your shower in peace.'
				act 'Get out of the shower': gt 'gdksport', 'start'
			end
		else
			act 'Not today (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	!! We only set IvanShowerQW = 1 if the player showers with Ivan because the scene that uses this
	!! variable where the player talks to Ivan about the shower at school assumes the player did
	!! not run away or kick out Ivan before anything happened. This scene was initially a one-off,
	!! but was changed to make it repeatable because showering with Ivan here is non-obviously an
	!! intermediate step in becoming a starter on the volleyball team. If avoiding needing this
	!! scene to be repeatable is desired, someone with a better sense of Ivan as a character than
	!! me could add a version of the followup scene at school for when the player doesn''t shower
	!! with Ivan using IvanShowerQW = 2 at some point. If this is done, this scene can be made
	!! non-repeatable by removing the (IvanShowerQW = 2 and rand(0,3) = 1) part
	elseif (kotovVSprohorov = 1 or (IvanShowerQW = 2 and rand(0,3) = 1)) and ShowerIvan < 3:
		'You enter the women''s shower and turning the water on, begin to lather your body with a washcloth. Suddenly, you hear the door creak open and you remember that you forgot to lock it.'
		'You look around and see Ivan standing in the doorway looking at you. "Hi <<$pcs_nickname>>. Can I join you? The men''s shower is full' + iif(IvanShowerQW = 2, ' again', '') + '." He smiles.'
		kotovVSprohorov = 2
		IvanShowerQW = 2
		gs 'willpower', 'bj', 'resist'
		if will_cost <= pcs_willpwr:
			act 'Throw Ivan out (<<will_cost>> Willpower)':
				*clr & cla
				gs 'willpower', 'bj', 'resist'
				gs 'willpower', 'pay', 'resist'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/community/shower1.jpg"></center>'
				'You cover your breasts with one hand and turn sideways crossing your legs as you hurl your washcloth at Ivan. He easily dodges the flying cloth and laughs as he exits the shower room.'
				'You quickly lock the door, before finishing your shower in peace.'
				act 'Get out of the shower': gt 'gdksport', 'start'
			end
		else
			act 'Throw Ivan out (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end

		act 'Uh, what?':
			*clr & cla
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/shower2.jpg"></center>'
			'Completely surprised and confused by Ivan''s sudden appearance, you are struck speechless. Ivan takes your inaction and silence as consent, and he walks into the shower room and closes the door behind him.'
			
			gs 'willpower', 'bj', 'resist', 'hard'
			if will_cost <= pcs_willpwr:
				act 'Escape from the shower (<<will_cost>> Willpower)':
					*clr & cla
					gs 'willpower', 'bj', 'resist', 'hard'
					gs 'willpower', 'pay', 'resist'
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/community/shower1.jpg"></center>'
					'You cover your breasts with one hand as you quickly grab your towel and run from the shower. As you run into the changing room, you can hear Ivan laughing.'
					act 'Get out of the shower': gt 'gdksport', 'start'
				end
			else
				act 'Escape from the shower (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
			act 'Wash together':
				IvanShowerQW = 1
				IvanShowerYes = 0
				if ShowerIvan = 0: ShowerIvan = 1
				gt 'gdksport', 'ShowerWithIvan'
			end
		end
	else
		'You enter the women''s shower and turning the water on begin to lather your body with a washcloth. After you rinse off the soap, you wash your hair. You then rinse your hair and feel completely clean.'
		if (trenerlust >= 40 or trenersex = 1) and rand(0,3) = 0 and VoltrenerVoyeur = 0:
			act 'Continue': gt 'VoltrenerSexShower', '0'
		elseif (trenerlust >= 40 or trenersex = 1) and rand(0,3) = 0 and VoltrenerVoyeur = 1:
			act 'Continue': gt 'VoltrenerSexShower', '1'
		elseif (trenerlust >= 40 or trenersex = 1) and rand(0,3) = 0 and VoltrenerVoyeur = 2 and IvanShowerYes = 0:
			act 'Continue': gt 'VoltrenerSexShower', '2'
		else
			'After your shower, you get dressed.'
			act 'Get out of the shower': gt 'gdksport', 'start'
		end
	end
	if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
end

if $ARGS[0] = 'ShowerWithIvan':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/home/bathroom/dush.mp4"></video></center>'
	'Ivan walks over to you, pulling his boxer shorts down and stepping out of them as they fall around his ankles. Stepping into the shower with you, getting himself wet under the water. His muscular body is very close to yours.'
	'You try not to look at him, but your eyes involuntarily drop to his groin where his thick cock swings as he moves. Ivan, seeing where you are looking winks. "Want to wash me?"'
	gs 'arousal', 'foreplay', 5
	gs 'stat'
	act 'Lather Ivan':
		*clr & cla
		gs 'boyStat', 'A3'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/community/shower.jpg"></center>'
		'You take your washcloth and begin to lather Ivan''s body. As you move around him, you can''t help but notice his <<dick>>cm <<$dick_girth>> cock begin to rise up and get hard. You feel it brush against your thigh.'
		'Ivan begins to rubs his hands over your body and caress you. After a few minutes, you feel his hands on your shoulders as he gently but firmly pushes you down to your knees.'
		gs 'arousal', 'foreplay', 5
		gs 'stat'
		act 'Give blowjob':
			*clr & cla

			if npc_Sex['A3'] = 0: npc_Sex['A3'] = 1 & guy += 1

			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/community/shover.jpg"></center>'
			'You slowly sink to your knees in front of Ivan and his <<dick>>cm <<$dick_girth>> cock is in front of your face. Ivan leans forward, probing impatiently with the head of his cock against your lips. Your mouth opens almost against your will and you let his cock slide in your mouth.'
			'Your lips tightly wrap around Ivan''s solid rod and you suck him as the streams of warm water wash over you. Suddenly Ivan pulls his dick out of your mouth and takes you by the hand, pulling you back up to your feet. He brings his lips to your breast and begins to suck on your nipple.'
			'Bliss sweeps over you as he suckles your stiff nipple. Releasing your nipple with a wet pop, Ivan pushes you back onto your knees and bends you backwards as he straddles your face, once again sliding his hot cock into your mouth. He begins pushing it deeper into your throat.'
			gs 'arousal', 'bj', 5, 'sub', 'deepthroat'
			gs 'stat'
			act 'Allow him to continue':
				cla & *clr
				if pcs_throat < 15:
					'<center><video autoplay loop src="images/shared/sex/blowjob/shower6.mp4"></video></center>'
					'Penetrating further and further into your mouth, then into your throat, his member blocks your breath, which causes a gag reflex, nearly causing you to vomit. Freeing your mouth from his dick and wiping your tears, you scream at him. "This isn''t some bottomless hole for you to shove your dick into, you know!" Ivan gives you a guilty look then pulls you back to your feet again as he begins to kiss you and caress your breasts and ass until you begin to moan with desire. He turns you around and bends you over.'
				else
					'<center><video autoplay loop src="images/shared/sex/blowjob/shower7.mp4"></video></center>'
					'Penetrating further and further into your mouth, then into your throat, you take his member to the base without any problems and without causing you discomfort, bringing Ivan "heavenly delight" if his groans and moans are any indication. Feeling that your classmate would flood your throat with his seed at any moment, you pull your mouth off of his cock and turn and bend over, presenting your ass to him. You also want some satisfaction.'
				end

				if agape > 0:
					act 'Continue':
						*clr & cla
						if pcs_throat < dick:pcs_throat += 1
						spafinloc = 12
						gs 'cum_manage'
						gs 'stat'
						'<center><img <<$set_imgh>> src="images/shared/sex/cum/mouth/cum49.jpg"></center>'
						'Bent over, expecting to feel his <<dick>>cm <<$dick_girth>> cock against your pussy at any moment, you are momentarily surprised when you feel it pressed up against your asshole.'
						'Thinking he is unaware you speak up. "Wrong hole Ivan!" Ivan just snorts in response. "Yeah I know." He then pushes the head of his <<dick>>cm <<$dick_girth>> cock into your ass. You moan in a mixture of pain and pleasure.'
						'He takes it slow, giving you time to adjust to his dick invading your ass. Once your moans turn more to ones of pleasure then pain, he slips it in deeper, slowly working himself balls deep into your ass.'
						*nl
						'Once there he begins stroking his <<dick>>cm <<$dick_girth>> cock faster and faster in your ass. Soon, his skin is slapping against your bare ass as he pounds you hard and fast.'
						'One of your hands rubs your clit while the other one stays against the wall to brace yourself. He has amazing stamina in a seemingly endless supply. No matter how much you love him fucking your ass, after a while you feel your ass beginning to get sore, your moans of pleasure start to turn into grunts of pain.'
						'Apparently sensing your growing discomfort, he makes one more powerful thrust with a grunt then pulls out of your ass. He pulls you around and pushes you back down to your knees before he slides his cock back in your mouth. You try to ignore the taste of his cock, considering just where it just was.'
						'You do you best to suck him off quickly and within moments, he is shooting his sperm into your mouth. Once he is done, he goes back to showering, quickly finishing up and starting to get dressed. He watches you as you get dressed. "That was great <<$pcs_nickname>>, we should do that again sometime." Without waiting for a reply, he leaves the room.'
						gs 'arousal', 'anal', 5, 'sub', 'rough'
						gs 'arousal', 'masturbate', 5
						minut -= 5
						gs 'arousal', 'end'
						gs 'stat'
						act 'Get out of the shower': gt 'gdksport', 'start'
					end
				else
					act 'Turn around and bend over':
						*clr & cla
						lubonus = 2
						spafinloc = 3
						gs 'Cum_Manage'
						if pcs_ass + lubonus + 2 < dick:
							if pcs_makeup > 1:pcs_makeup = 0
							pcs_horny -= 20
							pcs_mood -= 20
							if agape < 3:agape = 3
						elseif pcs_ass < dick:
							pcs_horny += 10
							if agape < 2 and lubonus = 0:agape = 2
						end
						gs 'stat'
						'<center><video autoplay loop src="images/shared/sex/vag/doggy/shover2.mp4"></video></center>'
						'As you bend over, you feel Ivan''s hand stroking your ass and his finger starts to massage your anus. You are momentarily surprised when you feel his fingers pressed up against your asshole. Thinking he is unaware you speak up. "That''s my <i>other</i> hole Ivan..."'
						'Ivan just snorts in response. "Yeah I know." He then pushes the head of his <<dick>>cm <<$dick_girth>> cock into your ass. You moan in a mixture of pain and pleasure. He takes it slow, giving you time to adjust to his dick invading your ass.'
						'Once your moans turn more to ones of pleasure then pain, he slips it in deeper, slowly working himself balls deep in your ass. Once there he begins stroking his <<dick>>cm <<$dick_girth>> cock faster and faster in your ass. Soon, his skin is slapping against your bare ass as he pounds you hard and fast.'
						'One of your hands rubs your clit while the other one stays against the wall to brace yourself. He has amazing stamina in a seemingly endless supply. For a while, you buck your hips back against him, fucking him as much as he is fucking you, but no matter how much you love him fucking your ass, after a while you feel your ass beginning to get sore.'

						gs 'arousal', 'anal', 5, 'sub', 'rough'
						gs 'arousal', 'masturbate', 5
						minut -= 5
						gs 'stat'

						if VoltrenerVoyeur = 3:
							act 'Continue': gt 'VoltrenerSexShower', '3'
						elseif VoltrenerVoyeur = 4:
							act 'Continue': gt 'VoltrenerSexShower', '4'
						elseif VoltrenerVoyeur = 5:
							act 'Continue': gt 'VoltrenerSexShower', '5'
						else
							if pcs_horny >= 100:
								if stat['anal'] >= 10 and orgasm > 0:
									pcs_mood += 20
									$orgasm_or = 'custom'
									$orgasm_txt = 'Your whole body contracts and then you cry out in orgasm.'
								end
							end
							'Your moans of pleasure start to turn into grunts of pain. Apparently sensing your growing discomfort, he makes one more powerful thrust with a grunt. His body spasms against yours as you feel him cumming in your ass. Once he is done he pulls out of you and goes back to showering, quickly finishing up and starting to get dressed.'
							'He watches you as you get dressed. "That was great <<$pcs_nickname>>, we should do that again sometime." Without waiting for a reply, he leaves the room.'
							cumspclnt = 1
							gs 'cum_cleanup'
							gs 'arousal', 'end'
							gs 'stat'
							act 'Get out of the shower': gt 'gdksport', 'start'
						end
					end
				end
			end
			gs 'willpower', 'anal', 'resist', 'hard'
			if will_cost <= pcs_willpwr:
				act 'That''s enough for now (<<will_cost>> Willpower)':
					gs 'willpower', 'anal', 'resist', 'hard'
					gs 'willpower', 'pay', 'resist'
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/community/shower1.jpg"></center>'
					'Ivan pauses for a brief second and you use the chance to quickly stand up and jump out of the shower.'
					'You look back at him and say "I think you''ve had enough of me for today. Maybe you can have more next time."'
					act 'Get out of the shower': gt 'gdksport', 'start'
				end
			else
				act 'That''s enough for now (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
		end
	end
end


if $ARGS[0] = 'Ivan_bored':
	menu_off = 1
	*clr & cla
	minut += 5
	pcs_horny += 10
	gs'stat'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/school/ivan2.jpg"></center>'
	'You look at Ivan for a long moment and bite your lower lip and then whisper just loud enough that he can barely hear you. "I''m bored..." He looks at you for a moment then smiles. He looks around, then takes you by the hand and leads you away from the others, into one of the lesser used areas of the school. He stops at one of the boys restrooms, going inside and leaving you outside. A few moments later, two younger boys are sent packing by Ivan. Once they round the corner, he pulls you into the bathroom.'
	
	gs 'willpower', 'anal', 'resist'
	if will_cost <= pcs_willpwr:
		act 'Leave (<<will_cost>> Willpower)':
			gs 'willpower', 'anal', 'resist'
			gs 'willpower', 'pay', 'resist'
			gs 'stat'
			gt 'gschool_lessons', 'short_break'
		end
	else
		act 'Leave (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end

	act 'Go into the bathroom with Ivan':
		*clr & cla
		pcs_horny += 20
		gs 'boyStat', 'A3'
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/school/bbivanbj.jpg"></center>'
		'Once inside, Ivan starts to kiss you passionately while pulling your clothes off and tossing them all over. You return his kiss and help remove your clothes. He backs up, pulling you into one of the stalls. Once your clothes are removed he starts removing his own clothes, which you are only to happy to help with. Once you''re both fully naked, he sits down on the toilet and gently pushes you down to your knees.'
		'He guides your head to his <<dick>>cm <<$dick_girth>> cock. Using one of your hands you grab his dick and start to stroke the shaft while you open your mouth and take his dick into your mouth. You wrap your lips tightly around his shaft and start sucking him, while using your tongue to tease the head. You alternate your hand from stroking him and fondling his balls.'
		'He moans and grabs your hair, you can feel he is restraining himself from forcing your head down and jamming his dick down your throat. After a couple of minutes, he growls a bit and stands up, pulling you up as well. Without explaining he turns you around so quickly you almost stumble, only his strong hands on you keep you from falling into the stall wall. He roughly bends you over, using one hand to guide his cock while the other grabs your butt cheek to spread it open.'
		gs 'arousal', 'kiss', 5, 'sub'
		gs 'arousal', 'hj', 5, 'dom'
		gs 'arousal', 'bj', 5, 'sub', 'deepthroat'
		minut -= 5
		gs 'stat'
		act 'Let him':
			*clr & cla
			lubonus = 2
			gs 'cum_call', 'anus', 'A3', 1

			if pcs_ass + lubonus + 2 < dick:
				if pcs_makeup > 1:pcs_makeup = 0
				pcs_horny -= 20
				pcs_mood -= 20
				if agape < 3:agape = 3

			elseif pcs_ass < dick:
				if agape < 2 and lubonus = 0:agape = 2

			end

			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/ivan/sex/school/schoolanal.jpg"></center>'
			'He rubs the tip of his dick against your asshole for a couple of moments and then you feel a sharp pain as he pushes it in. With only your saliva as lubrication, it doesn''t slide in as easily. You bite your lip and cry out a little in pain. He relaxes a little and rubs your back as he takes it slow, giving you time to stretch and adjust to his cock invading your ass.'
			'He slowly strokes his <<dick>>cm <<$dick_girth>> cock in your ass, with each stroke pushing it just a little deeper in your ass. Once he is about half way in your moans turn from pain to pleasure, while one of your hands starts rubbing your clit. You start moaning louder and panting, your pussy is now soaking wet. After a couple of minutes the pleasure is building up inside of your body so much you no longer even need to stimulate your clitorous any longer. "Fuck <<$pcs_nickname>>, you not only have the hottest ass of any girls in school, but the tightest one I have ever fucked." Ivan says as he can tell you''re getting into it, grabbing your hips with both hands. He drives himself balls deep into your ass, eliciting a squeak of pain from you, but sensation of pain is quickly overwhelmed by pleasure.'
			'Holding onto your hips with both hands, he holds you steady and keeps you from pulling away, as he jack hammers his <<dick>>cm <<$dick_girth>> cock balls deep in your ass. You moan in pain and pleasure, mostly pleasure, the sounds of your moans, almost drowned out the sounds of his skin slapping against yours, his balls slapping against your wet pussy. You place your hands against the stall wall to keep him from driving your head into it, from his powerful and violent thrusts. As he abuses your poor little asshole, you find yourself loving every second of it.'
			*nl
			'You have an intense orgasm that leaves your legs shaking and barely able to keep standing. You are almost to the point where you are unable to take it anymore, either from the intense pleasure or the growing burning sensation in your ass. Either way the matter is moot, as Ivan drives himself once more balls deep into your ass, but this time holds himself there. You feel his cock twitching as he shoots hot sperm deep in your ass, spurt after spurt filling you up with his semen in what seems an almost unending stream. Finally he takes a shuddering breath and pulls out of you, leaving you to almost collapse with out his support.'
			'You both start to get dressed, him faster than you, as your still unsteady on your feet, from your shaky legs. Once he is done getting dressed he helps you gather the rest of your clothes from where he tossed them aside. As you are seeing to the final adjustments of your clothes he goes to the bathroom door and looks out both ways down the hall, motioning you over just as the class bell rings. Oh well, at least you have a good excuse to be a little late, you think to yourself with a smile.'
			'As you start to go out the door, he stops you and squeezes your ass with his strong hand and says. "That was great <<$pcs_nickname>>, you are coolest chick in school, not to mention the hottest. Maybe we can do this again sometime soon, or maybe I will come see you in the shower at the community center some night, maybe even tonight." He grins and winks at you, giving your ass a hard slap, as he rushes off to class. You only have time to nod in agreement to his idea of doing this again, you bite your lip as you watch him go. You have mixed feelings about this, Ivan is a great guy and a lot of fun, but you know he doesn''t want a girlfriend. He just wants to be friends with benefits, but is that enough for you? You don''t have time to think on it more as you hurry to class.'

			$orgasm_or = 'yes'
			gs 'arousal', 'anal', 5, 'sub', 'rough'
			gs 'arousal', 'end'
			gs 'stat'
			act 'Continue': gt 'gschool_lessons', 'short_break'

		end

	end
end


if $ARGS[0] = 'Fedor First Date':
	menu_off = 1
	*clr & cla
	numnpc = 5
	gs 'stat'
	'<center><b><h4><font color="blue"><<"Fyodor [Fedor] Kozlov">></font></h4></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big5.jpg"></center>'
	if fedorkozbreak = 1:
		'You enter the sports club and see Fedor standing by the front door. He looks as though he is waiting for someone and as soon as he sees you, he flashes you a smile and he approaches with an affable smile on his face. "Hello <<$pcs_firstname>>." he says with a warm smile. He pauses for a moment, then reaches into his pockets and pulls out 2 tickets and says "Here is the deal. I know that we had a bit of a bumpy relationship before, but I would like to try again if you will. So what do you say? Wanna go on another date with me?"'
	else
		'You enter the sports club and see Fedor standing by the front door. He looks as though he is waiting for someone and as soon as he sees you, his eyes light up and he approaches you with an affable smile on his face. "Hello <<$pcs_firstname>>." he says with a warm smile. He pauses for a moment, then reaches into his pockets and pulls out 2 tickets and says "Here is the deal. I have an extra ticket to the movies and I would like know if you would be up for a good comedy?"'
	end

	act 'Agree':
		*clr & cla
		minut += 15
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/fedor/fedorev/park/walk.jpg"></center>'
		'"I would like that." you say with a smile and Fedor responds: "Good, I hear that this movie will have us in stiches." With a delighted look on his face, he wraps his arm around yours then walks you to the movie theater.'

		act 'Watch a movie':
			*clr & cla
			minut += 90
			pcs_mood += 90
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/shared/cinema/kino_1.jpg"></center>'
			'Fedor presents the tickets at the entrance and together you walk into the theater. You look around and notice that the seats are mostly empty, so Fedor leads you to the front row and you both sit down. The lights dim and the movie starts. Fedor sits motionless and only occasionally glances at you. The movie was quite interesting and you couldn''t help but laugh occasionally at the wackiness of it. When the movie ends, the lights turn on and Fedor walks you out. "<<$pcs_firstname>>. You seem like a cool girl. Maybe we could go out together. What do you say?"'

			act 'Agree':
				*clr & cla
				npc_rel['A5'] += 20
				fedorKozlovQW = 10
				minut += 15
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/fedor/fedorev/park/walk.jpg"></center>'
				'"Sure, I would love to go out with you." you reply and Fedor is visibly delighted. "Alright, I look forward to hanging out with you again. Whenever you are up for another date then meet me in the school yard, after school." Fedor says as he walks you back home. The two of you have fun discussing your favorite movies as you continue your way home.'

				act 'Leave': gt 'pav_residential'
			end
			
			act 'Refuse':
				*clr & cla
				if fedorkozbreak = 0:fedorKozlovQW = 0
				if fedorkozbreak = 1:fedorKozlovQW = -1
				npc_rel['A5'] = 70
				minut += 15
				gs 'stat'
				'<center><b><h4><font color="blue"><<"Fyodor [Fedor] Kozlov">></font></h4></b></center>'
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/fedor/fedorev/fedorsad.jpg"></center>'
				if fedorkozbreak = 1:
					'You shake your head. "Sorry Fedor, but I don''t think that this is really working out. I''m sorry." Fedor looks visibly upset as he replies "I guess it was never meant to be, I''m sorry for wasting your time..." He then silently walks you home.'
				else
					'You shake your head. "You seem like a cool guy, but I''m just not ready for a relationship right now." Fedor is visibly upset as he replies "I guess it wasn''t a good time. If you ever change your mind then pay me a visit at school." he says with a forced smile as he silently walks you home.'
				end

				act 'Leave': gt 'pav_residential'
			end
		end
	end
	
	act 'Refuse':
		*clr & cla
		npc_rel['A5'] = 70
		gs 'stat'
		'<center><b><h4><font color="blue"><<"Fyodor ">><<"[Fedor]">><<" Kozlov">></font></h4></b></center>'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/fedor/fedorev/fedorsad.jpg"></center>'
		'You shake your head. "I have too much that I need to do right now. Maybe some other time." Fedor lowers his head with a frown. "Okay. Maybe some other time."'

		act 'Leave': gt 'pav_residential'
	end
end

if $ARGS[0] = 'vballreact':
	cla
	menu_off = 1
	'As you approach the team, your coach notices you and calls you aside. "<<$pcs_firstname>>, are you pregnant? I can''t let you play like that. Also, a pregnant teenager would definitely reflect poorly on me and the rest of the team. Sorry, but off the team." Tears welling in your eyes, you leave.'
	minut += 5
	gs 'stat'
	
	act 'Continue':npc_pregtalk['A69'] = 1 & gt 'pav_commcenter'
end

--- gdksport ---------------------------------