glife/locations/city_saunawhore.qsrc

# city_saunawhore

if moodTypeRand <= 0:
	$moodType = 'bad'
elseif moodTypeRand >= 1 and moodTypeRand <= 3:
	$moodType = 'fairly normal'
elseif moodTypeRand >= 4:
	$moodType = 'good'
end

!! saunawork start ---------------------------------------------------------------------------------

if $ARGS[0] = 'saunawork':
	$loc = 'city_saunawhore'
	$loc_arg = 'saunawork'
	$locBroom = 'city_saunawhore'
	$menu_loc = 'city_saunawhore'
	$menu_arg = 'saunawork'
	$metkaBroom = 'saunawork'
	$locM = 'city_saunawhore'
	$locM_arg = 'saunawork'
	$location_type = 'public_indoors'
	menu_off = 0
	saunaYouRoom = 1

	if paymamka = 0:paymamka = 300
	if workDolg > 0:paymamka = 300
	if workDolg <= 0:paymamka = 500

	gs 'stat'
	'<center><b><font color="maroon">Sauna</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sauna1.jpg"></center>'
	''
	'The sauna is open to "customers" between 08:00 and 00:00.'
	'All the walls are covered in <a href="exec:gt ''mirror'', ''start''">mirrors</a>.'

	if saunaWorkNow = 1:
		saunaWorkNow = 0
		money -= paymamka
		'A nurse enters the room and takes <<paymamka>> per customer from you.'
	end

	gs 'city_saunawhore','debtPay'
	if workDolg > 0:'Your debt is <<workDolg>> <b>₽</b>'

	gs 'stat'

	if workDolg <= 0:act 'Leave':gt 'city_sauna'

	act 'Go to your room':gt 'city_sauna', 'saunaroom'

	act 'Use the staff bathroom': minut += 1 & gt 'city_saunawhore', 'bathroom'

	if workDolg > 0 and (pcs_mood <= 10 or drugVars['heroin_need'] > 0):
		cls
		workDolg += 420
		gs 'stat'
		'You are beckoned by the nurse. You walk up to her and she demands to see your arm. You present your arm and she takes out a syringe filled with drugs. "Sit still, I''ll give you a shot now and it will make you feel like normal again."'

		act 'Leave':
			minut += 10
			gs 'drugs', 'heroin'

			gt 'city_saunawhore', 'saunawork'
		end
		exit
	end
	if workDolg <= 0 and pcs_mood <= 50 and SaunaWhore > 0 and money >= 420:
		act 'Ask for some drugs':
			cls
			menu_off = 1
			gs 'stat'
			'"Okay, come here."'
			'You walk up to her and she asks to see your arm. You present your arm and she takes out a syringe filled with drugs. "Sit still, I''ll give you a shot now and it will make you feel like normal again."'

			act 'Leave':
				gs 'drugs', 'heroin'
				minut += 10
				money -= 420
				gt 'city_saunawhore', 'saunawork'
			end
		end
	end

	if cumcondslip > 0 and cumcondslip_aware > 0:
		act 'Ask to see a doctor':
			cla
			*clr
			minut += 25
			menu_off = 1
			gs 'stat'
			'You explain how you feel nauseous and have pain in your pubic area. The nurse checks you over and eventually comes to a conclusion.'
			'"I think it might be toxic shock. We''ll have to get you sorted out. Wait here I''ll call the doctor."'
			act 'Some time later':
				cla
				minut += 15
				gs 'cum_cleanup', 'cleanloc', 17
				cumcondslip = 0
				gs 'stat'
				'When he arrives, the doctor examines you and establishes that you''re suffering from toxic shock from a spent condom in your body.'
				'"I removed it as soon as I found it. If you were feeling sick, it should slowly subside."'
				'You reflexively thank the doctor, even though he''s visiting you in this place.'

				act 'Return':gt 'city_saunawhore', 'saunawork'
			end
		end
	end

	act 'See nurse for STD check up':
		if Gerpes+Sifilis+Triper > rand(2,4) or Kandidoz > 10:
			cls
			menu_off = 1
			gs 'stat'
			'The nurse has you strip and put your legs in stirrups then roughly examines you.'
		
			if GerpesOnce = 1:
				'You have genital herpes. You can''t afford the cure and I can''t provide it.'
				if Gerpes >= 3:
					if GerpesNapr = 0:
						GerpesNapr = 3 & 'I''m going to put you on a course of herpes shots. You''ll need a total of 3 injections (no more than 1 a day), each injection will add 750 <b>₽</b> to your debt or put you in debt if not already.'
					elseif GerpesNapr > 0:
						'You need to finish your course of herpes injections.'
					end
				else
					'Your herpes are in an inactive stage, take vitamins and it won''t show itself.'
				end
			end

			if SifacOnce = 1:
				sifNapr = 1
				'You have syphilis which if untreated can be fatal. However, thanks to modern medicine can now be cured with a single shot.'
				'The injection will cost 1,000 <b>₽</b>, which will be added to your debt or put you in debt if not already.'
			end

			if TriperOnce = 1:
				'We found gonorrhoea. In principle, this disease is curable.'
				if TriperNapr = 0: 
					TriperNapr = 5 & 'I''m going to put you on a course of gonorrhoea injections. You''ll need a total of 5 injections (no more than 1 a day), each injection will add 750 <b>₽</b> to your debt or put you in debt if not already.'
				elseif TriperNapr > 0:
					'You need to finish your course of gonorrhoea injections.'
				end
			end

			if KandidozOnce = 1:
				'You have an yeast infection. The cure for this disease is very expensive, but it''s not that harmful and can easily be suppressed.'

				if KandidNapr = 0:KandidNapr = 1 & mc_inventory['antibiotics'] += 5 & 'Here''s some pills, the drug company rep gives these away so I won''t add anything to your debt. When you have it in remission you must take vitamins to keep it that way.'
				if Kandidoz < 30:'Your yeast infection is currently in remission, take vitamins, and it will stay that way.'
			end
			act 'Return':gt 'city_saunawhore', 'saunawork'
		else
			'The nurse has you strip and put your legs in stirrups then roughly examines you. I can''t see anything wrong with you down there so whatever it is you got it''s in remission so you''re good to work.'
			act 'Return':gt 'city_saunawhore', 'saunawork'
		end
	end
		
	if GerpesNapr > 0 and GerpesUkolDay ! daystart:
		act 'See nurse for herpes shot':
			*clr & cla
			minut += 15
			workDolg += 750
			GerpesUkolDay = daystart
			GerpesNapr -= 1
			gs 'stat'
			'You see the nurse and she gives you a painful injection in your ass.'
				if GerpesNapr = 0:Gerpes = -10 & 'You have completed the treatment.'
			act 'Return':gt 'city_saunawhore', 'saunawork'
		end
	end

	if TriperNapr > 0 and TriperUkolDay ! daystart:
		act 'See nurse for gonorrhoea shot':
			*clr & cla
			minut += 15
			workDolg += 750
			TriperUkolDay = daystart
			TriperNapr -= 1
			gs 'stat'
			'You see the nurse and she gives you a painful injection in your ass.'
				if TriperNapr = 0:TriperOral = 0 & TriperOralSigns = 0 & Triper = 0 & Venera -= 1 & TriperOnce = 0 & 'You have completed the treatment.'
				act 'Return':gt 'city_saunawhore', 'saunawork'
		end
	end
		if Sifilis > 0:
		act 'See nurse for syphilis shot':
			*clr & cla
			minut += 15
			workDolg += 1000
			SifNapr = 0
			SifacOnce = 0
			Sifilis = 0
			Venera -= 1
			gs 'stat'
			'You see the nurse and she gives you a painful injection in your ass.'
			'"That''s it, you might still feel a bit off but the infection is now cured".'
				act 'Return':gt 'city_saunawhore', 'saunawork'
		end
	end


	if hour >= 8:
		act 'Sit on the couch':
			if pcs_makeup > 1 and pcs_hairbsh = 1 and pcs_sweat < 26 and pcs_leghair <= 3 and pcs_pubes <= 3:
				cls
				minut += 60
				menu_off = 1
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/saunawork.jpg"></center>'
				'You spend an hour sitting on the couch waiting for customers.'

				saunaWorkKlient = 0

				if hour >= 21:
					if rand(0, 100) >= 10:saunaWorkKlient = 1
				elseif hour >= 16:
					if rand(0, 100) >= 20:saunaWorkKlient = 1
				elseif hour >= 12:
					if rand(0, 100) >= 40:saunaWorkKlient = 1
				elseif hour >= 8:
					if rand(0, 100) >= 80:saunaWorkKlient = 1
				else
					if rand(0, 100) >= 40:saunaWorkKlient = 1
				end

				if saunaWorkKlient = 1:
					cls
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/saunawhore.jpg"></center>'
					'A client has arrived at the sauna, and the girls line up so that the customer can choose one of them.'

					if rand(0, 120) < pcs_apprnc:
						'The client jabs a finger at you. "This one."'
						act 'Go with the client':
							saunaWorkKlient = 1
							guy += 1
							SaunaWhore += 1
							menu_off = 1
							gt 'city_saunawhore', 'clientGate'
						end
					else
						'The client examines you closely, but turns away to chose another girl.'

						act 'Continue':gt 'city_saunawhore', 'saunawork'
					end
				else
					'The client chooses another girl and she leads him to one of the back rooms.'

					act 'Continue':gt 'city_saunawhore', 'saunawork'
				end
			else
				cla
				'The brothel madam walks over to you. "Our customers expect you to be clean, shaven, made-up and with your hair looking nice. Go and sort yourself out, now!"'
				act 'Leave':gt 'city_saunawhore', 'saunawork'
			end
		end
	end

	if clenerSauna ! daystart:
		act 'Clean toilets':
			cla
			*clr
			minut += 60
			clenerSauna = daystart
			pcs_mood -= 25
			gs 'exp_gain', 'cleaning', rand(1,3)
			menu_off = 1
			gs 'sweat', 'add', 30
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener2.jpg"></center>'
			if workDolg > 0:
				'You scrub the sauna toilets for an hour, reducing your debt by 100 <b>₽</b>.'
				workDolg -= 100
			else
				'You scrub the sauna toilets for an hour. You are paid 100 <b>₽</b> for your work.'
				money += 100
			end

			act 'Leave':gt 'city_saunawhore', 'saunawork'
		end
	end

	if clenerSauna2 ! daystart:
		act 'Scrub floors':
			cla
			*clr
			menu_off = 1
			minut += 60
			clenerSauna2 = daystart
			gs 'exp_gain', 'cleaning', rand(1,2)
			pcs_mood -= 25
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/residential/office/clener1.jpg"></center>'
			if workDolg > 0:
				'You spend an hour mopping and scrubbing all the floors, reducing your debt by 100 <b>₽</b>.'
				workDolg -= 100
			else
				'You spend an hour mopping and scrubbing all the floors. You are paid 100 <b>₽</b> for your work.'
				money += 100
			end

			gs 'sweat', 'add', 30


			act 'Leave':gt 'city_saunawhore', 'saunawork'
		end
	end

	if npc_QW['A113'] = 1 and workDolg <= 0 and belgangPay <= 0:
		cla & *clr
		menu_off = 0
		gs'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/fedor/fedorev/Strela/vadimbely.jpg"></center>'
		'You see a familiar face as you enter the sauna. Vadim Bely stands with his brother. "Good news little whore, you''ve finally paid off your debt. You''re free to do whatever you want now."'
		'You look at him with hate-filled eyes. "Do you know what you put me through here? You''re the most despicable man I''ve ever met in my life!"'
		*nl
		'Vadim laughs loudly. "Choose your words carefully girl. I''m still in control of your future and maybe I think you haven''t paid off your debt yet?"'
		'Not wanting to escalate the situation, you look down at the floor in silence.'
		'"Good girl. Now that you''re free, how about you come and party with us to celebrate your freedom?"'
		act 'No':
			cla & *clr
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/fedor/fedorev/Strela/vadimbely.jpg"></center>'
			'"No. I''m sorry, but I just want to go home... Maybe some other time."'
			'Vadim looks at you with a serious stare. "You''re lucky I''m in a good mood today. I''ll let it slide this time."'
			'You quickly gather your stuff before he has a change of heart and run outside the sauna.'
			npc_QW['A113'] = 2

			act 'Leave':gt 'city_residential'
		end
	end
