# Komp
if $ARGS[0] = 'start':
cla
clr
gs 'stat'
set elektro += 5
'<center><img src="images\pics\komp.jpg"></center>'
'With the computer happily welcomes you start window.'
	act '15 minutes play patience': gt 'Komp','pasians'

	if GameCD > 0: act 'Play Disopl': gt 'KGDstart'

	if GameCD2 > 0: act 'Play Sunset Dead': gt 'KGZstart'

	if GameCD3 > 0: act 'Play Albido': gt 'FSstart'
	!act 'Sunset Review of the Dead': gt 'KGZstart'
	if internet > 0:
	set internet = internetM/60
	'You´ve got <<internet>> hours of Internet'
		act 'Browser': gt 'Komp','brows'
	end
	if webCam > 0 and webcamday ! day: act 'Make self porno': gt 'selfPorno','start'
	if karta >= 10:
	'You can pay online through your bank account. 1:00 Internet costs 10 rubles. On account of <<karta>>rubles.'

		act 'Pay online bank account':
			cla
			intinp = input ("How much money to put on the internet? (h = 10 rubles).")
			if intinp <= 0 or intinp * 10 > karta:
				'Invalid amount.'
			end
			if intinp*10 <= karta:
				set inttime = intinp * 10
				set karta -= inttime

				set internetM += intinp * 60
				set internet = internetM/60
				'You paid <<inttime>> hours of Internet, you now have <<internet>> hours of the Internet. Your account was removed <<intinp>> rubles.'
			end
			act 'Get out of the payment system': gt 'Komp','start'
		end

	end

	act 'Shut down the computer':
	cla
	gt 'Komp','fin'
	end
end

if $ARGS[0] = 'brows':
cla
*clr
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You entered into a search engine.'
act 'Apartment repair site (0:15)': gt 'Komp','remont'
if housr = 1 and husband = 0: act 'Rent your apartment': gt 'Komp','sale'
act 'Porno (0:15)': gt 'Komp','porno'
act 'Singles (0:15)': gt 'Komp','znak'
if hour < 20 and hour > 7: act 'Jobs.su': gt 'Komp','rabota'
act 'Cable TV services (0:15)': gt 'Komp','kabtv'
act 'Online game': gt 'KGstart'
if shantfoto > 0: act 'Search photos heroine in "In the ass."': gt 'Komp','foto'
if gor_dorm = 7: act 'Letter from Evgenia': gt 'etoexhib','pos91'
act 'Exit the browser': gt 'Komp','start'
end

if $ARGS[0] = 'sale':
cla
*clr
set minut += 2
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You are logged in to the site for free ads.'
if obkvsdam = 0 and housrA = 1:
	act 'Rent out Residental apartment': set obkvsdam['Street'] = 1 & CompCheckedResponses = 1 & gt 'Komp','sale'
	act 'Rent out Downtown apartment': set obkvsdam['Down'] = 1 & CompCheckedResponses = 1 & gt 'Komp','sale'
	act 'Rent out Northern apartment': set obkvsdam['Nord'] = 1 & CompCheckedResponses = 1 & gt 'Komp','sale'
	end
if obkvsdam['Street']>0 or obkvsdam['Down']>0 or obkvsdam['Nord']>0:
	act 'Check responses to your ad':
		cla
		CompCheckedResponses = 1
		if obkvsdam['Street'] = 1: 'No one has responded to your residental apartment ad'
		if obkvsdam['Down'] = 1: 'No one has responded to your downtown apartment ad'
		if obkvsdam['Nord'] = 1: 'No one has responded to your northern apartment ad'
		if obkvsdam['Street']>1 or obkvsdam['Down']>1 or obkvsdam['Nord']>1:
			if obkvsdam['Street']>1:
				set predsumm= (obkvsdam['Street'] * 1000) + 5000
				'Want to stay in your residental apartment for a month (<<predsumm>> rub).'
				act 'Rent (Residental)':
					set sdaday['Street'] = day
					set sdamonth['Street'] = month + 1
					set houserent['Street'] = 1
					set money += predsumm
					gt 'Komp','sale'
				end
			end
			if obkvsdam['Down']>1:
				set predsumm= (obkvsdam['Down'] * 1000) + 5000
				'Want to stay in your downtown apartment for a month (<<predsumm>> rub).'
				act 'Rent (Downtown)':
					set sdaday['Down'] = day
					set sdamonth['Down'] = month + 1
					set houserent['Down'] = 1
					set money += predsumm
					gt 'Komp','sale'
				end
			end
			if obkvsdam['Nord']>1:
				set predsumm= (obkvsdam['Nord'] * 1000) + 5000
				'Want to stay in your northern apartment for a month (<<predsumm>> rub).'
				act 'Rent (Northern)':
					set sdaday['Nord'] = day
					set sdamonth['Nord'] = month + 1
					set houserent['Nord'] = 1
					set money += predsumm
					gt 'Komp','sale'
				end
			end
		end
		act 'Exit': gt 'Komp','start'
	end
