glife/locations/mey_home

# mey_home

*clr & cla
$metkaM = $ARGS[0]
$locM = $CURLOC
$metka = $ARGS[0]
$loc = $CURLOC
FColor = RGB(0,0,0)
BColor = RGB(255,255,255)
LColor = RGB(106,90,205)
$location_type = 'indoors'
!! a crutch for the action in the kitchen
if val($args[0]) > 0: args[0] = val($args[0])
!! check for availability
if args[0] < 0:
	$_str[0] = 'No time to walk-in guests...'
	$_str[1] = 'You walked up to the Meynolds residence and rang the doorbell...'
	$_str[2] = 'No one opens the door, you notice nobody''s home.'
	$_str[3] = 'After a short wait, you hear the lock click and you see Katja''s mom Kathy and sister Vicky standing by the door: <br><do>Oh hi, <<$pcs_nickname>>, welcome! Come in, make yourself at home.</do>'
	$_str[4] = 'Katja opens the door and quickly drags you to her room.'
	$_str[5] = 'You opened the door with the key and entered the house.'

	if mey_vika['key'] = 1:
		$_str[5]

		act 'Enter': gt 'mey_home', 0
		exit
	end

	if hour < 20 and ((week < 6 and hour >= 17) or (week >= 6 and hour > 10)):
		if mey_vika['mey_vika_qw'] >= 27:
			if mey_vika['mey_vika_qw'] = 27: gt 'mey_tamara_events', 'next_meet'
			i = 3
		else
			i = 2
		end
		if i = 2:
			cla
			$_str[1]+ '<br>' +$_str[4]

			act 'Go to Katjas room': 
				if frost > 0: frost = 0 
				gt 'KatjaHomeTalk'
			end
			exit
		end
		if i = 3:
			'<center><img src="images/locations/pavlovsk/resident/meynolds/tamara_tea1.jpg"></center>'
			$_str[1]+ '<br>' +$_str[3]

			act 'Enter': gt 'mey_home', 0
			exit
		end
	else
		'<center><img src="images/locations/pavlovsk/resident/meynolds/tamara_tea0.jpg"></center>'
		iif(hour < 10 or hour > 20,$_str[0],$_str[1]+ '<br>' +$_str[2])

		act 'Go back': minut += 10 & gt 'pavResidential'
		exit
	end
end

killvar '$_str'

mey_loc_id = args[0]
minut += 1
gs 'stat'
! ----- NAV array ----- !
$mey_desc[0+"_"+'name'] = 'Hall'
$mey_desc[1+"_"+'name'] = 'Kitchen'
$mey_desc[2+"_"+'name'] = 'Bathroom'
$mey_desc[3+"_"+'name'] = 'Guest Room'
$mey_desc[4+"_"+'name'] = 'Living-room'
$mey_desc[5+"_"+'name'] = 'Katja''s Room'
$mey_desc[6+"_"+'name'] = 'Vicky''s Room'
$mey_desc[7+"_"+'name'] = 'Tamara Mikhailovna''s Room'
$mey_desc[8+"_"+'name'] = 'Veranda'
$mey_desc[9+"_"+'name'] = 'The yard'

$mey_desc[0+"_"+'image'] = 'hall'
$mey_desc[1+"_"+'image'] = 'kitchen'
$mey_desc[2+"_"+'image'] = 'bathroom'
$mey_desc[3+"_"+'image'] = 'guestroom'
$mey_desc[4+"_"+'image'] = 'living-room'
$mey_desc[5+"_"+'image'] = 'katya_room'
$mey_desc[6+"_"+'image'] = 'vika_room'
$mey_desc[7+"_"+'image'] = 'tamara_room'
$mey_desc[8+"_"+'image'] = 'terrace'
$mey_desc[9+"_"+'image'] = 'courtyard'

