# city_musicstore

if $ARGS[0] = 'musicshop':
	*clr & cla	
	if ml_musicstorevisited = 0:
			ml_musicstorevisited = 1
			gt 'city_musicstore', 'firstvisit'
	elseif ml_didntbuyguitarthefirstvisit = 1:
		gt 'city_musicstore', 'cameback'
	else
		'<center><img src="images/locations/city/citycenter/mall/musicstore/music-store-600.jpg"></center>'
		'You enter the store, welcomed by the familiar mix of random notes and bits of songs screaming from the back.'
		'Jimmy just nods at you, then returns his attention to the guitar laying on the counter in front of him.'

		act 'Shop for guitars and amps': gt 'city_musicstore_stock', 'acoustic'
		act 'Try some guitars': 
!!			TODO: Better scenes here			
			if pcs_instrmusic < 30 and pcs_performing < 10:
				'You pick up a guitar to try it, but you are too shy and after strumming a few chords you put it back on it''s stand'
			else
				'Some texts here depending on music skill and performing skill'			
			end
		end
		act 'Leave': 
			if ml_boughtguitar > 0 or ml_boughtamp > 0:
				gt 'city_musicstore', 'payandtakestuff'
			end
			gt 'torgcentr'
		end
	end

end

if $ARGS[0] = 'firstvisit':
	'<center><img src="images/locations/city/citycenter/mall/musicstore/music-store-600.jpg"></center>'
	*nl
	'You enter the store, passing the door to be submerged in a loud, cacophonic environment. 
	The walls are filled with guitars, and in the back three teenaged guys are trying instruments in a very loud way.'
!!	TODO: Replace the image, Waynes world is fun but silly
	'<center><img src="images/locations/city/citycenter/mall/musicstore/waynesworld.jpg"></center>'
	*nl
    'A tall, dark haired man turns to you with a bored expression that turns into a perplexed smile as he takes your sight in.'
   	'He straightens up "Hello there, I''m Jimmy" - he greets you - "Is there anything I can help you with?"'
	*nl
	'<center><img src="images/locations/city/citycenter/mall/musicstore/jimmy.jpg"></center>'
	*nl
  	'Suddenly he turns and throws a sponge at one of the boys playing in the back "No. Stairway. To. Heaven." he growls and points at the sign on the wall before turning back to you.'
 	'<center><img src="images/locations/city/citycenter/mall/musicstore/nostairways.jpg"></center>'

	act 'Look for a guitar':
		*clr & cla
		'<center><img src="images/locations/city/citycenter/mall/musicstore/cheap_acoustic_1.jpg"></center>'		
		'You start to browse the guitars in the shop, not entirely sure what you are looking for and gladly accept the help of the store clerk. After answering his questions and chatting about music and what you are looking for he finally picks up an affordable acoustic guitar as a recommendation.'
		'After some conversation with the store owner he offers you an affordable acoustic guitar to buy'
		'Jimmy leaves you alone with the instrument, so you sit down to try it, strumming the chords that you know, trying to play something.'
		if money > 3400 or karta > 3400:
			if money < 14280 and karta < 14280:
				'While the guitar is not the best sounding one it''s comfortable and looking at the price tags, the only one you can afford.'
			else 
				'While the guitar is not the best sounding one it''s comfortable and looking at the price tags, you are not sure you should spend too much money until you are better at playing the guitar.'
			end
			if money > 3400: act 'Buy a cheap acoustic guitar (3,400 <b>P</b>) - pay with cash': gt 'city_musicstore', 'buycheapacoustic', 'money'

			if karta > 3400: act 'Buy a cheap acoustic guitar (3,400 <b>P</b>) - pay with card': gt 'city_musicstore', 'buycheapacoustic', 'karta'						
			act 'You have to think about it':
				ml_didntbuyguitarthefirstvisit = 1
				'You hesitate for a moment, unsure whether to buy it or not and finally decide to not do it, at least not now. "I will have to talk to my mum first" you say to Jimmy. '
				'He just nods "Don''t worry <<$pcs_firstname>>. You know what, I will put it aside for you for a bit in case you change your mind". He scribbles something on a post-it note, and sticks it on the guitar "I will try to keep the price the same, 3,400 rubels."'
				act 'Leave': gt 'torgcentr'
			end
		else
			ml_didntbuyguitarthefirstvisit = 1
			'While the guitar is not the best sounding one it''s comfortable. Unfortunately while it''s cheaper than the rest, it still costs more than you have. With a sigh you hand it back to Jimmy "I''m sorry, but, I can''t buy it now."'
			'He just nods "Don''t worry, I tell you what, I will put it aside for you if you change your mind. He scribbles something on a post-it note, and sticks it on the guitar "I will try to keep the price the same, 3,400 rubels."'
			act 'Leave': gt 'torgcentr'
		end				
	end
	act 'Leave': 
		ml_didntbuyguitarthefirstvisit = 1		
		gt 'torgcentr'
	end
