# buklinik

if $ARGS[0] = 'start':
	$menu_loc = 'buklinik'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla
	minut += 5	
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Mercy clinic</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli.jpg"></center>'
	'A quite run-down building with a large sign above the entrance displaying the name Mercy Clinic. Known for taking care of the homeless and providing shelter for domestic abuse victims.'
	'Walking up to the door you notice a note on the door.'
	'Working hours: 09:00 to 17:00'
	temp = rand(1, 10)
	if temp = 9:'There is a crowd of homeless people huddled together trying to find a shelter...'
	if temp = 2:'There is a homeless person trying to get into the shelter...'
	if temp = 3:'There is an older man standing outside the shelter...'
	if temp = 4:'There is a woman standing outside trying to console her crying child...'
	if temp = 5:'There is a bruised woman standing outside the shelter having a smoke...'
	if temp = 1:'There is a man walking up and down the path outside, yelling profanities...'
	if temp = 8:'There is a young woman with tears in her eyes, sitting on a bench right next to the shelter...'
	if temp = 7:'There is a couple loudly discussing if they really want to enter the shelter tonight...'
	if temp = 6:'There is a woman crying, arguing on the phone, probably with her husband...'
	if temp = 10:'Surprisingly, there is no one standing outside the shelter...'

	act 'Leave':gt 'city_industrial'
	
	if hour >= 9 and hour <= 17: act 'Enter the shelter':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'holl':
	$menu_loc = 'buklinik'
	$menu_arg = 'holl'
	menu_off = 0
	*clr & cla
	minut += 5
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Entrance</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_holl.jpg"></center>'
	'The interior is even worse than the exterior, the paint on the wall is falling off and hasn''t been repainted for quite a while. There are some lights working but not all of them and there is this weird smell that you can''t really pinpoint what it is.'
	if StoryLine = 1 and SchoolAtestat = 0 and kanikuli = 0 and week < 6 and bumtolik >= 5:
		'You can volunteer here on the weekends.'
	else
		if bumtolik > 4:'There is a lock on the <a href="exec:gt ''buklinik'', ''sklad''">storage</a> room.'
		if bumtolik > 5:'You can find the <a href="exec:gt ''buklinik'', ''registr3''">office</a> right by the entrance.'
		if bumtolik > 5:'Opposite the office you can find the <a href="exec:gt ''buklinik'', ''olga2''">accountants''</a> office.'
		if bumtolik > 5:'At the end of the corridor, you can find the <a href="exec:gt ''buklinik'', ''shower''">showers</a>.'
		if bumtolik = 6:'There are several doors leading into the <a href="exec:gt ''buklinik'', ''spal''">dormitory</a>.'
		if bumtolik > 6:'I shouldn''t interact with the people staying there right now...'
		if bumtolik > 5:'Visit the <a href="exec:gt ''buklinik'', ''stol''">canteen</a>.'
		if bumtolik > 5:'Behind the solid door you find the <a href="exec:gt ''buklinik'', ''sec''">Managers''</a> office.'
		if bumtolik > 5:'The <a href="exec:gt ''buklinik'', ''dir''">coordinators''</a> office is next to the canteen.'
	end

	act 'Leave':gt 'city_industrial'
	if (SchoolAtestat = 0 and bumtolik = 0) or bumtolik = 4: act 'Volunteer':gt 'buklinik', 'registr'
end

if $ARGS[0] = 'registr':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Counter</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_reg.jpg"></center>'
	'You approach the counter as you see two women in white coats sitting and chatting with each other, laughing.'

	if StoryLine = 1 and SchoolAtestat = 0 and bumtolik < 5:
		!r125
		'You clear you throat to get their attention, "Hello, my name is <<$pcs_firstname>>, I read on that note that you were looking for volunteers..."'
		'The two women cheerfully reply, "Hello! Welcome to our little humble shelter. As you probably noticed we really need some volunteers, just a fair warning the job is not always fun and there''s always lots to do. What you see here is just a small part of it, we even help out the elderly and the less fortunate ones outside the shelter.'
		'You nod your head, "I''m not afraid to get dirty and I''m sure that I''ll manage..."'
		'The woman behind the counter continues, "In addition, since you are still in high school, that the law states that you can only volunteer outside school hours, during the weekends."'
	else
		'You clear your throat, "Hello, my name is <<$pcs_firstname>>, I met a girl named Olga who said that you need volunteers. So here I am..."'
		'The woman quickly comes over, "Hello! We are very pleased to have you here. Just a couple of heads up before you make your mind up. The work hours are long and ungrateful, what you see here is just a small part of it, we even do some work outside the shelter with the less fortunate."'
	end

	act 'I have to think about it':gt 'city_industrial'
	act 'Accept':gt 'buklinik', 'registr2'
end