$mey_desc[0+"_"+'text'] = 'A large and bright hall, this "hallway" stretches for quite a bit, you''ve never seen anything like this before! There is a mirror covering half of one of the walls. You see the kitchen from the hallway, there''s a big oval dining table. There are stairs leading to the second floor. You can also see two doors where the signs say "Toilet" and "Bathroom".'
$mey_desc[1+"_"+'text'] = 'The kitchen is huge and luxurious. It is decorated in a minimalist high-tech style. An oval dining room table standing in the middle of the room. The appliances are all hidden. The kitchen is sparkling clean.'
$mey_desc[2+"_"+'text'] = 'A spacious bathroom with a shower cubicle with glass door, toilet with bidet, and a large hot tub that occupies a big part of the bathroom, it feels more like a small pool.'
$mey_desc[3+"_"+'text'] = 'It feels and looks like a standard room in a hotel. There is a bed, a small wardrobe, a desk, bedsides the table hangs a mirror on the wall.'
$mey_desc[4+"_"+'text'] = 'Spacious room with a sofa and armchairs, on the wall hangs a large plasma TV, located next to the bookcase, and on the opposite side is the fireplace, from the hall there is access to a bright veranda, overgrown with grapes'
$mey_desc[5+"_"+'text'] = 'Katja''s room feels like someone is living there temporarily and will soon move out. The stuff in the room are in the perfect order, depicting the feeling off a "non-residential premise". There are numerous flowers in the pots on the windowsill, there are pots hanging on the walls and there are even plants in pots on the floor giving the room a greenhouse feeling. There is a computer desk in one of the corners, opposite of the bed. In another corner is a hidden wardrobe. Lastly a well hidden bookshelf can be seen in the room, but it is kinda hard to spot because of wildly overgrown plants.'
$mey_desc[6+"_"+'text'] = 'Vicky''s room is always in a mess. It''s clean, but everything is scattered all over the place. There are soft toys laying around in enormous quantities, and all the walls are plastered with posters of pop stars and film actors. There''s a laptop on the table by the window, it accidentally brings a sense of orderliness. The stacks of magazines resemble music speakers. The rooms centerpiece is the ginormous bed, next to it is a wardrobe. There''s a lone chair somewhere in the corner hidden under all the stuff.'
$mey_desc[7+"_"+'text'] = 'You would say Tamara Mikhailovna''s room resembles an office, if it was not for the bed in the corner. There''s a computer on a desk, a wardrobe, and a big but a pretty modest bed. The room is quite small and cramped. There are no decorations but one, a sword hanging on the wall. It''s unclear what it''s doing there.'
$mey_desc[8+"_"+'text'] = 'You can see the yard looking from the porch. The neighbors wiew is obscured by a high fence and braided grapes. There is a summer kitchen with a grill and a collection of wicker furniture, few chairs, a table and a sunbed mattress.'	
$mey_desc[9+"_"+'text'] = 'A car belonging to Tamara Mikhailovna is parked in the yard, there''s also a small pool.'

'<center><h4><font color="maroon">'+$mey_desc[mey_loc_id+'_'+name]+'</font></h4></center>'
'<center><img src="images/characters/pavlovsk/school/girl/meynolds/event/'+$mey_desc[mey_loc_id+"_"+'image'] + '.jpg"></center>'
$mey_desc[mey_loc_id+"_"+'text']

killvar '$mey_desc'
! ---------------------- !

! actions
if mey_loc_id = 0:
	act '<b>On the street</b>': killvar 'mey_loc_id' & gt 'pavResidential'
	act 'Patio': gt $curloc, 9
end
if mey_loc_id ! 0: act 'Hallway': gt $curloc, 0
if mey_loc_id ! 1: act 'Kitchen': gt $curloc, 1
if mey_loc_id ! 2: act 'Bathroom': gt $curloc, 2
act '<center><img src="images/locations/pavlovsk/resident/meynolds/splitter.png" width=100% height=1></center>': exit
if mey_loc_id ! 3: act 'Guest room': gt $curloc, 3
if mey_loc_id ! 4: act 'Hall': gt $curloc, 4
if mey_loc_id = 4: act 'Veranda': gt $curloc, 8
if mey_loc_id ! 5: act 'Katja''s room': gt $curloc, 5
if mey_loc_id ! 6: act 'Vicky''s room': gt $curloc, 6
if mey_loc_id ! 7: act 'Tamara Mikhailovna''s room': gt $curloc, 7

