glife/locations/unused/webcam_site.qsrc

# webcam_site

if $args[0] = 'start':
	!count-in the show day:
	if webcam_show_day ! daystart: webcam_show_count = 2
	cls
	minut += 1
	gs'stat'
	'<center>Video chat with the best girls online!</center>'
	'<center><img <<$set_imgh>> src="images/shared/accessories/computer/webcam/webcam.jpg"></center>'
	act 'Logout': gt 'Komp', 'start'
	gs 'willpower', 'exhib', 'self', 'hard'
	if $webcam_name = 0 and will_cost <= pcs_willpwr:
		'<center>If you are beautiful and you want to earn a little, revealing yourself, you need to have a webcam and go through a simple registration.</center>'
		act 'Register (<<will_cost>> Willpower)': dynamic $webcam_rega
		gs 'willpower', 'pay', 'self'
		gs 'stat'
	elseif will_cost > pcs_willpwr:
		act 'Register (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to register online.</font>.'
	else
		if $webcam_name > 0: '<center>Your username: <<$webcam_name>></center>' 
		if $webcam_name > 0: '<center><a href="exec: dynamic $webcam_stat">View your statistics</a></center>'
		if webcam_show_count <= 0:
			'You have already done a show today.'
		else
			act 'Post Show': dynamic $webcam_index
		end
		act 'Help': dynamic $webcam_help
		act 'Change username': dynamic $webcam_rega
	end
end

!-----------------------------------------------!
!--------Registration page online chat----------!
!-----------------------------------------------!
$webcam_rega = {
	cls
	minut = minut + 5
	gs 'stat'
	*nl
	'Registering online, please choose a username...'
	!$web_gg_name = '<<$pcs_nickname>>'
	$webcam_name = input ('Your username')
	cla
	'Your username: <<$webcam_name>>'
	act 'Further': gt 'webcam_site'
	!if $webcam_name = 0: $webcam_name = $web_gg_name
}

!-----------------------------------------------!
!---------Page statistics online chat-----------!
!-----------------------------------------------!
$webcam_stat = {
	cls
	minut = minut + 5
	gs'stat'
	'Your webcam username: <<$webcam_name>>
	Number of shows performed: <<webcam_show_counter>>
	Times stretching: <<webcam_show_flex>>
	Times stripping: <<webcam_show_strip>>
	Played with breasts: <<webcam_show_tits>>
	Masturbated: <<webcam_show_mast>>
	Dildo in mouth: <<webcam_show_throat>>
	Dildo in pussy: <<webcam_show_pussy>> 
	Dildo in ass: <<webcam_show_anus>>
	Dildo ass and pussy: <<webcam_show_dp>>
	Fisting: <<webcam_show_vfisting>>
	Anal Fisting: <<webcam_show_afisting>>
	Orgasmed: <<webcam_show_orgazm>>
	Squirted: <<webcam_show_squirt>>
	<hz>
	Total time on cam: <<webcam_show_time>> minutes.
	Total tips earned: <<webcam_show_money>> <b>₽</b>.
	'
	act 'Return': gt 'webcam_site'
}
!-----------------------------------------------!
!-------------Help page online chat-------------!
!-----------------------------------------------!
$webcam_help = {
	cls
	minut = minut + 5
	gs'stat'
	'
	Description of service:
	Video conference - this software allows users to conduct real-time video chat via the Web-Camera
	After registering, you will be able to broadcast shows, receiving tips from customers.
	In order to receive more tips, you need attract more users.
	One show per day only.
	Things that will increase your tips: 
	Use dildos, available from your local sex shop (The larger the better).
	Self-fisting earns lots of tips, but for this you need lubricant and the ability to take it. Otherwise, you will cause yourself a lot of pain, and you will not be able to put on a show when in pain.
	Orgasming during a show will earn you a bonus tip.
	'
	act 'To main': gt 'webcam_site'
}

!-----------------------------------------------!
!--------------Home online chat-----------------!
!-----------------------------------------------!