end

if $ARGS[0] = 'bathroom':
	$loc = 'city_saunawhore'
	$loc_arg = 'bathroom'
	$locM = 'city_saunawhore'
	$locM_arg = 'bathroom'
	$menu_loc = 'city_saunawhore'
	$menu_arg = 'bathroom'
	$location_type = 'bathroom'
	menu_off = 0

	*clr & cla
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/brothel/brothelshower.jpg"></center>'
	''
	'You enter the staff bathroom, which is usually cleaned by the new girls who have just started working here, whether they want to or not.'
	'There is a <a href="exec:gt ''mirror'', ''start''">mirror</a>, where you can ' + iif(pcs_hairbsh < 1,'<a href="exec:gt ''mirror'',''brush''">brush</a>','brush') + ' your hair, a shower, toilet and a sink.'

	act 'Return to they foyer': minut += 1 & gt 'city_saunawhore', 'saunawork'

	act 'Take a shower (0:15)':
		cls
		minut += 15
		menu_off = 1
		gs 'stat'
		dynamic $showerdin
		'<center><h3>Staff Bathroom</h3></center>'
		'<center><img <<$set_imgh>> src="images/locations/shared/brothel/brothelshower.jpg"></center>'
		''
		'You strip from your clothes and gather up your towel, washcloth and soap before heading to the shower. You thoroughly wash yourself so you''re as clean as possible for potential customers.'
		if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
		if workDolg > 0:
			if mc_inventory['razor'] <= 0: mc_inventory['razor'] =  5
			dynamic $brit
		elseif workDolg = 0 and mc_inventory['razor'] > 0:
			dynamic $brit
		end
		dynamic $dryOff
	end

	if workDolg > 0 and mc_inventory['razor'] > 0:
		*nl
		'You have a handful of cheap razors you can use, enough for <<mc_inventory[''razor'']>> shaves. <a href="exec:gs ''din_van'', ''shave_options''">Shave Options</a>'
		dynamic $brit
	elseif workDolg > 0 and mc_inventory['razor'] =  0:
		*nl
		'You have <<mc_inventory[''razor'']>> razors left. You should go to your room and ask for more.'
	elseif workDolg <= 0 and mc_inventory['razor'] > 0:
		*nl
		'Your current pack of razors will last for <b><<mc_inventory[''razor'']>></b> more shaves. <a href="exec:gs ''din_van'', ''shave_options''">Shave Options</a>'
		dynamic $brit
	elseif workDolg = 0 and mc_inventory['razor'] =  0:
		*nl
		'You have <<mc_inventory[''razor'']>> razors left. You should to go to the store and buy more.'
	end
	gs 'din_van', 'prvt_pee'
	dynamic $enema
	dynamic $tampon
	dynamic $quickwash
	dynamic $bteeth
	dynamic $basin
	if mc_inventory['breast_pump'] > 0 and bp_unbox >= 1:
		act 'Use breast pump' :gt 'lact_bp', 'bp_milking'
	end