! corporate only at the end of the month on weekends, check
if day <= 25 and mey_vika['mey_vika_qw'] > 40: mey_vika['mey_vika_qw'] = 40

if mey_loc_id = 2: 
	!bathroom
	*clr & cla
	minut += 1
	gs 'stat'
	$location_type = 'bathroom'	
	'<center><b><font color = maroon></font></b></center>'
	'<center><img src="images/locations/pavlovsk/hotel/hotel.room.best1.jpg"></center>'
	'A luxurious bathroom looking like the five-star hotel bathrooms you read about in the magazines.'	
	!acts copy from [shulgabath]
	act 'Return to the hallway': gt $loc, $metka

	dynamic $shower
	dynamic $bteeth
	dynamic $tampon
	dynamic $quickwash
	dynamic $wearpan
	dynamic $basin

	if spdirtyc > 0:
		act 'Clean semen stains from your clothing':
			cls
			cumspclnt = 6
			gs 'cum_cleanup'
			minut = minut + 15
			gs'stat'

			'<center><img src="images/shared/sex/cum/frotsp.jpg"></center>'
			'You take fifteen minutes to thoroughly rinse the semen stains from your clothes. By the time you''re done, all that remains are some moist spots.'
			act 'Finish': gt 'shulgabath', 'start'
		end
	end

    if klisma = 1 and (klismaday ! daystart or arrpos('sparrloc', 3) ! -1):
		act 'Give yourself an enema (0:05)':
			cla
			*clr
			cumspclnt = 7
			gs 'cum_cleanup'
			minut += 5
			klismaday = daystart
			klismaday1= 1
			'<center><img src="images/shared/home/bathroom/klisma.jpg"></center>'
			'You give yourself an enema, feeling clean down there. Your ass is now ready for anal sex without any awkward surprises.'
			act 'Finish':gt 'shulgabath', 'start'
		end
	end

	if analplug = 1 and analplugin = 1:
		act 'Take out your butt plug (0:05)':
			cla
			*clr
			minut += 5
			analplugIN = 0
			if pcs_ass < 30:pcs_ass += 1

			'<center><img src="images/pc/body/analplug.jpg"></center>'
			'You squat and tug gently at the butt plug. You gasp as you push it out of you. You can''t help but feel a bit empty, now that it''s out.'
			act 'Finish':gt 'shulgabath', 'start'
		end
	elseif analplug = 1 and analplugin = 0 and klismaday = daystart:
		act 'Wear your butt plug (0:05)':
			cla
			*clr
			minut += 5
			analplugIN = 1
			if pcs_ass < 10:pcs_ass = pcs_ass + 5
			if pcs_ass >= 10 and pcs_ass < 20:pcs_ass += rand(1, 2)
			if pcs_ass >= 20 and pcs_ass < 30:pcs_ass += rand(0, 1)

			'<center><img src="images/pc/body/analplug.jpg"></center>'
			if butpluguse > 0:'You squat and gently rub the butt plug against your anus, after lubricating it with a bit of saliva. After a short while, you''ve relaxed your anus enough to be able to push it in. Once it''s in you give it a few gentle tugs, wondering if anyone will catch you wearing it today.'
			if butpluguse = 0:butpluguse = 1 & '"If I''m not going to use it, then why did I buy it?" you ask yourself. You look at the butt plug for a while, thinking "It is necessary to gape my anus, so I can enjoy a great adventures someday... It will probably be a huge and thick adventure with a crimson head, uh, I''m gettting carried away..." You''re slightly embarrassed at the thought for a second, but get even more determined by your horny fantasies. Determined to get the plug all the way in, you slowly press it against your anus after lubricating it with a bit of saliva. It hurts a bit at first, but once the thickest part is in the rest follows rather easily. Patting yourself on your ass once it''s in, you wonder if anyone will notice you''re wearing it today and then immediately feel naughty for even having thought that.'

			act 'Finish':gt 'shulgabath', 'start'
		end
	end

	if pregtest > 0:
		act 'Do a pregnancy test':
			cla
			pregtest -= 1
			gs 'stat'
			if pregchem > 120:
				knowpreg = 1
				thinkpreg = 1
				'The test shows the two stripes: you''re pregnant!'
			else
				knowpreg = 0
				'The test shows one stripe: you''re not pregnant.'
			end

			act 'Finish':gt 'shulgabath', 'start'
		end
	end

	if vibrator = 1 and vibratorIN = 1:
		act 'Remove the vibrator (0:05)':
			cla
			*clr
			minut += 5
			vibratorIN = 0
			if pcs_vag < 30:pcs_vag += 1
			'<center><img src="images/shared/accessories/toys/vibrator.jpg"></center>'
			'You spread your legs and take the vibrator out of your vagina, letting out a slight moan as you do so. You feel somewhat empty now.'
			act 'Finish':gt 'shulgabath', 'start'
		end
	elseif vibrator = 1 and vibratorIN = 0:
		act 'Insert the vibrator in your vagina (0:05)':
			cla
			*clr
			minut += 5
			vibratorIN = 1
			if pcs_vag < 30:pcs_vag += 2
			'<center><img src="images/shared/accessories/toys/vibrator.jpg"></center>'
			'You spread your legs and slowly insert the vibrator in your vagina, wondering if anyone will notice you wearing it today.'
			act 'Finish':gt 'shulgabath', 'start'
		end
	end
