glife/locations/gadmarket.qsrc

# gadmarket

*clr & cla
$loc = 'gadmarket'
$loc_arg = ''
$menu_loc = 'gadmarket'
$menu_arg = ''
menu_off = 0
$location_type = 'public_indoors'

frost = 0

*pl '<center><h1><font color="maroon">Village Shop</font></h1></center>'
*pl '<center><img <<$set_imgh>> src="images/locations/gadukino/village/market.jpg"></center>'

'You walk into the small shop with four narrow aisles with chest high shelves crammed full of food and other household goods. There is little variety in the selections, just the most essential products.'
'Slowly you browse the aisles looking for something to buy.'
*nl
'As you approach the teller, you notice a rack full of magazines, cigarettes, and a few hygienic items.'
*nl

$gadmarkettab = '<center><table align="center">'
$gadmarkettab += FUNC ('$stock_item', 10, 'Package of tea biscuits', 400, 'pranik', 'gadmarket')
$gadmarkettab += FUNC ('$stock_item', 20, 'Cigarettes', 150, 'siga', 'gadmarket')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Fashion magazine', 145, 'fashmag', 'gadmarket')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Computer magazine', 145, 'compmag', 'gadmarket')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Biographical magazine', 145, 'biomag', 'gadmarket')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Cooking magazine', 145, 'cookmag', 'gadmarket')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Knitting magazine', 145, 'knitmag', 'gadmarket')
if preziktype = 0: $gadmarkettab += FUNC ('$stock_item', 5, 'Condoms', 600, 'prezik', 'gadmarket')
if preziktype = 1 or preziktype = 2: $gadmarkettab += FUNC ('$stock_item', 5, 'Condoms', 600, 'prezikcount', 'gadmarket')
$gadmarkettab += FUNC ('$stock_item', 20, 'Tampons', 250, 'tampon', 'gadmarket')
$gadmarkettab += FUNC ('$stock_item', 25, 'Razors (number of shaves)', 350, 'stanok', 'gadmarket')
$gadmarkettab += FUNC ('$stock_item', 30, 'Shampoo', 250, 'shampoo', 'gadmarket')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Bottle of water', 100, 'bottle', 'gadmarket', '', iif(bag > 0, 0, 1), 'You need a purse')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Sandwich', 100, 'buterbrod', 'gadmarket', '', iif(bag > 0, 0, 1), 'You need a purse')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Cheap Bottle of wine', 200, 'wine', 'gadmarket', '', iif(bag > 0, 0, 1), 'You need a purse')
$gadmarkettab += FUNC ('$single_stock_item', 1, 'Umbrella', 1000, 'umbrella', 'gadmarket', '', iif(bag > 0, 0, 1), 'You need a purse')
$gadmarkettab += '</table></center>'
*pl $gadmarkettab
killvar '$gadmarkettab'
gs 'stat'

act 'Leave the market': minut += 5 & gt 'gadukino'
if grandmaQW['chore_groceries'] = 1:
	act 'Gather the things on Grandma''s list (0:30)':
		*clr & cla
		minut += 30
		gs 'stat'
		
		grandmaQW['chore_groceries'] = 2
		grandmaQW['help_amount'] += 1
		
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/market.jpg"></center>'
		'You take out the list Grandma gave you and begin browsing the shelves for the items she needs. After about half an hour you have gotten everything on the list.'
		*nl
		'You take your basket of goods up to the teller and explain that you are getting these things for your grandmother.'
		'"Of course! Go ahead and take these on home to her. Tell her I will be by this evening to pick up her payment. I know it''s hard for her to get out any more..."'
		
		act 'Thank him and leave': minut += 5 & gt 'gadukino'
		act 'Thank him and take the groceries back to your grandmother (0:10)':minut += 10 & gt 'gadhouse','grandma'
	end
end

--- gadmarket ---------------------------------