end
act 'Exit': gt 'Komp','start'
end

if $ARGS[0] = 'remont':
cla
*clr
set minut += 15
set internetM -= 60
set elektro += 3
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You are logged in apartment repairs.'
	if housr = 1:
		if rembedr = 0:
			act '50 refurbished bedrooms sput':
			if money >= 50000:
				cla
				set rembedr = 1
				set money -= 50000
				'You pay for repairs and you did it the same, just Dzhumshut Ravshan and wizards.'
			else
				cla
				'Unfortunately, you will not have enough money.'
			end
			act 'Exit': gt 'Komp','remont'
			end
		end

		if remsitr = 0:
			act 'Renovate hall 50,000 rubles':
			if money >= 50000:
				cla
				set remsitr = 1
				set money -= 50000
				'You pay for repairs and you did it the same, just Dzhumshut Ravshan and wizards.'
			else
				cla
				'Unfortunately, you will not have enough money.'
			end
			act 'Exit': gt 'Komp','remont'
			end
		end

		if remkorr = 0:
			act 'Repair corridor 50,000 rubles':
			if money >= 50000:
				cla
				set remkorr = 1
				set money -= 50000
				'You pay for repairs and you did it the same, just Dzhumshut Ravshan and wizards.'
			else
				cla
				'Unfortunately, you will not have enough money.'
			end
			act 'Exit': gt 'Komp','remont'
			end
		end

		if remvanr = 0:
			act 'Renovate the bathroom 50,000 rubles':
			if money >= 50000:
				cla
				set remvanr = 1
				set money -= 50000
				'You pay for repairs and you did it the same, just Dzhumshut Ravshan and wizards.'
			else
				cla
				'Unfortunately, you will not have enough money.'
			end
			act 'Exit': gt 'Komp','remont'
			end
		end

		if remkuhr = 0:
			act 'Renovate a kitchen 50,000 rubles':
			if money >= 50000:
				cla
				set remkuhr = 1
				set money -= 50000
				'You pay for repairs and you did it the same, just Dzhumshut Ravshan and wizards.'
			else
				cla
				'Unfortunately, you will not have enough money.'
			end
			act 'Exit': gt 'Komp','remont'
			end
		end
	end

act 'Exit': gt 'Komp','start'
end

if $ARGS[0] = 'porno':
cla
*clr
set minut += 15
set internetM -= 60
set manna += 5
set elektro += 3
set willpower += RAND(5,10)
set manna += RAND(10,50)
set horny += 5
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You went to a porn site.'
$pornomastr = {
cls
'<center><img src="images\pics\kompmas.jpg"></center>'
set minut += 15
sweat += 1
set horny += RAND(10,25)
if divanmastr = 0: divanmastr = 1 & set mastr += 1
gs 'stat'
'You get comfortable in front of the computer with one hand and began to fondle her breasts, a finger of the other hand you started rubbing and stroking a small bump between his legs that responded to the touch of pleasant languor covering your entire body.'
if horny >= 100: orgasm += 1 & horny = 0 & 'Suddenly a nice cramp brought your body and you covered powerful orgasm from which you groan.'
act 'Finish': divanmastr = 0 & gt 'Komp','porno'
if horny >= 50: act 'Proceed': dynamic $pornomastr
}

	act 'Watch porn on':
	cla
	'<center><img src="images\etogame\porno.jpg"></center>'
	gt 'Komp','porno'
	end

	if horny >= 50: act 'Masturbate (0:15)': dynamic $pornomastr

act 'Exit': gt 'Komp','start'
end

if $ARGS[0] = 'pasians':
cla
*clr
set minut += 15
set manna += 5
set elektro += 3
set willpower += RAND(5,10)
set manna += RAND(10,50)
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You entertained for an hour unfolding of solitaire on the computer.'
act 'Lay another 15 minutes': gt 'Komp','pasians'
act 'Close Solitaire': gt 'Komp','start'
end

if $ARGS[0] = 'znak':
cla
*clr
set minut += 15
set internetM -= 60
set manna += 5
set elektro += 3
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You are logged on to a dating site.'
'Selection of boys is only possible if there is no boyfriend.'

	if bfA <= 0:
		act 'To pick up a guy with a gentle disposition':
		cla
		gs 'boy'
		gs 'boyfrend','start'
		set stopboy = 0
		set harakBoyA = 0
		'You wrote a guy named <<$boyA>>and talked with him and left him telefonchik hoping that he will call you.'
		act 'Exit': gt 'Komp','start'
		end

		act 'To pick up a guy with a common character':
		cla
		gs 'boy'
		gs 'boyfrend','start'
		set stopboy = 0
		set harakBoyA = 1
		'You wrote a guy named <<$boyA>>and talked with him and left him telefonchik hoping that he will call you.'
		act 'Exit': gt 'Komp','start'
		end

		act 'To pick up a guy with a strong character':
		cla
		gs 'boy'
		gs 'boyfrend','start'
		set stopboy = 0
		set harakBoyA = 2
		'You wrote a guy named <<$boyA>>and talked with him and left him telefonchik hoping that he will call you.'
		act 'Exit': gt 'Komp','start'
		end
	end
	if gor_dorm = 8:
		act 'Pick suitors for Eugene':
			cla
			gor_dorm = 9
			'You shoveled tens of questionnaires before selecting suitable candidates in all respects and sent letters inviting them to meet.'
			'Now we have to wait her turn, something with them or not.'
			act 'Leave': gt 'Komp','start'
		end
	end


