# exercise

!{This will centralize calls for exercise. For calls where you wish to allow multiple types of exercises, such as a bedroom or yard, use gs 'exercise', 'start'
For direct calls use this format: gs 'exercise', $ARGS[0], ARG[1], $ARGS[2], $ARGS[3], $ARGS[4]
$ARGS[0] is the workout tier and the higher the tier, the greater the workout intensity.
	Values: 'tier1' 'tier2' 'tier3' 'tier4'
ARG[1] is the time override. By default the tiers are in 15 minute segments if being called from an event with predetermined time set this to 1
	Values: 0 (default of 15 minutes) 1 (time set to 0)
$ARGS[2] and on are the stats to be affected by the workout NOTE: use the gs 'exp_gain', 'name of varibale' variant, not the pcs_!!!!
	Values: 'stren' 'vital' 'agil' 'sprt' 'react'
	Other stats can be added if desired - for a dance-a-thon you might use gs 'exercise', 'tier1', 0, 'agil', 'danc'
}

if $ARGS[0] = 'start':
	if (pcs_stam >=15 or pcs_stam >= 10 and mc_inventory['book_yoga'] + mc_inventory['hula_hoop'] > 0):
		'There is enough space in the room to <a href="exec: gt ''exercise'', ''workout''">exercise</a>.'
	else
		'There is enough space in the room for a variety of exercises, but you don''t have the energy to work out now.'
	end
end

if $ARGS[0] = 'workout':
	$menu_loc = 'exercise'
	$menu_arg = 'workout'
	menu_off = 0
	*clr & cla
	exer_menu = 0
	gs 'exercise', 'routines'
	clothesAtLocation = FUNC('lost_clothes_here',$loc)
	if $clothingworntype = 'nude' and clothesAtLocation = 1:
		act 'End workout and get dressed':
			cla
			minut += 5
			gs 'underwear', 'wear'
			gs 'clothing', 'recover_lost_clothes', $loc, 1
			gs 'stat'
			gt $loc, $loc_arg
		end
	else
		act 'End workout':
			gt $loc, $loc_arg
		end
	end
	if pcs_stam < stammax / 5:
		'You do not have the energy/stamina to exercise currently'
	elseif $clothingworntype = 'nude' or $clothingworntype = 'danilovich_outfits':
		act 'Manual routines': gt 'exercise', 'manual'
		act 'Define routines': gt 'exercise', 'setup'
		if exer_stam[1] ! 0 and pcs_stam > exer_stam[1]: act '<<$excer_name[1]>> - (<<exer_stam[1]>> stamina)': exercisex = 1 & gt 'exercise', 'auto'
		if exer_stam[2] ! 0 and pcs_stam > exer_stam[2]: act '<<$excer_name[2]>> - (<<exer_stam[2]>> stamina)': exercisex = 2 & gt 'exercise', 'auto'
		if exer_stam[3] ! 0 and pcs_stam > exer_stam[3]: act '<<$excer_name[3]>> - (<<exer_stam[3]>> stamina)': exercisex = 3 & gt 'exercise', 'auto'
		if exer_stam[4] ! 0 and pcs_stam > exer_stam[4]: act '<<$excer_name[4]>> - (<<exer_stam[4]>> stamina)': exercisex = 4 & gt 'exercise', 'auto'
		if exer_stam[5] ! 0 and pcs_stam > exer_stam[5]: act '<<$excer_name[5]>> - (<<exer_stam[5]>> stamina)': exercisex = 5 & gt 'exercise', 'auto'
	else
		'<b>You need to equip the proper attire before you can exercise</b>'
	end
end