if $ARGS[0] = 'registr2':
	*clr & cla
	menu_off = 1
	minut += 15
	bumtolik = 5
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Counter</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_reg.jpg"></center>'
	'You smile, "I think I can handle it. Where do I start?'
	'The woman sighs a sigh of relief, "I am happy to hear that. Fill out this form. We give all our volunteers documentation that they''ve worked here in case of you need it for a future reference.'
	'You take some time to fill out the form and hand it back to the woman.'
	'The woman skims through it, "Great, so you see the the first door on the right down the corridor, enter there and you should find Olga there, she''ll show you around.'

	act 'Continue down the corridor':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'registr3':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Counter</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_reg.jpg"></center>'
	'You can usually find either Karina or Regina sitting by the counter, welcoming both volunteers and people needing help.'

	act 'Continue down the corridor':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'sklad':
	*clr & cla
	menu_off = 1
	minut += 5
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Storage room</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_sklad.jpg"></center>'
	'The storage room is filled with all sort of things. From clothing and food, to toys for the children and there is even a medicine box where a note says to <i>keep locked at all times!!!</i>'
	'You see several people sorting all the stuff, trying to make sense of the current chaos.'

	if bumtolik = 5:act 'Look for Olga':gt 'buklinik', 'olga'

	act 'Head back to the corridor':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'olga':
	*clr & cla
	menu_off = 1
	minut += 5
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Olga</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_olga.jpg"></center>'
	
	if bumtolik = 5:
		'You see Olga and walk up to her, "Hi Olga! I don''t know if you remember me, I am <<$pcs_nickname>>, you told me about this place and that you were looking for people to volunteer so I decided to come over and help out. The women at the reception told me that I would find you here."'
		'Olga looks at you, not really remembering who you are, "<<$pcs_nickname>>..., good afternoon! Good for you, welcome! Well as you can see we are swamped so any help is very welcome!" Olga smiles and continues, "Since you got sent to me I''ll be your mentor so feel free to ask me if you have any questions."'
		'You nod, "I understand!"'
		'Olga smiles, "Good, well, lets start off with a tour. We can start off here, the storage room. We pack up every donatation we get and sort it out and put it into boxes and if needed we transport it to the needy. Next up the managers'' office!"'
		
		act 'Visit the managers office':gt 'buklinik', 'sec'
	
	else
		'You look around the room, "So I was supposed to find an Olga here?"'
		'A woman looks up, "Right here, honey! And who might you be?" she asks.'
		'"<<$pcs_nickname>>" you answer, "The lady at the counter told me to find you."'
		'Olga crosses her arms, "Is that so?! Nothing to worry about, so I''m guessing you''re a new volunteer?"'
		'You nod.'
		'Olga smiles, "Good, well, lets start off with a tour. We can start off here, the storage room. We pack up every donatation we get and sort it out and put it into boxes and if needed we transport it to the needy. Next up the managers'' office!"'
		
		act 'Visit the managers office':gt 'buklinik', 'sec'
	end
end

if $ARGS[0] = 'sec':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Jeanne</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_sec.jpg"></center>'

	if bumtolik = 5:
		'The two of you knock on the door and walk right in, "<<$pcs_nickname>> meet our office manager Jeanne. She is responsible for everything operational here. If you find any organizational issues take it up with her and she''ll sort it out. Jeanne this is <<$pcs_nickname>> and is our new volunteer."'
		'Jeanne gives you a warm smile, "Welcome, I hope you will find our shelter not too demanding. And I really hope that Olga doesn''t give you too much trouble..." she jokingly says.'
		'Before you''re able to say anything Olga chimes in, "And that''s the thanks I get for recruiting volunteers. It''s clear we''re not welcome here <<$pcs_nickname>> so lets move on..."'
		'You manage to give a friendly nod before you and Olga head out the office, "Next stop, the coordinators'' office!"'
		act 'Head to the coordinator':gt 'buklinik', 'dir'
	elseif bumtolik > 5:
		'"Hello, <<$pcs_nickname>>! Is there anything I can help you with?"'
		act 'Head back to the corridor':gt 'buklinik', 'holl'
	end
end

if $ARGS[0] = 'dir':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Vera</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_dir.jpg"></center>'
	
	if bumtolik = 5:
		'Olga just barges in without even knocking, "And this is our coordinator Vera..."'
		'Vera sighs, "Again Olga? Haven''t I told you to knock when you''re entering the office and I told you before it''s only Vera."'
		'Olga brushes her off, "I heard you, I heard you." she turns to you, "Vera is not only the coordinator, but the mastermind behind this whole operation, she is one of the founders and also created the organization."'
		'You politely greet her, "My name is <<$pcs_nickname>> and I look forward to help you out the best I can!"'
		'Vera smiles, "Glad to hear that <<$pcs_nickname>>! You''re certainly most welcome, you''ve probably heard that we could use all the hands we can get hold of."'
		'The three of you chat for a while and before you know it it''s time to move on...'
		act 'Continue the tour':gt 'buklinik', 'olga2'
	elseif bumtolik > 5:
		'"Hello, <<$pcs_nickname>>! Is there anything I can help you with?"'
		act 'Head back to the corridor':gt 'buklinik', 'holl'
	end
