glife/locations/exhibitionistshop

# exhibitionistshop

if $ARGS[0] = 'start':
	CLOSE ALL
	$loc = 'exhibitionistshop'
	$metka = 'start'
    $location_type = 'public_indoors'
	cls
	minut += 5
	if exhibitionQW = 3: exhibitionQW = 4
	gs 'stat'

	if night_mode = 1:
		fcolor = rgb(255, 255, 255)
		bcolor = rgb(0, 0, 0)
		lcolor = rgb(106, 90, 205)
	else
		fcolor = rgb(0, 0, 0)
		bcolor = rgb(255, 255, 255)
		lcolor = rgb(106, 90, 205)
	end
	'<center><b><font color="maroon">Exhibitionist Shop</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/oldtown/exhibitshop/shop.jpg"></center>'
	'A shop in the most modern style who''s clothing is all very revealing and not nearly as classy as the store itself.'

	act 'Leave':
		minut += 5
		gt 'liames'
	end

	act 'View clothing':
		minut += 1
		gt 'exhibitionistshop', 'clo'
	end

	act 'View panties':
		minut += 1
		gt 'exhibitionistshop', 'panties'
	end

	act 'View bras':
		minut += 1
		gt 'exhibitionistshop', 'bras'
	end
end

if $ARGS[0] = 'clo':
	$metka = 'clo'
	$loc = 'exhibitionistshop'
	cls
	gs'stat'
	'<center><b><font color="maroon">Exhibitionist clothing</font></b></center>'
	*nl

	$Headerstring = '<TH>Prostitute clothing '
	if clothingfilter_prost = 0:
		$Headerstring += '<a href="exec:clothingfilter_prost = 1 & gt ''exhibitionistshop'', ''clo''">Included</a></TH>'
	else
		$Headerstring += '<a href="exec:clothingfilter_prost = 0 & gt ''exhibitionistshop'', ''clo''">Excluded</a></TH>'
	end

	$Headerstring += '<TH>Bimbo clothing '
	if clothingfilter_bimbo = 0:
		$Headerstring += '<a href="exec:clothingfilter_bimbo = 1 & gt ''exhibitionistshop'', ''clo''">Included</a></TH>'
	else
		$Headerstring += '<a href="exec:clothingfilter_bimbo = 0 & gt ''exhibitionistshop'', ''clo''">Excluded</a></TH>'
	end

	$Headerstring += '<TH>Clothing you are comfortable wearing '
	if clothingfilter_comf = 0:
		$Headerstring += '<a href="exec:clothingfilter_comf = 1 & gt ''exhibitionistshop'', ''clo''">Included</a></TH>'
	else
		$Headerstring += '<a href="exec:clothingfilter_comf = 0 & gt ''exhibitionistshop'', ''clo''">Excluded</a></TH>'
	end

	$Headerstring += '<TH>Daring clothing '
	if clothingfilter_daring = 0:
		$Headerstring += '<a href="exec:clothingfilter_daring = 1 & gt ''exhibitionistshop'', ''clo''">Included</a></TH>'
	else
		$Headerstring += 'g<a href="exec:clothingfilter_daring = 0 & gt ''exhibitionistshop'', ''clo''">Excluded</a></TH>'
	end

	$Headerstring += '<TH>Too daring for you clothing '
	if clothingfilter_too_daring = 0:
		$Headerstring += '<a href="exec:clothingfilter_too_daring = 1 & gt ''exhibitionistshop'', ''clo''">Included</a></TH>'
	else
		$Headerstring += '<a href="exec:clothingfilter_too_daring = 0 & gt ''exhibitionistshop'', ''clo''">Excluded</a></TH>'
	end

	act 'Return':
		cla
		minut += 5
		gt 'exhibitionistshop', 'start'
	end

	if Clothingstock >= 18:
		i = 1
	elseif Clothingstock >= 12:
		i = 2
	elseif Clothingstock >= 6:
		i = 3
	else
		i = 4
	end

	:loopexhibit
		if exhibit[i] = 0:
			gs 'clothing_attributes', 'exhibit', i
			if clothingfilter_comf = 0 and CloExhibit + 10 < pcs_exhibition:
				if (clothingfilter_prost = 0 or CloStyle ! 4) and (clothingfilter_bimbo = 0 or CloBimbo = 0): *p '<a href="exec: i = <<i>> & gt ''exhibitionistshop'', ''exhibit''"><img <<$set_imgh>> src="images/pc/clothing/9exhibit/<<i>>.jpg" 	height="250" /></a>'
			elseif clothingfilter_daring = 0 and CloExhibit + 10 >= pcs_exhibition and CloExhibit <= pcs_exhibition:
				if (clothingfilter_prost = 0 or CloStyle ! 4) and (clothingfilter_bimbo = 0 or CloBimbo = 0): *p '<a href="exec: i = <<i>> & gt ''exhibitionistshop'', ''exhibit''"><img <<$set_imgh>> src="images/pc/clothing/9exhibit/<<i>>.jpg" 	height="250" /></a>'
			elseif clothingfilter_too_daring = 0 and CloExhibit > pcs_exhibition:
				if (clothingfilter_prost = 0 or CloStyle ! 4) and (clothingfilter_bimbo = 0 or CloBimbo = 0): *p '<a href="exec: i = <<i>> & gt ''exhibitionistshop'', ''exhibit''"><img <<$set_imgh>> src="images/pc/clothing/9exhibit/<<i>>.jpg" 	height="250" /></a>'
			end
		end
		i += 4
	if i <= 57:jump 'loopexhibit'
