# grandmahelp

menu_off = 1
gs 'stat'

frost = 0

'<center><img <<$set_imgh>> src="images/locations/gadukino/village/grandmahelp.jpg"></center>'

'You ask your grandmother if there is anything you could help out with. Your grandmother turns to you and says:'

if $ARGS[0] = 'start':
	if month <= 4 or month >= 10:
		grandmaQW['chore_type'] = rand(0,6)
	elseif month = 5:
		grandmaQW['chore_type'] = rand(0,9)
	elseif month >= 6 and month <= 9:
		grandmaQW['chore_type'] = rand(0,14)
	end

	if grandmaQW['chore_type'] = 0:
		gt 'grandmahelp', 'cleanfloor'
	elseif grandmaQW['chore_type'] = 1:
		gt 'grandmahelp', 'washclothes'
	elseif grandmaQW['chore_type'] = 2 and hour < 9 and hour > 20:
		gt 'grandmahelp', 'milkcows'
	elseif grandmaQW['chore_type'] = 3:
		gt 'grandmahelp', 'groceries'
	elseif grandmaQW['chore_type'] = 4 and boletus_stored >= 5:
		gt 'grandmahelp', 'can_mushrooms'
	elseif grandmaQW['chore_type'] = 5 and bilberry_stored >= 5:
		gt 'grandmahelp', 'can_berries'
	elseif grandmaQW['chore_type'] = 6 and grandmaQW['chore_harvest_done'] = 1:
		gt 'grandmahelp', 'can_veggies'
	elseif grandmaQW['chore_type'] = 7:
		gt 'grandmahelp', 'feedchickens'
	elseif grandmaQW['chore_type'] = 8 and sunWeather = 1:
		gt 'grandmahelp', 'checkplants'
	elseif grandmaQW['chore_type'] = 9 and sunWeather = 1:
		gt 'grandmahelp', 'waterplants'
	elseif grandmaQW['chore_type'] = 10 and sunWeather = 1 and month >= 6 and month <= 9:
		gt 'grandmahelp', 'harvest'
	elseif grandmaQW['chore_type'] = 11 and boletus_stored <= 18:
		gt 'grandmahelp', 'pickforest_mushrooms'
	elseif grandmaQW['chore_type'] = 12 and bilberry_stored <= 18:
		gt 'grandmahelp', 'pickforest_berries'
	elseif grandmaQW['chore_type'] = 13 and ((boletus_stored + bilberry_stored) <= 16):
		gt 'grandmahelp', 'pickforest_both'
	else
		'"There is nothing to do today, <<$pcs_nickname>>. take the day off.'
		act 'Continue':gt 'gadhouse', 'grandma'
	end
end

if $ARGS[0] = 'cleanfloor':
	'"There is always something to do, <<$pcs_nickname>>. I''ve gotten quite old, and my strength is not what it used to be. Could you help me out by cleaning the floor?"'

	grandmaQW['chore_clean_floor'] = 1
	act 'Tell her you will do it soon':gt 'gadhouse', 'grandma'
	act 'Agree and start cleaning (1:00)':
		*clr & cla
		minut += 60
		grandmaQW['chore_clean_floor'] = 2
		grandmaQW['help_amount'] += 1
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/washfloor.jpg"></center>'
		'You grab a bucket and a rag, get down on your knees and begin scrubbing the floor. Within the hour, the floor shines, and you are satisfied with your work. You put the cleaning supplies into a corner and continue your day.'

		act 'Continue':gt 'gadhouse', 'start'
		act 'Return back to your grandmother': minut += 1 & gt 'gadhouse', 'grandma'
	end
end

