glife/locations/pushkin_parks.qsrc

# pushkin_parks
!!2021/05/12

if $ARGS[0] = 'start':
	*clr & cla
	$location_type = 'public_outdoors'
	gs 'shortgs', 'setloc', 'pushkin_parks', 'start'
	$region = 'pushkin'
	$locclass = 'city_park'
	menu_off = 0
	gs'stat'
	'<center><B>Pushkin Town Park</B></center>'
	'<center><img <<$set_imgh>> src="images/locations/pushkin/park/parkus.jpg" ></center>'
	'The gardens of the old palace have been sculpted over many years into a wonder landscape with a tranquil atmosphere.'
	'The Pushkin Park is a must-see for tourists and servers as the main attraction of Pushkin.'

	'Wander deeper into the <a href="exec:gt ''pushkin_parks'', ''lug''">park</a>.'


	act 'Go to Okhlopkov Square (0:05)': minut += 5 & gt 'pushkin_sq'

	act 'Go to Town Center (0:10)': minut += 10 & gt 'pushkin'

	act 'Walk around the park (1 hour)':
		if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1', 1
		cla
		minut += 60
		pcs_mood += 10
		gs'stat'
		'You leisurely stroll through Pushkin Park, breathing in the fresh air, and reflecting on the vicissitudes of fate.'

		act 'Complete outing.':gt 'pushkin_parks','start'
	end

	gs 'park_walkevents', 'run'

	if hour >= 20 or hour < 6 :
		if func('homes_properties', 'has_access', 'old_town_apartment') = 0 :
			!nowhere to live in town
			'It''s quite dark now, and you have no where to stay nearby. Maybe you should try to sleep on a bench?'
		else
			'It''s quite dark now, and you don''t feel like walking. Maybe you should try sleeping on a bench?'
		end
		act 'Sleep on a bench': gt'placer_sex','sleeping_park_bench'
	end

	act 'Sit down on the bench':gs 'placer_sex', 'sitting_park_bench'
	
	if mc_inventory['joints'] > 0 and drugVars['weed_high'] = 0: act 'Smoke a joint': minut += 10 & gs 'drugs', 'joint' & gt $loc, $loc_arg

	if pcs_inhib >= 35 or exhibitionist_lvl > 0:
		act 'Flash your tits':
			menu_off = 1
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			inhib_exp += rand(1,3)
			gs 'flash', 'tits', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pushkin_parks', 'start'
		end
	end

	if exhibitionist_lvl > 1:
		act 'Flash your pussy':
			menu_off = 1
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			gs 'flash', 'pussy', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pushkin_parks', 'start'
		end
	end
end

if $ARGS[0] = 'lug':
	$location_type = 'public_outdoors'
	gs 'shortgs', 'setloc', 'pushkin_parks', 'lug'
	$region = 'pushkin'
	$locclass = 'city_park'
	menu_off = 0
	gs'stat'
	'<center><img <<$set_imgh>> src="images/locations/pushkin/park/lug.jpg" ></center>'
	'It''s a small but well maintained meadow with evergreen grass, perfect for laying down to rest, have a picnic or just sunbathe. Mothers with small children regularly visit this place. Despite that, if you feel like exposing yourself here, there would be less people to see it, making it easier to find the bravery to do so.'

	streetrand = RAND(0,100)
	if streetrand >= 60 and pcs_lover < 3:
		vnerand = RAND(0,300)
		if vnerand <= pcs_apprnc:
			gs'boygirl', 0
			'<<$REPLACE($boybody_pref, "a", "A")>>, <<$boybod>>, <<$boyface>> haired guy comes up to you. He is wearing <<$boyClo>>'
			'The guy introduces himself as <<$boydesc>> and asks for your telephone number.'

			act 'Tell him your number':
				cla
				gs 'boyfrend', 'start'
				stopboy = 0
				'<<$boydesc>> thanks you and leaves.'
				act 'Complete outing': gt 'pushkin_parks', 'lug'
			end
		end

	end


	if pavserhom = 0 and psiha = 0 and func('homes_properties', 'has_access', 'city_apartment') = 0:
		temp = RAND(1,100)
		if temp >= 90:
			pcs_horny += 20
			gs'stat'
			'On the path stands a <a href="exec:dynamic $pavserjil">man</a> looking like he is waiting for someone.'
		end
	end

	gs 'kseniyaQW', 'events'

	if pcs_inhib >= 35:
		act 'Flash your tits':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			cls
			inhib_exp += rand(1,3)
			gs 'flash', 'tits', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pushkin_parks', 'lug'
		end
	end

	if exhibitionist_lvl > 0:
		act 'Flash your pussy':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			cls
			gs 'flash', 'pussy', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'pushkin_parks', 'lug'
		end
	end

	act 'Visit the pond':
		set minut += 10
		gt 'pushkin_parks', 'prut'
	end

	act 'Go toward the park entrance':
		set minut += 5
		gt 'pushkin_parks', 'start'
	end
	
	gs 'events', 'street_cum'
