# liames

$loc_arg = ''
$loc = 'liames'
$location_type = 'public_outdoors'
$menu_loc = 'liames'
$menu_arg = ''
menu_off = 0
CLOSE ALL
clr
gs'stat'
set palMir=0
set bordysh=0
set housrA=0
set palMir=0
set obdysh=0
set tanhouse1=0
set obMir=0
set obLoker=0
set houseob=0
set borMir=0
set borLoker=0
set minut+=10

'<center><B>High Street</B></center>'
'<center><img <<$set_imgh>> src="images/locations/oldtown/liames.jpg" ></center>'
'High Street is a square serving as the joining point of several smaller streets.  There are many small cafes and shops.'
'Another street runs straight to the <a href="exec:gt ''liam'',''start''">Town Center</a>.'
'High Street itself leads to the Old Town <a href="exec:gt ''parks'',''start''">Park</a>.'
if hour >= 8 and hour <= 20:
	'A small <a href="exec:gt ''larek'',''start''">grocery store</a> is currently open.'
else
	'There is a small whole foods store that is open from 8:00 - 20:00 everyday. It is currently closed.'
end

if hour >= 10 and hour <= 22:
	'A quaint little restaurant has put a sign outside of its door, reading, "<a href="exec:gt ''liamelkafe'',''start''">Liamel Cafe</a>."'
else
	'Liamel Cafe is current closed, it is open every day 10:00 - 22:00'
end

if exhibitionQW > 3:
	if week < 7 and hour >= 8 and hour <= 18:
		'<a href="exec:gt ''exhibitionistshop'',''start''">Expression of You</a> is just down a small side street from here.'
	else
		'<b>Expression of You,</b> is open Mon - Sat, 8:00 - 18:00'
	end
end

if hour >= 18 and hour <= 22:
	if pcs_inhib > 30:
		'There is a <a href="exec:gt ''burlesque'',''start''">burlesque club</a> with shows running until 22:00, that was once an old theatre.'
	else
		'There is a burlesque club in an old theatre here. It makes you self-conscious about your looks and you cannot bring yourself to go there.'
	end
else
	'The old theatre housing a burlesque club is closed now. It is open every day 18:00 - 22:00'
end

if home_owned[4] = 1: act '<b>Go home</b>':gt'korr2x'

if hour >= 8 and hour <= 17 and exhibitionQW = 3: act 'Search for the shop on the card from Kseniya': gt 'exhibitionistshop', 'start'

act 'wait':gs 'obj_din', 'wait'

if home_owned[4] = 1 and hour = meethour:
	if svidanie[0] = 1:'<b>Near the entrance you expect <a href="exec:lover_number = 0 & gt ''lover_meet'',''start''"><<$loverdesc[0]>></a></b>'
	if svidanie[1] = 1:'<b>Near the entrance you expect <a href="exec:lover_number = 1 & gt ''lover_meet'',''start''"><<$loverdesc[1]>></a></b>'
	if svidanie[2] = 1:'<b>Near the entrance you expect <a href="exec:lover_number = 2 & gt ''lover_meet'',''start''"><<$loverdesc[2]>></a></b>'
end

if rand(0,100) >= 60 and pcs_lover < 3 and rand(0,1200) <= pcs_apprnc:
	gs 'boy'
	'To you came <<$boybody>> <<$boybod>> <<$boyface>>. It <<$boyClo>>'
	'The guy introduced himself as <<$boydesc>> and asks you for your telephone number.'

	act 'Walk away': gt 'liames'
	act 'Tell him your telephone number.':
		cla
		gs'boyfrend', 'start'
		stopboy = 0
		'<<$boydesc>> saved your phone number and left.'
		act 'Continue': gt 'liames'
	end
end