end

if $ARGS[0] = 'debtPay':
	if money > workDolg:
		money -= workDolg
		workDolg = 0
	elseif workDolg > money:
		workDolg -= money
		money = 0
	end
end

if $ARGS[0] = 'clientGate':

	if rand(0,19) = 0:gt 'city_saunawhore', 'bdsmclient'

	moodTypeRand = rand(-3, 3)

	! customer body type
	! -1=skinny, 3-4=regular, 5-6=muscular, 7+=fat
	bodyTypeRand = 3

	! customer height type
	! -1=small, 3-4=regular, 5+=tall
	heightTypeRand = 3

	! customer age
	customerAge = rand(15, 90)

	gs 'npcgeneratec', 0, 'client', customerAge
	gs 'boyStat', $npclastgenerated

	! customer race, racial modifiers, dick modifiers
	raceRand = rand(1, 10)
	if RaceRand <= 7:
		$raceType = 'white'
		dickChance = 30
		bodyTypeRand += rand(-2, 8)
		heightTypeRand += rand(-1, 6)
	elseif RaceRand <= 9:
		$raceType = 'asian'
		dickChance = 20
		bodyTypeRand += rand(-6, 2)
		heightTypeRand += rand(-4, 1)
	else
		$raceType = 'black'
		dickChance = 40
		bodyTypeRand += rand(0, 6)
		heightTypeRand += rand(0, 6)
	end

	dickRand = rand(1, 100)
	if dickRand <= dickChance:
		dick = rand(15, 30)
	elseif dickRand <= (dickChance * 2):
		dick = rand(10, 20)
	else
		dick = rand(8, 12)
	end

	! customer dick size
	if dick >= 26:
		$dick_girth = 'monstrous'
		cumVol = rand(4, 5)
	elseif dick >= 23:
		$dick_girth = 'massive'
		cumVol = rand(3, 5)
	elseif dick >= 20:
		$dick_girth = 'thick'
		cumVol = rand(2, 5)
	elseif dick >= 16:
		$dick_girth = 'thicker than average'
		cumVol = rand(2, 4)
	elseif dick >= 12:
		$dick_girth = 'well proportioned'
		cumVol = rand(1, 4)
	else
		$dick_girth = 'slim'
		cumVol = rand(0, 3)
	end

	! customer cum volume
	if cumVol <= 1:
		$cumType = 'a bit of'
		cumVolMl = 10
	elseif cumVol = 2:
		$cumType = 'some'
		cumVolMl = 20
	elseif cumVol = 3:
		$cumType = 'his warm'
		cumVolMl = 40
	elseif cumVol = 4:
		$cumType = 'a lot of'
		cumVolMl = 60
	elseif cumVol >= 5:
		$cumType = 'an enormous amount of'
		cumVolMl = 100
	end

	if bodyTypeRand <= 1:
		$bodyType = 'thin'
	elseif bodyTypeRand >= 2 and bodyTypeRand <= 4:
		$bodyType = 'athletic'
	elseif bodyTypeRand >= 5 and bodyTypeRand <= 6:
		$bodyType = 'stout'
	elseif bodyTypeRand >= 7:
		$bodyType = 'fat'
	end

	if heightTypeRand <= 1:
		$heightType = 'short'
	elseif heightTypeRand >= 2 and heightTypeRand <= 4:
		$heightType = 'average height'
	elseif heightTypeRand >= 5:
		$heightType = 'tall'
	end

	if customerAge <= 18:
		$ageType = 'a teenage'
	elseif customerAge > 18 and customerAge <= 30:
		$ageType = 'a young'
	elseif customerAge > 30 and customerAge <= 45:
		$ageType = 'a middle-aged'
	elseif customerAge > 45 and customerAge <= 60:
		$ageType = 'a late middle-aged'
	elseif customerAge > 60 and customerAge <= 80:
		$ageType = 'an elderly'
	elseif customerAge > 80:
		$ageType = 'a very old'
	end

	minut += 5
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/room.jpg"></center>'
	'You lead the client into your room, closing the door behind him. He sits down in the chair and stares at you with obvious lust.'
	'He is <<$ageType>> <<$raceType>> man, and he is <<$heightType>> and <<$bodyType>>.'
	if dick >= 16:'From the bulge in his pants, you can tell he probably has a <<$dick_girth>> dick.'
	'He seems to be in a <<$moodType>> mood.'

	if $clothingworntype = 'nude':
		if pcs_inhib < 40:
			inhib_exp += rand(2,4)
		elseif pcs_inhib >= 40 and pcs_inhib < 60:
			inhib_exp += 1
		end
		moodTypeRand += 1
		act 'Get straight to business':gt 'city_saunawhore', 'strippedGate'
		gs 'arousal', 'foreplay', 3, 'prostitution'
		gs 'stat'
	else
		if pcs_dancero >= 10:act 'Do a little striptease':gt 'city_saunawhore', 'striptease'
		act 'Take off your clothes':gt 'city_saunawhore', 'simplystrip'
	end
