# boygirl

!!'<<$boydesc>> <<$boybody>> <<$boybod>> <<$boyface>>. <<$boydesc>> <<$boyClo>>'

!! For a boy:	gs 'boygirl', 0, 'A Male',  age, region
!! For a girl:	gs 'boygirl', 1, 'A Woman', age, region
if $ARGS[0] = '':
	!! Random age
	if ARGS[2] = 0: ARGS[2] = rand(18, 35)

	!! Random Name
	if $ARGS[1] = '':
		if ARGS[2] <= 25:
			$ARGS[1] = iif(ARGS[0] = 0, 'A Male', 'A Girl')
		else
			$ARGS[1] = iif(ARGS[0] = 0, 'A Male', 'A Woman')
		end
	end

	!! Determine region
	if ARGS[3] = 0:
		if $region = 'pav':
			ARGS[3] = 1
		elseif $region = 'city':
			ARGS[3] = rand(3, 4)
		end
	end

	!! {The NPC generator is now the primary system of creating new characters.}
	gs 'npcgeneratec', ARGS[0], $ARGS[1], ARGS[2], ARGS[3]
	gs 'boyStat', $npclastgenerated
	gs 'boygirl', 'details'
end

if $ARGS[0] = 'boy' or $ARGS[0] = 'm':
	gs 'boygirl', 0, $ARGS[1], ARGS[2], ARGS[3]
elseif $ARGS[0] = 'girl' or $ARGS[0] = 'f':
	gs 'boygirl', 1, $ARGS[1], ARGS[2], ARGS[3]
end

if $ARGS[0] = 'details':
	!Select Photos
	loverGenderTmp = npc_gender[$npclastgenerated]
	silaVag = npc_sexskill[$npclastgenerated]
	$npc_usedname[$npclastgenerated] = $npc_firstname[$npclastgenerated]
	$boydesc = $npc_usedname[$npclastgenerated]
	hairBoy = npc_haircol[$npclastgenerated]
	titBoy = npc_bust[$npclastgenerated]
	vneshBoy = npc_apprnc[$npclastgenerated]
	!!appearance
	gs 'boygirl', 'set_boybody'

	!!Variables responsible for any features like
	!!security, is responsible for the money and requirements
	gs 'boygirl', 'set_finance'

	gs 'boygirl', 'set_preferences'
end


if $ARGS[0] = 'set_boybody':
	boybodyrand = rand(1, 3)
	if boybodyrand = 1:
		$boybody = 'short'
		$boybody_pref = 'a short'
	elseif boybodyrand = 2:
		$boybody = 'average'
		$boybody_pref = 'an average'
	else
		$boybody = 'tall'
		$boybody_pref = 'a tall'
	end

	boybodrand = rand(1, 4)
	boyfacerand = rand(1, 3)

	if npc_gender[$npclastgenerated] = 0:
		if boybodrand = 1:
			$boybod = 'thin'
			$boybod_pref = 'a thin'
		elseif boybodrand = 2:
			$boybod = 'athletic'
			$boybod_pref = 'an athletic'
		elseif boybodrand = 3:
			$boybod = 'chunky'
			$boybod_pref = 'a chunky'
		else
			$boybod = 'fat'
			$boybod_pref = 'a fat'
		end

		if boyfacerand = 1: 
			$boyface = 'black'
		elseif boyfacerand = 2:
			$boyface = 'brown'
		else 
			$boyface = 'blond'
		end

	else
		if boybodrand = 1 and boybodyrand = 1:
			$boybod = 'petite'
			$boybod_pref = 'a petite'
		elseif boybodrand = 1 and boybodyrand = 2:
			$boybod = 'slender'
			$boybod_pref = 'a slender'
		elseif boybodrand = 2:
			$boybod = 'toned'
			$boybod_pref = 'a toned'
		elseif boybodrand = 3:
			$boybod = 'average'
			$boybod_pref = 'an average'
		else
			$boybod = 'chubby'
			$boybod_pref = 'a chubby'
		end

		if boyfacerand = 1: 
			$boyface = 'black'
		elseif boyfacerand = 2:
			$boyface = 'brunette'
		else 
			$boyface = 'blond'
		end
	end
end

if $ARGS[0] = 'set_finance':
	harakBoy = rand(0, 2)
	finance = npc_finance[$npclastgenerated]
	if npc_finance[$npclastgenerated] = 0:
		!!Gopnik beggar or a hard worker
		!!check in appearance Primary
		if harakBoy = 0:
			npc_apprnc[$npclastgenerated] = rand(0, 8)
		elseif harakBoy = 1:
			npc_apprnc[$npclastgenerated] = rand(0, 16)
		else 
			npc_apprnc[$npclastgenerated] = rand(0, 32)
		end

		$boyClo = 'wearing a tracksuit.'
	elseif npc_finance[$npclastgenerated] = 1:
		!!middle_peasant
		!!check in appearance
		if harakBoy = 0:
			npc_apprnc[$npclastgenerated] = rand(0, 16)
		elseif harakBoy = 1:
			npc_apprnc[$npclastgenerated] = rand(0, 24)
		else
			npc_apprnc[$npclastgenerated] = rand(0, 32)
		end

		$boyClo = iif(npc_gender[$npclastgenerated] = 0, 'wearing jeans and a sweater.', 'wearing jeans and a blouse.')
	elseif npc_finance[$npclastgenerated] = 2:
		!!middle_peasant
		!!check in appearance
		if harakBoy = 0:
			npc_apprnc[$npclastgenerated] = rand(16, 32)
		elseif harakBoy = 1:
			npc_apprnc[$npclastgenerated] = rand(24, 32)
		else
			npc_apprnc[$npclastgenerated] = rand(32, 40)
		end

		$boyClo = iif(npc_gender[$npclastgenerated] = 0, 'wearing an expensive suit.', 'wearing an expensive dress.')
	end