end

! hall
if mey_loc_id = 0:
	if mey_vika['mey_vika_qw'] = 30 and mey_vika['qw_day'] ! daystart and hour = 23: gs 'mey_vika_events', 'case_gift'
	if week mod 2 ! 0 and mey_vika['mey_vika_qw'] >= 32 and mey_vika['gym_day'] ! daystart and hour = 16 and minut >= 30: gs 'mey_vika_events', 'gym0'
	if week mod 2 ! 0 and mey_vika['mey_vika_qw'] >= 32 and mey_vika['gym_day'] ! daystart and hour = 17 and minut >= 30: gs 'mey_vika_events', 'gym1'
	if mey_vika['mey_vika_qw'] >= 32 and mey_vika['mey_vika_qw'] < 35 and mey_vika['qw_day'] ! daystart and hour >= 23: gs 'mey_vika_events', 'learning0'

	if mey_vika['mey_vika_qw'] >= 32:
		! welcome to the corporate
		if week = 7 and hour >= 12 and hour <= 16 and day > 25 and mey_vika['mey_vika_qw'] = 40 and mey_tamara['qw_end'] = 0 and pav_slut < 75:
			gt 'mey_tamara_events', 'party0'
		end
		! check appearance before going to corporate
		if (hour = 17 or hour = 18) and mey_vika['mey_vika_qw'] = 41:
			'<br><a href="exec: gt''mey_tamara_events'',''check_look''">Tamara Mikhailovna.</a> is waiting for you in the lobby.'

			exit
		end
		
		! need to fuck Katja!
		if KatjaSex >= 5 and mey_vika['mey_vika_qw'] > 35 and hour = 23 and mey_vika['mey_vika_bang_qw'] = 0:
			gs 'mey_vika_events', 'bang_katya'
			exit
		end
		
		! Vic calls in the shower
		if mesec = 0 and pcs_vag > 0 and mey_vika['bath_qw'] = 1 and mey_vika['bath_qw_day'] ! daystart and rand(0,10) > 5 and ((week < 6 and hour >= 16) or (week = 6 and hour >= 8)):
			gs 'mey_vika_events', 'bath_qw1'
			exit
		end
		
		if ((week < 6 and hour >= 16 and hour < 20) or (week = 6 and hour >= 10 and hour < 20)) and mey_tamara['help_day'] ! daystart:
			act 'Clean the house':
				cla
				mey_tamara['help_day'] = daystart
				mey_tamara['help_count'] += 1
				minut += rand(50,70)
				pcs_sweat += 3
				pcs_mood -= 5
				gs 'stat'
				if mey_vika['bath_qw'] = 0 and mey_vika['bath_qw_day'] ! daystart:
					gs 'mey_vika_events', 'bath_qw0'
				else
					'<br>You take out a hefty vacuum cleaner from the closet, and it takes you about an hour to vacuum the house.'

					act 'Finish': gt 'mey_home', 0
				end
			end
		end
	end
	if rand (0,2) ! 0:gs 'din_bad' & dynamic $mobile_check	