end

if $ARGS[0] = 'striptease':
	gs 'exp_gain', 'dancero', rand(0,1)
	if pcs_inhib < 40:
		inhib_exp += rand(2,4)
	elseif pcs_inhib >= 40 and pcs_inhib < 60:
		inhib_exp += 1
	end
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/striptease'+rand(1, 5)+'.mp4"></video></center>'
	'Hoping to please the customer, you decide to give him a little show. You count a beat in your head and begin dancing, slowly stripping away your clothes, one piece at a time. It would probably be better if you had actual music, but the client smirks and seems to enjoy it nonetheless.'
	moodTypeRand += 1
	gs 'arousal', 'foreplay', 5, 'prostitution'
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'strippedGate'
end

if $ARGS[0] = 'simplystrip':
	gs 'exp_gain', 'dancero', rand(0,1)
	if pcs_inhib < 40:
		inhib_exp += rand(1,2)
	elseif pcs_inhib >= 40 and pcs_inhib < 60:
		inhib_exp += rand(0,1)
	end
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/simplystrip'+rand(1, 2)+'.mp4"></video></center>'
	'You remove your clothes and toss them aside, mentally preparing for the task ahead. The client looks vaguely irritated - perhaps he expected something a bit more provacative?'
	moodTypeRand -= 1
	gs 'arousal', 'foreplay', 2, 'prostitution'
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'strippedGate'
end

if $ARGS[0] = 'strippedGate':
	minut += 2
	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/nakedstand.jpg"></center>'
	'You are fully naked in front of the client, his eyes devouring every inch of your body.'

	if pcs_dancero >= 20:act 'Dance naked':gt 'city_saunawhore', 'nakeddance'
	if guy >= 20:act 'Present your holes to him':gt 'city_saunawhore', 'holeshow'
	act 'Kneel and open your mouth':gt 'city_saunawhore', 'blowjob'
end

if $ARGS[0] = 'nakeddance':
	gs 'exp_gain', 'dancero', rand(0,1)
	if pcs_inhib < 40:
		inhib_exp += rand(3,6)
	elseif pcs_inhib >= 40 and pcs_inhib < 60:
		inhib_exp += rand(1,2)
	end
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/nakeddance'+rand(1, 4)+'.mp4"></video></center>'
	'You walk towards the client, straddle his legs, and begin to dance. He leans back and you proceed to give him the best lapdance you can muster. You alternate between rubbing your breasts in his face and turning around to grind your ass on his crotch. Judging from the hardness in his pants, it seems that he is pleased with your efforts.'
	moodTypeRand += 1
	gs 'arousal', 'foreplay', 5, 'prostitution'
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'blowjob'
end

if $ARGS[0] = 'holeshow':
	if pcs_inhib < 40:
		inhib_exp += rand(3,6)
	elseif pcs_inhib >= 40 and pcs_inhib < 60:
		inhib_exp += rand(1,2)
	end
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/holeshow'+rand(1, 5)+'.mp4"></video></center>'
	'You decide to tease him further. You lean in close to him and open your mouth, sticking your tongue out and sucking your fingers before you turn around, bend over and grab your ass with both hands.'
	'You pull your ass cheeks apart, giving him a great view of both your holes.'
	moodTypeRand += 1
	gs 'arousal', 'foreplay', 5, 'prostitution'
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'blowjob'
end

if $ARGS[0] = 'blowjob':
	minut += 5
	
	if $moodType = 'fairly normal':
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/blowjob'+rand(1, 5)+'.mp4"></video></center>'
		'You kneel in front of him and bite your lip, caressing his cock through his pants with your hands. He pulls out his <<$dick_girth>> dick and brings it to your <<$pc_desc[''lips'']>> lips.'
		'You start kissing the tip, licking it all around and putting it a bit inside your mouth and sucking the head.'
		gs 'arousal', 'bj', 5, 'prostitution'
		gs 'stat'

		act 'Suck it':gt 'city_saunawhore', 'blowjobGate'
	elseif $moodType = 'good':
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/blowjob'+rand(1, 5)+'.mp4"></video></center>'
		'You kneel in front of him and bite your lip, caressing his cock through his pants with your hand.'
		'He then fondles your hair and face and takes you gently by your arm, pulling you up from the floor. He directs you to the bed, undresses and both of you lie down.'

		act 'Embrace him':gt 'city_saunawhore', 'fuckGate'
	elseif $moodType = 'bad':
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/slapface'+rand(1, 1)+'.mp4"></video></center>'
		'You kneel in front of him and bite your lip, caressing his cock through his pants with your hands.'
		'He comes close to you and suddenly slaps your face hard. You''re caught by surprise and tears well up in your eyes. He seems very angry and even aroused by your misfortune.'
		'As you kneel in front of him in tears, he grabs you roughly by your arms, painfully twisting them behind your back, and slams you down on the bed.'
		gs 'pain', 1, 'cheeks', 'slap'
		if slutty < 10:
			Mana -= 50
		else
			Mana -= 10
		end

		gs 'pain', 2, 'armL', 'twist'
		gs 'pain', 2, 'armR', 'twist'
		act 'Brace yourself':gt 'city_saunawhore', 'fuckRoughGate'
	end
	gs 'stat'
end

