# danceclass
clr
minut += 5
razdtumbler = 0
gs 'stat'
fcolor = rgb(0, 0, 0)
bcolor = rgb(255, 255, 255)
lcolor = rgb(106, 90, 205)
'<center><b><font color="maroon">Dance Studio</font></b></center>'
'<center><img src="images/etogame/danceclass.jpg"></center>'
'A big, open room with good lighting and huge mirrors, perfect for developing dance skills.'

act 'Modern dance class (2:00)':
	cla
	*clr
	minut += 120
	fat -= 5
	speed+= rand(1, 3)
	manna -= 5
	sweat += 3
	dance += rand(5, 15)
	'<center><img src="images/etogame/fit1.jpg"></center>'

	if dance < 100:'You studied modern dance, which is very popular in clubs.'
	if dance >= 100:'Though you worked hard, you realize there is nothing more worth learning from this class.'

	act 'Leave':gt 'fit', 'dressing room'
end

act 'Striptease class (2:00)':
	cla
	*clr
	minut += 120
	fat -= 5
	agil+= rand(1, 3)
	manna -= 8
	sweat += 3
	!!stripdance += 1
	'<center><img src="images/etogame/stripdance.jpg"></center>'

	if dance >= 100:
		stripdance += rand(2, 10)
		'You studied the art of burlesque, imaging yourself stripping to the music.'

		if stripdance >= 100:'But there is nothing more worth learning, since you have already mastered the art.'
	elseif dance < 100:
		dance += rand(5, 15)
		'This isn''t just taking clothes off, it''s a difficult dance style and your basics aren''t upto the task. The teacher recommends that you work on your modern dancing first.'
	end

	act 'Leave':gt 'fit', 'dressing room'
end

act 'Pole dancing class (2:00)':
	cla
	*clr
	minut += 120
	fat -= 10
	stren += rand(1, 3) + (steroid_dose - rand(0,steroid_dose)) & gs 'obj_din', 'steroids'
	vital += rand(1, 3) + (steroid_dose - rand(0,steroid_dose)) & gs 'obj_din', 'steroids'
	manna -= 5
	sweat += 3
	!!poledance += 1
	'<center><img src="images/etogame/poledance.jpg"></center>'

	if dance >= 100 and stripdance >= 100 and stren >= 80:
		poledance += rand(2, 5)
		'You studied various acrobatics on the pole.'

		if poledance >= 100:'But you could not learn anything new, you''re already a master of the art.'
	elseif dance < 100 or stripdance < 100 or stren < 80:
		'It''s not pretty and you bang your head on the pole, you realize you are out of your league. It will help if you improve your modern dancing or striptease first.'

		if stren < 80:'The instructor tries to be patient, but it is clear that you are too weak for this sort of dance.'
	end

	act 'Leave':gt 'fit', 'dressing room'
end

--- danceclass ---------------------------------