if rand(1,100) >= 95:
	*clr & cla
	minut += 5
	gs'stat'
	'<center><img <<$set_imgh>> src="images/locations/oldtown/liamhud1.jpg"></center>'

	'Making your way down High Street, you see a woman waiting patiently while an artist paints her portrait.'

	act 'Continue': gt'liames'
end

if hour >= 8 and hour <= 20 and sunWeather = 1 and temper >= 15 and ml_guitar['carried'] = 1 and ml_performance['performed_minutes'] < ml_performance['max_perform_minutes'] and ml_performance['max_perform_minutes'] >= 15:
	*nl
	'With the weather being pleasant and sunny, there are groups of people moving around the streets. You could play some music, practice performing songs and maybe make some money too.'
	ml_buskingtime =  min((ml_performance['max_perform_minutes']-ml_performance['performed_minutes']), 60)
	if pcs_inhib < 30: 
		if pcs_inhib < 10: 
			$diff = 'hard'
		elseif pcs_inhib < 20: 
			$diff = 'medium'
		else
			$diff = 'easy'
		end
		
		gs 'willpower', 'skill', 'self', $diff
		will_cost = (will_cost * 3) - (pcs_perform)
		if will_cost <= pcs_willpwr:
			act 'Start busking (<<ml_buskingtime>> minutes) (<<will_cost>> Willpower)': 
				inhib_exp += rand(1,3)
				gs 'willpower', 'pay', 'self'
				gs 'stat'
				gs 'music_buskingevents', 'busking', 'oldtown'
			end
		else	
			act 'Start busking (<<ml_buskingtime>> minutes) (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end		
	else
		act 'Start busking (<<ml_buskingtime>> minutes)': gs 'music_buskingevents', 'busking', 'oldtown'
	end
end

if hour >= 15 and hour <= 22 and tusa = 0:
	act 'Go to the local hangout':
		*clr & cla
		menu_off = 1
		minut += 20
		tusa = 1
		gs 'dibodi'
		gs'stat'
		'<center><img <<$set_imgh>> src="images/locations/oldtown/photo.jpg"></center>'
		'Local youth get-together.'
		act 'Explore it': gt 'dibodi', 'sgtusa'
	end
elseif hour >= 15 and hour <= 22 and tusa = 1 and tusnyakday ! daystart:
	act 'Go to the local hangout':
		*clr & cla
		menu_off = 1
		minut += 20
		gs'dibodi'
		gs'stat'
		'<center><img <<$set_imgh>> src="images/locations/oldtown/photo.jpg"></center>'
		'The girls and boys at the local hangout happily greet you.'

		act'Leave': gt 'liames'
		
		if $pantyworntype = 'none' and sttan = 0:
			cla
			'"Hey guys, <<$pcs_nickname>> is going commando," one of the boys says.'
			act 'Continue':gt 'dibodi', 'sotusa'
		end

!!		if sttan = 1 and $pantyworntype = 'none':
!!			'- <<$pcs_nickname>>, and again without panties, - said one of the boys - Pussy pokezh?'
!!			'- And yet to show? - you said - How do I want and go.'
!!			act 'Further':gt'etoexhib','pos2'
!!		end

!!		if sttan = 1 and $pantyworntype ! 'none':
!!			'- Vav <<$pcs_nickname>> truselya put.'
!!			act 'Answer':gt'etoexhib','pos3'
!!		end
	end
end

if stallionQ = 3:
	*clr & cla
	'There is a rumbling in your stomach, you need to use the restroom. There appears to be a public restroom tucked into the corner of a building. Unfortunately, the female one has a sign reading, "Out of order."'
	gs 'willpower', 'misc', 'resist', 'easy'
	if will_cost <= pcs_willpwr:
		act 'Hold it (<<will_cost>> Willpower)':
			gs 'willpower', 'pay', 'resist'
			stallionQ = 1
			gt 'liames'
		end
	else
		act 'Hold it (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end
	act 'Use the Men''s Restroom': gt 'stallion','start'
end

--- liames ---------------------------------

