# pav_complexb2
!2021/05/02
!SETTINGS:
CLOSE ALL
gs 'themes', 'indoors'
$loc_arg = ''
$loc = 'pav_complexb2'
!elevator does not work
if liftnotwork_day ! daystart: liftnotwork_count = 1
!Apartment Uncle Misha
if mishahouse_day ! daystart: mishahouse_count = 1
!how much money for sex give boys
rnd_money_sex = rand(50,350)



!================================================================================================!
!FLOORS: ---------------------------Entrance to the town-------------------------------------- FLOORS:!
!================================================================================================!
!housemates
if $ARGS[0] = 'housemates':
	menu_off = 1
	*clr & cla
	minut +=1
	gs 'stat'
	 '<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/housemates.jpg"></center>'
	'Floor 1 - Apartment number'
	'Floor 2 - Apartment number'
	'Floor 3 - Apartment number'
	'Floor 4 - Apartment number 17: Anushka Konstantinov'
	'Floor 5 - Apartment number'

	act 'Leave': gt 'pav_complexb2', 'etaj_1'
end

!!locked in Pavlovsk, floor 1
if $ARGS[0] = 'etaj_1':
	$menu_loc = 'pav_complexb2'
	$menu_arg = 'etaj_1'
	menu_off = 0
	CLOSE ALL
	if sound = 0:PLAY 'sound/podezd.mp3',30
	gs 'stat'
	'<center><b><font color = maroon>Ground floor of the apartment building</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/podezd2.jpg"></center>'
	'<center>A dirty and poorly maintained stairwell, the same as any other in your town.</center>'

	'There''s a <a href="exec: gt ''pav_complexb2'', ''housemates''">list</a> of the people who live here on the wall.'
	'Someone put up some <a href="exec:gt ''pav_complexb2'',''pod_objava''">advertisements</a> on the wall near the entrance.'
	act 'Leave the building': minut += 1 & gt 'pav_complex', 'start'
	act 'Go up to the second floor': minut +=1 & gt 'pav_complexb2','etaj_2'
	act 'Take the elevator': gt 'pav_complexb2','lift','etaj_1'

end

!floor 2
if $ARGS[0] = 'etaj_2':
	$menu_loc = 'pav_complexb2'
	$menu_arg = 'etaj_2'
	menu_off = 0
	gs 'stat'
	'<center>2nd floor of the apartment building</center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/etaj2.jpg"></center>'
	'<center>The second floor stairwell is clean and well maintained. It was renovated not long ago, and the inhabitants do their best to keep it clean.</center>'
	act 'Go down to the first floor': minut +=1 & gt 'pav_complexb2','etaj_1'
	act 'Go up to the third floor': minut +=1 & gt 'pav_complexb2','etaj_3'
	act 'Take the elevator': gt 'pav_complexb2','lift','etaj_2'
end

!floor 3
if $ARGS[0] = 'etaj_3':
	$menu_loc = 'pav_complexb2'
	$menu_arg = 'etaj_3'
	menu_off = 0
	gs 'stat'
	'<center>3rd floor of the apartment building</center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/etaj3.jpg"></center>'
	'<center>The third floor stairwell is clean and well maintained. It was renovated not long ago, and the inhabitants do their best to keep it clean.</center>'
	act 'Go down to the second floor': minut +=1 & gt 'pav_complexb2','etaj_2'
	act 'Go up to the fourth floor': minut +=1 & gt 'pav_complexb2','etaj_4'
	act 'Take the elevator': gt 'pav_complexb2','lift','etaj_3'
end

!floor 4
if $ARGS[0] = 'etaj_4':
	$menu_loc = 'pav_complexb2'
	$menu_arg = 'etaj_4'
	menu_off = 0
	gs 'stat'
	'<center>4th floor of the apartment building</center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/etaj4.jpg"></center>'
	'<center>The fourth floor stairwell was renovated not long ago, but some hoodlums have already sprayed graffiti on the walls.</center>'
	act 'Go down to the third floor': minut +=1 & gt 'pav_complexb2','etaj_3'
	act 'Go up to the fifth floor': minut +=1 & gt 'pav_complexb2','etaj_5'
	if anushkaQW['first_visit'] ! 0:
		act 'Apartment 17: Anushka Konstantinov': gt 'anushapt', 'home'
	end
	act 'Take the elevator': gt 'pav_complexb2','lift','etaj_4'
end

!floor 5
if $ARGS[0] = 'etaj_5':
	$menu_loc = 'pav_complexb2'
	$menu_arg = 'etaj_5'
	menu_off = 0
	gs 'stat'
	'<center>Floor #5</center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/etaj5.jpg"></center>'
	'<center>The fifth floor stairwell looks like most of the other floors, but it has a final set of stairs at the other end of the hall that go up to the roof.</center>'
	act 'Go down to the fourth floor': minut +=1 & gt 'pav_complexb2','etaj_4'
	act 'Go up to the roof': minut +=1 & gt 'pav_complexb2', 'roof'
	act 'Take the elevator': gt 'pav_complexb2','lift','etaj_5'
end

