# portmirror
$portmirror = {
	cla
	*clr
	'<center><img src="<<FUNC(''$face_image'')>>"></center>'
	'<<$hair>> <<$mop>> <<$skin>> <<$vnesh>>'
	if daystart < 10 and StoryLine = 0:'In the mirror, you looked quite strange woman''s face which is exactly copied all your actions. You hardly get to accept the idea that it is now is you.'
	if daystart >= 10 and daystart < 30 and StoryLine = 0:'From the mirror looks at you a woman''s face, to which you have become accustomed to, but sometimes, no, no and yes flash the idea that it is not your face.'
	if kosmetica > 0:'Cosmetics <<kosmetica>>'
	if kosmetica = 0:'You have no makeup.'

	if lipbalm > 0:'Lip Balm <<lipbalm>>'
	if lipbalm = 0:'You have no lip balm left.'

	if hapri = 0 and AutoHapri = 1:
		minut += 3
		hapri = 1
		'You brush your hair'
	end

	if mop = 1 and kosmetica > 0 and AutoMakeup = 1:
		mop = AutoMakeupType
		if kosmetica < 3 and mop = 4:mop = 3
		if kosmetica < 2 and mop = 3:mop = 2
		if kosmetica < 1 and mop ! 1:
			mop = 1
			'You have no make-up left'
		else
			if mop = 2:
				'Applied light make-up'
				minut -= 3
				kosmetica -= 1
			end

			if mop = 3:
				'Applied natural make-up'
				minut -= 5
				kosmetica -= 2
			end

			if mop = 4:
				'Applied heavy make-up'
				minut -= 10
				vidageday -= 1
				kosmetica -= 3
			end
		end
	end

	if lipbalm > 0 and lipbalmstat <= 0 and AutoLipBalm = 1:
		minut -= 10
		lipbalm -= 1
		lipkoef += rand(5, 15)
		if lipkoef > 50:
			lipkoef = 0
			lip += 1
		end

		lipbalmstat += 8
		'You smeared lip moisturizing balm'
	end

	if hapri = 0:
		act 'Brush your hair':
			cla
			minut += 3
			hapri = 1
			act 'View results':dynamic $portmirror
		end
	end

	if mop = 1 and kosmetica > 0:
		act 'Apply makeup':
			cla
			*clr
			'<center><img src="images/etogame/mop.jpg"></center>'
			act 'Light make-up':
				cla
				minut += 3
				kosmetica -= 1
				mop = 2
				recmop = mop
				'You legonechko summed eyes and lips a little tint.'
				act 'View results':dynamic $portmirror
			end

			if kosmetica >= 2:
				act 'Natural makeup':
					cla
					minut += 5
					kosmetica -= 2
					mop = 3
					recmop = mop
					'You lipstick, summed up his eyes and eyelids.'
					act 'View results':dynamic $portmirror
				end
			end

			if kosmetica >= 3:
				act 'Heavy makeup':
					cla
					minut += 10
					kosmetica -= 3
					vidageday -= 1
					mop = 4
					recmop = mop
					'You densely nakrasili eyes, eyelids and mascara, lip contour nakrasili pencil and lipstick.'
					act 'View results':dynamic $portmirror
				end
			end
		end
	end

	if lipbalm > 0 and lipbalmstat <= 0:
		act 'Smear lip balm moisturizing':
			cla
			minut += 10
			lipbalm -= 1
			lipkoef += rand(5, 15)
			if lipkoef > 50:
				lipkoef = 0
				lip += 1
			end

			lipbalmstat += 8
			'You smeared lip moisturizing balm.'
			act 'View results':dynamic $portmirror
		end
	end

	act 'Move away from the mirror':
		cla
		if $gt2 = '':
			if $gt1 = 'stwork':dynamic $striptoilet
			if $gt1 = 'kafedinamic':dynamic $kafetualet
			if $gt1 = 'vokzalGin':
				if vokzalToilet = 1:dynamic $din_vokzalg_toilet_f
				if vokzalToilet = 2:dynamic $din_vokzalg_toilet_m
			end
			if $gt1 ! 'stwork' and $gt1 ! 'kafedinamic' and $gt1 ! 'vokzalGin':gt '<<$gt1>>'
		else
			gt '<<$gt1>>', '<<$gt2>>'
		end
	end
}
--- portmirror ---------------------------------