# boy

!!'<<$boydesc>> <<$boybody>> <<$boybod>> <<$boyface>>. <<$boydesc>> <<$boyClo>>'
if $ARGS[0] = '':
	!randomly age
	boyage = rand(18,35)

	!! {The NPC generator is now the primary system of creating new characters.}
	gs 'npcgeneratec', 0, 'A Male', boyage
	gs 'boyStat', $npclastgenerated
	gs 'boy', 'details'
end

if $ARGS[0] = 'details':
	!Select Photos

:boydetailsloop
	picrand =  RAND(1,30)
	if picrand = boypic[0] or picrand = boypic[1] or picrand = boypic[2]: jump 'boydetailsloop'

	silaVag = npc_sexskill[$npclastgenerated]
	$npc_usedname[$npclastgenerated] = $npc_firstname[$npclastgenerated]
	$boydesc = $npc_usedname[$npclastgenerated]

	!!appearance
	boybodyrand = rand(1, 3)

	if boybodyrand = 1: $boybody = 'tall'
	if boybodyrand = 2: $boybody = 'average'
	if boybodyrand = 3: $boybody = 'short'

	boybodrand = rand(1, 4)

	if boybodrand = 1: $boybod = 'thin'
	if boybodrand = 2: $boybod = 'athletic'
	if boybodrand = 3: $boybod = 'chunky'
	if boybodrand = 4: $boybod = 'fat'

	boyfacerand = rand(1, 3)

	if boyfacerand = 1: $boyface = 'black'
	if boyfacerand = 2: $boyface = 'brunet'
	if boyfacerand = 3: $boyface = 'blond'

	!!variable is responsible for guy
	boyonce = 0

	!!Variables responsible for any features like
	!!security, is responsible for the money and requirements
	harakBoy = rand(0, 2)
	finance = rand(0, 2)

	if finance = 0:
		!!Gopnik beggar or a hard worker
		!!check in appearance Primary
		if harakBoy = 0: npc_app[$npclastgenerated] = rand(0, 8)
		if harakBoy = 1: npc_app[$npclastgenerated] = rand(0, 16)
		if harakBoy = 2: npc_app[$npclastgenerated] = rand(0, 32)

		$boyClo = 'wearing a tracksuit.'
	elseif finance = 1:
		!!middle_peasant
		!!check in appearance
		if harakBoy = 0: npc_app[$npclastgenerated] = rand(0, 16)
		if harakBoy = 1: npc_app[$npclastgenerated] = rand(0, 24)
		if harakBoy = 2: npc_app[$npclastgenerated] = rand(0, 32)

		$boyClo = 'wearing jeans and a sweater.'
	elseif finance = 2:
		!!middle_peasant
		!!check in appearance
		if harakBoy = 0: npc_app[$npclastgenerated] = rand(16, 32)
		if harakBoy = 1: npc_app[$npclastgenerated] = rand(24, 32)
		if harakBoy = 2: npc_app[$npclastgenerated] = rand(32, 40)

		$boyClo = 'wearing an expensive suit.'
	end

	!!requirements of the figure, chest size, hair color.
	!!0 - ass less 80, 1 back from 80 prior_to 100, 2 ass over 100
	figurBoy = rand(0, 2)
	!!0 - chest less 3, 1 breast 3-4, 2 breasts bigger 4
	npc_bust[$npclastgenerated] = rand(0, 2)
	!!0 - black, 1 - brown, 2 - Redhead, 3 - blonde
	npc_haircol[$npclastgenerated] = rand(0, 3)
	!!character 0 - soft, 1 -norm 2 - aggressor
	randizvrat = rand(0, 100)

	if randizvrat < 80:izvrat = 0
	if randizvrat >= 80:izvrat = 1



	hairBoy = npc_haircol[$npclastgenerated]
	titBoy = npc_bust[$npclastgenerated]
	vneshBoy = npc_app[$npclastgenerated]


	!! trying to make the preference section 
	!! Variables here are clotTypePref, clotQualPref, clotTopPref, bottShorPref, clotThinPref, bimbPref, pierPref, tattPref, lipsPref, bodyPref, makePref, IQPref.


	!!This is for clothing type preference
	!! If you notice how rare it is to get a preference that is intentional
	!!0 - none, 1 - cheap, 2 - average, 3 - formal, 4 - fetish.
	clotTypePref = 0
	if rand(0, 4) = 4:
		if finance = 0:
			clotTypePref = rand(1,2)
			if rand(0, 1) = 1 and izvrat = 1:clotTypePref = 4
		elseif finance = 1:
			clotTypePref = rand(1,3)
			if rand(0, 2) = 2 and izvrat = 1:clotTypePref = 4
		elseif finance = 2:
			clotTypePref = rand(2,3)
			if rand(0, 1) = 1 and izvrat = 1:clotTypePref = 4
		end
	end


	!!This is for the quality of clothing
	!! 0 - no preference, 1 - 1 to 4 units cheap to average (Locked if formal chosen), 2 - 5 to 7 units expensive to ballroom quality (Locked if fetish is chosen)
	clotQualPref = 0
	if rand(0, 5) = 5:
		if finance = 0:
			clotQualPref = 1
		elseif finance = 1:
			clotQualPref = rand(1, 2)
			randchan = rand(0, 1)
			if randchan = 0 and clotTypePref ! 3:
				clotQualPref = 1
			elseif randchan = 1 and clotTypePref ! 1:
				clotQualPref = 2
			end
		elseif finance = 2:
			randchan = rand(0, 2)
			if randchan = 2 and clotTypePref ! 1:
				clotQualPref = 2
			end
		end
	end

	!!This is for the clothing top cut for the clothing


	!!Need to add modifiers based on breast size, where larger breasts end up forcing the player to show more cleavage than those with smaller breasts.
	!! 0 - no preference, 1 - 1 to 2 or neckline to moderate, 2 - 3 to 4 or heavy to severe, 3 - 5 to 7 or buldging to outpouring 
	!! The breast size must be adjusted either when the action is being calculeted or we can base it on their ideal breast size :titBoy + 0/3 depending on the players breast size


	!!0 - no preference, 1 - 1 neckline , 2 - 2 or moderate, 3 - 3 to 4 or heavy to severe
	!! It doesn''t matter if your poor or rich, everyone loves tits.

	slutConstant = 0
	if rand(0, 1) = 1 and izvrat = 1:slutConstant = 1


	clotTopPref = 0
	if rand(0, 2) = 2:
		randchan = rand(0, 2)
		if randchan = 0 and clotTypePref ! 4:
			clotTopPref = 1 + slutConstant
		elseif randchan = 1 and clotTypePref ! 4:
			clotTopPref = 2 + slutConstant
		elseif randchan = 2 and clotTypePref ! 3:
			clotTopPref = 3
		end
		if clotTopPref ! 0 and titBoy = 2:
			if clotPref ! 3:
				clotTopPref += 1
			end
		end
	end

	!! This is for pants and skirt shortness and will be grouped together as such.
	!! 0 - no preference, 1 - 1 to 2 units or ankle to calf length, 2 - 3 to 4 units or knee to miniskirt, 3 - 5 units to 6 or slut to hoe.

	bottShorPref = 0
	if rand(0, 2) = 2:
		randchan = rand(0, 2)
		if randchan = 0 and clotTypePref ! 4:
			bottShorPref = 1 
		elseif randchan = 1:
			bottShorPref = 2 
		elseif randchan = 2:
			bottShorPref = 3
		end
		randchan = rand(0, 1)
		if slutConstant = 1 and randchan = 1 and clotTypePref = 4:
			bottShorPref = 3
		end
	end

	!! This is for clothes thinness.
	!! 0 - no preference, 1 - 0 to 2 (Conservative), 2 - 3 to 4 (Moderate), 3 - 4 to 6 (really thin)
	!! I see the moderate to really thin overlapping. Its intentional.

	clotThinPref = 0
	if rand(0, 2) = 2:
		randchan = rand(0, 2)
		if randchan = 0:
			clotThinPref = 1 + slutConstant
		elseif randchan = 1:
			clotThinPref = 2 + slutConstant
		elseif randchan = 2 and clotTypePref ! 3:
			clotThinPref = 3
		end
	end


	!!This is to find out if they want you to wear bimbo clothing
	!! 0 - no preference, 1 - Prefers bimbo clothing.

	bimbPref = 0
	if rand(0, 2) = 2 and clotTypePref ! 3:bimbPref = 1

	!!This is to find out if they want you to wear piercings.
	!! 0 - no preference, 1 - 0 to 2 piercings, 2 - 3 to 5 piercings, 3 - 6 or more piercings.

	pierPref = 0
	if rand(0, 3) = 3:
		randchan = rand(0, 2)
		if randchan = 0:
			pierPref = 1 + slutConstant
		elseif randchan = 1:
			pierPref = 2 + slutConstant
		elseif randchan = 2:
			pierPref = 3
		end
	end


	!!This is to find out if they want you to have tattoos.
	!! 0 - no preference, 1 - 0 to 2 tattoos, 2 - 3 to 5 tattoos, 3 - 6 or more tattoos.

	tattPref = 0
	if rand(0, 3) = 3:tattPref =  rand(1, 3)

	!!This is to find out how big they want your lips.
	!! 0 - no preference, 1 - 2 to 3 units (average) , 2 - 4 units (THIC lips)

	lipsPref = 0
	if rand(0, 2) = 2:
		randchan = rand(0, 2)
		if randchan = 0:
			lipsPref = 1 + slutConstant
		elseif randchan = 2:
			lipsPref = 2
		end
	end

	!!This is to find out how big they want YOU.
	!! 0 - no preference, 1 - 1 to 3 units (Skinny) , 2 - 3 to 6 units (Average), 3 - 6 + units (THIC)
	!! Notice how this one overlaps. I believe that it should because changing ones weight is very hard.

	bodyPref = 0
	if rand(0, 3) = 3:bodyPref = rand(1, 3) 

	!!This is to find out how much makeup they want you to wear.
	!! 0 - no preference, 1 - 1 (light makeup) , 2 - 2 (moderate makeup), 3 - 3(heavy makeup)
	!! Plan to make a way for you to set what you makeup you want to wear at your bedside and giving into his wishes would automatically change the automated setting.

	makePref = 0
	if rand(0, 1) = 1:
		randchan = rand(0, 2)
		if randchan = 0:
			makePref = 1 + slutConstant 
		elseif randchan = 1:
			makePref = 2 + slutConstant
		elseif randchan = 2 and clotTypePref ! 3:
			makePref = 3 
		end
	end


	!! This is to see if they like a ditz, average, or a smartypants
	!!0 - no preference, 1 - 1 to 30 intelligence, 2 - 30 to 85 intelligence, 3 - 85 + intelligence. 

	IQPref = 0
	if rand(0, 4) = 4:IQPref = rand(1, 3) 

end

--- boy ---------------------------------