glife/locations/Zvereva_house_events.qsrc

# Zvereva_house_events
!!22/05/14 - Alaratt

!!christinaQW['bully'] - earned if you stand up for yourself or not - less then 50 is you standing up, more then 50 is you being meek - at a certain point these unlock the below options
!!christinaQW['pre_fight'] - 1 means you are preparing to fight her
!!christinaQW['fight'] - 1 means you fought and won, -1 means you lost and are now her plaything
!!christinaQW['pre_bm'] - 1 means you are searching for the blackmail material to use against her
!!christinaQW['blackmail'] - 1 means you have the blackmail and need to talk to her to initiate, 2 means you have her blackmailed and are mostly safe from her bullying
!!christinaQW['submit'] - 1 means you willingly submitted, stays at 0 if you lose the fight, for reference on how you became her pet
!!christinaQW['subpath'] - 1 means you are looking to become her pet, 2 means you are her new pet, 3 means you have seen shower events, more will come to increase this

if $ARGS[0] = 'Chris_walk_home':
	menu_off = 1
	gs 'stat'
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
	if christinaQW['subpath'] = 4:
		christinaQW['subpath'] = 5
		'"About time, bitch. Come on, lets go." She starts walking away at a brisk pace. You follow, making sure to stay at least one step behind her.'

		act 'Follow her':
			minut += 10
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/christina_home/front_door.jpg"></center>'
			'You follow her into the residential district of Pavlovsk, until you get to a large house about ten minutes from the school. Christina''s parents are obviously fairly wealthy, to own a house this size.'
			*nl
			'You enter the house behind her.'
			gs 'stat'
			act 'Listen to her':
				*clr & cla
				'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
				'"Ok, here are the rules you will follow, or I will '+iif(christinaQW['fight'] = -1, 'beat you black and blue. Again.','spank the absolute shit out of you.')+'"'
				*nl
				'"1. You will not speak unless spoken to, or otherwise given permission. When you do, you will either call me by name in the presence of others, or Mistress when we are alone."'
				*nl
				'"2. You will do anything I say. If I say clean, you will clean. If I say strip and lick my pussy, you will do it. No hesitation."'
				*nl
				'"3. If you meet my parents or brothers, you will be polite, demure, and discreet about anything and everything I do. Only Sly knows anything about my personal life. He is the youngest of my older brothers, and the only one who lives here with me, full time. My parents are almost always traveling for work, so you will only see them on special occasions."'
				*nl
				'"4. You will listen to Sly. His demands are usually pretty simple: suck his dick, spread your legs, that kind of thing. You don''t have to do everything he says, but if you annoy him, it better be for a damned good reason because he is the only member of my family I give a shit about."'
				*nl
				'"You may speak."'

				act 'I''m a lesbian':
					*clr & cla
					'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
					'Christina rolls her eyes. "Ugh. Of course you are. Sly gonna love that. Fine, Lina is his favorite toy anyway, but you better work extra hard to please me."'
					'"Yes, Mistress. Thank you. What about Lariska? Does she get him off?"'
					'"Jealous? ...No, not anymore, she refuses to touch him. Don''t ask me why, if he wasn''t my brother..." She stares off into space for a few moments before coming back to the conversation. "Anyway. Those are the rules, for now. Follow them, or else."'

					act 'Yes, Mistress':
						christinaQW['svet_lez_yes'] = 1
						gt 'Zvereva_house', 'chris_bedro'
					end
				end
				act 'Yes, Mistress': gt 'Zvereva_house', 'chris_bedro'
			end
		end
	else
		'"About time, bitch. Come on, lets go." She starts walking away at a brisk pace. You follow, making sure to stay at least one step behind her.'
		act 'Follow her':
			minut += 10
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/christina_home/front_door.jpg"></center>'
			'You follow her home and into her house, to her room.'
			gs 'stat'
			gt 'Zvereva_house', 'chris_bedro'
		end
	end
end

if $ARGS[0] = 'chris_shower':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
	'You find Christina in the shower. She hasn''t noticed you yet.'

	gs 'arousal', 'erotic_nudity', 5
	act 'Leave':
		gs 'arousal', 'end'
		gs 'stat'
		gt 'Zvereva_house', 'hallw'
	end
	act 'Join her':
		*clr & cla
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
		'Removing your clothes, you walk over to the glass door and softly clear your throat and wait to be noticed.'
		'When she sees you, she opens the door and says "Get in here, I need my back washed."'
		'You step inside, lather your hands in soap, and start washing her.'

		noShampoo = 1
		dynamic $showerdin
		pcs_horny += 10
		pcs_hairbsh = 1
		pcs_makeup = 1
		if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
		gs 'arousal', 'erotic_nudity', 20, 'lesbian'
		gs 'stat'
		act 'Finish the shower':
			gs 'arousal', 'end'
			gs 'stat'
			gt 'Zvereva_house', 'bathr'
		end
	end
end

--- Zvereva_house_events ---------------------------------