end



if $ARGS[0] = 'set_preferences':
	!!requirements of the figure, chest size, hair color.
	!!0 - ass less 80, 1 back from 80 prior_to 100, 2 ass over 100
	figurBoy = rand(0, 2)

	!character 0 - soft, 1 - norm,  2 - aggressor
	temp_rand = rand(0, 100)
	if temp_rand < 80:
		izvrat = 0
	elseif temp_rand < 90 and npc_gender[$npclastgenerated] = 1:
		izvrat = 0
	else
		izvrat = 1
	end

	!! trying to make the preference section
	!! Variables here are clotTypePrefTmp, clotQualPrefTmp, clotTopPrefTmp, bottShorPrefTmp, clotThinPrefTmp, bimbPrefTmp, pierPrefTmp, tattPrefTmp, lipsPrefTmp, bodyPrefTmp, makePrefTmp, IQPrefTmp.

	!!This is for clothing type preference
	!! If you notice how rare it is to get a preference that is intentional
	!!0 - none, 1 - cheap, 2 - average, 3 - formal, 4 - fetish.
	clotTypePrefTmp = 0
	if rand(0, 4) = 4:
		if izvrat = 1 and rand(0, 1 + npc_finance[$npclastgenerated] mod 2) = 0:
			clotTypePrefTmp = 4
		elseif npc_finance[$npclastgenerated] = 0:
			clotTypePrefTmp = rand(1, 2)
		elseif npc_finance[$npclastgenerated] = 1:
			clotTypePrefTmp = rand(1, 3)
		elseif npc_finance[$npclastgenerated] = 2:
			clotTypePrefTmp = rand(2, 3)
		end
	end



	!!This is for the quality of clothing
	!! 0 - no preference, 1 - 1 to 4 units cheap to average (Locked if formal chosen), 2 - 5 to 7 units expensive to ballroom quality (Locked if fetish is chosen)
	clotQualPrefTmp = 0
	if rand(0, 5) = 0:
		if npc_finance[$npclastgenerated] = 0:
			clotQualPrefTmp = 1
		elseif npc_finance[$npclastgenerated] = 1:
			clotQualPrefTmp = rand(1, 2)
			temp_rand = rand(0, 1)
			if temp_rand = 0 and clotTypePrefTmp ! 3:
				clotQualPrefTmp = 1
			elseif temp_rand = 1 and clotTypePrefTmp ! 1:
				clotQualPrefTmp = 2
			end
		elseif npc_finance[$npclastgenerated] = 2:
			temp_rand = rand(0, 2)
			if temp_rand = 2 and clotTypePrefTmp ! 1:
				clotQualPrefTmp = 2
			end
		end
	end


	!!This is for the clothing top cut for the clothing


	!!Need to add modifiers based on breast size, where larger breasts end up forcing the player to show more cleavage than those with smaller breasts.
	!! 0 - no preference, 1 - 1 to 2 or neckline to moderate, 2 - 3 to 4 or heavy to severe, 3 - 5 to 7 or buldging to outpouring 
	!! The breast size must be adjusted either when the action is being calculeted or we can base it on their ideal breast size :npc_bust[$npclastgenerated] + 0/3 depending on the players breast size


	!!0 - no preference, 1 - 1 neckline , 2 - 2 or moderate, 3 - 3 to 4 or heavy to severe
	!! It doesn''t matter if your poor or rich, everyone loves tits.

	slutConstant = 0
	if izvrat = 1 and rand(0, 1 + npc_gender[$npclastgenerated]) = 0: slutConstant = 1

	clotTopPrefTmp = 0
	if rand(0, 2) = 0:
		temp_rand = rand(0, 5) - npc_gender[$npclastgenerated]
		if temp_rand < 2 and clotTypePrefTmp ! 4:
			clotTopPrefTmp = 1 + slutConstant
		elseif temp_rand < 4 and clotTypePrefTmp ! 4:
			clotTopPrefTmp = 2 + slutConstant
		elseif temp_rand >= 4 and clotTypePrefTmp ! 3:
			clotTopPrefTmp = 3
		end

		if clotTopPrefTmp ! 0 and npc_bust[$npclastgenerated] = 2:
			if clotPref ! 3:
				clotTopPrefTmp += 1
			end
		end
	end


	!! This is for pants and skirt shortness and will be grouped together as such.
	!! 0 - no preference, 1 - 1 to 2 units or ankle to calf length, 2 - 3 to 4 units or knee to miniskirt, 3 - 5 units to 6 or slut to hoe.

	bottShorPrefTmp = 0
	if rand(0, 2) = 0:
		temp_rand = rand(0, 5) - npc_gender[$npclastgenerated]
		if temp_rand < 2 and clotTypePrefTmp ! 4:
			bottShorPrefTmp = 1
		elseif temp_rand < 4:
			bottShorPrefTmp = 2
		elseif temp_rand >= 4:
			bottShorPrefTmp = 3
		end

		if slutConstant = 1 and rand(0, 1) = 0 and clotTypePrefTmp = 4:
			bottShorPrefTmp = 3
		end
	end


	!! This is for clothes thinness.
	!! 0 - no preference, 1 - 0 to 2 (Conservative), 2 - 3 to 4 (Moderate), 3 - 4 to 6 (really thin)
	!! I see the moderate to really thin overlapping. Its intentional.

	clotThinPrefTmp = 0
	if rand(0, 2) = 2:
		temp_rand = rand(0, 5) - npc_gender[$npclastgenerated]
		if temp_rand < 2:
			clotThinPrefTmp = 1 + slutConstant
		elseif temp_rand < 4:
			clotThinPrefTmp = 2 + slutConstant
		elseif temp_rand > 4 and clotTypePrefTmp ! 3:
			clotThinPrefTmp = 3
		end
	end


	!!This is to find out if they want you to wear bimbo clothing
	!! 0 - no preference, 1 - Prefers bimbo clothing.

	bimbPrefTmp = 0
	if rand(0, 2 + 8 * npc_gender[$npclastgenerated]) = 0 and clotTypePrefTmp ! 3: bimbPrefTmp = 1


	!!This is to find out if they want you to wear piercings.
	!! 0 - no preference, 1 - 0 to 2 piercings, 2 - 3 to 5 piercings, 3 - 6 or more piercings.

	pierPrefTmp = 0
	if rand(0, 3) = 3:
		temp_rand = rand(0, 2)
		if temp_rand = 0:
			pierPrefTmp = 1 + slutConstant
		elseif temp_rand = 1:
			pierPrefTmp = 2 + slutConstant
		elseif temp_rand = 2:
			pierPrefTmp = 3
		end
	end


	!!This is to find out if they want you to have tattoos.
	!! 0 - no preference, 1 - 0 to 2 tattoos, 2 - 3 to 5 tattoos, 3 - 6 or more tattoos.

	tattPrefTmp = 0
	if rand(0, 3) = 0: tattPrefTmp = rand(1, 3)


	!!This is to find out how big they want your lips.
	!! 0 - no preference, 1 - 2 to 3 units (average) , 2 - 4 units (THIC lips)

	lipsPrefTmp = 0
	if rand(0, 2 + npc_gender[$npclastgenerated]) = 0:
		temp_rand = rand(0, 2)
		if temp_rand = 0:
			lipsPrefTmp = 1 + slutConstant
		elseif temp_rand = 2:
			lipsPrefTmp = 2
		end
	end


	!!This is to find out how big they want YOU.
	!! 0 - no preference, 1 - 1 to 3 units (Skinny) , 2 - 3 to 6 units (Average), 3 - 6 + units (THIC)
	!! Notice how this one overlaps. I believe that it should because changing ones weight is very hard.

	bodyPrefTmp = 0
	if rand(0, 3) = 0: bodyPrefTmp = rand(1, 3)


	!!This is to find out how much makeup they want you to wear.
	!! 0 - no preference, 1 - 1 (light makeup) , 2 - 2 (moderate makeup), 3 - 3(heavy makeup)
	!! Plan to make a way for you to set what you makeup you want to wear at your bedside and giving into his wishes would automatically change the automated setting.

	makePrefTmp = 0
	if rand(0, 1) = 0:
		temp_rand = rand(0, 5) - npc_gender[$npclastgenerated]
		if temp_rand < 2:
			makePrefTmp = 1 + slutConstant 
		elseif temp_rand < 4:
			makePrefTmp = 2 + slutConstant
		elseif temp_rand >= 4 and clotTypePrefTmp ! 3:
			makePrefTmp = 3
		end
	end


	!! This is to see if they like a ditz, average, or a smartypants
	!!0 - no preference, 1 - 1 to 30 intelligence, 2 - 30 to 85 intelligence, 3 - 85 + intelligence. 

	IQPrefTmp = 0
	if rand(0, 4) = 0:
		if npc_gender[$npclastgenerated] = 0:
			IQPrefTmp = rand(1, 3)
		else
			!! IQPrefTmp is capped at 3. With old code: rand(1, 2) + rand(1, 2) + rand(0,1) => 1/8 chance for 2 else 3 (or more)
			IQPrefTmp = min(rand(2, 9), 3)
		end
	end

	killvar 'temp_rand'
end


--- boygirl ---------------------------------