glife/locations/moncheri.qsrc

# moncheri

if $ARGS[0] = 'start':
	$loc_arg = $ARGS[0]
	$loc = 'moncheri'
    $location_type = 'public_indoors'
	$menu_loc = 'moncheri'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla
	mag = 1
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Mon Chéri</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/mall/boutique/butik.jpg"></center>'
	*nl
	'You''re inside the boutique only a few seconds before a tall, slender brunette woman saunters up to you. Everything about her is poised and perfect, from the beautiful silver dress she''s wearing to her unblemished skin and pearly white teeth. "Welcome to Mon Chéri, dear. We sell only the most beautifully luxurious items here. Come, take a look! You won''t be disappointed," she smiles as she ushers you further inside with a small flourish. Everything in the boutique is high-end, definitely not for the average shopper, but the items on display are simply stunning.'
	*nl

	if rand(1, 100) >= 80 and pcs_skin >= 20 and lesbiQW = 0:
		'In the boutique you see a stylish and slender woman, about forty years old.'

		act 'Stare at the woman':gt 'event', 'lesbi'
	end

	if QWdogreiqTimer = 0 and QWdogReiq = 1 and week = 7 and qwdogiventday ! daystart:
		qwdogiventday = daystart
		'Going into the boutique you begin to look at some dresses on hangers, considering to buy one. You casually try one on in the changing room when suddenly one of the dresses attracts your attention. When you look at it more closely, you feel strange, as if you are being watched.'

		act 'Disregard':gt 'moncheri', 'start'
		act 'Look around':gt 'moncheri', 'rima'

		exit
	end

	if RimmaSex > 0:
		if rimmaday ! daystart:
			'<a href="exec:gt ''RimmaSexQW''">Rima</a> smiles at you. She bites her lip and looks longingly in your direction.'
		else
			'Rima smiles at you and continues to do her business.'
		end
	end

	'The boutique sells designer winter coats, formal clothing, beautiful shoes and exquisite handbags.'

	act 'Leave the boutique': minut += 3 & gt 'torgcentr'
	
	act 'View clothing': minut += 5 & gt 'moncheri', 'clothes'

	act 'View shoes': minut += 5 & gt 'moncheri', 'shoes'

	act 'View purses': minut += 5 & gt 'moncheri', 'purses'

	act 'View coats':
		cla
		act 'Return': minut += 1 & gt 'moncheri', 'start'
		if coat[9] < 1: 
			if coat[9] = 0:dynamic 'act ''Look at designer coat 9'':gt ''clothing'', ''view_clothing_item'', ''shop'', ''coat'', 9, 50000'
		end
		if coat[11] < 1:
			if coat[11] = 0:dynamic 'act ''Look at designer coat 11'':gt ''clothing'', ''view_clothing_item'', ''shop'', ''coat'', 11, 50000'
		end
	end

end

if $ARGS[0] = 'clothes':
	$loc_arg = 'clothes'
	$loc = 'moncheri'
	$menu_loc = 'moncheri'
	$menu_arg = 'clothes'
	menu_off = 0
	*clr & cla
	gs'stat'
	'<center><b><font color="maroon">Viewing Mon Chéri outfits</font></b></center>'
	*nl

	gs 'clothing_QV', 'shop_header'

	act 'Return': minut += 1 & gt 'moncheri', 'start'

	clothingfilter['qualitycheck'] = 7
	:loopquality
		if Clothingstock > 11:
			i = 1
		else
			i = 2
		end

		:loopmoncheri
			if moncheri[i] = 0:
				gs 'clothing_attributes', 'moncheri', i
				gs 'clothing_QV', 'shop_filter'

				if clothingfilter['quality'] = 0 or clothingfilter['qualitycheck'] = CloQuality:
				
					if clothingfilter_risk = 1 and clothingfilter_pandb = 1 and clothingfilter_norm2 = 1: *p '<a href="exec: i = <<i>> & gt ''moncheri'', ''moncheri''"><img src="images/pc/clothing/4formal/<<i>>.jpg" 	height="250" /></a>'
				end
			end
			i += 2
		if i <= 185:jump 'loopmoncheri'
	if clothingfilter['quality'] = 1 and clothingfilter['qualitycheck'] > 0: clothingfilter['qualitycheck'] -=1 & jump 'loopquality'
end

if $ARGS[0] = 'moncheri':
	cla
	menu_off = 1
	if moncheri[i] ! 0:
		msg 'You already own these clothes.'
		gt 'moncheri', 'clothes'
	end

	gt 'clothing', 'view_clothing_item', 'shop', 'moncheri',i, 20000

end

