glife/locations/gadforestswamp.qsrc

# gadforestswamp

$location_type = 'secluded'
if $ARGS[0] = '1':
	$metka = '1'
	$loc = 'gadforestswamp'

	gs 'gadukino_event', 'sound'
	gs 'stat'
	'<center><H4>Swamp</H4></center>'
	if month >= 4 and month <= 10:
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/gadforestlostswamp.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/gadforestlostswamp_night.jpg"></center>'
		end
	else
		if hour >= 8 and hour < 18:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/gadforestlostswamp_winter.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/gadforestlostswamp_winter_night.jpg"></center>'
		end
	end
	'You went to the marsh, behind it you can see some kind of hut. You can go back into the woods or try to get to the hut through the mash, but will you have enough strength and dexterity to overcome this mess?'

	act 'Go back to the forest':gt 'gadforestlost','4'

	act 'To go through the mire':
		*clr & cla
		minut += 10
		swamprand = pcs_stren + pcs_agil
		pcs_sweat += 10
		gs 'stat'

		if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and CloSkirtShortness = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/goswamp.jpg"></center>'
		if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and CloSkirtShortness > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/goswamp_ski.jpg"></center>'
		if $clothingworntype = 'nude':'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/goswamp_nude0.'+rand(4,5)+'.jpg"></center>'
		'You entered the swamp and felt your feet starting to sink into the mud...'
		temp_gads = RAND(1,100)
		act 'Go further':
			if swamprand > temp_gads:gt 'swamp_yard'
			if swamprand < temp_gads and temp_gads >= 90:over = 10 & gt 'gameover'
			if swamprand < temp_gads and temp_gads < 90:gt 'gadforestswamp', '2'
		end
	end
end

if $ARGS[0] = '2':
	$metka = '2'
	$loc = 'gadforestswamp'
	gs 'gadukino_event', 'sound'

	pcs_hairbsh = 0
	if pcs_makeup > 1:pcs_makeup = 0
	!clothes wear out, "dirty" to avoid at a time 
	if dirty = 0 and ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear'):dirty = 1 & dirtyclothes = 1 & dynamic $clothingworntype + 'H[<<clothingwornnumber>>] -= 10'
	!add remove cloth if worn out, need better texting by illume.
	if dyneval('RESULT = <<$clothingworntype>>H[<<clothingwornnumber>>]') <= 0:
		'Your clothes are torn to pieces, you are naked now.'
		gs 'clothing', 'strip'
	end
	gs 'stat'
	'<center><H4>Swamp</H4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/panicswamp.jpg"></center>'
	'You are stuck in the quagmire."I''m stuck!", you think in panic "What do I do?". '

	act 'Call for help':
		*clr & cla
		minut += 10
		if pcs_sweat < 10: pcs_sweat += 10	
		if week = 6 or week = 7:temp_gads = RAND(1,3)
		if week < 6:temp_gads = RAND(1,5)
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/gadforestlosthelp.jpg"></center>'
		'You are exhausted and begin to scream for help, suddenly you see people...'

		act 'Wait':
			if temp_gads = 1:
				*clr & cla
				minut += 10
				hanters = 1
				hanterhelp = 1
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/handshelp.jpg"></center>'
				'You hear men speaking and begin to shouting louder. The voices come closer and finally, someone''s strong hands grabbed you and dragged back to solid ground.'

				act 'Further':gt 'swamp_yard'
			else
				*clr & cla
				minut += 10
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/panicswamp.jpg"></center>'
				'No one responds to your call, looks like you are all alone.'
				act 'Further':gt 'gadforestswamp','2'
			end
		end
	end

	act 'Trying to get back to the woods':
		*clr & cla
		minut += 10
		swamprand = pcs_stren + pcs_agil
		stren_exp += rand(0,1)
		agil_exp += rand(0,1)
		pcs_sweat += 30
		temp_gads = RAND(1,100)
		gs 'stat'

		dynamic $swampclothes
		'You decided not to tempt fate more and turn back...'

		act 'Go':
			if swamprand > temp_gads:gt 'gadforestswamp','1'
			if swamprand < temp_gads and temp_gads <= 20:over = 10 & gt'gameover'
			if swamprand < temp_gads and temp_gads > 20:gt 'gadforestswamp','2'
		end
	end
	act 'Try to go on to the house':
		cla
		*clr
		minut += 10
		swamprand = pcs_stren + pcs_agil
		stren_exp += rand(0,1)
		agil_exp += rand(0,1)
		pcs_sweat += 30
		temp_gads = RAND(1,100)
		gs 'stat'

		dynamic $swampclothes
		'You thought more about it and decided against it. You move on from the house...'

		act 'Go':
			if swamprand > temp_gads:gt 'swamp_yard'
			if swamprand < temp_gads and temp_gads <= 30:over = 10 & gt'gameover'
			if swamprand < temp_gads and temp_gads > 30:gt 'gadforestswamp','2'
		end 
	end
end

$swampclothes = {
	if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and CloSkirtShortness = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/goswamp1.jpg"></center>'
	if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and CloSkirtShortness > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/goswamp_ski1.jpg"></center>'
	if $clothingworntype = 'nude':'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/goswamp_nude0.'+rand(4,5)+'.jpg"></center>'
}

--- gadforestswamp ---------------------------------