act 'Exit': gt 'Komp','start'
end

if $ARGS[0] = 'kabtv':
cla
*clr
set minut += 15
set internetM -= 60
set elektro += 3
clr
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You are logged in to the website provider of cable TV.'
	if kabel = 1:
		'Do you have a cable TV (subscription fee of 300 rubles per month lifted the 25th day of)'
		act 'Abandon cable TV':
		cla
		'You have disconnected cable channels, paying the current month'
		kabel = 1
		money = money - 300
		gt 'Komp','kabtv'
		end
	end
	if kabel = 0 and TV = 1:
		'You do not have a cable TV'
		act 'Connect cable TV':
		cla
		'Unfortunately for viewing cable television requires a more modern TV'
		gt 'Komp','kabtv'
		end
	end
	if kabel = 0 and TV >= 2:
		'You do not have a cable TV'
		act 'Connect Cable TV (300 rubles per month)':
		cla
		'You hooked up cable TV services'
		kabel = 1
		gt 'Komp','kabtv'
		end
	end
act 'Exit': gt 'Komp','start'
end

if $ARGS[0] = 'foto':
cla
*clr
set internetM -= 60
set elektro += 3
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
'You are logged in to the social network "in the ass."'
	if shantfoto > 0:
		act 'Search':
		cla
		set minut += 60
		set fotsearchrand = rand(0,10)
			if fotsearchrand <= 7:
			'You did not find anyone, maybe better luck later.'
			act 'Finish': gt 'Komp','foto'
			end
			if fotsearchrand > 7:
			set shantfoto -= 1
			set gerofotorand = rand(0,100)
			'You found the heroine a photo shoot'
				if gerofotorand > 30:
				'Judging by the photos on her page this poor girl and take her with nothing.'
				act 'Finish': gt 'Komp','foto'
				end
				if gerofotorand >= 5 and gerofotorand <= 30:
				set shantsr += 1
				'Judging by the photos on her page is non-existent girl from the middle classes. You send her photo and asked to be transferred to your account 5000.'
				act 'Finish': gt 'Komp','foto'
				end
				if gerofotorand < 5:
				set shantbog += 1
				'Judging by the photos on her page is very secured lady. You send her photo and asked to be transferred to your account 30000.'
				act 'Finish': gt 'Komp','foto'
				end
			end
		end
	end
act 'Browser': gt 'Komp','brows'
end

if $ARGS[0] = 'rabota':
cla
*clr
set minut += 60
set internetM -= 60
set komprabota = RAND(0,10)
gs 'stat'
'<center><img src="images\pics\komp.jpg"></center>'
if komprabota = 0:
	'You found an ad: "Wanted girl model looks for advertising underwear, cash on filming zavershinii 2000 rubles."'
	if vnesh < 30: 'But you are under this description does not fit'
	if vnesh >= 30:
		act 'Go at': gt 'qjob','var1'
		end
	if hour < 20 and hour > 7: act 'Search more': gt 'Komp','rabota'
	act 'Finish': gt 'Komp','brows'
	end
if komprabota = 1:
	'You found an ad: "Wanted girl model looks for advertising underwear, cash on filming zavershinii 2000 rubles."'
	if vnesh < 30: 'But you are under this description does not fit'
	if vnesh >= 30:
		act 'Go at': gt 'qjob','var2'
		end
	if hour < 20 and hour > 7: act 'Search more': gt 'Komp','rabota'
	act 'Finish': gt 'Komp','brows'
	end
if komprabota > 1 and komprabota < 5:
	'You found an ad: "The artist is required naturschitsa, simpotichnoy appearance, cash 1,000 rubles."'
	if vnesh < 15: 'But you are under this description does not fit'
	if vnesh >= 15:
		act 'Go at': gt 'qjob','var3'
		end
	if hour < 20 and hour > 7: act 'Search more': gt 'Komp','rabota'
	act 'Finish': gt 'Komp','brows'
	end
if komprabota > 4:
	'You did not find anything suitable.'
	if hour < 20 and hour > 7: act 'Search more': gt 'Komp','rabota'
	act 'Finish': gt 'Komp','brows'
	end
end

if $ARGS[0] = 'fin':
gt $locM, $metkaM
end
--- Komp ---------------------------------