if $ARGS[0] = 'auto':
	exer_auto = 1
	if exer_rout0[exercisex] > 0:
		timemult = exer_rout0[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'push'
	elseif exer_rout1[exercisex] > 0:
		timemult = exer_rout1[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'press'
	elseif exer_rout2[exercisex] > 0:
		timemult = exer_rout2[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'rope'
	elseif exer_rout3[exercisex] > 0:
		timemult = exer_rout3[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'yoga'
	elseif exer_rout4[exercisex] > 0:
		timemult = exer_rout4[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'hula'
	elseif exer_rout5[exercisex] > 0:
		timemult = exer_rout5[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
	end
end

if $ARGS[0] = 'auto1':
	if exer_rout1[exercisex] > 0:
		timemult = exer_rout1[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'press'
	elseif exer_rout2[exercisex] > 0:
		timemult = exer_rout2[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'rope'
	elseif exer_rout3[exercisex] > 0:
		timemult = exer_rout3[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'yoga'
	elseif exer_rout4[exercisex] > 0:
		timemult = exer_rout4[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'hula'
	elseif exer_rout5[exercisex] > 0:
		timemult = exer_rout5[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
	else
		gt 'exercise', 'auto_end'
	end
end

if $ARGS[0] = 'auto2':
	if exer_rout2[exercisex] > 0:
		timemult = exer_rout2[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'rope'
	elseif exer_rout3[exercisex] > 0:
		timemult = exer_rout3[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'yoga'
	elseif exer_rout4[exercisex] > 0:
		timemult = exer_rout4[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'hula'
	elseif exer_rout5[exercisex] > 0:
		timemult = exer_rout5[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
	else
		gt 'exercise', 'auto_end'
	end
end

if $ARGS[0] = 'auto3':
	if exer_rout3[exercisex] > 0:
		timemult = exer_rout3[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'yoga'
	elseif exer_rout4[exercisex] > 0:
		timemult = exer_rout4[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'hula'
	elseif exer_rout5[exercisex] > 0:
		timemult = exer_rout5[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
	else
		gt 'exercise', 'auto_end'
	end
end

if $ARGS[0] = 'auto4':
	if exer_rout4[exercisex] > 0:
		timemult = exer_rout4[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'hula'
	elseif exer_rout5[exercisex] > 0:
		timemult = exer_rout5[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
	else
		gt 'exercise', 'auto_end'
	end
end

if $ARGS[0] = 'auto5':
	if exer_rout5[exercisex] > 0:
		timemult = exer_rout5[exercisex] & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
	else
		gt 'exercise', 'auto_end'
	end
end

if $ARGS[0] = 'auto_end':
	exer_auto = 0
	gt 'exercise', 'workout'
end

if $ARGS[0] = 'manual':
	$menu_loc = 'exercise'
	$menu_arg = 'manual'
	menu_off = 0
	cla
	act 'Return':gt 'exercise', 'workout'
	if pcs_stam < 5 * (10 - sport_clothes_exercise_bonus):
		'You don''t have the energy/stamina to work out anymore now.'
	else
		act 'Do pushups':
			cla
			act 'Return':gt 'exercise', 'manual'
			if pcs_stam >= (15*1 * (10 - sport_clothes_exercise_bonus)) / 2: act '15 minutes': timemult = 1 & gs 'exercise', 'timestring' & gt 'exercise', 'push'
			if pcs_stam >= (15*2 * (10 - sport_clothes_exercise_bonus)) / 2: act '30 minutes': timemult = 2 & gs 'exercise', 'timestring' & gt 'exercise', 'push'
			if pcs_stam >= (15*3 * (10 - sport_clothes_exercise_bonus)) / 2: act '45 minutes': timemult = 3 & gs 'exercise', 'timestring' & gt 'exercise', 'push'
			if pcs_stam >= (15*4 * (10 - sport_clothes_exercise_bonus)) / 2: act '60 minutes': timemult = 4 & gs 'exercise', 'timestring' & gt 'exercise', 'push'
		end

		act 'Do crunches':
			cla
			act 'Return':gt 'exercise', 'manual'
			if pcs_stam >= (15*1 * (10 - sport_clothes_exercise_bonus)) / 2: act '15 minutes': timemult = 1 & gs 'exercise', 'timestring' & gt 'exercise', 'press'
			if pcs_stam >= (15*2 * (10 - sport_clothes_exercise_bonus)) / 2: act '30 minutes': timemult = 2 & gs 'exercise', 'timestring' & gt 'exercise', 'press'
			if pcs_stam >= (15*3 * (10 - sport_clothes_exercise_bonus)) / 2: act '45 minutes': timemult = 3 & gs 'exercise', 'timestring' & gt 'exercise', 'press'
			if pcs_stam >= (15*4 * (10 - sport_clothes_exercise_bonus)) / 2: act '60 minutes': timemult = 4 & gs 'exercise', 'timestring' & gt 'exercise', 'press'
		end

		act 'Do squats':
			cla
			act 'Return':gt 'exercise', 'manual'
			if pcs_stam >= 5*1 * (10 - sport_clothes_exercise_bonus): act '15 minutes': timemult = 1 & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
			if pcs_stam >= 5*2 * (10 - sport_clothes_exercise_bonus): act '30 minutes': timemult = 2 & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
			if pcs_stam >= 5*3 * (10 - sport_clothes_exercise_bonus): act '45 minutes': timemult = 3 & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
			if pcs_stam >= 5*4 * (10 - sport_clothes_exercise_bonus): act '60 minutes': timemult = 4 & gs 'exercise', 'timestring' & gt 'exercise', 'butt'
		end

		if mc_inventory['skipping_rope'] > 0 and $loc ! 'meadow':
			act 'Jump rope':
				cla
				act 'Return':gt 'exercise', 'manual'
				if pcs_stam >= (15*1 * (10 - sport_clothes_exercise_bonus)) / 2: act '15 minutes': timemult = 1 & gs 'exercise', 'timestring' & gt 'exercise', 'rope'
				if pcs_stam >= (15*2 * (10 - sport_clothes_exercise_bonus)) / 2: act '30 minutes': timemult = 2 & gs 'exercise', 'timestring' & gt  'exercise', 'rope'
				if pcs_stam >= (15*3 * (10 - sport_clothes_exercise_bonus)) / 2: act '45 minutes': timemult = 3 & gs 'exercise', 'timestring' & gt  'exercise', 'rope'
				if pcs_stam >= (15*4 * (10 - sport_clothes_exercise_bonus)) / 2: act '60 minutes': timemult = 4 & gs 'exercise', 'timestring' & gt  'exercise', 'rope'
			end
		end

		if mc_inventory['book_yoga'] > 0:
			act 'Do yoga':
				cla
				act 'Return':gt 'exercise', 'manual'
				if pcs_stam >= 5*1 * (10 - sport_clothes_exercise_bonus): act '15 minutes': timemult = 1 & gs 'exercise', 'timestring' & gt 'exercise', 'yoga'
				if pcs_stam >= 5*2 * (10 - sport_clothes_exercise_bonus): act '30 minutes': timemult = 2 & gs 'exercise', 'timestring' & gt  'exercise', 'yoga'
				if pcs_stam >= 5*3 * (10 - sport_clothes_exercise_bonus): act '45 minutes': timemult = 3 & gs 'exercise', 'timestring' & gt  'exercise', 'yoga'
				if pcs_stam >= 5*4 * (10 - sport_clothes_exercise_bonus): act '60 minutes': timemult = 4 & gs 'exercise', 'timestring' & gt  'exercise', 'yoga'
			end
		end

		if mc_inventory['hula_hoop'] > 0 and $loc ! 'meadow':
			act 'Use your hula hoop':
				cla
				act 'Return':gt 'exercise', 'manual'
				if pcs_stam >= 5*1 * (10 - sport_clothes_exercise_bonus): act '15 minutes': timemult = 1 & gs 'exercise', 'timestring' & gt 'exercise', 'hula'
				if pcs_stam >= 5*2 * (10 - sport_clothes_exercise_bonus): act '30 minutes': timemult = 2 & gs 'exercise', 'timestring' & gt  'exercise', 'hula'
				if pcs_stam >= 5*3 * (10 - sport_clothes_exercise_bonus): act '45 minutes': timemult = 3 & gs 'exercise', 'timestring' & gt  'exercise', 'hula'
				if pcs_stam >= 5*4 * (10 - sport_clothes_exercise_bonus): act '60 minutes': timemult = 4 & gs 'exercise', 'timestring' & gt  'exercise', 'hula'
			end
		end

		if pcs_stam < (15*1 * (10 - sport_clothes_exercise_bonus)) / 2:
			delact 'Jump rope'
			delact 'Do crunches'
			delact 'Do pushups'
		end
	end
end

if $ARGS[0] = 'routines':
	*clr & cla
	'<center><h2>Exercise Routines</h2></center>'
	*nl
	'<center><table>'
	'<TD><b>Routine</b></TD><TD><b>Push ups</b></TD><TD><b>Crunches</b></TD><TD><b>Jump rope</b></TD><TD><b>Yoga</TD><TD><b>Hula hoop</b></TD><TD><b>Squats</b></TD>'
	'<TR><TD width="100" cellspacing="2" align="left">'+iif(exer_menu = 1,'<a href="exec:$excer_name[1] = input (''<center>Enter name for exercise routine 1<br>Leave blank to restore default name.</center>'') & gs ''exercise'', ''rename'' & gt ''exercise'', ''setup''"><<$excer_name[1]>>:</a> ','<<$excer_name[1]>>:</a> ')+'</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout0[1]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout1[1]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout2[1]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout3[1]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout4[1]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout5[1]*15>></b> minutes</TD>'
	'<TR><TD width="100" cellspacing="2" align="left">'+iif(exer_menu = 1,'<a href="exec:$excer_name[2] = input (''<center>Enter name for exercise routine 2<br>Leave blank to restore default name.</center>'') & gs ''exercise'', ''rename'' & gt ''exercise'', ''setup''"><<$excer_name[2]>>:</a> ','<<$excer_name[2]>>:</a> ')+'</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout0[2]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout1[2]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout2[2]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout3[2]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout4[2]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout5[2]*15>></b> minutes</TD>'
	'<TR><TD width="100" cellspacing="2" align="left">'+iif(exer_menu = 1,'<a href="exec:$excer_name[3] = input (''<center>Enter name for exercise routine 3<br>Leave blank to restore default name.</center>'') & gs ''exercise'', ''rename'' & gt ''exercise'', ''setup''"><<$excer_name[3]>>:</a> ','<<$excer_name[3]>>:</a> ')+'</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout0[3]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout1[3]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout2[3]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout3[3]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout4[3]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout5[3]*15>></b> minutes</TD>'
	'<TR><TD width="100" cellspacing="2" align="left">'+iif(exer_menu = 1,'<a href="exec:$excer_name[4] = input (''<center>Enter name for exercise routine 4<br>Leave blank to restore default name.</center>'') & gs ''exercise'', ''rename'' & gt ''exercise'', ''setup''"><<$excer_name[4]>>:</a> ','<<$excer_name[4]>>:</a> ')+'</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout0[4]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout1[4]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout2[4]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout3[4]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout4[4]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout5[4]*15>></b> minutes</TD>'
	'<TR><TD width="100" cellspacing="2" align="left">'+iif(exer_menu = 1,'<a href="exec:$excer_name[5] = input (''<center>Enter name for exercise routine 5<br>Leave blank to restore default name.</center>'') & gs ''exercise'', ''rename'' & gt ''exercise'', ''setup''"><<$excer_name[5]>>:</a> ','<<$excer_name[5]>>:</a> ')+'</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout0[5]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout1[5]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout2[5]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout3[5]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout4[5]*15>></b> minutes</TD><TD width="100" cellspacing="2" align="left"><b><<exer_rout5[5]*15>></b> minutes</TD>'
	'<TR><TD colspan="7"><br><br><center><a href="exec:gt ''exercise'', ''setup''">Define up to 5 automated exercise routines.</a></center></TD></TR>'
	'</table></center>'
	*nl
end

if $ARGS[0] = 'setup':
	$menu_loc = 'exercise'
	$menu_arg = 'setup'
	menu_off = 0
	*clr & cla
	exer_menu = 1
	gs 'exercise', 'routines'
	act 'Return': gt 'exercise', 'workout'
	act 'Define <<$excer_name[1]>>':stamindx = 1 & gt 'exercise', 'matrix'
	act 'Rename <<$excer_name[1]>>':
		$excer_name[1] = input ('<center>Enter name for exercise routine 1<br>Leave blank to restore default name.</center>')
		gs 'exercise', 'rename'
		gt 'exercise', 'setup'
	end
	act 'Define <<$excer_name[2]>>':stamindx = 2 & gt 'exercise', 'matrix'
	act 'Rename <<$excer_name[2]>>':
		$excer_name[2] = input ('<center>Enter name for exercise routine 2<br>Leave blank to restore default name.</center>')
		gs 'exercise', 'rename'
		gt 'exercise', 'setup'
	end
	act 'Define <<$excer_name[3]>>':stamindx = 3 & gt 'exercise', 'matrix'
	act 'Rename <<$excer_name[3]>>':
		$excer_name[3] = input ('<center>Enter name for exercise routine 3<br>Leave blank to restore default name.</center>')
		gs 'exercise', 'rename'
		gt 'exercise', 'setup'
	end
	act 'Define <<$excer_name[4]>>':stamindx = 4 & gt 'exercise', 'matrix'
	act 'Rename <<$excer_name[4]>>':
		$excer_name[4] = input ('<center>Enter name for exercise routine 4<br>Leave blank to restore default name.</center>')
		gs 'exercise', 'rename'
		gt 'exercise', 'setup'
	end
	act 'Define <<$excer_name[5]>>':stamindx = 5 & gt 'exercise', 'matrix'
	act 'Rename <<$excer_name[5]>>':
		$excer_name[5] = input ('<center>Enter name for exercise routine 5<br>Leave blank to restore default name.</center>')
		gs 'exercise', 'rename'
		gt 'exercise', 'setup'
	end
!!exer_rout1 = default
end

if $ARGS[0] = 'rename':
	if $excer_name[1] = '':$excer_name[1] = 'Default 1'
	if $excer_name[2] = '':$excer_name[2] = 'Default 2'
	if $excer_name[3] = '':$excer_name[3] = 'Default 3'
	if $excer_name[4] = '':$excer_name[4] = 'Default 4'
	if $excer_name[5] = '':$excer_name[5] = 'Default 5'
end


if $ARGS[0] = 'matrix':
	*clr & cla
	exer_stam[stamindx] = exer_stam0[stamindx] + exer_stam1[stamindx] + exer_stam2[stamindx] + exer_stam3[stamindx] + exer_stam4[stamindx] + exer_stam5[stamindx]
	
	act'Confirm': gt 'exercise', 'setup'

	'Choose your exercise options from the following table:'
	'<center><table border=0 cellspacing=0 cellpadding=10 width=1000><TH>Exercise</TH><TH>None</TH><TH>15 mins</TH><TH>30 mins</TH><TH>45 mins</TH><TH>60 mins</TH>'
	gs 'exercise', 'matrixdata', 0, 'Push ups'
	gs 'exercise', 'matrixdata', 1, 'Crunches'
	if mc_inventory['skipping_rope'] > 0 and $loc ! 'meadow': gs 'exercise', 'matrixdata', 2, 'Jump rope'
	if mc_inventory['book_yoga'] > 0: gs 'exercise', 'matrixdata', 3, 'Yoga'
	if mc_inventory['hula_hoop'] > 0 and $loc ! 'meadow': gs 'exercise', 'matrixdata', 4, 'Hula hoop'
	gs 'exercise', 'matrixdata', 5, 'Squats'

	'</center></table>'
	*nl
	'Total stamina required - <<exer_stam[stamindx]>>'
end

if $ARGS[0] = 'matrixdata':
	'<TR>'
	*p '<TD><<$ARGS[2]>></TD>'

	if dyneval('RESULT = exer_rout<<ARGS[1]>>[<<stamindx>>]') = 0:
		dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = 0'
		*p '<TD>Selected</TD>'
	else
		*p '<TD><a href="exec:dynamic ''exer_rout<<ARGS[1]>>[stamindx] = 0'' & gt ''exercise'', ''matrix''">Select</a></TD>'
	end

	if dyneval('RESULT = exer_rout<<ARGS[1]>>[<<stamindx>>]') = 1:
		if ARGS[1] >= 3:
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = 5 * (10 - sport_clothes_exercise_bonus)'
		else
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = (15 * (10 - sport_clothes_exercise_bonus)) / 2'
		end
		*p '<TD>Selected</TD>'
	else
		*p '<TD><a href="exec:dynamic ''exer_rout<<ARGS[1]>>[stamindx] = 1'' & gt ''exercise'', ''matrix''">Select</a></TD>'
	end

	if dyneval('RESULT = exer_rout<<ARGS[1]>>[<<stamindx>>]') = 2:
		if ARGS[1] >= 3:
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = 10 * (10 - sport_clothes_exercise_bonus)'
		else
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = (30 * (10 - sport_clothes_exercise_bonus)) / 2'
		end
		*p '<TD>Selected</TD>'
	else
		*p '<TD><a href="exec:dynamic ''exer_rout<<ARGS[1]>>[stamindx] = 2'' & gt ''exercise'', ''matrix''">Select</a></TD>'
	end

	if dyneval('RESULT = exer_rout<<ARGS[1]>>[<<stamindx>>]') = 3:
		if ARGS[1] >= 3:
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = 15 * (10 - sport_clothes_exercise_bonus)'
		else
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = (45 * (10 - sport_clothes_exercise_bonus)) / 2'
		end
		*p '<TD>Selected</TD>'
	else
		*p '<TD><a href="exec:dynamic ''exer_rout<<ARGS[1]>>[stamindx] = 3'' & gt ''exercise'', ''matrix''">Select</a></TD>'
	end

	if dyneval('RESULT = exer_rout<<ARGS[1]>>[<<stamindx>>]') = 4:
		if ARGS[1] >= 3:
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = 20 * (10 - sport_clothes_exercise_bonus)'
		else
			dynamic 'exer_stam<<ARGS[1]>>[<<stamindx>>] = (60 * (10 - sport_clothes_exercise_bonus)) / 2'
		end
		*p '<TD>Selected</TD>'
	else
		*p '<TD><a href="exec:dynamic ''exer_rout<<ARGS[1]>>[stamindx] = 4'' & gt ''exercise'', ''matrix''">Select</a></TD>'
	end

	exer_stam[stamindx] = exer_stam0[stamindx] + exer_stam1[stamindx] + exer_stam2[stamindx] + exer_stam3[stamindx] + exer_stam4[stamindx] + exer_stam5[stamindx]
end

if $ARGS[0] = 'butt':
	cla
	*clr
	gs 'exercise', 'tier2', (15*timemult), 'stren', 'butt_tr'
	timemult = 0

	if $clothingworntype ! 'nude':
		'<center><img <<$set_imgh>> src="images/pc/activities/exercises/butt_home_dressed.jpg"></center>'
	elseif $pantyworntype ! 'none':
		'<center><img <<$set_imgh>> src="images/pc/activities/exercises/butt_home_underwear.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/pc/activities/exercises/butt_home_nude.jpg"></center>'
	end
	'You do squats for <<$timestring>> minutes, strengthening your thighs and scupting your butt.'
	gs 'stat'
	if exer_auto = 1:
		act 'Continue': gt 'exercise', 'auto_end'
	else
		act 'Continue': gt 'exercise', 'manual'
	end
end

if $ARGS[0] = 'hula':
	cla
	*clr
	gs 'exercise', 'tier2', (timemult*15), 'agil', 'react'
	timemult = 0
	if $clothingworntype ! 'nude':
		if $location_type = 'secluded':
			if month >=5 and month <= 9:
				'<center><img <<$set_imgh>> src="images/pc/activities/exercises/hula_outdoor.jpg"></center>'
			else
				'<center><video autoplay loop src="images/pc/activities/exercises/hula_winter.mp4"></video></center>'
			end
		else
			'<center><video autoplay loop src="images/pc/activities/exercises/hula_dressed.mp4"></video></center>'
		end
	elseif $pantyworntype ! 'none':
		'<center><video autoplay loop src="images/pc/activities/exercises/hula_underwear.mp4"></video></center>'
	else
		'<center><video autoplay loop src="images/pc/activities/exercises/hula_nude.mp4"></video></center>'
	end
	'You improve your dexterity by using your hula hoop for <<$timestring>> minutes.'
	gs 'stat'
	if exer_auto = 1:
		act 'Continue': gt 'exercise', 'auto5'
	else
		act 'Continue': gt 'exercise', 'manual'
	end
end

if $ARGS[0] = 'yoga':
	*clr & cla
	gs 'exercise', 'tier2', (timemult*15), 'sprt', 'agil'
	if willday_yoga ! daystart:
		willday_yoga = daystart
		yoga_counter = 4
	end
	:timeloopyoga
	if yoga_counter > 0 and timemult > 0:
		pcs_willpwr += rand(1,2)
		yoga_counter -= 1
		timemult -= 1
		if yoga_counter = 0: will_counter += 1
		jump 'timeloopyoga'
	end
	timemult = 0

	if $clothingworntype ! 'nude':
		if $location_type = 'secluded':
			'<center><img <<$set_imgh>> src="images/pc/activities/exercises/yoga_dressed_outdoor.jpg"></center>'
		else
			'<center><video autoplay loop src="images/pc/activities/exercises/yoga_dressed.mp4"></video></center>'
		end
	elseif $pantyworntype ! 'none':
		'<center><video autoplay loop src="images/pc/activities/exercises/yoga_underwear.mp4"></video></center>'
	else
		'<center><img <<$set_imgh>> src="images/pc/activities/exercises/yoga_nude.jpg"></center>'
	end

	'You spend <<$timestring>> minutes stretching and straining your muscles in various poses, improving your will and flexibility.'
	gs 'stat'
	if exer_auto = 1:
		act 'Continue': gt 'exercise', 'auto4'
	else
		act 'Continue': gt 'exercise', 'manual'
	end
end

if $ARGS[0] = 'rope':
	cla
	*clr
	gs 'exercise', 'tier3', (15*timemult), 'agil', 'react'
	timemult = 0

	if $clothingworntype ! 'nude':
		'<center><video autoplay loop src="images/pc/activities/exercises/rope_dressed.mp4"></video></center>'
	elseif $pantyworntype ! 'none':
		'<center><img <<$set_imgh>> src="images/pc/activities/exercises/rope_underwear.jpg"></center>'
	else
		'<center><video autoplay loop src="images/pc/activities/exercises/rope_nude.mp4"></video></center>'
	end

	'You jump rope for <<$timestring>> minutes, improving your speed.'
	gs 'stat'
	if exer_auto = 1:
		act 'Continue': gt 'exercise', 'auto3'
	else
		act 'Continue': gt 'exercise', 'manual'
	end
end

if $ARGS[0] = 'press':
	cla
	*clr
	gs 'exercise', 'tier3', (15*timemult), 'vital'
	timemult = 0

	if $clothingworntype ! 'nude':
		'<center><video autoplay loop src="images/pc/activities/exercises/abdominal_dressed.mp4"></video></center>'
	elseif $pantyworntype ! 'none':
		'<center><video autoplay loop src="images/pc/activities/exercises/abdominal_underwear.mp4"></video></center>'
	else
		'<center><video autoplay loop src="images/pc/activities/exercises/abdominal_nude.mp4"></video></center>'
	end

	'You do a series of abdominal exercises for <<$timestring>> minutes, improving your endurance.'
	gs 'stat'
	if exer_auto = 1:
		act 'Continue': gt 'exercise', 'auto2'
	else
		act 'Continue': gt 'exercise', 'manual'
	end
end

if $ARGS[0] = 'push':
	cla
	*clr
	gs 'exercise', 'tier3', (15*timemult), 'stren'
	timemult = 0

	if $clothingworntype ! 'nude':
		'<center><video autoplay loop src="images/pc/activities/exercises/push_dressed.mp4"></video></center>'
	elseif $pantyworntype ! 'none':
		'<center><video autoplay loop src="images/pc/activities/exercises/push_underwear.mp4"></video></center>'
	else
		'<center><video autoplay loop src="images/pc/activities/exercises/push_nude.mp4"></video></center>'
	end
	'You do push-ups for <<$timestring>> minutes, improving your strength.'

	randpushfact = rand(-5,5)
	if pcs_energy < 40: randpushfact -= RAND(1,10)

	pushnum = (pcs_stren * pcs_sleep * pcs_health)  / ( 1 * 67 *  healthmax) + randpushfact

	if pushnum < 1: pushnum = rand(1,5)
	KILLVAR 'randpushfact'
	'<br>You managed to do <<pushnum>> push-ups. Your previous record is <<pushrecord>>.'

	if pushrecord < pushnum:pushrecord = pushnum & 'This is a new record!'
	gs 'stat'
	if exer_auto = 1:
		act 'Continue': gt 'exercise', 'auto1'
	else
		act 'Continue': gt 'exercise', 'manual'
	end
end

if $ARGS[0] = 'tier1':
	if ARGS[1] = 0:
		minut += 15
		mult = 1
	else
		minut += ARGS[1]
		mult = (ARGS[1]-1)/15 + 1
	end

	gs 'exercise', 'get_sport_clothes_exercise_bonus'
	pcs_stam -= (5*mult * (10 - sport_clothes_exercise_bonus)) / 2

	gs 'sweat', 'add', (3*mult)
	fat -= (4 + mult/2)
	pcs_energy -= 1*mult
	pcs_hydra -= 2*mult
	pcs_mood += (3 + mult)
	mcnt = 0
	:timeexploop1
	if $ARGS[3] = '':
		gs 'exp_gain', $ARGS[2], 1
		if $ARGS[2] = 'vital' or $ARGS[2] = 'stren':
			gs 'exp_gain', $ARGS[2], rand(0,steroid_dose)
			if steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
		end
	else
		i = 2
		:exploop1
		if $ARGS[i] ! '':
			gs 'exp_gain', $ARGS[i], rand(0,1)
			if $ARGS[i] = 'vital' or $ARGS[i] = 'stren': 
				gs 'exp_gain', $ARGS[i], rand(0,steroid_dose)
				steroidcheck = 1
			end
			i += 1
			jump 'exploop1'
		else
			if steroidcheck = 1 and steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
			killvar 'steroidcheck'
			killvar 'i'
		end
	end
	mcnt += 1
	if mcnt < mult: jump 'timeexploop1'
	killvar 'mcnt'
	killvar 'mult'
end

if $ARGS[0] = 'tier2':
	if ARGS[1] = 0:
		minut += 15
		mult = 1
	else
		minut += ARGS[1]
		mult = (ARGS[1]-1)/15 + 1
	end

	gs 'exercise', 'get_sport_clothes_exercise_bonus'
	pcs_stam -= 5*mult * (10 - sport_clothes_exercise_bonus)

	gs 'sweat', 'add', (10*mult)
	fat -= (3 + mult/2)
	pcs_energy -= 2*mult
	pcs_hydra -= 4*mult
	pcs_mood += (5 + mult)
	mcnt = 0
	:timeexploop2
	if $ARGS[3] = '':
		gs 'exp_gain', $ARGS[2], rand(2,3)
		if $ARGS[2] = 'vital' or $ARGS[2] = 'stren':
			gs 'exp_gain', $ARGS[2], rand(0,steroid_dose)
			if steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
		end
	else
		i = 2
		:exploop2
		if $ARGS[i] ! '':
			gs 'exp_gain', $ARGS[i], rand(1,2)
			if $ARGS[i] = 'vital' or $ARGS[i] = 'stren': 
				gs 'exp_gain', $ARGS[i], rand(0,steroid_dose)
				steroidcheck = 1
			end
			i += 1
			jump 'exploop2'
		else
			if steroidcheck = 1 and steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
			killvar 'steroidcheck'
			killvar 'i'
		end
	end
	mcnt += 1
	if mcnt < mult: jump 'timeexploop2'
	killvar 'mcnt'
	killvar 'mult'
end

if $ARGS[0] = 'tier3':
	if ARGS[1] = 0:
		minut += 15
		mult = 1
	else
		minut += ARGS[1]
		mult = (ARGS[1]-1)/15 + 1
	end

	gs 'exercise', 'get_sport_clothes_exercise_bonus'
	pcs_stam -= (15*mult * (10 - sport_clothes_exercise_bonus)) / 2

	gs 'sweat', 'add', (15*mult)
	fat -= (2 + mult/2)
	pcs_energy -= 3*mult
	pcs_hydra -= 6*mult
	pcs_mood += (5 + mult)
	mcnt = 0
	:timeexploop3
	if $ARGS[3] = '':
		gs 'exp_gain', $ARGS[2], rand(3,5)
		if $ARGS[2] = 'vital' or $ARGS[2] = 'stren':
			gs 'exp_gain', $ARGS[2], rand(0,steroid_dose)
			if steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
		end
	else
		i = 2
		:exploop3
		if $ARGS[i] ! '':
			gs 'exp_gain', $ARGS[i], rand(2,3)
			if $ARGS[i] = 'vital' or $ARGS[i] = 'stren': 
				gs 'exp_gain', $ARGS[i], rand(0,steroid_dose)
				steroidcheck = 1
			end
			i += 1
			jump 'exploop3'
		else
			if steroidcheck = 1 and steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
			killvar 'steroidcheck'
			killvar 'i'
		end
	end
	mcnt += 1
	if mcnt < mult: jump 'timeexploop3'
	killvar 'mcnt'
	killvar 'mult'
end

if $ARGS[0] = 'tier4':
	if ARGS[1] = 0:
		minut += 15
		mult = 1
	else
		minut += ARGS[1]
		mult = (ARGS[1]-1)/15 + 1
	end

	gs 'exercise', 'get_sport_clothes_exercise_bonus'
	pcs_stam -= (25*mult * (10 - sport_clothes_exercise_bonus))/2

	gs 'sweat', 'add', (25*mult)
	fat -= (1 + mult/2)
	pcs_energy -= 4*mult
	pcs_hydra -= 12*mult
	pcs_mood += (5 + mult)
	mcnt = 0
	:timeexploop4
	if $ARGS[3] = '':
		gs 'exp_gain', $ARGS[2], rand(7,10)
		if $ARGS[2] = 'vital' or $ARGS[2] = 'stren':
			gs 'exp_gain', $ARGS[2], rand(0,steroid_dose)
			if steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
		end
	else
		i = 2
		:exploop4
		if $ARGS[i] ! '':
			gs 'exp_gain', $ARGS[i], rand(3,5)
			if $ARGS[i] = 'vital' or $ARGS[i] = 'stren': 
				gs 'exp_gain', $ARGS[i], rand(0,steroid_dose)
				steroidcheck = 1
			end
			i += 1
			jump 'exploop4'
		else
			if steroidcheck = 1 and steroid_dose > 0 and rand(1,5) <= steroid_dose:clit_size += rand(0,1)
			killvar 'steroidcheck'
			killvar 'i'
		end
	end
	mcnt += 1
	if mcnt < mult: jump 'timeexploop4'
	killvar 'mcnt'
	killvar 'mult'
end

if $ARGS[0] = 'timestring':
	if timemult = 1: $timestring = 'fifteen'
	if timemult = 2: $timestring = 'thirty'
	if timemult = 3: $timestring = 'forty-five'
	if timemult = 4: $timestring = 'sixty'
end


if $ARGS[0] = 'get_sport_clothes_exercise_bonus':
	sport_clothes_exercise_bonus = 0
	if $braworntype = 'sport' or $braworntype = 'danilovich':
		sport_clothes_exercise_bonus += 1
	elseif PCloBra = 1 and $clothingworntype = 'danilovich_outfits':
		sport_clothes_exercise_bonus += 1
	end
	if $pantyworntype = 'sport' or $pantyworntype = 'danilovich':
		sport_clothes_exercise_bonus += 1
	elseif PCLoPanties = 1 and $clothingworntype = 'danilovich_outfits':
		sport_clothes_exercise_bonus += 1
	end
	if $clothingworntype = 'danilovich_outfits':
		sport_clothes_exercise_bonus += 1
	end
	if $shoeworntype = 'danilovich':
		sport_clothes_exercise_bonus += 1
	end
end

--- exercise ---------------------------------