end

! kitchen
if mey_loc_id = 1:
	cla
	$loc = $curloc
	$metka = str(mey_loc_id)
	if mey_vika['mey_vika_qw'] >= 32 and ((week < 6 and hour >= 16 and hour < 20) or (week = 6 and hour >= 10 and hour < 20)) and mey_tamara['help_day'] ! daystart:
		act 'Cook for the whole family':
			cla
			mey_tamara['help_day'] = daystart
			mey_tamara['help_count'] += 1
			minut += rand(50,70)
			gs 'stat'
			'<br>You take out the food from the refrigerator, and start cooking for the whole family. It takes you about an hour to finish.'

			act 'Finish': gt 'mey_home', 0
		end
	end
	!copy acts from [gadhouse]
	act 'Eat a full meal (0:30)':gs 'food', 'm_meal'

	act 'Eat a light meal (0:20)':gs 'food', 's_meal'

	act 'Have a snack (0:15)':gs 'food', 'snack'

	act 'Have a cup of tea (0:05)':
		cls
		minut += 5
		water += 80
		cumspclnt = 2
		gs 'cum_cleanup'
		pcs_breath = 0
		pcs_mood += rand(1, 3)
		'You make a refreshing cup of tea and everything seems a little better.'

		gs 'stat'

		act 'Get up from the table':gt 'mey_home'
	end

	if pranik > 0:
		'You brought your <<pranik>> cookies with you.'

		act 'Drink tea with cookies (0:05)':
			cla
			*clr
			minut += 5
			pranik -= 1
			pcs_health += 30
			pcs_mood += 30
			pcs_energy += 20
			water += 20
			cumspclnt = 2
			gs 'cum_cleanup'
			pcs_breath = 0
			fat += 4
			frost = 0
			gs 'stat'
			'<center><img src="images/shared/food/food.jpg"></center>'
			'You enjoy a cup of tea while you eat some cookies. You know they''re too sweet and can''t be good for your figure, but they taste so good!'

			act 'Get up from the table':gt 'mey_home'
		end
	end

	if edaD > 0:
		act 'Eat diet food (0:30)':
			cla
			*clr
			frost = 0
			minut += 30
			pcs_health += 10
			pcs_mood += 20
			edaD -= 1
			'<center><img src="images/shared/food/food.jpg"></center>'
			if pcs_energy >= 100:
				'You prepare a diet meal and try to eat it, but you''re really not hungry at all. You can''t finish the meal.'
			elseif pcs_energy >= 80:
				pcs_energy += 40
				'You try to enjoy the diet meal, but half-way in you realize you weren''t all that hungry yet. You manage to finish the meal, but feel like it was kind of a waste to prepare it.'
			else
				pcs_energy += 80
				'The diet meal is tasty, and you enjoy eating it.'
			end

			if water >= 80:
				'You don''t need any more tea.'
			else
				water = 100
				cumspclnt = 2
				gs 'cum_cleanup'
				pcs_breath = 0
				'You have a cup of tea, quenching your thirst.'
			end

			act 'Get up from the table':gt 'mey_home'
		end
	end

	dynamic $fatdel

	if lekarstvo > 0:
		'You have <<lekarstvo>> tablet(s) left.'

		if sick > 0 and lekarday ! daystart:
			act 'Take a pill (0:05)':
				cla
				*clr
				minut += 5
				lekarday = daystart
				lekarstvo -= 1
				sick -= sick * 20 / 100
				if water < 50 : water += 30 else water +=15
				if water > 100: water = 100

				'<center><img src="images/locations/shared/apartment/event/sick/lekr<<picrand>>.jpg"></center>'
				'You swallow the pill, and shortly after you feel a bit better.'

				act 'Continue':gt 'mey_home'
			end
		end
	end

	if vitamin > 0:
		'You have <<vitamin>> vitamin pills left.'

		if vitaminday ! daystart:
			act 'Take vitamins (0:05)':
				cla
				*clr

				minut += 5
				vitaminday = daystart
				vitamin -= 1
				frost = 0
				if water < 50 : water += 30 else water +=15
				if water > 100: water = 100

				if KandidozOnce = 1:Kandidoz -= 2
				if GerpesOnce = 1:Gerpes -= 2
				if SifacOnce = 1 and Sifilis >= 10:Sifilis -= rand(0, 1)

				pcs_skin += 1

				'You take some vitamins to stay healthy.'

				act 'Continue':gt 'mey_home'
			end
		end
	end

	gs 'events', 'read'

	
	act 'Leave': gt 'mey_home', 0
	if rand (0,2) ! 0:gs 'din_bad' & dynamic $mobile_check
