glife/locations/VolleyTrenerSpeak.qsrc

# VolleyTrenerSpeak
!{ Change log
March 25, 2016
fixed goto reference
}
minut += 15
CLOSE ALL
gs 'stat'

!At disco
if volleysostav > 0:
	if trenerSex ! 0:
	   gt 'Voltrenersex', 'discoSex'
	else
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/teacher/mikhail/volleytrener2.jpg"></center>'
		'You go up to Mikhail Nikolaevich, and politely say hello.'
		'"<<$pcs_lastname>>, I was told you were here, are you really that stupid? There''s a game tomorrow!"'
		'"I... err... was... erm... dropping off a book for a friend," you mumble.'
		if alko > 1:
			'"You''ve been drinking! If you can''t even take the team seriously, then you''re not playing tomorrow."'
			npc_rel['A69'] -= 1
! The flag is for no admission to the game on Saturday
			seealko = 1 
		end
		'"Come on I''d better take you home," The coach says. Looks like you are done with the dance for tonight.'

		act 'Go with the coach':
			Discoclose = 1 &!closing disco on this day not to forget stat
			music_loop = 0
			close all
			minut += 20
			gs 'stat'
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/gorodok.jpg"></center>'
			'You walk through town. As you get near your apartment, the coach stops and turns to you to say something.'
			act 'Listen to him': gt 'Voltrener', 'trener_speak'
		end
	end
else
	!---------------------------While not in the squad-------------------------
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/teacher/mikhail/volleytrener1.jpg"></center>'
	'You go up to Mikhail Nikolaevich and politely say hello.'
	if pcs_vball < 20:
		'Mikhail turns and looks at you. "Uh... have we met?" He doesn''t seem to recognize you. "Ah, I''ve seen you at school. You''re in pretty good shape, you should come to volleyball training."'
	elseif pcs_vball < 35:
		'The coach looks at you with condemnation. "<<$pcs_lastname>>, well done. You''re getting a hang of the basics. You don''t belong here though... although, what do I know?"'
	elseif pcs_vball < 60:
		'The coach looks at you with condemnation. "<<$pcs_lastname>>, you were pretty good in training, but places like this help to regress the formation of skills. You should go home."'
	elseif pcs_vball < 80:
		'The coach looks at you with condemnation. "What are you doing here?"'
		'"What are you doing here?" You turn the question back onto him.'
		'"<<$pcs_lastname>>, don''t piss me off. What I do is my business, and what you are doing here is also my business.'
		if pcs_horny > 79:
			trenerlust += 1
			'"Is that the truth, Mr. Nikolaevich? Are you here because of me?" You move closer to the coach and flutter your eyes at him.'
			'"I meant as your coach, and don''t think you can win just by fluttering your eyes. Want to impress me? Workout, and no partying."'
		else
			'"As your coach," he adds with a slight blush.'
		end
	else
		'The coach looks at you with condemnation. "<<$pcs_lastname>>, you here again, what the fuck? This is not the place for candidates for the team.'
		'"Mr. Nikolaevich, you never said anything about not going out on a Friday."'
		'"<<$pcs_lastname>>, are you thick? When does the team play?"'
		'"Saturday," you respond, sheepishly.'
		'"So, on Friday I expect my players not to hang out here but go home and get some sleep. Or they aren''t going to be fit to play tomorrow. Clear? You have some skill, sort out your attitude and you might yet make the team."'
	end
end
!------------------------------------------Included in the line--------------------------------------

act 'Move away':gt $loc, $loc_arg
--- VolleyTrenerSpeak ---------------------------------