glife/locations/fight3.qsrc

# fight3
$resultUderDin = {
	if Aktiv > Passiv:
		point += 1
		Ku += 1
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/f3u.jpg"></center>'
		'You''ve successfully locked your opponent.'

		act '...':stoper = 0 & gt 'fight2'

	! if Aktiv <= Passiv:
	elseif Aktiv = Passiv:
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/f1u2.jpg"></center>'
		'The two of you try to one up each other without being able to gain the superiority.'

		act '...':gt $curloc
	else
		pointE += 1
		KzE += 1
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/f3u2.jpg"></center>'
		'You''re not able to do anything as your opponent breaks your lock.'

		act '...':gt 'RoundStop'
	end
}

$resultBrosDin = {
	if Aktiv > Passiv:
		point += 2
		lustw += 1
		Kb += 1
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/f3b.jpg"></center>'
		'You''re successfully thrown your opponent.'

		act '...':stoper = 0 & gt 'fight1'
	! if Aktiv <= Passiv:
	else
		pointE +=1
		KzE += 1
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/f3u2.jpg"></center>'
		'You''re not able to do anything as your opponent counters.'

		act '...':gt 'RoundStop'
	end
}

!!you top
!!opponent bottom facing you
koef = 100
koefE = 100
rMin -= 1
stoper += 1
gs 'fightStat'
'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/kickboxing/f3.jpg"></center>'
'<<$nameE>> lies beneath you, while you sit on top of her. <<$nameE>> is desperately trying to throw you off her.'

if endur <= 0 or lustw <= 0:gt 'SubLoss'

if endurE <= 0 or lustwE <= 0:gt 'SubWin'

if stoper < 3:
	if rMin > 0:
		act 'Make an attempt to hold':
			cls
			dynamic $uderdin
			dynamic $resultUderDin
		end

		act 'Make an attempt to throw':
			cls
			dynamic $brosdin
			dynamic $resultBrosDin
		end
	else
		'The referee blows the whistle and tells you to stand up. End of round.'

		act 'up':gt 'RoundEnd'
	end
elseif stoper >= 3:
	pointE += 1
	'The referee blows the whistle and tells you to stand up. You''ve failed with your offence. <<$nameE>> receives one point.'

	act 'Get up':gt 'RoundStop'
end

--- fight3 ---------------------------------