glife/locations/sergeihunter.qsrc

# sergeihunter
!2020/10/16
gs 'boyStat', 'A174'
harakBoy = 1
boyage = year - ((npc_dob['A174'] - (npc_dob['A174'] mod 10000)) / 10000)

if huntersSergeiLove = 0 or (huntersSergeiQw >= 10 and huntersSergeiQw <= 50):
	if huntersSergeiLove > 0 and pcs_horny <= 60 and huntersSergeisex = 0  and rand(0,2) = 0:
		*clr & cla
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.4.jpg"></center>'
		'You go to Sergei to spend time together, but instead, he kisses you and playfully bites on your lip.'
		'"<<$pcs_nickname>>, I want you," he whispers after the kiss.'
		huntersSergeisex += rand(9,30)
		gs 'arousal', 'foreplay', 5
		gs 'stat'

		act 'Agree':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt2.'+rand(4,6)+'.jpg"></center>'
			*nl 'Smiling, you bite softly on Sergei''s neck. He rushes to pull you along with him.'
			minut += 5
			huntersSergeiQw += 1
			gs 'stat'

			act 'Go':gt 'hunterLoveSex','Sergei'
		end
		act 'Decline':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/pc/reactions/speak_to_the_hand.jpg"></center>'
			*nl '"No, Sergei, not now, but soon." You give him a small look of regret as you leave.'
			minut += 5
			huntersSergeiQw -= 1
			gs 'stat'

			act 'Go':gt $loc, $loc_arg
		end
	else
		'<center><b><font color = maroon>Sergei</font></b></center>'
		'<center><img <<$set_imgh>> src="images/characters/shared/photos/big174.jpg"></center>'
		*nl
		'Sergei is a friend of Andrei and Igor, and a member of the group of hunters that frequents the woods and swamp by Gadukino. He''s <<boyage>> years old. He is married and lives in the City Center...'
		if huntersSergeiQw < 0:
			'You and him have a bad relationship because you offended him in the past.'
		elseif huntersSergeiQw < 10:
			'You have a normal relationship with him.'
		elseif huntersSergeiQw < 20:
			'You have friendly relations with him.'
		elseif huntersSergeiQw < 25:
			'You''re good friends.'
		elseif huntersSergeiQw < 30:
			'It seems he has a crush on you.'
		elseif huntersSergeiQw <= 35:
			'You have a mutual crush on each other.'
		else
			if huntersSergeiLove = 1:'You two love each other.' else 'You have an unrequited love for him.'
		end
		gs 'stat'

		act 'Chat (0:30)':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/talk1.'+rand(1,3)+'.jpg"></center>'
			if huntersSergeiQw >= 0:'You spend some time chatting with Sergei, listening to interesting stories from his life and telling some stories of your own.'
			if huntersSergeiQw < 0:'You talk with Sergei. He seems uncomfortable but doesn''t force you away.'
			minut += 30
			if huntersSergeiQw < 10:huntersSergeiQw += 1
			gs 'stat'

			act'Continue':gt $loc, $loc_arg
		end

		if huntersSergeiQw >= 10:
			if huntersSergeiLove = 0:
				act 'Flirt':
					*clr & cla
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt1.'+rand(1,3)+'.jpg"></center>'
					*nl 'You flirt playfully with Sergei. He is glad for your company, though he can''t stop himself from letting his eyes wander.'
					minut += 5
					!!not using arousal as no orgasm chance
					pcs_horny += 10
					if huntersSergeiQw <= 35 and huntersKnowSlut = 0:huntersSergeiQw += 1
					if huntersIgorQw >= 10 and huntersKnowSlut = 0:huntersIgorQw -= 1
					if huntersAndreiQw >= 10 and huntersKnowSlut = 0:huntersAndreiQw -= 1
					gs 'stat'


					if huntersSergeiQw >= 30 and huntersKnowSlut = 0 and pcs_apprnc >= 60:
						act 'Continue flirting':
							*clr & cla
							'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss1.jpg"></center>'
							*nl 'Suddenly, he cups your chin in his hand and gives you a kiss full of passion.'
							gs 'arousal', 'foreplay', 5
							gs 'stat'

							act 'Answer kiss':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss2.jpg"></center>'
								*nl 'You''ve been waiting for this and respond just as passionately. Sergei keeps kissing you, and you are right there with him, returning every kiss.'
								huntersSergeiLove = 1
								huntersSergeiQw += 1
								pcs_mood = 100
								gs 'arousal', 'kiss', 5
								gs 'stat'

								if pcs_horny >= 40:
									act'Further':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss3.jpg"></center>'
										*nl '"<<$pcs_nickname>>, I want to make love to you," he says when he finally pulls back. You answer Sergei with a kiss every bit as passionate as the one that started this. You begin to make your way back towards his room as you do so.'
										minut += 5
										gs 'stat'

										act 'Go inside': gt'hunterLoveSex', 'Sergei'
									end
								else
									act'Continue':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterkiss3.jpg"></center>'
										*nl '"That was great <<$pcs_nickname>>," Sergei says when your lips finally part. You see a look that clearly shows he wishes for more and smile.'
										minut += 5
										gs 'stat'

										act'Continue':gt $loc, $loc_arg
									end
								end
							end
							act 'Move away':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/pc/reactions/speak_to_the_hand.jpg"></center>'
								*nl '"Sorry, Sergei, but this isn''t what I wanted," you say. He leaves with an angry look on his face.'
								minut += 5
								huntersSergeiQw -= 50
								gs 'stat'

								act'Leave':gt $loc, $loc_arg
							end
						end
					end
					act'Leave':gt $loc, $loc_arg
				end
			else
				act 'Spend time together':
					*clr & cla
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.'+rand(1,4)+'.jpg"></center>'
					*nl 'You and Sergei spend time together, spooning the whole while. You can almost feel how much he needed to spend time with you. You notice the happy look on his face and feel very satisfied you put it there.'
					minut += 120
					!!not using arousal as no orgasm chance
					pcs_horny += 10
					huntersSergeiQw += 1
					if huntersIgorLove > 0 or huntersAndreiLove > 0:hunterslut += 1
					if huntersIgorLove = 0 and huntersAndreiLove = 0:hunterslut -= 1
					pcs_mood = 100
					gs 'stat'

					act'Leave':gt $loc, $loc_arg
				end
				if pcs_horny >= 60:
					act 'Have sex':
						*clr & cla
						'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt2.'+rand(1,6)+'.jpg"></center>'
						*nl 'You pull Sergei off to the side and kiss him. You guide his hands to your sopping, needy snatch so there''s no doubt what you want. Sergei doesn''t hesitate and leads you to his bed, never removing his hand.'
						huntersSergeiQw += 1
						huntersSergeisex += rand(9,30)
						gs 'arousal', 'foreplay', 10
						gs 'stat'

						act 'Go':gt 'hunterLoveSex','Sergei'
					end
				end
				if rand(0,6) = 0:
					act 'Break up with Sergei':
						*clr & cla
						'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/brosila.jpg"></center>'
						*nl '"Sergei, the passion is gone," you say, "I think it''s time we parted." You leave without looking back.'
						minut += 5
						huntersSergeiLove = 0
						huntersSergeiQw -= 100
						gs 'stat'

						act 'Leave':gt $loc, $loc_arg
					end
				end
			end
		end
		act 'Depart':gt $loc, $loc_arg
	end
else
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/brosil.jpg"></center>'
	*nl
	if huntersSergeiQw < 10:
		'You want to talk to Sergei, but he beats you to it and starts speaking before you can get a word in.'
		'<<$pcs_nickname>>, I realized that our relationship has no future and we need to stop seeing each other, " he says and, trying not to look in your direction, resolutely walks away.'
		'"Well, maybe it''s for the best," you think as you leave in the other direction.'
		huntersSergeiQw -= 10
	else
		'You want to talk to Sergei, but before you say anything, he speaks instead.'
		'"<<$pcs_nickname>>, I realized that our relationship has no future. Your passion is unmatched, but I really love my family. I can''t risk that for you," he says. He turns and walks away without saying another word nor giving you time to say anything.'
		'"Well, that''s how you feel is it?" you think as you stand there stunned. "Although, this is probably for the best since he is married," you conclude before walking away.'
		huntersSergeiQw -= 50
	end
	minut += 5
	huntersSergeiLove = 0
	gs 'stat'

	act 'Leave':gt $loc, $loc_arg
end

--- sergeihunter ---------------------------------