glife/locations/city_suburbs.qsrc

# city_suburbs
! 14-09-22 Added Metro link to navigation line 41

$location_type = 'public_outdoors'

if $ARGS[0]='start':
	$loc = 'city_suburbs'
	$loc_arg = 'start'
	$menu_loc = 'city_suburbs'
	$menu_arg = 'start'
	menu_off = 0
	gs'stat'
	'<center><H4>Elite settlement<H4></center>'
	'<left><img <<$set_imgh>> src="images/locations/city/suburb/settlement.jpg" ></left>'

	if car > 0 and cardrive = 28:'Your <a href="exec:GS ''carF'', ''start''"><<$car>></a> stands on the street.'

    if hour >= 4 and hour <= 23:'The <a href="exec: minut += 20 & gt ''metro'', ''start''">Metro</a> station is a 20 minute walk from here.'

	gs 'taxi'

	if AlexandriaQW > 6:
		if hour > 7 and hour < 20:'You can visit <a href="exec: minut += 5 & gt ''AlexandriaHome'', ''intercom''">Aleksei''s home</a> if you want to see the cranky wizard.'
	end

	if BDSMClub = 1 or BDSMmeet > 0:
		act 'BDSM-club':gt'BDSM_Club','start'
	end
	
	if func('homes_properties', 'has_access', 'matryona_mansion') = 0:
		'There is a vacant piece of land for sale where a large mansion could be constructed.'
		act 'Visit the land for sale': minut += 10 & gt 'city_mansion_entrance'
	elseif func('homes_properties', 'is_property_of_status', 'owned', 'matryona_mansion'):
		constructionstatus = func('homes_properties', 'get_property_construction_status', 'matryona_mansion')
		if constructionstatus = 0:
			'Your vacant plot of land is near hear'
		elseif constructionstatus = 1:
			'You mansion is partially built near here.'
		else
			'Your mansion is not too far from her'
		end
		act 'Visit your mansion': minut += 10 & gt 'city_mansion_entrance'
	else
		'One of the most impressive buildings is your newly built mansion.'
		act 'Visit Matryona Mansion': gt 'city_mansion_entrance'
	end
	act 'View the insane asylum': minut += 2 & gt 'city_suburbs', 'ps1'
	act 'View the creepy old building': minut += 2 & gt 'city_suburbs', 'ps2'

	act 'Walk to the main road':nroad = 1 & minut += 15 & gt 'road'
	if hour >= 4 and hour <= 23:
		act 'Walk to the Metro': minut += 5 & gt 'metro', 'start'
	end

	if AlexandriaQW = 6:
		gs 'willpower', 'misc', 'self', 'easy'
		if will_cost <= pcs_willpwr:
			act 'Look for Alexandria''s direction (<<will_cost>> Willpower)':
				gs 'willpower', 'pay', 'easy'
				gt'alexandriaEv','interview1'
			end
		else
			act 'Look for Alexandria''s direction (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	end
end

if $ARGS[0]='ps1':
	cla
	*clr
	$menu_loc = 'city_suburbs'
	$menu_arg = 'ps1'
	menu_off = 0
	gs'stat'
	'<center><H4>Insane asylum<H4></center>'
	'The inscription on the sign by the road reads, "Closed to the public".'
	if psiklik = 0:'<center><img <<$set_imgh>> src="images/locations/city/suburb/asylum0.jpg" ></center>'
	if psiklik = 1:'<center><img <<$set_imgh>> src="images/locations/city/suburb/asylum1.jpg" ></center>'

	act 'Go': minut += 2 & gt'city_suburbs','start'
end

if $ARGS[0]='ps2':
	cla
	*clr
	$menu_loc = 'city_suburbs'
	$menu_arg = 'ps2'
	menu_off = 0
	gs'stat'
	'<center><H4>An old abandoned building<H4></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/suburb/abandoned.jpg" ></center>'
	'An abandoned building that spoils the local communities appearance and intimidates local residents.'

	act 'Go': minut += 2 & gt'city_suburbs','start'
end

--- city_suburbs ---------------------------------