if $ARGS[0] = 'blowjobGate':
	'You begin to suck his cock in earnest, bobbing your head back and forth while running your tongue along the underside of his shaft.'
	'He is rock hard now and you can see his <<$dick_girth>> <<dick>>cm member in all its glory.'
	'He seems to be content with your performance, but you think he wants you to go further.'
	gs 'arousal', 'bj', 5, 'prostitution'
	gs 'stat'
	if dick > pcs_throat:
		'There''s no way you''ll be able to fit the entire thing in your mouth.'
		act 'Try to deepthroat him':gt 'city_saunawhore', 'blowjobCaress'
	else
		act 'Deepthroat him':gt 'city_saunawhore', 'blowjobDeepthroat'
	end
end

if $ARGS[0] = 'blowjobCaress':
	'You try to deepthroat him, but his <<$dick_girth>> cock is just too big for you to handle, and you end up gagging yourself and coughing.'
	gs 'arousal', 'bj', 5, 'prostitution', 'deepthroat'
	''
	moodChange = rand (-2, 0)
	moodTypeRand += moodChange

	if $moodType = 'good':
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/blowjob'+rand(1, 5)+'.mp4"></video></center>'
		'He seems to enjoy your efforts anyway, and signals that he''s ready to move on to the next stage.'
		act 'Continue':gt 'city_saunawhore', 'fuckGate'
	elseif $moodType = 'fairly normal':
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/blowjob'+rand(1, 5)+'.mp4"></video></center>'
		'He seem to have had enough as he takes your hand and directs you towards the bed.'
		act 'Continue':gt 'city_saunawhore', 'fuckGate'
	elseif $moodType = 'bad':
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/slapface'+rand(1, 1)+'.mp4"></video></center>'
		'He scowls at your pathetic attempt and pulls his cock out of your mouth.'
		question = rand (1, 3)
		if question = 1:
			'He slaps your face hard. "What the hell is wrong with you? What kind of whore is this bad at sucking cock?!"'
		elseif question = 2:
			'He slaps your face hard. "My cock isn''t tasty enough for you to suck on properly, bitch?!"'
		elseif question = 3:
			'He slaps your face hard. "What kind of good-for-nothing whore are you?!"'
		end
		gs 'pain', 1, 'cheeks', 'slap'
		'Furious, he grabs you roughly by your arms, painfully twisting them behind your back, and slams you down on the bed.'
		act 'Continue':gt 'city_saunawhore', 'fuckRoughGate'
	end
	gs 'stat'
end

if $ARGS[0] = 'blowjobDeepthroat':
	moodChange += rand (-1, 2)
	moodTypeRand += moodChange
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/deepthroat'+rand(1, 5)+'.mp4"></video></center>'
	'The client groans as you take him all the way to the hilt - his <<$dick_girth>> <<dick>>cm cock is pushing deep into your throat.'
	'You try to hold it as long as possible while teasing his balls with your tongue.'
	if $moodType = 'bad':
		'He gets a sadistic look in his eye, and then grabs the back of your head and holds you down, not letting you escape.'
		'You feel yourself beginning to suffocate and panic, trying to get away from him, but he is much stronger than you and holds you tightly in place. Your eyes begin to roll back and you feel your conciousness fading when he finally releases you. You hack and sputter, thick strands of saliva hanging from his cock to your mouth. He seems to have enjoyed that quite a lot.'
	end
	gs 'arousal', 'bj', 5, 'prostitution', 'deepthroat'
	'He seems to have had enough and signals that he wants some more.'
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'fuckGate'
end

if $ARGS[0] = 'fuckGate':
	minut += 2
	noCondChance = rand(1, 100)
	if noCondChance < 40:
		'He leers at you lustfully. "So baby, how much for not using a condom?"'
		'When you hesitate, he adds, "Come on, I''ll pay you double."'
		act 'Let him fuck you without a condom':gt 'city_saunawhore', 'fuckGateCondomNo'
		act 'Insist on using a condom':gt 'city_saunawhore', 'fuckGateCondomYes'
	else
		gs 'city_saunawhore', 'fuckGateCondomYes'
	end
	gs 'stat'
end

if $ARGS[0] = 'fuckGateCondomYes':
	useCondom = 1
	moodTypeRand -= 2
	gs 'city_saunawhore', 'fuckGateGo'
end

if $ARGS[0] = 'fuckGateCondomNo':
	useCondom = 2
	moodTypeRand += 1
	gs 'city_saunawhore', 'fuckGateGo'
end

if $ARGS[0] = 'fuckGateGo':
	minut += 2
	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/lieonbedboth.jpg"></center>'
	'You lie back on the bed in front of the client.'
	'"How do you want me?" you ask teasingly.'
	if $moodType = 'bad':
		'"How do I want you whore? I want you screaming!"'
		forced = 1
		act 'Continue':gt 'city_saunawhore', 'fuckRoughGate'
	else
		forced = 2
		holeType = rand(1, 2)
		if holeType = 1:
			'"I want some pussy."'
			act 'Spread your legs':gt 'city_saunawhore', 'fuckVaginal'
		elseif holeType = 2:
			'"I want to fuck your ass."'
			act 'Turn around and spread your ass':gt 'city_saunawhore', 'fuckAnal'
		end
	end
	gs 'stat'
end

if $ARGS[0] = 'fuckVaginal':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/fuckvaginal'+rand(1, 5)+'.mp4"></video></center>'
	'He climbs on top of you and pushes his dick inside you.'
	if dick > pcs_vag:
		'His <<$dick_girth>> <<dick>>cm cock is too big for your pussy and causes you intense pain, stretching you past your limit and bringing tears to your eyes. At least he isn''t too rough.'
		'He thrusts his <<$dick_girth>> <<dick>>cm cock into you over and over, seeming to enjoy the tightness and not caring much about your pain.'
		DMG = (dick - pcs_vag) / 2
		gs 'pain', 1, 'vaginal', 'stretch'
		pcs_mood -= (DMG * 5)
		gs 'arousal', 'vaginal', 10, 'prostitution', 'rough'
	else
		'He thrusts his <<$dick_girth>> <<dick>>cm cock into you over and over, not caring much about technique or your own pleasure.'
		gs 'arousal', 'vaginal', 10, 'prostitution'
	end
	''
	'After a while, you can sense that he''s about to cum.'
	gs 'stat'
	if 	useCondom = 2:
		act 'Ask him not to cum inside you':
			not_inside = 1
			gt 'city_saunawhore', 'cumClientGate'
		end
	end
	act 'Let him cum wherever he wants':
		not_inside = 2
		gt 'city_saunawhore', 'cumClientGate'
	end