end

if $ARGS[0] = 'shower':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Showers</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_show.jpg"></center>'
	'Shared showers for the people staying here. There''s a note put up by the staff:'
	'Men: Every even hour. Do not enter if you''re a female!!!'
	'Women: Every odd hour. Do not enter if you''re a male!!!'
	'Note: Staff might enter during any hours!'
	*nl
	'You better not stay here all too long some of the people staying here might take offense to you being there.'

	act 'Head back to the corridor':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'stol':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Canteen</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_stol.jpg"></center>'
	'There''s a large canteen with lots of tables and chairs with lots of space. This is probably the biggest room in this building.'
	*nl
	'There is a sign by the entrance:'
	'Breakfast: 08:00 - 09:30'
	'Dinner: 17:00 - 19:00'

	act 'Leave the canteen':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'spal':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Dormitory</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_spal.jpg"></center>'
	'A shared dormitory with plenty of beds where you can find all kind of people. There are plenty of alcoholics, vagrants and drug addicts which are homeless. Mixed in with women with their children that have ran away from their abusive husbands.'
	'Within the dormitory there is a small divide where the male population stick to one side while the women keep on the other.'

	if bumtolik = 6: act 'Introduce yourself':gt 'buklinik_event', 'pos1'

	act 'Leave the dormitory':gt 'buklinik', 'holl'
end

if $ARGS[0] = 'olga2':
	*clr & cla
	menu_off = 1
	minut += 15
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b>Olga</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/mercyclinic/bukli_olga.jpg"></center>'

	if bumtolik > 5:'"Hello, <<$pcs_nickname>>! Is there anything I can help you with?"'
	if buklinikDay = daystart:'"All the assignments are done for today. Finally we can relax a bit..."'
	if bumtolik >= 7 and buklinikDay ! daystart:'"<<$pcs_nickname>>, we need help to <a href="exec:gt ''buklinik_event'', ''pos6''">feed the needy</a>."'
	if bumtolik >= 8 and buklinikDay ! daystart: '"<<$pcs_nickname>>, here is the address of one the <a href="exec:gt ''buklinik_event'',''pos8''">elderly men</a>, would you be so kind and help him out with some housework.'
	if bumtolik = 9 and buklinikDay ! daystart: '"<<$pcs_nickname>>, I''m going to need some help persuade an alcoholic to stop wandering the streets, and come stay at the <a href="exec:gt ''buklinik_event'',''pos9''">shelter</a>."'
	if bumtolik = 10 and buklinikDay ! daystart: '"We need a babysitter for one very <a href="exec:gt ''buklinik_event'',''event0''">strange man</a>. Can you please go visit him?"'
	if bumtolik = 11 and buklinikDay ! daystart: '"<<$pcs_nickname>>, would you be kind and visit <a href="exec:gt ''buklinik_event'',''entrance'',0">Michael</a>?"'
	if bumtolik = 12 and buklinikDay ! daystart: '"<a href="exec:gt ''buklinik_event'',''entrance'',1">Michael</a> is asking for you, <<$pcs_nickname>>. You must''ve made a great impression."'
	if bumtolik = 13 and buklinikDay ! daystart: '"<<$pcs_nickname>>, <a href="exec:gt ''buklinik_event'',''entrance'',2">Michael</a> won''t stop nagging us about you... Can you please go and see him?"'
	if bumtolik = 14 and buklinikDay ! daystart: '"<<$pcs_nickname>>, <a href="exec:gt ''buklinik_event'',''entrance'',3">Michael</a> is expecting you."'
	if bumtolik = 15 and buklinikDay ! daystart: '"Why the hell is <a href="exec:gt ''buklinik_event'',''entrance'',4">Michael</a> always asking for you to visit him?'
	if bumtolik = 16 and week = 1 and buklinikDay ! daystart: '"Guess who is asking for you, you guessed it, <a href="exec:gt ''buklinik_event'',''entrance'',5">Michael</a>."'
	!bumtolik = 3000 if michael events stoped.
	if bumtolik = 5:
		bumtolik = 6
		'Olga shows you around, "Over here we have the corridor beds, showers and the dining room where guests eat for free. I think that''s all, ask away if I forgot something to show you. Oh yeah, at the reception we have Regina and Karina, whom you''ve already met. There are plently of other volunteers but I''ll let you meet them."'
		'You thank Olga for the tour as she quickly heads back to the storage room.'
	end

	act 'Head back to the corridor':gt 'buklinik', 'holl'
end

--- buklinik ---------------------------------

