GirlLife_BPP/locations/pavCommercial.qsrc

# pavCommercial

!{Change log
25 March 2016
Fixed diplaced period after church link
Fixed visting links to look the same
Added start of Andrei kidnapping
}
$location_type = 'public_outdoors'

$metka = ''
$loc = 'pavCommercial'
$metkaStreet = ''
$locStreet = 'pavCommercial'
CLOSE ALL
if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7:PLAY 'sound/street_night.mp3',30
	end
end

cla
*clr
litltown = 1
alkoblock = 0
boynumBlock = 0
!!sets the return location for bank and post office
bankloc = 0

!call random events from [street_events], and display them before show location.
if streetevent_hour + 2 < hour:gt'street_event','pavCommercial', 'main'

'<center><h2>Pavlovsk</h2></center>'
if month >= 11 or month <= 3:
	if hour >= 8 and hour <= 21:
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/gorodokw.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/pavbuswn.jpg"></center>'
	end
else
	if hour >= 8 and hour <= 21:
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/gorodok.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/pavbusn.jpg"></center>'
	end
end
*nl
'<center>The high street of a provincial town in a rural area of Russia.  Population: about 15000 inhabitants.</center>'
'<center>Apart from the old <a href="exec:view''images/locations/pavlovsk/palace/pav_palace.jpg''">Imperial palace</a> with its surrounding gardens and forest, built by Catherine the Great, and the recently rebuilt <a href="exec:view''images/locations/pavlovsk/fortress/bip_hotel.png''">Bip fortress</a> (which is now a Luxury hotel and restaurant), it looks much like all the other towns in the region.</a></center> '
'<center>The tallest building in town is the <a href="exec:minut += 10 & gt ''ParChurch'',''start''">church of St Nikolas.</a></center>'
*nl

gs'street_event','pavCommercial', 'extras'

if AlbFather >= 1:
	if AlbFaterBlackTime = 0:AlbFaterBlackTime = totminut + 2880

	'You can see election posters on the walls all over town. They say: "Vote for Boris Barlovsky!" Wait a minute... isn''t that Albina''s father?'
end

if AlbFaterBlackTime > 0 and AlbFaterBlackTime <= totminut and hour >= 14 and AlbFather = 1:gt 'AlbFatherQW'
if hour >= 14 and hour <= 22 and AlbFather = 2 and AlbZaDay + 30 < daystart and year > 2015:
	gt 'AlbStarsEnd'
end

if StoryLine > 0 and hour < 4 and motherWorry = 0 and SchoolAtestat = 0 and age < 18 and home_owned[2] = 1:
	motherWorry = 1
end

if rand(1, 5) >= 4 and pav_slut >= 50:
	if pav_slut < 75:
		'You catch people staring at you intently, as if they''re supposed to know who you are but can''t quite remember why. You sincerely hope they don''t realize your promiscuous adventures are the reason why. The occasional person chuckling and pointing at you crushes those hopes, and you quickly keep walking before they get a chance to say anything.'
	elseif pav_slut < 100:
		'People look at you with lewd grins on their faces, some of them even making vulgar gestures. Looks like they know what you''ve been up to.'
	else
		'Everywhere you go, people recognize you as a whore. Some even come over and slap you on the ass, claiming they know you like it when they do, or claiming they want to sample your goods. An elderly woman sitting on a bench calls out to you, loudly calling you a slut and a whore. You hide your face and run away as fast as you can, before she can draw too much attention to you.'
	end
end

gs 'stat'

if car > 0 and cardrive = 24:
	cardrive = 24
	'Your <a href="exec:gs ''carF'', ''start''">car<<$car>></a> is parked in the street.'
end

if hour >= 8 and hour <= 20:
	$Pharmname = ', and the <a href="exec: minut += 5 & gt ''gaptek'', ''start''">pharmacy</a> is right across the street.'
else
	$Pharmname = '.'
end

'You are on the high street, at one end is the <a href="exec:minut += 15 & gt ''pavtrain''">train station</a> and access to the highway. Near the highway you can also find a <a href="exec:minut += 5 & gt ''zaprF'', ''start''">gas station</a>.'
'The nearby residential area is next to the lake and the town surrounds the old palace grounds which are now a large <a href="exec:minut += 5 & gt ''gskver'', ''start''">public park</a>.'
'There is a small <a href="exec:minut += 5 & gt ''gpoli''">clinic</a><<$Pharmname>>'

if leonidSlave = 1:
	'Near the town hall there is an old <a href="exec:minut += 15 & gt ''pavCommercialOffices''">office building</a>.'
end


if hour >= 8 and hour <= 17:'The local <a href="exec: minut += 3 & gt ''barbershop'', ''start''">barbershop</a> is within walking distance, merely a few minutes away.'
if hour >= 7 and hour <= 18:'Pavlovsk has a <a href="exec:minut += 15 & gt ''etoexhib'', ''pos20''">vocational school</a>, where young adults can learn a trade.'
if hour >= 8 and hour <= 20:'There is a big chain <a href="exec:minut += 2 & gt ''shop'', ''start''">supermarket</a> nearby.'
if week < 6 and hour >= 9 and hour <= 18:'You can see the most important <a href="exec:gt ''bank'', ''start''">Bank</a> in the city from here.'
if (week < 6 and hour >= 9 and hour <= 16) or (week = 6 and hour >= 9 and hour <= 13):'The local <a href="exec:minut += 3 & gt ''postoffice'', ''start''">post office</a> branch is open.'

'A <a href="exec:minut += 15 & gt ''Gshveyfab'', ''start''">garment factory</a> named Paris Commune is situated in the industrial area on the outskirts of town, close to the highway.'

''

if workPTU > 2:act '<b>Go to the hostel</b>':gt 'etoexhib', 'pos40'

act 'Go to the residential area':minut += 5 & gt 'pavResidential'

act 'Walk to the city highway':minut += 15 & nroad = 20 & gt 'road'

act 'Wait':gs 'obj_din', 'wait'

if rand (0,2) ! 0:gs 'din_bad' & dynamic $mobile_check

if npc_QW['A113'] = 1 and daybelisex ! daystart and hour >= 9 and hour <= 23 and week = 7:
	cla & *clr
	daybelisex = daystart
	minut += 5

	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/vadim/belyjeep.jpg"></center>'
	'As you walk through Pavlovsk, Vadim Belys Mitsubishi Pajero stops near you.'

	act 'Go to the jeep': return_residential = 0 & gt 'belgang', 'payday'
elseif npc_QW['A113'] = 1 and daybelisex ! daystart and hour >= 9 and hour <= 23 and week ! 7 and belgangPayWeek >= 300 and belgangProstitute = 1 and rand (0,2) = 0:
	cla & *clr
	daybelisex = daystart
	minut += 5

	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/vadim/belyjeep.jpg"></center>'
	'You see the by now familiar old Mitsubishi Pajero driving through the streets with Vadim Bely and his gang. Your heart skips a beat as you notice one of them pointing at you, and soon they pull over.'

	act 'Go to the jeep': return_residential = 0 & gt 'belgang', 'workofdebt'
end

--- pavCommercial ---------------------------------