end

! guestroom
if mey_loc_id = 3:
	cla
	$loc = $curloc
	$metka = str(mey_loc_id)
	!add room function from [bedrpar]
	'A <a href="exec:gt ''mirror'', ''start''">mirror</a> hangs on the wall near the front door, besides that are the <a href="exec:gt ''cloakroom'', ''view_coat_list''">coat hooks</a>.'
	if komp = 1:'Your <a href="exec:GT ''Komp'',''start''">laptop</a> is on the desk.'
	
	act '<b>Go outside</b>':
		if ($clothingworntype = 'nude' or $clothingworntype = 'swimwear'):
			*clr
			'<center><img src="'+'images/pc/clothing/'+iif(tanga=0,'0','tanga')+'.jpg'+'"></center>'
			'<center><font color=red><b>You can''t go out dressed like this!</b></font></center>'
			exit
		end
		gt 'mey_home', 0
	end

	act 'Sleep': gs 'bed', 'start'		
	
	act 'Cabinet': gt 'clothing', 'view_clothing_list', 'wardrobe'

	gs 'exercise', 'start'

	if pcs_horny >= 50:	act 'Masturbate':gt 'selfplay'
	if pornMagazine > 0:
		'You hide your porn magazines under the mattress of your bed.'
		gs 'events', 'read_porn'	
	end
	
	gs 'events', 'read'
	
	if dur > 0 and narkday ! daystart:
		act 'Snort the White Lady (0:05)':
			cla
			*clr
			minut += 5
			narkday = daystart
			pcs_health = vital * 10 + pcs_stren * 5
			pcs_willpwr = pcs_intel * 5 + pcs_sprt * 5
			pcs_mood = 100
			pcs_horny = 100
			nark += 10
			dur -= 1
			'<center><img src="images/shared/drugs/dur.jpg"></center>'
			'You snort some White Lady, feeling dizzy for a moment. After that you feel fantastic, and incredibly horny.'

			act 'Continue':gt $curloc
		end
	end

	if tanga = 0:
		act 'Wear underwear':
			cla
			tanga = 1
			gt $curloc
		end
	elseif tanga = 1:
		act 'Take off your underwear':
			cla
			tanga = 0
			gt $curloc
		end
	end
	
	act 'Wait':
		cla
		waiting = input ("How long would you like to wait? (Not more than 120 minutes)")

		if waiting <= 0 or waiting > 120:
			minut += 15
		elseif waiting > 0 and waiting <= 120:
			minut += waiting
		end

		act 'Take a look at the clock':gt curloc
	end

	if rand (0,2) ! 0:gs 'din_bad' & dynamic $mobile_check	
end

! courtyard
if mey_loc_id = 9:
	if hour = 7 and minut >= 30 and week < 6:
		'<a href="exec:gs''mey_tamara_events'',''tamara''">Aunt Tamara</a> is in the yard talking on the phone.'

	end
end

if mey_loc_id = 5:
!add room katja
	cla
	$loc = $curloc
	$metka = str(mey_loc_id)
	if katjaFirstKiss >= 1:
		if hour >= 17 and week < 6 and kanikuli = 0 and hour < 20 or hour >= 9 and week >= 6 and kanikuli = 0 and hour < 20 or hour >= 9 and kanikuli > 0 and hour < 20:
			act 'Chat with Katja': gt'KatjaHomeTalk'
		end
	else
		'<font color=red>Your relationship with Katja is not good enough to just barge into her room, better leave as soon as possible.</font>'
	end
	act '<b>Out</b>': gt 'mey_home', 0
end

--- mey_home ---------------------------------