glife/locations/bedrPar2.qsrc

!! FOLDER: home_parents
# bedrPar2
!! Your parents' bedroom
!2021/04/26
if $ARGS[0] = '':
	CLOSE ALL
	*clr & cla
	$loc = 'bedrPar2'
	$loc_arg = ''
	$locclass = 'bedr'
	$location_type = 'private'
	$menu_loc = 'bedrPar2'
	$menu_arg = ''
	menu_off = 0
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'family_schedule'
	'<center><h1><font color="maroon">Master bedroom</font></h1></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/bedrpar2.jpg"></center>'
	*nl
	'The room in which your parents sleep. Their large bed, <a href="exec: gt ''bedrPar2'',''parents_wardrobe''">wardrobe</a> and other closets take up most of the space.'
	if locat['Fam_inGad'] = 0:
		if locat['Mother'] = 1 and locat['Stepdad'] = 1:
			'Your mother and stepfather are sleeping on the bed.'
		elseif locat['Mother'] = 1:
			'Your mother is sleeping on the bed.'
		elseif locat['Stepdad'] = 1:
			'Your stepfather is sleeping on the bed.'
		end
	end

	act 'Return to the hallway':gt 'korrPar'

	if locat['Fam_inGad'] = 1 or (locat['Fam_inGad'] = 0 and hour > 6 and hour < 21):
		if kamasutra_day ! daystart:
			'You notice a <a href="exec: gt ''bedrPar2'',''kamasutra''">book laying on the bed</a>.'
		end
		if prezikday ! daystart:
			if prezikProver >= 3:
				prezikday = daystart - 4
				act 'Steal condoms from your parents'' stash':
					*clr & cla
					menu_off = 1
					minut+= rand(5,7)
					gs 'stat'
					if preziktype = 0: prezik += rand(1,3)
					if preziktype = 1 or preziktype = 2: prezikcount += rand(1,3)
					prezikday = daystart
					prezikProver = 0
					'<center><img <<$set_imgh>> src="images/pc/items/accessories/birthcontrol/condoms_steal.jpg"></center>'
					'After you make sure you''re not seen, you quickly search your parents'' room for their condom stash and take a few. You now have '+iif(preziktype = 0, '<<prezik>>', '<<prezikcount>>')+' condoms.'
					act 'Continue': gt 'bedrPar2'
				end
			end
		end
	end
end

! book
if $ARGS[0] = 'kamasutra':
	*clr & cla
	menu_off = 1
	minut += 1
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/book.jpg"></center>'
	'The cover says "Kama Sutra"'
	act 'Leave': gt $loc, $loc_arg
	act 'Read': kamasutra_page = 0 & kamasutra_day = daystart & gt 'bedrPar2', 'read_book'
end

! read book
if $ARGS[0] = 'read_book':
	*clr & cla
	menu_off = 1
	pcs_horny += 2
	minut += 3
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/kamasutra/ik' + kamasutra_page + '.jpg"></td></tr><tr><td align=center>'+iif(kamasutra_page < 1, '', '<a href="exec: kamasutra_page-=1 & gt''bedrPar2'',''read_book''"><br>Previous page</a>')+'</td><td align=center>'+iif(kamasutra_page > 45, '', '<a href="exec: kamasutra_page+=1 & gt''bedrPar2'',''read_book''"><br>Next page</a>')+'</center>'
	act 'Close the book': gt $loc, $loc_arg
	if pcs_horny >= 60 and week = 6 and family_trip = 1: act 'Masturbate': gt 'selfplay', 'start'
end

! parent''s wardrobe
if $ARGS[0] = 'parents_wardrobe':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/wardrobe.jpg"></center>'
	'An old looking wardrobe, probably from the Soviet times.'
	act 'Leave ': gt $loc, $loc_arg
	act 'Rummage': gt 'bedrPar2', 'wardrobe_search'
end