if $ARGS[0] = 'washclothes':
	'"Of course, <<$pcs_nickname>>, you can help me wash your grandfather''s dirty clothes?"'

	grandmaQW['chore_wash_clothes'] = 1
	act 'Tell her you will wash them in a little bit':gt 'gadhouse', 'grandma'
	act 'Agree and start washing (1:00)':
		*clr & cla
		minut += 60
		grandmaQW['chore_wash_clothes'] = 2
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/washclothes1.jpg"></center>'
		'You pick up grandfather''s dirty clothes and take them with you outside, where you soak them in the metal basin for an hour.'

		act 'Hang the Laundry':
		    *clr & cla
		    minut += 10
		    gs'stat'
		    '<center><img <<$set_imgh>> src="images/locations/gadukino/village/washclothes2.jpg"></center>'
		    'Once done with the washing, you walk to the clothesline, where you carefully hang the clothes to dry.'

		    act 'Continue':gt'gaddvor'
			act 'Return back to your grandmother': minut += 1 & gt 'gadhouse', 'grandma'
		end
	end
end

if $ARGS[0] = 'milkcows':
	'"<<$pcs_nickname>>, go to the barn and milk the cows."'

	grandmaQW['chore_milk_cow'] = 1
	act 'Tell her you will do it in a bit':gt 'gadhouse', 'grandma'
	act 'Agree and go to the barn (0:10)':
		*clr & cla
		minut += 10
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		'You walk over to the barn where the cows are kept.'

		act 'Continue':gt'gadsarai','cow'
	end
end

if $ARGS[0] = 'groceries':
	'"Oh yes, <<$pcs_nickname>>. I was going to go down to the store today to buy some groceries, but my knees are aching. Do you think you could go down there and get them for me? I have a list of what we need, and the grocer will come by later to collect the money."'

	grandmaQW['chore_groceries'] = 1
	act 'Tell her you will go to the store later':gt 'gadhouse', 'grandma'
	act 'Agree and go to the store (0:15)':
		*clr & cla
		minut += 15
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/izba.jpg"></center>'
		'Your grandmother shuffles around, looking for her list for a few minutes, finally finding it and giving it to you. You grab a basket and set out for the store.'
		act 'Continue':gt 'gadmarket'
	end
end

if $ARGS[0] = 'can_mushrooms':
	'"I need to get some of these mushrooms canned, <<$pcs_nickname>>, so we can store them. Can you please help me prepare them?"'

	grandmaQW['chore_can_mushrooms'] = 1
	act 'Tell her you will help her in a little while':gt 'gadhouse', 'grandma'
	act 'Agree to help her right now (2:00)':
		*clr & cla
		minut += 45
		gs'stat'

		boletus_stored -= 5
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cleaning_mushrooms.jpg"></center>'
		'Grandma gives you a basket of mushrooms, and you spend a while cleaning them, washing them, and cutting them up in preparation for canning.'
		act 'Continue':
			*clr & cla
			minut += 60
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/canning.jpg"></center>'
			'Once they are prepared, you help put them in glass jars. Once they are ready, Grandma places the jars in her canner and boils them for an hour.'
			act 'Continue':
				*clr & cla
				minut += 15
				gs'stat'

				grandmaQW['chore_can_mushrooms'] = 0
				grandmaQW['help_amount'] += 2
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/canned_mushrooms.jpg"></center>'
				'Finally, you help Grandma take them out of the canner and set them aside to cool.'
				'"Thank you, <<$pcs_nickname>>," she says. "It is important to save food up for the hard winter months. Sure, now you can walk to the store and get whatever you want, but it wasn''t always that way!"'
				act 'Finish':gt 'gadhouse','start'
			end
		end
	end
end

if $ARGS[0] = 'can_berries':
	'"It is time to can these berries, <<$pcs_nickname>>. Can you please help me? My fingers aren''t as spry as they used to be."'

	grandmaQW['chore_can_berries'] = 1
	act 'Tell her you will help her in a little while':gt 'gadhouse', 'grandma'
	act 'Agree to help her right now (2:00)':
		*clr & cla
		minut += 45
		gs'stat'

		bilberry_stored -= 5
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cleaning_berries.jpg"></center>'
		'Grandma gives you a basket of berries, and you spend a while cleaning them, removing stems, and picking out any shrivelled or bad ones.'
		act 'Continue':
			*clr & cla
			minut += 60
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/canning.jpg"></center>'
			'Once they are prepared, you help pour them into glass jars. Once they are ready, Grandma places the jars in her canner and boils them for an hour.'
			act 'Continue':
				*clr & cla
				minut += 15
				gs'stat'

				grandmaQW['chore_can_berries'] = 0
				grandmaQW['help_amount'] += 2
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/canned_berries.jpg"></center>'
				'Finally, you help Grandma take them out of the canner and set them aside to cool.'
				'"There, now we will have berries for the winter," she says. "I think your grandfather could live off of these berries alone! He will be very grateful that you helped me."'
				act 'Finish':gt 'gadhouse','start'
			end
		end
	end