$webcam_index = {
	!act 'Exit': gt 'Komp', 'start'	
	if hour < 15 or (week < 6 and hour < 19):
		if hour < 7:
			'It''s too late to start a show. Too many people are asleep.'
		else
			if week < 6:
				'It''s too early to start a show. Too many people are at work.'
			else
				'Even if it''s the weekend, it''s still too early to start a show.'
			end
		end	
		if pav_slut <= 50: 'Maybe that''s for the best. You''re not sure you should be risking someone recognizing you anyway.'
	else
		my_show_show = 0
		my_show_tits = 0
		my_show_mast = 0
		my_show_throat = 0
		my_show_pussy = 0
		my_show_anus = 0
		my_show_afisting = 0
		my_show_vfisting = 0
		my_show_dp = 0
		my_show_sex = 0	
		my_show_squirt = 0	
		my_show_flex = 0
		show_counter = 0
		my_show_tip_all = 0
		my_show_tip = 0
		dynamic $webcam_show
	end
}
!-----------------------------------------------!
!---------Webcam shows online chat--------------!
!-----------------------------------------------!
!if $args[0] = 'show':
$webcam_show = {
	act 'Exit': gt 'Komp', 'start'
	
	my_show_tip_all += my_show_tip
!------------------------------!
!----------Late Show-----------!
!------------------------------!
	if show_counter = 4:
		*clr
		'<center><video autoplay loop src="images/shared/accessories/computer/webcam/end'+rand(1,2)+'.mp4"></video></center>'
		'You are already super tired, and the viewers need to take a breather after your super-duper show. It''s time to call it a day.'

		
		'You collected <<my_show_tip_all>> <b>₽</b> during today''s show.'

		webcam_show_day = daystart
		webcam_show_count -= 1
		money += my_show_tip_all	
		webcam_show_money += my_show_tip_all 
		webcam_show_time += 60 
		webcam_show_counter += 1
		elektro += 3
		internet -= 1
		minut += 60
		
		cla
		act 'Logout': gt 'webcam_site'
	end	
!------------------------------!
!--------Continued show--------!
!------------------------------!
	if show_counter > 0 and show_counter < 4:
		gs'stat'
		*clr
		'<center><video autoplay loop src="images/shared/accessories/computer/webcam/show'+rand(5,7)+'.mp4" ></video></center>'
		'The show must go on!'
		
		'You have already collected <<my_show_tip_all>> <b>₽</b> for the show.'
		
		show_counter += 1
		
		cla
		if my_show_show = 0:
			act 'Show yourself':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/show'+rand(1,4)+'.mp4" ></video></center>'
				'You bring your crotch right against the camera and let all your viewers see everything is as it should be.'
				
				my_show_tip = rand(50, 400)
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_show = 1
				
				cla
				act 'Further': dynamic $webcam_show
			end	
		end
!------------------------------!
!------------Boobs-------------!
!------------------------------!			
		if my_show_tits = 0:
			act 'Play with your breasts':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/tits'+rand(1,4)+'.mp4" ></video></center>'
				'At the request of the audience, you play with your breasts.'
				
				my_show_tip = rand(100, 400)
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_tits = 1
				webcam_show_tits +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end
		end			
!------------------------------!
!---------Masturbation---------!
!------------------------------!	
		if my_show_mast = 0:
			act 'Masturbate':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/mast'+rand(1,9)+'.mp4" ></video></center>'
				'You caress your pussy and ass, stroke your clitoris and rub your nipples.'
				
				my_show_tip = rand(100, 500)
				pcs_horny += 30
				
				!orgasm-Bonus Money				
				if pcs_horny > 100:
					'Soon you bring yourself to the limit and cum violently. Your tips sharply increase when this happens.'
					webcam_show_orgazm +=1
					my_show_tip += rand(50, 500)
					pcs_horny = 0
				end
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_mast = 1
				webcam_show_mast +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end
		end
!-----------------------------------------------!
!-----------Rubber cock in her mouth------------!
!-----------------------------------------------!	
		!! This was updated to include all the dildos as it previously was missing some. Most of the code was left
		!! as is with the additional dildos just merged into existing paths for simplicity. If this file is ever
		!! added back to the game, there should probably be separate branches for all dildo sizes. At the very
		!! least, they should give different tip amounts
		if my_show_throat = 0 and (dildo = 1 or (pcs_throat >= 15 and middildo = 1) or (pcs_throat >= 20 and largedildo = 1) or (pcs_throat >= 25 and bigdildo = 1) or (pcs_throat >= 30 and extradildo = 1) or (pcs_throat >= 35 and superdildo = 1) or (pcs_throat >= 40 and maddildo = 1)):
			act 'Dildo in the mouth':
				gs'stat'
				*clr
				!!Enormous dildos 35cm and 40cm
				if (pcs_throat >= 35 and superdildo = 1) or (pcs_throat >= 40 and maddildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/extrthroat'+rand(1,2)+'.mp4" ></video></center>'		

					'You take out your enormous ' + iif(pcs_throat >= 40 and maddildo = 1, '40cm', '35cm') + ' dildo and start trusting it into your throat.'
					
					my_show_tip = rand(600, 1400)
					if pcs_throat < 40: pcs_throat += 1
				!!Giant dildos 25cm and 30cm
				elseif (pcs_throat >= 25 and bigdildo = 1) or (pcs_throat >= 30 and extradildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/bigthroat'+rand(1,3)+'.mp4" ></video></center>'		

					'You get out your giant ' + iif(pcs_throat >= 30 and extradildo = 1, '30cm', '25cm') + ' dildo and begin to rhythmically drive it into your throat.'
					
					my_show_tip = rand(500, 1000)
					if pcs_throat < 30 or (pcs_throat < 35 and extradildo = 1): pcs_throat += 1
				!!Big dildos 15cm and 20cm
				elseif (pcs_throat >= 15 and middildo = 1) or (pcs_throat >= 20 and largedildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/midthroat'+rand(1,3)+'.mp4" ></video></center>'	
					'You get out your big ' + iif(pcs_throat >= 20 and largedildo = 1, '20cm', '15cm') + ' dildo and start licking it, sucking it, and shoving it into your mouth.'
					
					my_show_tip = rand(100, 500)
					if pcs_throat < 20 or (pcs_throat < 25 and largedildo = 1): pcs_throat += 1
				!!Normal dildo 10cm
				else
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/throat'+rand(1,3)+'.mp4" ></video></center>'
					'You get out your 10cm dildo and start to gently suck it.'
					
					my_show_tip = rand(100, 500)
					if pcs_throat < 15: pcs_throat += 1
				end
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_throat = 1
				webcam_show_throat +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end	
		end		
!-----------------------------------------------!
!-------------Rubber dick in pussy--------------!
!-----------------------------------------------!
		!! This was updated to include all the dildos as it previously was missing some. Most of the code was left
		!! as is with the additional dildos just merged into existing paths for simplicity. If this file is ever
		!! added back to the game, there should probably be separate branches for all dildo sizes. At the very
		!! least, they should give different tip amounts
		if vgape < 3 and my_show_pussy = 0 and (dildo = 1 or (pcs_vag >= 15 and middildo = 1) or (pcs_vag >= 20 and largedildo = 1) or (pcs_vag >= 25 and bigdildo = 1) or (pcs_vag >= 30 and extradildo = 1) or (pcs_vag >= 35 and superdildo = 1) or (pcs_vag >= 40 and maddildo = 1)):
			act 'Dildo in the pussy':
				gs'stat'
				*clr
				!!Enormous dildos 35cm and 40cm
				if (pcs_vag >= 35 and superdildo = 1) or (pcs_vag >= 40 and maddildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/extrvagin'+rand(1,2)+'.mp4" ></video></center>'		

					'You take out your enormous ' + iif(pcs_vag >= 40 and maddildo = 1, '40cm', '35cm') + ' dildo and start thrusting it into your pussy.'
					
					my_show_tip = rand(700, 1400)
					if pcs_vag < 40: pcs_vag += 1
				!!Giant dildos 25cm and 30cm
				elseif (pcs_vag >= 25 and bigdildo = 1) or (pcs_vag >= 30 and extradildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/bigvagin'+rand(1,3)+'.mp4" ></video></center>'		

					'You get out your giant ' + iif(pcs_vag >= 30 and extradildo = 1, '30cm', '25cm') + ' dildo and begin rhythmically driving it into your pussy.'
					
					my_show_tip = rand(400, 800)
					if pcs_vag < 30 or (pcs_vag < 35 and extradildo = 1): pcs_vag += 1
				!!Big dildos 15cm and 20cm
				elseif (pcs_vag >= 15 and middildo = 1) or (pcs_vag >= 20 and largedildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/midvagin'+rand(1,3)+'.mp4" ></video></center>'	
					'You get out your big ' + iif(pcs_vag >= 20 and largedildo = 1, '20cm', '15cm') + ' dildo and begin rhythmically driving it into your pussy.'
					
					my_show_tip = rand(200, 700)
					if pcs_vag < 20 or (pcs_vag < 25 and largedildo = 1): pcs_vag += 1
				!!Normal dildo 10cm
				else
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/vagin'+rand(1,3)+'.mp4" ></video></center>'
					'You get out your 10cm dildo and begin rhythmically driving it into your pussy.'
					
					my_show_tip = rand(100, 600)
					if pcs_vag < 15: pcs_vag += 1
				end
				
				pcs_horny += 30
				!orgasm-Bonus Money
				if pcs_horny > 100:
					'Soon you bring yourself to the limit and cum violently. Your tips sharply increase when this happens.'
					webcam_show_orgazm +=1
					my_show_tip += rand(100, 500)
					pcs_horny = 0
				end	
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_pussy = 1
				webcam_show_pussy +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end	
		end
!-----------------------------------------------!
!---------Rubber dick in the ass----------------!
!-----------------------------------------------!		
		!! This was updated to include all the dildos as it previously was missing some. Most of the code was left
		!! as is with the additional dildos just merged into existing paths for simplicity. If this file is ever
		!! added back to the game, there should probably be separate branches for all dildo sizes. At the very
		!! least, they should give different tip amounts
		if agape < 3  and my_show_anus = 0 and (dildo = 1 or (pcs_ass >= 15 and middildo = 1) or (pcs_ass >= 20 and largedildo = 1) or (pcs_ass >= 25 and bigdildo = 1) or (pcs_ass >= 30 and extradildo = 1) or (pcs_ass >= 35 and superdildo = 1) or (pcs_ass >= 40 and maddildo = 1)):
			act 'Dildo in the ass':
				gs'stat'
				*clr
				'You part your buttocks' + iif(analplugin = 1, ', remove your anal plug,', '') + ' and begin to massage your anus with your fingers, first one, then two.'
				!Butt plug
				analplugin = 0
				!grease
				if lubri > 0:
					lubri -= 1
					'You squeeze some lube onto your hand and begin to spread it on your hole. After that, you smear a little on your dildo.'
				end
				!!Enormous dildos 35cm and 40cm
				if (pcs_ass >= 35 and superdildo = 1) or (pcs_ass >= 40 and maddildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/extranal'+rand(1,3)+'.mp4" ></video></center>'		

					'You then take your enormous ' + iif(pcs_ass >= 40 and maddildo = 1, '40cm', '35cm') + ' dildo and start thrusting it into your ass.'
					
					my_show_tip = rand(700, 1400)
					if pcs_ass < 40: pcs_ass += 1
				!!Giant dildos 25cm and 30cm
				elseif (pcs_ass >= 25 and bigdildo = 1) or (pcs_ass >= 30 and extradildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/biganal'+rand(1,3)+'.mp4" ></video></center>'		

					'You then take your giant ' + iif(pcs_ass >= 30 and extradildo = 1, '30cm', '25cm') + ' dildo and begin rhythmically driving it into your ass.'
			
					my_show_tip = rand(500, 1000)
					if pcs_ass < 30 or (pcs_ass < 35 and extradildo = 1): pcs_ass += 1
				!!Big dildos 15cm and 20cm
				elseif (pcs_ass >= 15 and middildo = 1) or (pcs_ass >= 20 and largedildo = 1):
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/midanal'+rand(1,3)+'.mp4" ></video></center>'	
					'You then take your big ' + iif(pcs_ass >= 20 and largedildo = 1, '20cm', '15cm') + ' dildo and begin rhythmically driving it into your ass.'
					
					my_show_tip = rand(300, 800)
					if pcs_ass < 20 or (pcs_ass < 25 and largedildo = 1): pcs_ass += 1
				!normal dildo 10cm
				else
					'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/anal'+rand(1,3)+'.mp4" ></video></center>'
					'You then take your 10cm dildo and begin rhythmically driving it into your ass.'

					my_show_tip = rand(100, 500)
					if pcs_ass < 15: pcs_ass += 1
				end
				
				pcs_horny += 30
				!orgasm-Bonus Money
				if pcs_horny > 100:
					'Soon you bring yourself to the limit and cum violently. Your tips sharply increase when this happens.'
					webcam_show_orgazm +=1
					my_show_tip += rand(100, 500)
					pcs_horny = 0
				end	
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_anus = 1
				webcam_show_anus +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end	
		end	
!------------------------------!
!------Double penetration------!
!------------------------------!
		!! Might be good to differentiate between different dildo sizes here. In particular, maybe there should
		!! be different tip amounts for larger dildos like there are for the single dildo actions.
		if max(agape, vgape) < 3 and my_show_dp = 0 and iif(min(pcs_ass, pcs_vag) >= 10, dildo, 0) +  iif(min(pcs_ass, pcs_vag) >= 15, middildo, 0) + iif(min(pcs_ass, pcs_vag) >= 20, largedildo, 0) + iif(min(pcs_ass, pcs_vag) >= 25, bigdildo, 0) + iif(min(pcs_ass, pcs_vag) >= 30, extradildo, 0) + iif(min(pcs_ass, pcs_vag) >= 35, superdildo, 0) + iif(min(pcs_ass, pcs_vag) >= 40, maddildo, 0) >= 2:
			act 'Dildo in ass and pussy':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/toys/dp'+rand(1,3)+'.mp4" ></video></center>'
				'You part your legs' + iif(analplugin = 1, ', remove your anal plug,', '') + ' and begin massaging yourself with your fingers, first your pussy, then your ass.'
				!Butt plug
				analplugin = 0
				!grease
				if lubri > 0:
					lubri -= 1
					'You then squeeze some lube onto your hand and begin to spread it on them.'
				end
				'Now ready, you grab a pair of dildos and begin to rhythmically fuck your holes.'
				
				pcs_horny += 30
				!orgasm-Bonus Money
				if pcs_horny > 100:
					'Soon you bring yourself to the limit and cum violently. Your tips sharply increase when this happens.'
					webcam_show_orgazm +=1
					my_show_tip += rand(100, 600)
					pcs_horny = 0
				end		
				
				my_show_tip = rand(600, 1600)
				my_show_dp = 1
				webcam_show_dp +=1
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				cla
				act 'Further': dynamic $webcam_show
			end	
		end			
!------------------------------!
!-------Hand in the ass--------!
!------------------------------!		
		if agape < 3 and pcs_ass >= 30 and my_show_afisting = 0:
			act 'Anal fisting':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/afist'+rand(1,2)+'.mp4" ></video></center>'
				'You part your buttocks' + iif(analplugin = 1, ', remove your anal plug,', '') + ' and begin to massage your anus with your fingers, first one, then two.'
				!Butt plug
				analplugin = 0
				!grease
				if lubri = 0: agape = 3
				if lubri > 0:
					lubri -= 1
					'You squeeze some lube onto your hand and begin to spread it on your ass.'
				end
				'Now ready, you slowly begin to push more and more of your hand inside.'
				
				my_show_tip = rand(400, 1800)
				my_show_afisting = 1
				webcam_show_afisting +=1
				if pcs_ass <= 30: pcs_ass +=1
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				cla
				act 'Further': dynamic $webcam_show
			end	
		end	
!------------------------------!
!---------Hand in pussy--------!
!------------------------------!
		if vgape < 3 and pcs_vag >= 30 and my_show_vfisting = 0:
			act 'Vaginal fisting':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/vfist'+rand(1,3)+'.mp4" ></video></center>'
				'You part your legs and begin massaging your hole with your fingers, first one, then two.'
			
				!grease
				if lubri = 0: vgape = 3
				if lubri > 0:
					lubri -= 1
					'You squeeze some lube onto your hand and began to smear it on your pussy.'
				end
				'Now ready, you slowly begin to push more and more of your hand inside.'
		
				my_show_tip = rand(400, 1600)
				my_show_vfisting = 1
				webcam_show_vfisting +=1
				if pcs_vag <= 30: pcs_vag +=1
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				cla
				act 'Further': dynamic $webcam_show
			end	
		end		
!------------------------------!
!---------Sex - Vasily---------!
!------------------------------!
		if $loc='shulga_room' and npc_rel['A11'] >= 100 and week >= 6 and hour >= 15 and vgape < 3 and agape < 3 and pcs_vag >= 1 and my_show_sex = 0:
			act 'Call Vasily and arrange a sex show':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/sex'+rand(1,5)+'.mp4" ></video></center>'
				'Vasily ' + iif(analplugin = 1, 'pulls your anal plug out of your ass and ', '') + 'begins to stroke between your legs, massaging your holes with his fingers.'	
				!Butt plug
				analplugin = 0
				!grease
				if lubri = 0: vgape = 1
				if lubri > 0:
					lubri -= 1
					'He forced lubrication his arms and began to lubricate your charms'
				end
				'For 30 minutes, the two of you fuck on camera, honoring the chat and performing the whims of spectators. Sometimes he fucks you quickly, sometimes slowly, sometimes in your pussy, sometimes in your ass. You even blow him for a bit.'
					
				pcs_horny += 30
				!orgasm-Bonus Money
				if pcs_horny > 100:
					'Soon he bring you to orgasm, and you cum violently. Your tips sharply increase when this happens.'
					webcam_show_orgazm +=1
					my_show_tip += rand(100, 500)
					pcs_horny = 0
				end		

				'Your viewers like all the action. Your view count increases, and your tips rise even faster.'
		
				my_show_tip = rand(800, 2000)
				my_show_sex = 1
				webcam_show_sex +=1
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				cla
				act 'Further': dynamic $webcam_show
			end	
		end			
!------------------------------!
!-----------Squirt-------------!
!------------------------------!			
		if webcam_show_counter >= 30 and my_show_squirt = 0:
			act 'Squirt':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/squirt'+rand(1,2)+'.mp4" ></video></center>'
				'At the request of the audience, you squirt directly at the camera.'
				
				my_show_tip = rand(400, 1200)
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_squirt = 1
				webcam_show_squirt +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end
		end			
!------------------------------!
!-----------Bracing------------!
!------------------------------!			
		if pcs_danc >= 50 and my_show_flex = 0:
			act 'Bracing':
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/flex'+rand(1,3)+'.mp4" ></video></center>'
				'You show your audience your flexibility.'
				
				my_show_tip = rand(pcs_dancero,pcs_dancero*2)
				
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				my_show_flex = 1
				webcam_show_flex +=1
				
				cla
				act 'Further': dynamic $webcam_show
			end
		end		
	end
!------------------------------!
!-------Start the show---------!
!------------------------------!	
	if show_counter = 0:
		'You turn on the webcam. It''s time to start the show!'
		
		show_counter = 1
		!if dyed and combed bonus money
		if pcs_makeup = 1: my_show_tip = rand(10, 50)
		if pcs_makeup = 2: my_show_tip = rand(10, 100)
		if pcs_makeup = 3: my_show_tip = rand(10, 150)
		if pcs_makeup = 4: my_show_tip = rand(10, 200)
		if pcs_hairbsh = 1: my_show_tip = rand(10, 200)
		cla
		act 'Undress':
			*clr
			'<center><video autoplay loop src="images/shared/accessories/computer/webcam/undress'+rand(1,7)+'.mp4" ></video></center>'
			'You take off your clothes.'
			
			my_show_tip = rand(100, 200)
			
			'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
			
			cla
			act 'Further': dynamic $webcam_show
		end	
!------------------------------!
!---------STRIPTEASE-----------!
!------------------------------!		
		if pcs_dancero > 10:
			act 'Striptease':
				gs'stat'
				*clr
				'<center><video autoplay loop src="images/shared/accessories/computer/webcam/strip'+rand(1,7)+'.mp4" ></video></center>'
				'You slowly undress to the music, gently removing one garment after another.'
				
				!health check
				if agape > 2 or vgape > 2 or pcs_sleep < 8:
					'You do not feel good. You only manage to dance half as well as you normally could.'
					
					my_show_tip_mod = 2
				else
					my_show_tip_mod = 1
				end
				
				my_show_tip = (pcs_dancero + pcs_danc/2)/my_show_tip_mod
				webcam_show_strip +=1
				'For this little idea, you have earned <<my_show_tip>> <b>₽</b>.'
				
				cla
				act 'Further': dynamic $webcam_show
			end
		end
	end	
}
--- webcam_site ---------------------------------