if $ARGS[0] = 'wardrobe_search':
	*clr & cla
	if locat['Fam_inGad'] = 0 and (locat['Mother'] = 1 or locat['Mother'] = 3 or locat['Stepdad'] = 1 or locat['Stepdad'] = 2):
		'What are you thinking? You can''t go through the wardrobe while your parents are in the room!'
		act 'Leave ': gt $loc, $loc_arg
		exit
	end
	if rand(1,100) > 75:
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/wardrobesearch'+rand(1,4)+'.jpg"></center>'
		$failwords[0]= 'You don''t find anything interesting.'
		$failwords[1]= 'You find some clothes and underwear.'
		$failwords[2]= 'You dig through your mother''s closet, but find nothing interesting except underwear.'
		*pl $failwords[rand(0,2)]
		killvar '$failwords'
	else
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/wardrobetoy.jpg"></center>'
		$findmomtoy[0]= 'Digging through the closet, you find a <a href="exec: gt ''bedrPar2'',''momtoy_play''">dildo</a>.'
		$findmomtoy[1]= 'Rummaging through your mother''s lingerie, you find a small <a href="exec: gt ''bedrPar2'',''momtoy_play''">dildo</a>.'
		$findmomtoy[2]= 'You find your mother''s <a href="exec: gt ''bedrPar2'',''momtoy_play''">toy</a>.'
		*pl $findmomtoy[rand(0,2)]
		killvar '$findmomtoy'
	end
	act 'Close the cabinet': gt $loc, $loc_arg
end

if $ARGS[0] = 'momtoy_play':
	*clr & cla
	menu_off = 1
	dildo = 1
	dildohand = 10
	selfmomtoyplay = 1
	'<center><img <<$set_imgh>> src="images/shared/sex/mast/start.jpg"></center>'
	if pcs_horny < 70:
		act 'Put it back': gt $loc, $loc_arg
	else
		act 'Play with it': gt 'selfplay', 'start'
	end
end

if $ARGS[0] = 'peek':
	cla & *clr
	parentsexday = daystart
	minut += 2
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/mom/sex/momvlad1.jpg"></center>'
	'You crack the door open just a little and you see your mother and Vladimir near their bed. "Stop! The kids are here," your mother says as Vlad starts running his hands over her body.'
	'He doesn''t seem to care about what she says as he doesn''t stop. "Come on, they won''t hear us and you know you want it."'
	act 'Leave': gt 'korrPar'

	act 'Keep peeking':
		cla & *clr
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/mom/sex/momvlad2.jpg"></center>'
		'You mother seems to be loving the attention and doesn''t put up much of a fight as he starts to undress her. Once she''s mostly naked, he pushes her down on the bed so she''s sitting on it in front of him, her head about crotch height to him. Knowing what he wants, she opens the fly on his pants and pulls out his cock, stroking it a few times in her hand until he gets hard. She then takes his dick into her mouth and starts sucking it. He moans softly as she does. "Fuck, you''re the best cocksucker ever, Natasha."'
		gs 'arousal', 'voyeur_sex', 3
		gs 'stat'

		act 'Leave': gt 'korrPar'

		act 'Keep peeking':
			cla & *clr
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/mom/sex/momvlad3.jpg"></center>'
			'After spending several minutes sucking Vlad''s cock, she helps him strip while continuing to suck his dick. Once he''s naked, he lies down on the bed and she straddles him and quickly starts riding his dick reverse cowgirl style.'
			'Both of them start moaning as they fuck. "Oh god Vlad, your dick feels so good in my pussy! It''s so big!"'
			gs 'arousal', 'voyeur_sex', 5
			gs 'stat'

			act 'Leave': gt 'korrPar'

			act 'Keep peeking':
				cla & *clr
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/mom/sex/momvlad4.jpg"></center>'
				'Vlad suddenly grabs her and throws her on her side on the bed. He turns on his side, lifting up her leg with one hand while using the other to guide his cock. He feels around until he places the head of his dick against her anus, then pushes it in, using only her pussy juices for lubrication. It slides in surprisingly easy and you can only guess that this is far from the first time your mother has had a dick in her ass. They both moan in pleasure and she rubs her clit as Vlad fucks her ass.'
				gs 'arousal', 'voyeur_sex', 5
				gs 'stat'
				act 'Leave':gt 'korrPar'

				act 'Keep peeking':
					cla & *clr
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/mom/sex/momvlad5.jpg"></center>'
					'They keep going for several more minutes until Vlad starts to pant and buries his dick balls deep in your mother''s ass and lets out a loud moan as he twitches. After a few seconds, he pulls out of her and rolls off the bed as she gets on her back and spreads her ass, giving both you and Vlad a good view of her asshole as his cum starts leaking out of it.'
					'"You''re such a nasty bitch, Natasha!" he laughs.'
					'She smiles at him. "That''s why you love me," she replies. They start getting cleaned up and you decide it''s time to go before you get caught.'
					gs 'arousal', 'voyeur_sex', 3
					gs 'stat'
					act 'Leave': gt 'korrPar'
				end
			end
		end
	end
end

--- bedrPar2 ---------------------------------