end

if $ARGS[0] = 'can_veggies':
	'"We have had good luck with the garden this year, <<$pcs_nickname>>. But now we need to can these vegetables before they spoil. Can you help me, please?"'

	grandmaQW['chore_can_veggies'] = 1
	act 'Tell her you will help her in a little while':gt 'gadhouse', 'grandma'
	act 'Agree to help her right now (3:00)':
		*clr & cla
		minut += 75
		gs'stat'

		grandmaQW['chore_harvest_done'] = 0
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cleaning_veggies.jpg"></center>'
		'You and Grandma spend some time sorting out all the vegetables from the garden. Once they are sorted, you begin cleaning them, cutting them up, removing stems and leaves, and preparing them for canning.'
		act 'Continue':
			*clr & cla
			minut += 90
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/canning.jpg"></center>'
			'It is a tedious process, but eventually, you finish and help Grandma put them all in jars. Then, you stand by while she boils the jars, helping her remove them from the canner when needed and replacing them with others.'
			act 'Continue':
				*clr & cla
				minut += 15
				gs'stat'

				grandmaQW['chore_can_veggies'] = 0
				grandmaQW['help_amount'] += 3
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/canned_veggies.jpg"></center>'
				'Finally, you help Grandma take the last jars out of the canner and set them aside to cool.'
				'"You know <<$pcs_nickname>>, if you know how to can your own food, you can survive years of poor harvests," she says.'
				'"Your grandfather and I had many hard times when we were younger, but saving our crops during the good times kept us from starving to death in the bad times. You would do well to remember that, young lady!"'
				act 'Finish':gt 'gadhouse','start'
			end
		end
	end
end

if $ARGS[0] = 'feedchickens':
	'"Of course, <<$pcs_nickname>>. Would you be kind and feed the chickens?"'

	grandmaQW['chore_feed_chickens'] = 1
	act 'Tell her you will do it in a little while':gt 'gadhouse', 'grandma'
	act 'Agree and go to the yard (0:10)':
		*clr & cla
		minut += 10
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/feed_chickens.jpg"></center>'
		'You take the grain mix for the chickens and walk to the yard.'

		act 'Continue':gt'gaddvor','chickens'
		
	end
end

if $ARGS[0] = 'checkplants':
	'"<<$pcs_nickname>>, can you please go work in the garden?"'

	grandmaQW['chore_work_in_garden'] = 1
	act 'Tell her you will get to it later':gt 'gadhouse', 'grandma'
	act 'Agree and go to the garden (0:10)':
		*clr & cla
		minut += 10
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		'You go to the garden.'

		act 'Continue':gt'gadgarden','garden'
	end
end

if $ARGS[0] = 'waterplants':
	'"Dear <<$pcs_nickname>>, could you go and water the plants in the garden?"'

	grandmaQW['chore_water_garden'] = 1
	act 'Tell her you will do it after a while':gt 'gadhouse', 'grandma'
	act 'Agree and go to the garden (0:10)':
		*clr & cla
		minut += 10
		gs'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		'You bring a watering can along with you to the garden.'

		act 'Continue':gt'gadgarden','garden'
	end
end

