glife/locations/Nudelake

# Nudelake
$location_type = 'secluded'
'<center><b>nudist beach</b></center>'
'<center><img <<$set_imgh>> src="images/locations/city/residential/lake/nudelake.jpg"></center>'
'The nudist beach - clothing optional.'

if $clothingworntype ! 'swimwear' and $clothingworntype ! 'nude':
	if pcs_exhibition > 30:
		minut += 5
		gs 'underwear', 'remove'
		gs 'clothing', 'strip'
		'You strip naked, enjoying the warm breeze on your bare skin.'
	else
		'You feel uncomfortable here in your clothes but you don''t have the confidence to go nude. Maybe you would be OK in swimwear?'
		act 'Return': gt 'lake', 'start'
	exit
	end
elseif $clothingworntype = 'swimwear':
	if pcs_exhibition > 30:
		act'Strip naked':
			cls
			minut += 5
			gs 'underwear', 'remove'
			gs 'clothing', 'strip'
			xgt 'Nudelake'
		end
	end
end
gs 'stat'

if hour >= 6 and hour <= 20 and temper >= 15:
	'Here you can <a href="exec:gt ''Nudelake'', ''zagarat''">sunbathe</a> and <a href="exec:gt ''Nudelake'', ''swim''">swim</a>'
	'Also, you can play <a href="exec:gt ''Nudelake'', ''voleybol''">beach volleyball</a>'
elseif hour >= 6 and hour <= 20:
	'Its too cold for any nudist activities.'
else
	'The nudist beach is closed.'
end

act 'Return to the main beach':
	if $clothingworntype = 'nude':gs 'clothing', 'wear_last_worn'
	gs 'underwear', 'wear'
	gt 'lake', 'start'
end

if katday ! daystart and npc_rel['A219'] >= 1:
	'You see Kat on the beach.'

	act 'Approach Kat':gt 'Katlake', 'kat'
end

if $ARGS[0] = 'voleybol':
    $location_type = 'event_outdoors'
	cls
	minut += 1
	'<center><img <<$set_imgh>> src="images/locations/city/residential/lake/voleybol.jpg"></center>'
	'You go to the volleyball court.'

	act 'Watch':gt 'Nudelake', 'smotr'
	act 'Leave':gt 'Nudelake'

	act 'Play':
		cla
		*clr
		agil_exp += 1
		react_exp += 1
		vball_exp += rand(1,3)
		minut += 30
		'<center><img <<$set_imgh>> src="images/locations/city/residential/lake/voleybol.jpg"></center>'
		'You go up to the players and ask whether it is possible to join in, they are happy to put you on a team.'

		act 'Finish':gt 'Nudelake'
	end
end

if $ARGS[0] = 'zagarat':
    $location_type = 'event_outdoors'
	cls
	minut += 30
	if pcs_sweat < 35 : pcs_sweat += 5
	exhibition_exp += rand(1,3)
	pcs_mood += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/residential/lake/nudezagarat.jpg"></center>'

	if krem = 0:
		pcs_tan += 1
		'You go to the beach and sunbathe.'
	else
		krem -= 1
		pcs_tan += 3
		'You smear sunblock on your body and sunbathe.'
	end

	nzagrand = rand(0, 100)

	if nzagrand >= 60 and nzagrand < 70 and npc_rel['A219'] > 30 and katkey = 0:gt 'Katlake', 'key'
	if nzagrand >= 70 and nzagrand < 80 and kat = 0 and katday ! daystart:gt 'Katlake'
	if nzagrand >= 80 and nzagrand < 90:gt 'Vnlake1'
	if nzagrand >= 90:gt 'Vnlake2'

	act 'Finish':gt 'Nudelake'
end

if $ARGS[0] = 'swim':
    $location_type = 'event_outdoors'
	cla
	*clr
	cumspclnt = 4
	gs 'cum_cleanup'
	minut += 60
	if $clothingworntype = 'nude': gs 'exercise', 'tier1', 1, 'stren_exp', 'exhibition_exp'
	if $clothingworntype ! 'nude': gs 'exercise', 'tier1', 1, 'stren_exp'
	pcs_sweat = 10 + rand(0,4)
	
	'<center><img <<$set_imgh>> src="images/locations/shared/lake/nudeswim.jpg"></center>'
	'You go for a swim.'

	act 'Finish':gt 'Nudelake'
end

if $ARGS[0] = 'smotr':
    $location_type = 'event_outdoors'
	cls
	minut += 30
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/residential/lake/voleybol.jpg"></center>'
	'You watch the others play.'

	act 'Leave':gt 'Nudelake'
end

--- Nudelake ---------------------------------