glife/locations/zaprF

# zaprF

if $ARGS[0] = 'start':

	$metka = 'start'
	$loc = 'zaprF'
	$location_type = 'public_outdoors'
	cla
	*clr
	minut += 5
	gs 'stat'
	'<center><b>Gas Station</b></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/gas/zapr.jpg"></center>'
	'The local gas station, the cheap pumps are limited in functionality and will always fill the tank up completely.'
	*nl
	'When the weather is nice sometimes girls will offer a car washing service for some tips, there''s no structure to it so you could always try it.'
	'The petrol price is 30 <b>₽</b> per liter.'
	*nl

	if hour < 9:
		'It''s too early to wash cars.'
	elseif hour > 19:
		'It''s too late to wash cars.'
	else
		act 'Wash car windows (1:00)':gt 'zaprFWash', 'start'
	end
	act 'Go to the toilet':gt 'zaprF', 'toilet'

	if car > 0:
		if cardrive = 6 or cardrive = 21:'Your <a href="exec:GS ''carF'', ''start''"><<$car>></a> is parked here.'
	end

	zprbenz = 40 - benz

	if benz < 40 and car > 0 and cardrive = 6 or benz < 40 and car > 0 and cardrive = 21:
		zprbenz = 40 - benz

		if zprbenz * 30 <= money:
			act 'Fill the tank with petrol':
				cla
				*clr
				benz = 40
				zprpay = zprbenz * 30
				money -= zprpay

				! WD: Uninitialised ~ 'pol'
				! if pol > 0:'<center><img <<$set_imgh>> src="images/locations/shared/gas/zapr1.jpg"></center>'

				'<center><img <<$set_imgh>> src="images/locations/shared/gas/zapr1.jpg"></center>'

				'You filled the tank and paid <<zprpay>> <b>₽</b>.'

				act 'Disengage from the pump':gt 'zaprF', 'start'
			end
		else
			'You do not have enough money to refuel.'
		end
	end

	if car > 0:
		act 'Buy a canister able to contain up to 5 liters of gasoline for 150 <b>₽</b>':
			cla
			kanistra += 1
			money -= 150
			'You bought a canister of gasoline. (It was automatically put in the trunk)'

			act 'Disengage from the pump':gt 'zaprF', 'start'
		end
	end

	act 'Leave':
		if cardrive = 6:
			gt 'nord'
		elseif cardrive = 21:
			gt 'pavCommercial'
		elseif litltown = 0:
			gt 'nord'
		elseif litltown = 1:
			gt 'pavCommercial'
		end
	end
end

if $ARGS[0] = 'toilet':
	CLOSE ALL
	if night_mode = 1:
		fcolor = rgb(255, 255, 255)
		bcolor = rgb(0, 0, 0)
		lcolor = rgb(106, 90, 205)
	else
		fcolor = rgb(0, 0, 0)
		bcolor = rgb(255, 255, 255)
		lcolor = rgb(106, 90, 205)
	end
	cla
	*clr
	$locM = 'zaprF'
	$metka = 'toilet'
	$metkaM = 'toilet'
	$loc = 'zaprF'
	$location_type = 'bathroom'
	$gt1 = 'zaprF'
	$gt2 = 'toilet'
	minut += 2
	gs 'stat'

	'<center><h4>Gas station toilet</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/bathroom/toilet.jpg"></center>'
	'You are in a dirty gas station toilet. At least it provides some privacy.'

	act 'Look in the mirror':
		cla
		gt 'portmirror', 'start'
	end

	if pcs_hairbsh = 0:
		act 'Brush your hair': gt 'portmirror', 'brush'
	end

	if (cumloc[6] = 1 or cumloc[7] = 1):
		act 'Wipe the cum off your clothes (0:10)':
			cla
			*clr
			cumspclnt = 6
			gs 'cum_cleanup'
			minut += 10
			'<center><img <<$set_imgh>> src="images/shared/sex/cum/frotsp.jpg"></center>'
			'You spend ten minutes wiping and rinsing the cum stains out of your clothes. In the end, all that remains of the stains are some damp spots that should dry up in a few minutes.'

			act 'Continue':gt 'zaprF', 'toilet'
		end
	end

	dynamic $tampon
	dynamic $quickwash
	dynamic $basin

	act 'Leave the restroom':gt 'zaprF', 'start'
end

--- zaprF ---------------------------------