if $ARGS[0] = 'harvest':
	if month = 7:
		'"<<$pcs_nickname>> dear, the strawberries are ripe for picking. Could you go over to the plot and pick them today?"'

		grandmaQW['chore_collect_strawberries'] = 1
		act 'Tell her you will do it in a little bit':gt 'gadhouse', 'grandma'
		act 'Agree and go to the strawberry plot (0:10)':
			*clr & cla
			minut += 10
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
			'You bring a basket with you and walk to the strawberry plot in the garden.'

			act 'Continue':gt'gadgarden','strawberry'
		end
	elseif month = 8 or month = 9:
		'"<<$pcs_nickname>> dear, the fruits are ripe, and it is time to start collecting them. Could you go and do it today?"'

		grandmaQW['chore_collect_fruit'] = 1
		act 'Tell her you will do it in a little bit':gt 'gadhouse', 'grandma'
		act 'Agree and go to the orchard (0:10)':
			*clr & cla
			minut += 10
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
			'You bring a basket with you and walk to the fruit garden.'

			act 'Continue':gt'gadgarden','fruit_garden'
		end
	elseif month = 6:
		'"<<$pcs_nickname>> dear, could you go to the garden today? It''s time to collect the harvest."'

		grandmaQW['chore_harvest_garden'] = 1
		act 'Tell her you will do it in a little bit':gt 'gadhouse', 'grandma'
		act 'Agree and go to the garden (0:10)':
			*clr & cla
			minut += 10
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
			'You bring the harvest tools with you and go over to the garden.'

			act 'Continue':gt'gadgarden','garden'
		end
	end
end

if $ARGS[0] = 'pickforest_mushrooms':
	grandmaQW['chore_gather_mushrooms'] = 1
	grandmaQW['chore_mushroom_quantity'] = rand(1,2)
	'"<<$pcs_nickname>>, it''s mushroom season. Would you mind going into the forest to pick some for us?"'
	'"How much do we need, Grandma?" you ask.'
	'"Oh, I would say you should be able to find at least <<grandmaQW[''chore_mushroom_quantity'']>> kilos," Grandma replies.'

	act 'Tell her you will go get some soon':gt 'gadhouse', 'grandma'
	act 'Agree and go to the forest (1:00)':
		*clr & cla
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_night.jpg"></center>'
		end
		'You decide that now is as good a time as any to do it. You grab a basket and head out, walking to the forest.'
		minut += 60
		act 'Continue': gt 'gadforest', 'forest_edge'
	end
end

if $ARGS[0] = 'pickforest_berries':
	grandmaQW['chore_gather_berries'] = 1
	grandmaQW['chore_berry_quantity'] = rand(1,2)
	'"<<$pcs_nickname>>, the wild berries are ripe for picking. We should gather them now while we can."'
	'"How much do you want, Grandma?" you ask.'
	'"<<grandmaQW[''chore_berry_quantity'']>> kilos will be a good start," Grandma replies.'

	act 'Tell her you will go get some soon':gt 'gadhouse', 'grandma'
	act 'Agree and go to the forest (1:00)':
		*clr & cla
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_night.jpg"></center>'
		end
		'You decide now is as good a time as any to do it. So you grab a basket and head out, walking to the forest.'
		minut += 60
		act 'Continue': gt 'gadforest', 'forest_edge'
	end
end

if $ARGS[0] = 'pickforest_both':
	grandmaQW['chore_gather_both'] = 1
	grandmaQW['chore_mushroom_quantity'] = rand(1,2)
	grandmaQW['chore_berry_quantity'] = rand(1,2)
	'"This is the time of year that the forest provides us with its gifts, <<$pcs_nickname>>. Can you go and harvest some mushrooms and berries for us?"'
	'"How much of each should I get?" you ask.'
	'"If you could, try to find <<grandmaQW[''chore_mushroom_quantity'']>> kilos of mushrooms and <<grandmaQW[''chore_berry_quantity'']>> kilos of berries," Grandma replies. "It is important to stock up while we can."'

	act 'Tell her you will go get some soon':gt 'gadhouse', 'grandma'
	act 'Agree and go to the forest (1:00)':
		*clr & cla
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_night.jpg"></center>'
		end
		'You decide now is as good a time as any to do it. So you grab a basket and head out, walking to the forest.'
		minut += 60
		act 'Continue': gt 'gadforest', 'forest_edge'
	end
end


--- grandmahelp ---------------------------------