end

if $ARGS[0] = 'fuckAnal':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/fuckanal'+rand(1, 5)+'.mp4"></video></center>'
	'He climbs on the bed behind you, presses the tip of his dick against your asshole and begins to push it in.'
	if dick > pcs_ass:
		'His <<dick>> cm <<$dick_girth>> cock is too big for your ass and causes you intense pain as it stretches you out painfully and presses deep inside of you.'
		'He thrusts his <<$dick_girth>> <<dick>>cm cock into your ass over and over, seeming to enjoy the tightness and not caring much about your pain.'
		DMG = (dick - pcs_ass) / 2
		gs 'pain', 1, 'asshole', 'stretch'
		pcs_mood -= (DMG * 5)
		gs 'arousal', 'anal', 10, 'prostitution', 'rough'
	else
		'He thrusts his <<$dick_girth>> <<dick>>cm cock into your ass over and over, not caring much about technique or whether or not you''re enjoying it.'
		gs 'arousal', 'anal', 10, 'prostitution'
	end
	''
	'After a while, you can sense that he''s about to cum.'
	gs 'stat'
	act 'Let him cum wherever he wants':
		not_inside = 2
		gt 'city_saunawhore', 'cumClientGate'
	end
end


if $ARGS[0] = 'fuckRoughGate':
	minut += 5
	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bedoverpowered.jpg"></center>'
	'The man is much stronger than you, and you are completely overpowered and entirely at his will.'
	'He keeps your arms pinned painfully behind your back as he fucks you hard.'
	pcs_mood -= 50
	useCondom = rand(1,2)
	forced = 1
	gs 'pain', 2, 'armL', 'twist'
	gs 'pain', 2, 'armR', 'twist'
	holeType = rand(1, 2)
	if holeType = 1 and useCondom = 1:
		'You feel the tip of his cock against your pussy. It feels like he''s using a condom.'
		act 'Continue':gt 'city_saunawhore', 'fuckRoughVaginal'
	elseif holeType = 1 and useCondom = 2:
		'You feel the tip of his cock against your pussy. It feels like he''s not wearing a condom!'
		act 'Continue':gt 'city_saunawhore', 'fuckRoughVaginal'
	elseif holeType = 2:
		'You feel the tip of his cock pressing against your asshole.'
		act 'Continue':gt 'city_saunawhore', 'fuckRoughAnal'
	end
	gs 'stat'
end

if $ARGS[0] = 'fuckRoughVaginal':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/fuckroughvaginal'+rand(1, 5)+'.mp4"></video></center>'
	'He forces his dick inside you and begins to roughly fuck your tender pussy.'
	'You cannot help but scream in pain, which seems to arouse him even more and makes him push even harder and deeper.'
	if dick > pcs_vag:
		'His <<$dick_girth>> <<dick>>cm is too big for your pussy and causes you intense pain, stretching you horribly and slamming against your cervix.'
		DMG = (dick - pcs_vag)
		gs 'pain', 2, 'vaginal', 'stretch'
		!gs 'pain', 2, 'cervix', 'pinch'
		pcs_mood -= (DMG * 5)
	end
	gs 'arousal', 'vaginal', 10, 'prostitution', 'rough', 'bound'
	''
	'After seemingly endless fucking, you finally sense that he''s about to cum.'
	gs 'stat'
	if 	useCondom = 2:
		act 'Beg him not to cum inside you':
			not_inside = 1
			gt 'city_saunawhore', 'cumClientGate'
		end
	end
	act 'Let him cum wherever he wants':
		not_inside = 2
		gt 'city_saunawhore', 'cumClientGate'
	end
end

if $ARGS[0] = 'fuckRoughAnal':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/fuckroughanal'+rand(1, 5)+'.mp4"></video></center>'
	'He roughly shoves his entire cock up your ass and begins to fuck it furiously.'
	'You cannot help but scream in agony, which arouses him even more and makes him push even harder and deeper.'
	if dick > pcs_ass:
		'His <<$dick_girth>> <<dick>>cm is too big for your ass and causes you intense pain, stretching you out and making it feel like you''re being ripped open.'
		DMG = (dick - pcs_ass)
		gs 'pain', 2, 'asshole', 'stretch'
		pcs_mood -= (DMG * 5)
	end
	not_inside = 2
	gs 'arousal', 'anal', 10, 'prostitution', 'rough', 'bound'
	''
	'After seemingly endless assfucking, you finally sense that he''s about to cum.'
	gs 'stat'
	act 'Let him cum wherever he wants':gt 'city_saunawhore', 'cumClientGate'
end

if $ARGS[0] = 'cumClientGate':
	if $moodType = 'bad':
		if not_inside = 2:
			cumRand = rand(1, 10)
			if cumRand <= 9 and holeType = 1:
				'You feel his cock twitch and realize he''s about to cum inside you.'
				act 'Continue':gt 'city_saunawhore', 'cumVaginal'
			elseif cumRand <= 9 and holeType = 2:
				'You feel his cock twitch and realize he''s about to cum in your ass.'
				act 'Continue':gt 'city_saunawhore', 'cumAnal'
			else
				'He pulls out and brings his cock up to your face.'
				act 'Continue':gt 'city_saunawhore', 'cumFace'
			end
		else
			cumRand = rand(1, 2)
			if cumRand = 1 and holeType = 1:
				'He just laughs and you realize he''s going to cum inside you anyway.'
				act 'Continue':gt 'city_saunawhore', 'cumVaginal'
			elseif cumRand = 2:
				'He just smirks. "Fine. How about in your eyes then, whore?"'
				gs 'pain', 1, 'eyes', 'burn'
				act 'Continue':gt 'city_saunawhore', 'cumFace'
			end
		end
	else
		if not_inside = 2:
			cumRand = rand(1, 5)
			if cumRand = 1 and holeType = 1:
				'You feel his cock twitch and realize he''s about to cum inside you.'
				act 'Continue':gt 'city_saunawhore', 'cumVaginal'
			elseif cumRand = 1 and holeType = 2:
				'You feel his cock twitch and realize he''s about to cum in your ass.'
				act 'Continue':gt 'city_saunawhore', 'cumAnal'
			elseif cumRand = 2:
				'He pulls out and brings his cock up to your face.'
				act 'Continue':gt 'city_saunawhore', 'cumFace'
			elseif cumRand = 3:
				'He pulls out and brings his cock up to your face.'
				act 'Continue':gt 'city_saunawhore', 'cumMouth'
			elseif cumRand = 4:
				'He pulls out and holds his cock over your body.'
				act 'Continue':gt 'city_saunawhore', 'cumBelly'
			elseif cumRand = 5:
				'He pulls out and holds his cock over your body.'
				act 'Continue':gt 'city_saunawhore', 'cumTits'
			end
		else
			cumRand = rand(1, 9)
			if cumRand <= 2:
				'He nods, pulls out and brings his cock up to your face.'
				act 'Continue':gt 'city_saunawhore', 'cumFace'
			elseif cumRand <= 4:
				'He nods, pulls out and brings his cock up to your face.'
				act 'Continue':gt 'city_saunawhore', 'cumMouth'
			elseif cumRand <= 6:
				'He nods, pulls out and holds his cock over your body.'
				act 'Continue':gt 'city_saunawhore', 'cumBelly'
			elseif cumRand <= 8:
				'He nods, pulls out and holds his cock over your body.'
				act 'Continue':gt 'city_saunawhore', 'cumTits'
			else
				'He shakes his head. "Sorry, I can''t stop now!" You realize he''s going to cum in you anyway!'
				act 'Continue':gt 'city_saunawhore', 'cumVaginal'
			end
		end
	end
