# city_train

if $ARGS[0] = 'start':
	$loc_arg = 'start'
	$loc = 'city_train'
	$location_type = 'public_outdoors'
	$menu_loc = 'city_train'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla
	gs'stat'
	'<center><B>City center railway station</B></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/shared/trainstation/central_station_inside.jpg"></center>'
	'The grand old station in the city center is an impressive building. It is busy and has a number of shops and bars as well as all the platforms and trains. '
	*nl
	if car > 0 and cardrive = 2:
		'In the parking lot is <a href="exec:GS ''carF'',''start''">your <<$car>></a>.'
	end

	act 'Walk to the city center (0:05)':minut += 5 & gt 'city_center'
	if transportVars['trainpass_day'] > daystart:
		func('transport_functions', 'display_trainpass_time')
		act 'Go to the platforms': gt 'city_train', 'platform'
	else
		act 'Go to the ticket office': gt 'city_train', 'tickets'
	end
end

if $ARGS[0] = 'tickets':
	$menu_loc = 'city_train'
	$menu_arg = 'tickets'
	menu_off = 0
	*clr & cla
	gs 'stat'
	'<center><h4>Ticket office</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/kassa.jpg" ></center>'

	*nl
	gs 'transport_functions', 'set_train_wait_time', 'center'
	'The next train in the direction of Pavlovsk ' + iif(transportVars['train_wait_pavlovsk'] = 0, 'is leaving now!', 'leaves in <<transportVars[''train_wait_pavlovsk'']>> minutes.')

	act 'Leave the ticket office': minut += 1 & gt 'city_train', 'start'
	
	act 'Look at the train schedule':
		*clr & cla
		gs 'transport_functions', 'display_train_schedule'
		act 'Stop looking at the schedule': gt 'city_train', 'tickets'
	end

	act 'Buy a ticket':
		cla
		gs 'city_train', 'buy_ticket'
	end

	gs 'transport_functions', 'buy_train_pass'
end

if $ARGS[0] = 'buy_ticket':
	$menu_loc = 'city_train'
	$menu_arg = 'buy_ticket'
	menu_off = 0

	act 'Leave the ticket office': minut += 1 & gt 'city_train', 'start'

	gs 'transport_functions', 'buy_train_ticket', 'center'
end

if $ARGS[0] = 'platform':
	$location_type = 'public_outdoors'
	$menu_loc = 'city_train'
	$menu_arg = 'platform'
	menu_off = 0
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/indusplat.jpg" ></center>'
	'When you arrive at the platform, you can''t help but notice it bustling with activity. Lots of passengers are coming and going, all carrying shopping bags. It feels like it is always busy here, no matter at what time of the day it is.'
	*nl
	gs 'transport_functions', 'set_train_wait_time', 'center'
	'The next train in the direction of Pavlovsk ' + iif(transportVars['train_wait_pavlovsk'] = 0, 'is leaving now!', 'leaves in <<transportVars[''train_wait_pavlovsk'']>> minutes.')
	
	act 'Return to the station hall': gt 'city_train', 'start'

	act 'Look at the train schedule':
		*clr & cla
		gs 'transport_functions', 'display_train_schedule'
		act 'Stop looking at the schedule': gt 'city_train', 'platform'
	end

	act 'Take a train to the city industrial area (<<func(''transport_functions'', ''display_train_timecost'', ''center'', ''ind'')>>)': gt 'train', 'center_ind'
	act 'Take a train to the old platform by the communal village (<<func(''transport_functions'', ''display_train_timecost'', ''center'', ''communal'')>>)': gt 'train', 'center_communal'
	act 'Take a train to the village of Gadukino (<<func(''transport_functions'', ''display_train_timecost'', ''center'', ''gadukino'')>>)': gt 'train', 'center_gadukino'
	act 'Take a train to Pavlovsk (<<func(''transport_functions'', ''display_train_timecost'', ''center'', ''pavlovsk'')>>)': gt 'train', 'center_pavlovsk'
end

--- city_train ---------------------------------