end


if $ARGS[0] = 'prut':
	cls
	gs 'shortgs', 'setloc', 'pushkin_parks', 'prut'
	gs 'stat'
	$location_type = 'public_outdoors'

	'<center><B>Park Pond</B></center>'
	'<center><img <<$set_imgh>> src="images/locations/pushkin/park/prut.jpg" ></center>'
	'A large and pretty pond near the end of the park, it continues off in to a wooded area.'


	act 'Explore the wooded area':
		set minut += 10
		gt 'pushkin_parks', 'prut2'
	end

	act 'Return to the small meadow':
		set minut += 10
		gt'pushkin_parks', 'start'
	end
end

if $ARGS[0] = 'prut2':
	cls
	gs 'shortgs', 'setloc', 'pushkin_parks', 'prut2'
	$region = 'pushkin'
	gs 'stat'
	$location_type = 'public_outdoors'

	'<center><B>Woodland Pond</B></center>'
	'<center><img <<$set_imgh>> src="images/locations/pushkin/park/prut2.jpg" ></center>'
	'The pond is still and beautiful here and the trees offer some privacy, it feels quite magical.'
	'There is a large field beyond that is hidden from the tourist trail.'

	act 'Go to the field':
		set minut += 15
		gt 'pushkin_parks', 'luzhayka'
	end

	act 'Follow the pond back out of the woods':
		set minut += 10
		gt 'pushkin_parks', 'prut'
	end

	! Setup for teleport circle
	if tpKnown['PushkinPark'] = 1:
		act 'Enter the hidden circle of trees': gt 'treeCircle', 'PushkinPark'
	else
		act 'Investigate a mysterious copse of trees': gt 'treeCircle', 'PushkinPark'
	end

	if $start_type[1] ! 'nomagic' and rand (1, 4) <= pcs_magik and (hour <=6 or hour >=19):
		if knowsfairy < 1 and fairyskip = 0:
			$loc_arg = 'prut2'
			xgt 'MagEncounterFairy'
		elseif fairyskip = 0:
			act 'Go to where the Fairy may be': xgt 'MagEncounterFairy'
		end
	end

	if temper >= 15 and month >= 5 and month <= 9 and hour >= 6 and hour <= 20:
		if pcs_inhib > 30:
			act 'Strip off and skinny dip (1:00)':
				*clr & cla
				cumspclnt = 4
				gs 'cum_cleanup'
				minut += 60
				pcs_sweat = 10 + rand(0,4)
				pcs_mood += 5
				if pcs_stren < 30: gs 'exp_gain', 'stren', 1
				gs 'arousal', 'flash', 10, 'exhibitionism'
				gs 'clothing', 'strip_all'
				if pcs_horny >= 80 and pcs_inhib >= 60 and PCloPanties > 0:
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/secluded_beach/self/wetpussypants3.jpg"></center>'
					'AS you strip off. A couple of passing men do a double-take and pause a moment to look at your sopping wet panties, probably thinking about what is making you so excited. You don''t care about what they might say or think of you and carry on stripping.'
					'Once you are naked you play around and have fun in the pond, enjoying the feel of the warm water on your body. The clean pond water refreshes and invigorates you.'
				elseif pcs_inhib >= 60:
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/secluded_beach/dress/undressnudebeach.jpg"></center>'
					'Not caring if anyone is looking at you, you slowly take off your clothes. You peel off each item like a stripper. Soon, you are completely naked.'
					'You play around and have fun in the pond, enjoying the feel of the warm water on your naked body. The clean pond water refreshes and invigorates you.'
				else
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/secluded_beach/dress/undressnudebeach.jpg"></center>'
					'You quickly check to see if anyone is watching, and when you''re satisfied no one is paying you undue attention, you take off your clothes.'
					'You play around and have fun in the pond, enjoying the feel of the warm water on your naked body. The clean pond water refreshes and invigorates you.'
				end
				act'Get out and dressed':
					gs 'underwear', 'wear'
					gs 'clothing', 'wear_last_worn'
					gt 'pushkin_parks', 'prut2'
				end
			end
		else
			'It would be a good place for skinny dipping but you''re too worried about what people would think to do such a thing.'
		end
	end
end

if $ARGS[0] = 'luzhayka':
	cls
	gs 'shortgs', 'setloc', 'pushkin_parks', 'luzhayka'
	gs'stat'

	'<center><img <<$set_imgh>> src="images/locations/pushkin/park/luzhayka.jpg" ></center>'
	'A quiet hidden field that is well maintained but apart from the occasional grounds keeper you feel like it is all yours.'

	act 'Return to the woodland pond':
		set minut += 15
		gt 'pushkin_parks', 'prut2'
	end
end

--- pushkin_parks ---------------------------------