end

if $ARGS[0] = 'cumVaginal':
	minut += 5
	if useCondom = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/cumcondomvaginal.jpg"></center>'
		'The client''s cock twitches several more times as he cums into the condom.'
		'He rips the condom from his dick, and you see that it has <<$cumType>> cum in it.'
		moodTypeRand += rand (-2, 2)
		if $moodType = 'bad':
			'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/cumcondompourface.jpg"></center>'
			'He then suddenly grabs your head and pours the contents over your face.'
			gs 'cum_call', '', 'sauna client', 0, 3, 0, cumVolMl
			gs 'cum_call', 'face', 'sauna client', 0, 0, 0, cumVolMl
		elseif $moodType = 'fairly normal':
			'He throws it on the floor, not caring about spilling the fluids around.'
			gs 'cum_call', '', 'sauna client', 0, 3, 0, cumVolMl
		elseif $moodType = 'good':
			'He throws it in the waste bin and gently caresses your hair afterwards.'
			gs 'cum_call', '', 'sauna client', 0, 3, 0, cumVolMl
		end
	else
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/cumvaginal'+rand(1, 5)+'.mp4"></video></center>'
		'The client''s cock twitches several more times, and you feel a warmth spreading inside you as he pumps <<$cumType>> cum deep inside your pussy.'
		gs 'cum_call', '', 'sauna client', 0, 0, 0, cumVolMl
		if rand(1,100) >= 70:gs 'dinSex', 'std_trigger'
	end
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'clientLeave'
end

if $ARGS[0] = 'cumAnal':
	if useCondom = 1:
		'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/cumcondomanal.jpg"></center>'
		'The client''s cock twitches several more times as he cums into the condom.'
		'He rips the condom from his dick, and you see that it has <<$cumType>> cum in it.'
		moodTypeRand += rand (-2, 2)
		if $moodType = 'bad':
			'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/cumcondompourface.jpg"></center>'
			'He then suddenly grabs your head and pours the contents over your face.'
			gs 'cum_call', 'anus', 'sauna client', 0, 3, 0, cumVolMl
			gs 'cum_call', 'face', 'sauna client', 0, 0, 0, cumVolMl
		elseif $moodType = 'fairly normal':
			'He throws it on the floor, not caring about spilling the fluids around.'
			gs 'cum_call', 'anus', 'sauna client', 0, 3, 0, cumVolMl
		elseif $moodType = 'good':
			'He throws it in the waste bin and gently caresses your hair afterwards.'
			gs 'cum_call', 'anus', 'sauna client', 0, 3, 0, cumVolMl
		end
	else
		'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/cumanal'+rand(1, 5)+'.mp4"></video></center>'
		'The client''s cock twitches several more times, and you feel a warmth spreading inside you as he pumps <<$cumType>> cum deep inside your bowels.'
		if rand(1,100) >= 70:gs 'dinSex', 'std_trigger'
		gs 'cum_call', 'anus', 'sauna client', 0, 0, 0, cumVolMl
	end
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'clientLeave'
end

if $ARGS[0] = 'cumFace':
	
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/cumface'+rand(1, 5)+'.mp4"></video></center>'
	if useCondom = 1:
		'The client rips the condom from his dick and <<$cumType>> cum splatters all over your face.'
	else
		'The client finishes himself off and <<$cumType>> cum splatters all over your face.'
	end
	gs 'cum_call', 'face', 0, 0, 0, cumVolMl
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'clientLeave'
end

if $ARGS[0] = 'cumMouth':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/cummouth'+rand(1, 5)+'.mp4"></video></center>'
	if useCondom = 1:
		'The client rips the condom from his dick and shoots <<$cumType>> cum inside your mouth.'
	else
		'The client stuffs his dick back inside your mouth and shoots <<$cumType>> cum into your throat.'
	end
	if rand(1,100) >= 70:gs 'dinSex', 'std_trigger_oral'
	gs 'cum_call', 'mouth_swallow', 0, 0, 0, cumVolMl
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'clientLeave'
end

if $ARGS[0] = 'cumBelly':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/cumbelly'+rand(1, 5)+'.mp4"></video></center>'
	if useCondom = 1:
		'The client rips the condom from his dick and <<$cumType>> cum splatters all over your belly.'
	else
		'The client finishes himself off and <<$cumType>> cum splatters all over your belly.'
	end
	gs 'cum_call', 'stomach', 0, 0, 0, cumVolMl
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'clientLeave'
end

if $ARGS[0] = 'cumTits':
	'<center><video autoplay loop src="images/locations/city/residential/sauna/sex/cumtits'+rand(1, 5)+'.mp4"></video></center>'
	'You kneel down in front of him, raising your breasts higher for him to shoot his load on them.'
	if useCondom = 1:
		'The client rips the condom from his dick and shoots <<$cumType>> cum all over your tits.'
	else
		'The client finishes himself off and shoots <<$cumType>> cum all over your tits.'
	end
	gs 'cum_call', 'breasts', 0, 0, 0, cumVolMl
	gs 'stat'
	act 'Continue':gt 'city_saunawhore', 'clientLeave'
end