end


if $ARGS[0] = 'cameback':
	*clr & cla
	'<center><img src="images/locations/city/citycenter/mall/musicstore/music-store-600.jpg"></center>'
	*nl
	'You enter the store, passing the door to be submerged in a loud, cacophonic environment.'
	if money > 3400 or karta > 3400: 
		act 'Ask Jimmy about the guitar':
			cla
			'You walk up to the counter where Jimmy is busy tinkering with a guitar.'
			'"Hi Jimmy... I was wondering if you still has that guitar..."'
			'Jimmy looks up from the guitar "Hi <<$pcs_firstname>>, sure, I have it. Let me get it for you."'
			'He disappears for several minutes before he brings out the guitar. "See, all in good shape. Properly set up and everything."'
			if money > 3400: act 'Buy a cheap acoustic guitar (3,400 <b>P</b>) - pay with cash': gt 'city_musicstore', 'buycheapacoustic', 'money'
			if karta > 3400: act 'Buy a cheap acoustic guitar (3,400 <b>P</b>) - pay with card': gt 'city_musicstore', 'buycheapacoustic', 'karta'						
		end
	end
	act 'Shop for guitars and amps': gt 'city_musicstore_stock', 'acoustic'
	act 'Try some guitars': 
!!			TODO: Better scenes here			
		if pcs_instrmusic < 30 and pcs_performing < 10:
			'You pick up a guitar to try it, but you are too shy and after strumming a few chords you put it back on it''s stand'
		else
			'Some texts here depending on music skill and performing skill'			
		end
	end
	act 'Leave': 
		if ml_boughtguitar > 0 or ml_boughtamp > 0:
			gt 'city_musicstore', 'payandtakestuff'
		end
		gt 'torgcentr'
	end
end


if $ARGS[0] = 'buycheapacoustic':
	*clr & cla
	'<center><img src="images/locations/city/citycenter/mall/musicstore/starterkit.jpg"></center>'
	if ml_didntbuyguitarthefirstvisit = 1:
		'You finally decide to buy the guitar, taking it to the checkout. Jimmy throws in a gigbag to carry the gitar and a set of strings and picks. "A proper starter kit" he states and rings up the purchase.'
		killvar 'ml_didntbuyguitarthefirstvisit'
	else
		'Jimmy puts the guitar in a gigbag, and drops a set of strings and picks in the the pocket. "A proper starter kit" he states and rings up the purchase.'
	end
	'He looks at you thoughtfully, then drops a thick, slightly worn booklet in the bag "Some stuff to learn from" he says handing your purchase to you "Congratulations, welcome to the starving musician community."'
	ml_guitars['jb-budget-acoustic'] = 1
	ml_strings = 2
	ml_guitar['chordbook'] = 1
	ml_guitar['hasguitar'] = 1 
	ml_guitar['carried'] = 1
	
	if $ARGS[1] = 'money': money -= 3400
	if $ARGS[2] = 'karta': karta -= 3400
	gs 'stat'
	act 'Leave': gt 'torgcentr'
end

if $ARGS[0] = 'payandtakestuff':
	if ml_boughtamp + ml_guitar['carried'] > 0 or ml_boughtguitar > 1:
		minut += (ml_boughtguitar * 5) + (ml_boughtguitar * 5)
		'Jimmy takes your details and your home address after you pay, and sets up the delivery. "It should be there tomorrow, <<$pcs_nickname>>."'
	else	
		minut += 20
        ml_guitar['carried'] = 1
		'Jimmy disappears with your chosen guitar in the back of the shop only to return after about 10 minutes. "It''s all set up, <<$pcs_nickname>>, if you need to tweak anything, just bring it in, we will do it, no charge."'
		*nl
		'He puts the guitar in ' + iif(ml_gigbag = 1, 'a gigbag', '') + iif(ml_hardcase = 1, 'its case', '') + ' and hands it to you. "All the best, <<$pcs_nickname>>."'
	end
	killvar 'ml_boughtamp'
	killvar 'ml_boughtguitar'
	killvar 'ml_gigbag'
	killvar 'ml_hardcase'
	act 'Leave': gt 'torgcentr'
end
--- city_musicstore ---------------------------------