if $ARGS[0] = 'shoes':
	$loc_arg = $ARGS[0]
	$loc = 'moncheri'
	$menu_loc = 'moncheri'
	$menu_arg = 'shoes'
	menu_off = 0
	*clr & cla
	gs'stat'

	act 'Return': minut += 1 & gt 'moncheri', 'start'

	if Clothingstock > 11:
		i = 1
	else
		i = 2
	end

	:loopboutique_shoes
		if sboutique[i] = 0:*p '<a href="exec: i = <<i>> & gt ''moncheri'', ''boutique_shoes''"><img src="images/pc/shoes/boutique/<<i>>.jpg" height="250" /></a>'
		i += 2
	if i <= 37:jump 'loopboutique_shoes'
end

if $ARGS[0] = 'boutique_shoes':	gt 'shoes', 'view_shoe_item', 'shop', 'boutique',i, 5000

if $ARGS[0] = 'purses':
	$loc_arg = 'purses'
	$loc = 'moncheri'
	$menu_loc = 'moncheri'
	$menu_arg = 'purses'
	menu_off = 0
	*clr & cla
	gs'stat'

	act 'Return': minut += 1 & gt 'moncheri', 'start'

	i = 1

	:loopmoncheri_purses
		if moncheri_purses[i] = 0:*p '<a href="exec: i = <<i>> & gt ''moncheri'', ''purses2''"><img src="images/pc/items/moncheri/purses/<<i>>.jpg" 	height="150" /></a> '
		i += 1
	if i <= 20:jump 'loopmoncheri_purses'
end

if $ARGS[0] = 'purses2': gt 'purses', 'view_purse_item', 'shop', 'moncheri',i, 4000

