# andreihunter
!2020/10/16
menu_off = 1
gs 'boystat', 'A172'
harakBoy = 2
boyage = npc_dob[$boy]
boyage = (boyage - boyage mod 10000) / 10000
boyage = year - boyage

if huntersAndreiLove > 0 and huntersAndreiQw < 10:
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/brosil.jpg"></center>'
	*nl
	'You want to talk to Andrei, but he cuts in before you can say anything.'
	'"<<$pcs_nickname>>, It''s over between us," he says firmly and walks away.'
	'"Well, maybe it''s for the best," you think as you leave in the other direction.'
	minut += 3
	huntersAndreiLove = 0
	huntersAndreiQw -= 10
	gs 'stat'

	act 'Leave': gt $loc, $loc_arg
else
	if huntersAndreiLove > 0 and pcs_horny <= 60 and huntersAndreiQw >= 10 and huntersAndreisex = 0 and rand(0,2) = 1 :
		*clr & cla
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.4.jpg"></center>'
		*nl 'As soon as you walk up to Andrei, he pulls you in for a kiss without saying a word. You have no time to get a word in as he pulls you towards him.'
		gs 'arousal', 'kiss', 5
		gs 'stat'

		act 'Go with Andrei':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterhands.jpg"></center>'
			*nl 'You go with Andrei with your hand in his. You know how this ends, and you really don''t mind.'
			huntersAndreisex += rand(6,24)
			huntersAndreiQw += 1
			gs 'arousal', 'foreplay', 5
			gs 'stat'

			act 'Further':gt 'hunterLoveSex','Andrei'
		end
		act 'Refuse':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/pc/reactions/speak_to_the_hand.jpg"></center>'
			*nl '"No, Andrei not now." You quickly leave back the way you came.'
			minut += 5
			huntersAndreiQw -= 1
			huntersAndreisex += 1
			gs 'stat'

			act 'Leave':gt $loc, $loc_arg
		end

	else
		'<center><b><font color = maroon>Andrei</font></b></center>'
		'<center><img <<$set_imgh>> src="images/characters/shared/photos/big172.jpg"></center>'
		*nl
		'Andrei is the leader of the group of hunters that frequent the woods and swamp by Gadukino while living close by. He''s <<boyage>> years old and divorced.'
		if huntersAndreiQw < 0:
			'You and him have a bad relationship, because you offended him in the past.'
		elseif huntersAndreiQw < 10:
			'You have a normal relationship with him.'
		elseif huntersAndreiQw < 15:
			'You have friendly relations with him.'
		elseif huntersAndreiQw < 25:
			'You''re good friends.'
		else
			if huntersAndreiLove = 1:'You love each other.' else 'You love him.'
		end
		gs 'stat'

		act 'Chat (0:30)':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/talk1.'+rand(1,3)+'.jpg"></center>'
			*nl
			if huntersAndreiQw >= 0: *nl 'You chat with Andrei. You learn interesting tidbits about hunting from him.' else *nl 'You talk to Andrei. He makes it clear he''d rather not talk to you, but takes part in the conversation anyway.'
			minut += 30
			if huntersAndreiQw < 10 : huntersAndreiQw += 1
			gs 'stat'

			act'Continue':gt $loc, $loc_arg
		end

		if huntersAndreiQw >= 10:
			if huntersAndreiLove = 0:
				act 'Flirt':
					*clr & cla
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt1.'+rand(1,3)+'.jpg"></center>'
					*nl 'You flirt with Andrei. He doesn''t say so aloud, but he likes the attention. You notice him checking you out when he thinks you aren''t looking.'
					if huntersAndreiQw <= 35 and huntersKnowSlut = 0:huntersAndreiQw += 1
					if huntersIgorQw >= 10 and huntersKnowSlut = 0:huntersIgorQw -= 1
					if huntersSergeiQw >= 10 and huntersKnowSlut = 0:huntersSergeiQw -= 1
					minut += 5
					!!not using arousal as no orgasm chance
					pcs_horny += 10
					gs 'stat'

					if huntersAndreiQw >= 25 and huntersKnowSlut = 0 and pcs_apprnc >= 60:
						act 'Continue Flirt':
							*clr & cla
							'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss1.jpg"></center>'
							*nl 'You smile sweetly at Andrei while you flirt, and you are caught off guard when he suddenly goes in for a kiss.'
							gs 'arousal', 'foreplay', 5
							gs 'stat'

							act 'Answer kiss':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss2.jpg"></center>'
								*nl 'Your lips touch... your heart skips a beat. Andrei takes control and continues aggressively, so you find yourself responding to his whims.'
								huntersAndreiLove = 1
								huntersAndreiQw += 1
								pcs_mood = 100
								gs 'arousal', 'kiss', 5
								gs 'stat'
								if pcs_horny >= 40:

									act'Continue':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss3.jpg"></center>'
										*nl '"<<$pcs_nickname>>, I want you", Andrei whispers when your lips finally part. You nod eagerly then Andrei gently takes you by the hand and leads you to his bed.'
										minut += 5
										gs 'stat'

										act 'Go':gt 'hunterLoveSex','Andrei'
									end
								else
									act'Further':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss3.jpg"></center>'
										*nl '"Maybe next time we won''t stop there, <<$pcs_nickname>>", Andrei says when your lips finally part. "For now though, let''s go back."'
										minut += 5
										gs 'stat'

										act'Continue':gt $loc, $loc_arg
									end
								end if
							end
							act 'Push away':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/pc/reactions/speak_to_the_hand.jpg"></center>'
								*nl '"Sorry... Andrei... I can''t right now", you tell him. He leaves with an angry look on his face.'
								minut += 5
								hunterslut += 1
								huntersAndreiQw -= 50
								gs 'stat'

								act'Leave':gt $loc, $loc_arg
							end
						end
					end if
					act'Leave':gt $loc, $loc_arg
				end
			else
				act 'Spend time together':
					*clr & cla
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.'+rand(1,4)+'.jpg"></center>'
					*nl 'You spend time together with Andrei. He can''t keep his hands and lips off of you as you lie there together. He is happy with your company. You can see a look of satisfaction on his face and feel wonderful knowing you''re the one who put it there'
					minut += 60
					!!not using arousal as no orgasm chance
					pcs_horny += 10
					huntersAndreiQw += 1
					if huntersIgorLove > 0 or huntersSergeiLove > 0:hunterslut += 1
					if huntersIgorLove = 0 and huntersSergeiLove = 0:hunterslut -= 1
					pcs_mood = 100
					gs 'stat'

					act'Leave':gt $loc, $loc_arg
				end
				if pcs_horny >= 60:
					act 'Have sex':
						*clr & cla
						'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt2.'+rand(1,6)+'.jpg"></center>'
						*nl 'You catch Andrei''s eyes with yours and give him a look that leaves no doubt what you want. He nods then places an arm around your shoulders to lead you inside.'
						huntersAndreiQw += 1
						huntersAndreisex += rand(6,24)
						gs 'arousal', 'foreplay', 10
						gs 'stat'

						act 'Go':gt 'hunterLoveSex','Andrei'
					end
				end if
				if rand(0,9) = 0:
					act 'Break up with Andrei':
						*clr & cla
						'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/brosila.jpg"></center>'
						*nl '"Andrei, I feel that our relationship has no future. I''m breaking up with you", you say. You leave while trying not to look back at him.'
						minut += 5
						huntersAndreiLove = 0
						huntersAndreiQw -= 100
						gs 'stat'

						act 'Leave':gt $loc, $loc_arg
					end
				end if
			end if
		end if
		act'Leave':gt $loc, $loc_arg
	end if
end if

--- andreihunter ---------------------------------
