glife/locations/katspalnya.qsrc

# katspalnya
$sexloc = 'katspalnya'

if $ARGS[0] = 'start':
	$loc_arg = 'start'
	$loc = 'katspalnya'
	$location_type = 'private'
	$locclass = 'bedr'
	$menu_loc = 'katspalnya'
	$menu_arg = 'start'
	menu_off = 0
	cls
	gs 'stat'
	'<center><b><font color="maroon">Katja''s apartment</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/city/katja/bedroom.jpg"></center>'
	
	'Katja''s apartment. It''s mostly just one large room, with a huge bed in it. There''s a small couch to the side.'

	if hour >= 18 and hour < 23:'<a href="exec:gt ''katspalnya'', ''kat''">Kat</a> is sitting on the couch. She''s watching TV.'
	if hour >= 23 or hour < 6:'<a href="exec:gt ''katspalnya'', ''katslip''">Kat</a> is sound asleep in her huge bed.'

	act 'Leave Kat''s apartment':gt 'city_residential'
end

if $ARGS[0] = 'katslip':
	*clr & cla
	minut += 30

	if katjob = 0 and npc_rel['A219'] > 60:gt 'katspalnya', 'katjobs'

	'<center><img <<$set_imgh>> src="images/characters/city/katja/kat.jpg"></center>'
	'When you awaken Kat, she rubs her eyes tiredly: "Hey, <<$pcs_nickname>>... what''s up?"'

	act 'Chat with her for a while':gt 'katspalnya', 'start'

	if npc_rel['A219'] > 50:act 'Seduce her':gt 'lezbsex', 'start'
end

if $ARGS[0] = 'kat':
	*clr & cla
	minut += 30

	if katjob = 0 and npc_rel['A219'] > 60:gt 'katspalnya', 'katjobs'

	'<center><img <<$set_imgh>> src="images/characters/city/katja/kat.jpg"></center>'
	'Kat smiles when she sees you approach and says cheerfully: "<<$pcs_nickname>>, hi! How''s it going? Come, sit with me!"'

	act 'Make up an excuse and leave':gt 'katspalnya', 'start'

	if npc_rel['A219'] > 50:act 'Seduce her':gt 'lezbsex', 'start'

	act 'Chat with Kat':
		*clr & cla

		if telkat = 0:telkat = 1

		npc_rel['A219'] += 1
		minut += 30
		'<center><img <<$set_imgh>> src="images/characters/city/katja/kat.jpg"></center>'
		'You talk with Kat for half an hour, occasionally glancing at the TV. She''s a lot of fun to be around.'

		act 'Finish':gt 'katspalnya', 'start'
	end
end

if $ARGS[0] = 'katjobs':
	*clr & cla
	katjob = 1
	minut += 30
	'<center><img <<$set_imgh>> src="images/characters/city/katja/kat.jpg"></center>'
	'Kat talks about her job for a while, and then suggests: "By the way... if you want, I can put in a good word for you! Maybe you could work at the clinic as well!"'

	act '"But I''m not qualified to work as a nurse!"':
		cla
		'You shrug off the idea at first, saying: "But I''m not a nurse! I wouldn''t know what to do!"'
		'Kat laughs and says: "Oh, come on! Do you think I knew what I was doing when I started? Just wear the fancy coat and be there, you''ll learn as you go! It''ll be fun, I promise! We could have so much fun, working together!"'
		'"Well, okay, I''ll think about it!" you say, earning you an enthusiastic hug and a "Yay!" cheer from Kat. How bad could it be?'

		act 'Continue':gt 'katspalnya', 'start'
	end
end

--- katspalnya ---------------------------------