# pav_library

!2021/10/05
!2023/09/11 Loan update by Anjuna

$loc_arg = ''
$loc = 'pav_library'
$location_type = 'public_indoors'
$menu_loc = 'pav_library'
$menu_arg = ''
menu_off = 0
frost = 0
gs 'stat'
gs 'themes', 'indoors'
'<center><b><font color="maroon">Community center library</font></b></center>'
'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/library/gdkbibl.jpg"></center>'
'For such a small town, the library is surprisingly large, containing many interesting books on a wide variety of subjects.'
'Between the bookshelves are some tables which can be used for studying. Some of them have <a href="exec: gs ''internet_mobile'', ''get_access'', ''free'', ''noporn'',''nocamshow'' & gs ''internet_mobile'', ''add_limitation'', ''general-text'', ''On this public computer all adult content sites are blocked'' & gt ''Komp'',''start''">computers</a> for public use.'
if lernHome > 0:
	'You could do your homework with the help of one of the computers.'
end

if mid($start_type,1,2) = 'sg' and kanikuli = 0 and week < 6 and nerdstudynight['day'] ! daystart and hour > 14 and SchoolAtestat = 0:
	'The nerds are sitting at a table studying together.'
end

if mid($start_type,1,2) = 'sg' and kanikuli = 0 and week > 5 and hour >= 12 and hour < 14:
	if nataliaQW['library_day_check'] ! daystart:
		nataliaQW['library_day_check'] = daystart
		if rand(0,3) = 0: nataliaQW['library_day'] = daystart
	end
	if nataliaQW['library_day'] = daystart:
		'You see your classmate <a href="exec: gt ''natalia_pavlova'',''library''">Natalia Pavlova</a> sitting alone at one of the tables.'
	end
end

act 'Leave': gt 'pav_commcenter'
act 'Go to the toilets': gt 'gdktoilet', 'start'
if nerd_game['game_day'] = daystart and hour = 19: act 'Wait for game night to start': minut += 60-minut & gt 'pav_library'
if nerd_game['game_day'] = daystart and hour = 20: act 'Join the nerds': gt 'nerd_game_night', 'game'

killvar '$downlibrary'
$downlibrary['read'] = {
	*clr & cla
	menu_off = 1
	if blizoruk = 500 or glassqw = 1:
		glassqw = 1
		msg '	The text blurs across the page. It seems you have poor eyesight. Maybe you should visit an ophthalmologist?'
		gt 'pav_library'
	end
	if pcs_nerd > 0:
		lastread = totminut
		lastreadday = daystart
		pcs_nerd += 1
	end
	minut += 60
	blizoruk += 1
}

if hour >= 8 and hour < 18:
	act 'Read a book':
		gt 'pav_library', 'read'	
	end
	
	act 'Borrow a book':
		gt 'pav_library', 'loan'
	end

	act 'Study for an hour':
		dynamic $downlibrary['read']
		lern += rand(1,3)
		grupvalue[3] += 2
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/learning' + rand(1,3) + '.jpg"></center>'
		'You read several books that should help you with your school work, you feel that you learned something today.'
		act 'Put the book back': gt 'pav_library'
	end

	gs 'willpower', 'chore', 'self', iif(grupTipe = 4 and pcs_traits['nerd_status'] = 0, 'hard', iif(pcs_traits['nerd_status'] > 0, 'easy', 'medium'))
	if pcs_traits['nerd_status'] = 2: will_cost = will_cost / 2
	if lernHome > 0 and (will_cost <= pcs_willpwr or pcs_traits['nerd_status'] = 3):
		act 'Do your homework (1:00'+iif(pcs_traits['nerd_status'] = 3, '', ' and <<will_cost>> Willpower')+')':
			cla & *clr
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/library/homework.jpg"></center>'
			minut += 60
			pcs_mood += 5 * pcs_traits['nerd_status']
			lern += 1
			gs 'willpower', 'chore', 'self', iif(grupTipe = 4, 'hard', iif(pcs_traits['nerd_status'] > 0, 'easy', 'medium'))
			if pcs_traits['nerd_status'] = 2: will_cost = will_cost / 2
			if pcs_traits['nerd_status'] < 3: gs 'willpower', 'pay', 'self'
			gs 'stat'
			gs 'grades', 'homework', 'school', 'yes', 1, 0, 0
			'You sit down at one of the tables with a computer and use it to help you do your homework.'
			'After an hour, you''ve '+iif(lernHome = 0, 'completed', 'done a part of')+' your homework.'
			act 'Get up from the table': gt 'pav_library'
		end
	elseif lernHome > 0 and will_cost > pcs_willpwr:
		act 'Do your homework (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end
	
	if mid($start_type,1,2) = 'sg' and kanikuli = 0 and week < 6 and nerdstudynight['day'] ! daystart and hour > 14 and SchoolAtestat = 0 and SchoolBlock = 0 _
	and (class['school_grades_above_40'] + class['school_grades_above_70'] + class['school_grades_above_90'] <= 20 or grupTipe = 3):
		act 'Join the nerd''s study group': gt 'pav_library_nerdstudy', 'nerd_study_night'
	end
else
	'The library is closed.'
end