!!roof
if $ARGS[0] = 'roof':
	$menu_loc = 'pav_complexb2'
	$menu_arg = 'roof'
	killvar '$locclass'
	menu_off = 0
	minut +=1
	gs 'stat'
	'<center>Roof</center>'
	if month >= 11 or month <= 3:
		!!if hour >= 8 and hour <= 21:
			!!'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/roof/roofw.jpg"></center>'
		!!else
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/roof/roofw.jpg"></center>'
		!!end
	else
		if hour >= 8 and hour <= 21:
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/roof/roof.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/roof/roofn.jpg"></center>'
		end
	end
	'<center>The roof is fairly flat, with the roof access door in a raised part in the middle of the roof. Along one of the walls is another door to some type of storage or maintenances access. There is several ventilation stacks on the roof as well.</center>'

	act 'Go down to the fifth floor':
		if PCloswimwear = 1 or $clothingworntype = 'nude':
			msg '<center><font color = red>You need to get dressed first</font></center>'
			gt 'pav_complexb2','roof'
		else
			minut += 1
			gt 'pav_complexb2','etaj_5'
		end
	end
	if PCloswimwear = 1 or $clothingworntype = 'nude':
		act 'Change back into your clothes':
			minut += 5
			gs 'clothing', 'wear', $lastwornclothingtype['swim'], lastwornclothingnumber['swim']
			gs 'panties', 'wear', $lastwornpantytype['swim'], lastwornpantynumber['swim']
			gs 'bras', 'wear', $lastwornbratype['swim'], lastwornbranumber['swim']
			gt 'pav_complexb2','roof'
		end
	end
	if temper >= 15 and hour >= 8 and hour <= 20:
		if func('changingroom','count_swim_item') > 0 and PCloswimwear = 0:
			act 'Change into a bikini':gt 'changingroom', 'view_swim_list'
		end
		if PCloswimwear = 1:
			act 'Sunbathe (1:00)':
				cla
				*clr
				minut += 60
				inhib_exp += rand(1,3)
				if pcs_sweat < 35: gs 'sweat', 'add', 5
				menu_off = 1
				pcs_mood += 5
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/zagar1.jpg"></center>'

				if mc_inventory['suncream'] =  0:
					pcs_tan += 1
					'You lie down to sunbathe.'
				elseif  mc_inventory['suncream'] > 0:
					mc_inventory['suncream'] -=  1
					pcs_tan += 3
					'You put the sunblock on your body and lie down on the roof to sunbathe.'
				end

				act 'Get Up':gt 'pav_complexb2', 'roof'
			end
		end
	end
end

!================================================================================================!
!ELEVATOR: ------------------------------------------------------------------------------------ ELEVATOR:!
!================================================================================================!
!the lift
if $ARGS[0] = 'lift':
	menu_off = 1
	*clr & cla
	minut +=1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/elevator.jpg"></center>'
	'<center>The elevator in the apartment building is quite old. The building supervisor does his best to keep it running, but it breaks down a lot. Someone put up a <a href="exec:gt ''pav_complexb2'',''elev_objava'',$ARGS[1]">notification</a> in the elevator.</center>'
	act 'Push button: Floor 1': gt 'pav_complexb2','etaj_1'
	act 'Push button: Floor 2': gt 'pav_complexb2','etaj_2'
	act 'Push button: Floor 3': gt 'pav_complexb2','etaj_3'
	act 'Push button: Floor 4': gt 'pav_complexb2','etaj_4'
	act 'Push button: Floor 5': gt 'pav_complexb2','etaj_5'
	pod_lift_ev = RAND(0,100)
	if pod_lift_ev <=5:
		*clr & cla
		minut +=1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/event/elevator'+rand(1,2)+'.jpg"></center>'
		'When the elevator door opens, you are surprised to see a naked woman standing in it. She looks at you in panic and is frantically pressing all the elevator buttons. You''re too baffled to do anything until it''s too late. The door has already closed, and the elevator is moving away from you.'
		act 'Leave': gt 'pav_complexb2',$ARGS[1]
	elseif pod_lift_ev <=10 or liftnotwork_count <=0:
		*clr & cla
		minut +=1
		liftnotwork_day = daystart
		liftnotwork_count -= 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/liftnotwork.jpg"></center>'
		'The building supervisor has put a sign on the elevator: "Dear tenants, the elevator is out of order for today. Don''t worry, I should have it working again by tomorrow!"'
		act 'Leave': gt 'pav_complexb2',$ARGS[1]
	end
	killvar 'pod_lift_ev'
end

!elevator ads
if $ARGS[0] = 'elev_objava':
		*clr & cla
		minut +=1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/elevator_ob'+rand(1,2)+'.jpg"></center>'
	act 'Continue': gt 'pav_complexb2','lift',$ARGS[1]
end

!locked ads
if $ARGS[0] = 'pod_objava':
		*clr & cla
		minut +=1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/pod_ob'+rand(1,2)+'.jpg"></center>'
	act 'Continue': gt 'pav_complexb2','etaj_1'
end

!!new scene for going to this complex if Sveta has a friendship of 50 > and has not been to Anushka''s apartment. Once she has been once this doesn''t show up again. This is a temporary way to start Anushka''s story with out having to go to detention first.
if $ARGS[0] = 'anushkaFirst':
	menu_off = 1
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big144.jpg"></center>'
	'As you walk into the building, you nearly run into Anushka. "Hey <<$pcs_nickname>>, what''s up?"'
	'You''re a little surprised to see her, but not disappointed. "Bored and just killing time, you know?"'
	'She nods and finishes checking the mail. "Yeah, I know the feeling. Want to come up to my place and hang out?"'
	act 'I can''t': minut += 1 & gt 'pav_complex', 'start'
	act 'Sure': minut += 2 & gt 'anushapt', 'firstvisit'
end


--- pav_complexb2 ---------------------------------