end

if $ARGS[0] = 'exhibit':
	cla
	
	if exhibit[i] ! 0:
		msg 'You already own these clothes.'
		gt 'exhibitionistshop', 'clo'
	end

	gt 'clothing', 'view_clothing_item', 'shop', 'exhibit',i, 1000
end

if $ARGS[0] = 'panties':
	$metka = 'panties'
	$loc = 'exhibitionistshop'
	cls
	gs'stat'

	act 'Return':
		cla
		minut += 5
		gt 'exhibitionistshop', 'start'
	end

	i = 2

	:loopexhibitionist_panties
		if exhibitionist_panties[i] = 0:*p '<a href="exec: i = <<i>> & gt ''exhibitionistshop'', ''panties2''"><img src="images/pc/panties/exhibitionist/<<i>>.jpg" height="150" /></a> '
		i += 1
	if i <= 59:jump 'loopexhibitionist_panties'
end

if $ARGS[0] = 'panties2':
	cla
	
	if exhibitionist_panties[i] ! 0:
		msg 'You already own these panties.'
		gt 'exhibitionistshop', 'panties'
	end

	gt 'panties', 'view_panty_item', 'shop', 'exhibitionist',i, 600

end

if $ARGS[0] = 'bras':
	$metka = 'bras'
	$loc = 'exhibitionistshop'
	cls
	gs'stat'

	act 'Return':
		cla
		minut += 5
		gt 'exhibitionistshop', 'start'
	end

	i = 2

	:loopexhibitionist_bras
		if exhibitionist_bras[i] = 0:*p '<a href="exec: i = <<i>> & gt ''exhibitionistshop'', ''bras2''"><img src="images/pc/bras/exhibitionist/<<i>>.jpg" height="150" /></a> '
		i += 1
	if i <= 37:jump 'loopexhibitionist_bras'
end

if $ARGS[0] = 'bras2':
	cla
	
	if exhibitionist_bras[i] ! 0:
		msg 'You already own these bras.'
		gt 'exhibitionistshop', 'bras'
	end

	gt 'bras', 'view_bra_item', 'shop', 'exhibitionist',i, 600

end


--- exhibitionistshop ---------------------------------