if $ARGS[0] = 'bdsmclient':
	cla
	*clr
	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bdsm1.jpg"></center>'
	'You''re brought into one of the private sauna rooms where they tell you that today you''ll be performing a different task than your regular routine.'
	'You look around and see some ropes hanging by a bench. Your body tenses as you come to the realization that the ropes are for you...'
	'"Don''t worry <<$pcs_nickname>>. This client is only somewhat kinky, so he won''t hurt you." they assure you as they make you sit on the bench and tie you up.'
	'"Just one last thing." they say as they put a paper bag over your head. They leave the room as you sit in silence.'
	act 'Sit and wait':
		cla
		*clr
		gs 'pain', 2, 'handL', 'bind'
		gs 'pain', 2, 'handR', 'bind'
		minut += 15
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bdsm2.jpg"></center>'
		'The ropes are chaffing, you''re uncomfortable and it feels like an eternity until you hear someone open the door. You hear some heavy steps come towards you but you can''t see anything.'
		'"Let me help you there." you hear a deep voice say as he removes the bag from your head. You flinch as you see he''s wearing a mask over his head.'
		'The man tells you to relax and that he doesn''t want to fuck you, only watch you squirm.'
		act 'Squirm':
			cla
			*clr
			minut += 4
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bdsm3.jpg"></center>'
			'Not wanting to upset the patron you begin acting as you''re fighting to get loose, grunting and moaning.'
			'"Good good." the man says as he drops his pants and begins touching his little cock. It''s quite clear why you needn''t have worried about getting fucked by this guy.'
			'You do this for some time while the man begins touching himself. This continues for a few minutes until he suddenly stops touching himself and also commands you to stop. He walks over to the door and whispers something to the men standing outside.'
			act 'Stand up':
				cla
				*clr
				minut += 10
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bdsm4.jpg"></center>'
				'The men quickly enter the room, grab hold of you and stand you up. "How do you want her?"'
				'The man stands pondering what to do next. "Tie her up like she is. I want to observe her while standing." the voice behind the mask commands.'
				'The men are pretty quick and tie your hands, mid-section and legs so you can''t move. They leave as soon as they''re done while the man begins touching his cock once again.'
				'"You have a great body girl, has anyone told you that?" he asks as you try to move your body to a comfortable position.'
				'"That''s right, squirm you little whore. I know you''re uncomfortable. How does it feel having someone else in control of your fate?"'
				'You''re starting to worry about what his intentions actually are.'
				act 'On all fours':
					cla
					*clr
					gs 'pain', 2, 'legs', 'bind'
					minut += 10
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bdsm5.jpg"></center>'
					'The man claps his hands and the men run inside the room again. "I want to see her from behind. And be sure to tie her up nicely, no weak ass shit like the last time."'
					'They quickly finish up, leaving you at the mercy of the man. "Like I said, you don''t have to worry. I won''t fuck you. To be in control is enough for me."'
					'You nod as you''re too afraid to speak. "Now spread your legs. I want to see your beautiful pussy lips."'
					'You try to spread your legs as much as you can, but the ropes are preventing you and the harder you try, the more painfully the ropes dig into you. You let out a desperate cry as he starts grunting.'
					act 'On your back':
						cla
						*clr
						gs 'pain', 4, 'labia', 'pinch'
						'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/sex/bdsm6.jpg"></center>'
						'"You little minx! Do you want me to cum this quickly? No no, we''re not done just yet." He once again calls in the men and they lie you on your back, spread your legs and tie you tightly. They also tie your hands above your head.'
						'"Excellent work. Did you bring what I asked for?" the man asks.'
						'Your stomach starts churning as you listen. The men hand over a brown bag and leave the room.'
						'The man walks up to you and without saying anything, takes out a number of pins and clips them along your labia. The pinching hurts, but is arousing at the same time.'
						'"Feels great, right? I know how to please women." the man confidently says. You answer with a loud moan. That''s enough for him as he starts tugging at his cock and it doesn''t take long before he cums on the floor. He quickly gets dressed, leaving you tied up.'
						gs 'arousal', 'foreplay', 15, 'prostitution', 'bound', 'sub'
						gs 'stat'
						act 'Finish':
							cla
							*clr
							basePay = (10 * rand(85,135))
							payment = (basePay / 2)
							'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/givemoney.jpg"></center>'
							if workDolg > 0:
							    workDolg -= payment
								'The client leaves the room and pays the sauna <<payment>> <b>₽</b> for your services.'
								'The men untie you and have you slowly turn around so the madam can be sure you are unmarked, then leave.'
							else
								money += payment
								'The client counts the money out as his men untie you. He hands you <<payment>> <b>₽</b> for your services.'
							end

							gs 'arousal', 'end'
							gs 'stat'

							act 'Head back to the main area':gt 'city_saunawhore', 'saunawork'
						end
					end
				end
			end
		end
	end
end

if $ARGS[0] = 'clientLeave':
	basePay = (10 * rand(75,125))
	if mc_inventory['equipped_condoms'] = 0:
		condomPrice = 100
	elseif mc_inventory['equipped_condoms'] > 0:
		dynamic $prezik
		condomPrice = 0
	end
	if forced = 2:
		payment = (basePay * useCondom) - condomPrice
	else
		payment = (basePay / 2) - condomPrice
	end
	'<center><img <<$set_imgh>> src="images/locations/city/residential/sauna/givemoney.jpg"></center>'

	if workDolg > 0:
		workDolg -= payment
		'Having finished with you, the client gets dressed, leaves the room and pays the sauna <<payment>> <b>₽</b> for your services.'

		gs 'arousal', 'end'
		gs 'stat'

		act 'Head back to the main area':gt 'city_saunawhore', 'saunawork'
	elseif nichTarSauna = 1:
		nichTarSaunaPay += payment
		'Having finished with you, the client gets dressed, leaves the room and pays the sauna <<payment>> <b>₽</b> for your services. This money will be collected by Taras later.'
		'You earned <<nichTarSaunaPay>> <b>₽</b> for Taras.'
		gs 'arousal', 'end'
		gs 'stat'
		act 'Head back to the main area':gt 'city_saunawhore', 'saunawork'
	else
		money += payment
		'Having finished with you, the client gets dressed, takes his wallet out and hands you <<payment>> <b>₽</b>.'

		gs 'arousal', 'end'
		gs 'stat'

		act 'Take the money and see him out':gt 'city_saunawhore', 'saunawork'
	end
end


--- city_saunawhore ---------------------------------