if $ARGS[0] = 'rima':
	*clr & cla
	menu_off = 1
	minut += 5
    $location_type = 'event'
	gs 'stat'
	'Turning your head, you think nobody noticed, but your actions have attracted the saleswoman. The seller is a young girl in a little-too-narrow shirt with the logo of the Boutique, it''s not enough that her shirt was so tight, but she had to unbutton the top button as well (You think if it was a woman''s shirt it would be okay, but since it''s a man you wonder what the administration must be thinking.) she came up to you a little bit uncomfortably and quickly asked:'
	'"Can I help you with anything?" the seller asks.'

	act 'No, thank you':gt 'moncheri', 'start'
	act 'Silently leave': minut += 8 & gt 'city_center'

	act 'Stare at her breasts':
		*clr & cla
		gs 'stat'
		'Seeing that the she is a novice saleswoman and that you are most likely her first client, you decided to go for it. just as you opened your mouth to say some harsh sentence, your eyes came to rest on her chest. The Bra together with the shirt successfully emphasized her breasts, and even though only the upper part of her chest was visible, your imagination filled in the rest. You wonder what her nipples are like The thought crossed your mind suprisingly'
		'"Yes, you can give me a few minutes of your time, "You said.'
		'Your words make an impression on the saleswoman, and she blushes slightly embarassed.'
		'"Yes, yes, yes - often we ask: what dress color do you like? shape of the neckline of the dress? do you want more freedom to move? or turn? do you want to highlight your perfect figure?"'
		'"Stop, stop, - you''re a person and not a stranger, first tell me what you would like me to call you" Your words make an impression on the girl, she is flattered by your words. '
		'"Irina" she says, before correcting herself "Saleswoman Rima."'
		'"May I call you Rimma?" You ask."I''m <<$pcs_nickname>>".'
		'"Yes, of course, if you''d like.", responds Rima, smiling shyly.'
		
		gs 'arousal', 'erotic', 5
		gs 'stat'

		act 'Choose a dress with Rimma':
			*clr & cla
			minut += 5
			gs 'stat'

			if pcs_hairbsh = 1 and pcs_makeup > 1 and pcs_leghair <= 0 and pcs_sweat < 20 and $clothingworntype = 'moncheri':
				'You choose some things  and evaluate them together with Rima while hanging out a bit.'
				'"Rima, where is the dressing room?" You ask suddenly.'
				'Come with me - Rima didn''t notice that the invisible barrier between you is lost: the seller and the buyer.'

				act 'Go inside the dressing room':
					*clr & cla
					minut += 5
					gs 'stat'
					'You and Rima went together into the dressing room.'

					act 'You do not like the dress':
						*clr & cla
						minut += 5
						gs 'stat'
						'As a result, you spent time together, while in your head you wonder about Rima, and her mysterious and curious body.'
						'As you go home you suddenly feel eyes on you'

						act 'Ignore': minut += 8 & gt 'city_center'

						act 'Look around':
							*clr & cla
							minut += 5
							gs 'stat'
							'You start to turn your head, looking around sharply.'
							'You notice that a girl is looking at you.'

							act 'Approach her':
								*clr & cla
								minut += 5
								gs 'stat'
								'You silently move towards her and give her a look'
								nl
								'"Good afternoon," you announce. "Do I know you?"'
								'"Good day," she says, "Do you not remember me?"'
								'The girl does not respond to your sharpness'
								'"In principle, there is no way out of the situation that you had?" the girl answers'
								'"What is the situation where when?" You will not hide anger.'
								'"Yes, in the vacant lot where you were having ''fun'' with a dog" girl replied with a grin.'

								act 'Yes you ohereli! (Go)': minut += 8 & gt 'city_center'

								act 'Extort taken in head? What do you want?':
									*clr & cla
									minut += 5
									QWdogReiq = 2
									QWdogreiqTimer = 7
									gs 'stat'
									'"So you decided to blackmail me? And how much do you want?" You spit viciously '
									'Again, your words fail to disturb her. she cocks her head to the side, and asks "Is your tantrum over?"'
									'You tell her irritably that you have not even begun to get angry.'
									'"No, you''re still upset let''s meet next week." The girl says suddenly.'
									'"I guess..." you say, shaking your head.'
									'"That''s fine, my name is Margaret" she says, looking at you expectantly.'
									'"<<$pcs_nickname>>" you reply.'
									'"I''m looking forward to our meeting." she says as she leaves.'

									act 'Leave': minut += 8 & gt 'city_center'
								end
							end
						end
					end

					act 'Take your panties off in front of Rimma.':
						*clr & cla
						minut += 5
						gs 'stat'
						'You remove your panties in front Rimma and noticed how her cheeks glowed red, and her breathing quickened.'

						act 'Do you like me?':
							*clr & cla

							if RimmaSex = 0:RimmaSex = 1 & girl += 1

							rimmaday = daystart
							gs 'stat'
							'<center><img <<$set_imgh>> src="mod/bestmod/images/beast/zoo/primer.jpg"></center>'
							'"Rimma, do you like me?" you ask quietly'
							'"yes, very much" Rimma answers excitedly'
							'"Then lick me" you demand'
							'Rimma kneels down and begins to kiss your body, not very skillfully at first, starting by timidly kissing your belly then licking and covering all of your body as she grew more confident. Rimma successfully made your pussy very wet. She starts kissing and licking your crotch little by little, then bites at it. The unexpectedness makes the body flow into a sweet languor. '
							'You smell of sex, Rimma looks up at you from between your legs for a second'
							'After putting her right palm gently on the pubis, Rimma fingers spread your wet lips, poking out her tongue and running it inside.'
							'The Soft reciprocating action of the tongue on the clitoris excits you and causes a mild spasm. Rimma suddenly begins to press her tongue on your clitoris. Your body is already weak and no longer obeys your brain, only trying not moan load enough to alert the whole store.'
							$orgasm_or = 'custom'
							$orgasm_txt = 'Suddenly, Your body begins to shake and is covered in a soft wave of spasms, with the last spasm you cum. You let out a loud moan while falling to your knees.'
							'You collapse to the floor, exhausted with pleasure.'
							
							gs 'arousal', 'cuni', 10, 'dom', 'lesbian'
							gs 'arousal', 'vaginal_finger', 10, 'dom', 'lesbian'
							minut -= 10
							gs 'arousal', 'end'
							gs 'stat'

							act 'leave the dressing room':
								*clr & cla
								minut += 5
								QWdogReiq = 2
								QWdogreiqTimer = 7
								gs 'stat'
								'Rimma walked you to the door.'
								'"<<$pcs_nickname>>, did you like it?" Rimma asked, blushing.'
								'"What do you think? I want more, Do you want to continue?"'
								'"No, I can''t, my parents are waiting at home" Rimma tells you, looking upset. '
								'"Then how about next week?" you offer'
								'"let''s do it" Rimma looks very happy.'
								'You head home, on the way you hear a woman''s voice behind you:'
								'"Goodnight" said the strange woman.'
								'Looking closely you recognize her as girl at the vacant lot.'
								'"Hi" you cheerfully answered, "was it you that was watching me the entire time?"'
								'"Yes," she smiled in response. "I saw you in the boutique, but I didn''t dare to approach you at that time, so I decided to wait outside for you."'
								'"But why did you wait?"'
								'"Now it''s too late, Meet me next week so we can talk" She looks at you, waiting for your response'
								'"Let''s meet then," You agree"By way I''m <<$pcs_nickname>>"'
								'"Margaret" She responds'

								act 'Leave': minut += 8 & gt 'city_center'
							end
						end
					end
				end
			else
				'You and Rimma search for a dress, but couldn''t find one. You leave and Rimma is a little sad in saying goodbye to you.'
				'You think it might help keep her attention if you make a real effort with your appearance and wear one of the nce outfits from here.'

				act 'Leave': minut += 8 & gt 'city_center'
			end
		end
	end
end

--- moncheri ---------------------------------