glife/locations/vokzaltorg.qsrc

# vokzaltorg
cls
minut += 30
prodskill = pcs_apprnc/4 + pcs_sprt + pcs_dom

if prodskill < 20:prodskill = 20
if prodskill > 150:minimumtov = 3
if prodskill > 100 and prodskill <= 150:minimumtov = 2
if prodskill < 100:minimumtov = 1

tovarand = rand(minimumtov, prodskill / 10)

if tovarand > tovarL:tovarand = tovarL

tovpay = tovarand * 300
money += tovpay
tovarL -= tovarand
sprt_exp += rand(0, 1)
TorgVokzalTimes += 1
pcs_dom += 1
gs 'stat'
'<center><img <<$set_imgh>> src="images/locations/pavlovsk/market/peron.jpg"></center>'
'You manage to sell <<tovarand>> trinkets to passengers today, while earning <<tovpay>> <b>₽</b>.'

act 'Leave':
	cls
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/katalkin/katalkin.jpg"></center>'
	if pcs_intel + pcs_prcptn > 80 and rand(0,5) = 5:
		'Two police officers had been keeping an eye on you while you were trying to sell your goods, and when you move to leave the platform they move to intercept you, but you time your leaving with a large group of students and hide yourself amongst them. The police officers get caught up in the crowd and your route clear opens up.'

		act 'Leave':minut += 1 & gt 'vokzalGin'
	exit

	else
		'Two police officers had been keeping an eye on you while you were trying to sell your goods, and when you move to leave the platform they approach you. Captain Katalkin says: "Excuse me miss, we saw you were attempting to sell items to passengers. Do you have the proper permits for that? We need to see your papers."'
	end

	if money >= 500:
		act 'Bribe them (500 <b>₽</b>)':
			cls
			money -= 500
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/katalkin/katalkin.jpg"></center>'
			'You smile at them: "Permits, officer? Of course I have the permits, one moment..."'
			'You look around and, when you''re sure the coast is clear, stick out your hand with a 500 <b>₽</b> note in it.'
			'The police officers smile at you and quickly take the money before they walk away: "I see everything''s in order. Have a nice day, miss."'

			act 'Leave':minut += 1 & gt 'vokzalGin'
		end
	end

	act 'Beg him to forgive you':
		cls
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/katalkin/katalkin.jpg"></center>'
		'You show him your best innocent face and say: "Please sir, times are tough! I''ll get the permit, I''m sorry! Please let me go, I promise it won''t happen again!"'

		if katalkinSexOnce = 0:
			schtraf = 500
			'Captain Katalkin grins at you: "We''ll see... come with me to the police station, we''ll have to have a little chat about this."'

			act 'Go to the police station':minut += 5 & katalkinNoexit = 1 & gt 'katalkin'
		else
			if katalkinSexDay+7 >= daystart:
				'Captain Katalkin recognizes you and grins, remembering his recent adventures with you: "You again? Well okay, go on then, run along."'

				act 'Thank him and leave':minut += 1 & gt 'vokzalGin'
			elseif katalkinSexDay + 7 < daystart:
				'Captain Katalkin suddenly recognizes you and frowns: "<<$pcs_nickname>>? You haven''t come to see me in a long time... I thought we had an agreement. Are you avoiding me?"'

				act 'No you haven''t!':
					cls
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/katalkin/katalkin.jpg"></center>'
					'You blurt out a mixture of protests and apologies: "No sir! I''ve just been busy, that''s all... I''m sorry."'
					'Captain Katalkin''s face brightens: "We can fix that. You''re coming with me to the police station now. I think I need to perform a thorough cavity search, to make sure you''re not smuggling anything."'
					'He firmly puts his hand on your shoulder, and begins to walk towards the police station.'

					act 'Blush and let him guide you':minut += 5 & katalkinNoexit = 1 & gt 'katalkin'
				end
			end
		end
	end

	act 'Admit you have no permit':
		cls
		money = 0
		tovarL = 0
		minut += 120
		pcs_mood = 5
		gs'stat'

		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/katalkin/katalkin.jpg"></center>'
		'You decide to come clean to them, and admit you don''t have the required papers. The policemen do what you expected. They take you to the police station and confiscate all of your money and items, even the money that you didn''t earn by selling souvenirs. You try to object, but they don''t listen and tell you you''re lucky to not end up in jail for this. After two hours and a stern talking-to about the importance of permits, you''re free to go. You feel terrible.'

		act 'Leave the police station':minut += 1 & gt'vokzalGin'
	end
end

--- vokzaltorg ---------------------------------