if $ARGS[0] = 'read':
	cla
	if hour < 18:
		act 'Go back': gt 'pav_library'

		act 'Read a book on science (1:00)':
			dynamic $downlibrary['read']
			gs 'exp_gain', 'intel', rand(3,6) + (mentats_dose - rand(0,mentats_dose))
			grupvalue[3] +=1
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/science1.jpg"></center>'
			'You spend an hour reading, trying to make sense of all the clever propositions written inside and understand the subject it describes.'
			act 'Put the book back': gt 'pav_library', 'read'
		end

		act 'Read an adventure novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			grupvalue[3] +=1
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/fiction' + rand(1,2) + '.jpg"></center>'
			'You spend an hour reading an adventure novel, immersing yourself in daring deeds and awesome twists.'
			act 'Put the book back': gt 'pav_library', 'read'
		end

		act 'Read a fantasy novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			grupvalue[3] += 1
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/fantasy' + rand(1,9) + '.jpg"></center>'
			'You spend an hour reading a fantasy novel, rescuing damsels from dragons, digging for jewels with dwarves and performing word changing magic alongside elves and druids.'
			act 'Put the book back': gt 'pav_library', 'read'
		end

		act 'Read a science fiction novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			grupvalue[3] += 1
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/scifi' + rand(1,6) + '.jpg"></center>'
			'You spend an hour reading a science fiction novel - flying off into space, travelling though time, running from rogue AI and creating monsters with your hunchbacked assistant.'
			act 'Put the book back': gt 'pav_library', 'read'
		end

		act 'Read a romance novel (1:00)':
			dynamic $downlibrary['read']
			pcs_mood = 100
			pcs_horny += 20
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/romance' + rand(1,20) + '.jpg"></center>'
			'You spend a very short hour reading a romance novel - choosing between a vampire or a werewolf, falling in love with an obscenely wealthy Grey... Several of the scenes are very steamy and you find yourself getting quite aroused.'
			act 'Put the book back': gt 'pav_library', 'read'
		end
		
		temp = pcs_intel * 2 + pcs_sprt
		if temp < 100:
			$diff = 'hard'
		elseif temp < 150:
			$diff = 'medium'
		else
			$diff = 'easy'
		end
		gs 'willpower', 'misc', 'self', $diff
		if will_cost <= pcs_willpwr:
			act 'Read from the collected works of Leo Tolstoy (1:00) (<<will_cost>> Willpower)':
				gs 'willpower', 'pay', 'self'
				killvar 'will_cost'

				dynamic $downlibrary['read']
				gs 'exp_gain', 'sprt', rand(3,6)
				grupvalue[3] += 2
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/tolstoy.jpg"></center>'
				'You read the book for an hour. Tolstoy is certainly a classic writer, but he used a <i>lot</i> of words.'
				act 'Put the book back': gt 'pav_library', 'read'
			end
		else
			act 'Read from the collected works of Leo Tolstoy (1:00) (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	else
		!! Note find stern librarian image
		'The librarian finds you still reading and shooshes you out of the library'
		act 'Leave': gt 'pav_commcenter'
	end
end

if $ARGS[0] = 'loan':
	cla
	if $lib_book_loaned ! '':
		'You''ve currently borrowed a <<$lib_book_loaned>>.'
		if lib_debt <= 0:
			temp_loan_days_left = lib_debt / -50
			'You have <<temp_loan_days_left>> days left before you need to return it.'
		else
			'<font color="red">Your book is overdue!</font>'
		end

		act 'Return your loaned book':
			if lib_book_read = 0:
				if $lib_book_loaned = 'fantasy': f_book -= 1
			elseif lib_book_read = 1:
				if $lib_book_loaned = 'fantasy': fantasybook = 0
			end
			$lib_book_loaned = ''
			if lib_debt <= 0: lib_debt = 0
			lib_book_read = 0
			gt 'pav_library'
		end
	end

	if lib_debt > 0:
		'You owe an outstanding debt of <<lib_debt>> <b>₽</b> to the library.'
		if money < lib_debt and karta < lib_debt:
			'You don''t have enough money to pay your debt!'
		else
			if money >= lib_debt:
				act 'Pay your debt (cash)':
					money -= lib_debt
					lib_debt = 0
					gt 'pav_library', 'loan'
				end
			end
			if karta >= lib_debt:
				act 'Pay your debt (card)':
					karta -= lib_debt
					lib_debt = 0
					gt 'pav_library', 'loan'
				end
			end
		end
	end

	if $lib_book_loaned = '' and lib_debt = 0:
		!!There''s currently only code for fantasy novels
		!{act 'Borrow a science book':
			*clr & cla
			menu_off = 1
			s_book += 1
			$lib_book_loaned = 'a science book'
			lib_debt = -700
			!!Picture here
			'You find a science book that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."' 
			act 'Continue': gt 'pav_library'
		end
		
		act 'Borrow an adventure novel':
			*clr & cla
			menu_off = 1
			a_book += 1
			$lib_book_loaned = 'an adventure novel'
			lib_debt = -700
			!!Picture here
			'You find an adventure novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'pav_library'
		end}
		
		act 'Borrow a fantasy novel':
			*clr & cla
			menu_off = 1
			f_book += 1
			$lib_book_loaned = 'a fantasy novel'
			lib_debt = -700
			!!Picture here
			'You find a fantasy novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'pav_library'
		end
		
		!{act 'Borrow a science fiction novel':
			*clr & cla
			menu_off = 1
			sf_book += 1
			$lib_book_loaned = 'a science fiction novel'
			lib_debt = -700
			!!Picture here
			'You find a science fiction novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'pav_library'
		end
		
		act 'Borrow a romance novel':
			*clr & cla
			menu_off = 1
			r_book += 1
			$lib_book_loaned = 'a romance novel'
			lib_debt = -700
			!!Picture here
			'You find a romance novel that catches your interest and bring it to the librarian, who notes your name and the title of the book down before handing it to you.'
			'"You need to return it within 2 weeks. Every day that you''re late incurs a 50 <b>₽</b> fine."'
			act 'Continue': gt 'pav_library'
		end}
	end

	act 'Go back': gt 'pav_library'
end

--- pav_library ---------------------------------

