glife/locations/lab

# lab
if $ARGS[0] = 'start':
	cla
	clr
	*clr
	CLOSE ALL
	if sound = 0:PLAY 'sound/street.mp3',30
	minut += 5
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Tatianas'' Laboratory</font></b></center>'
	'<center><img src="images/qwest/lab.jpg"></center>'

	if succubusflag = 1 and sucbypass = 0:
		if sucpcinfo < 2:
			xgt 'lab', 'suctraining'
		elseif sucpcinfo >= 6 and sucskill < 3 and sctrainprep = 1:
			xgt 'lab', 'suctraining'
		end
	elseif succubusflag = 1 and sucbypass = 1:
		sucbypass = 0
	end

	act 'Leave':
		cla
		minut += 5
		gt 'down'
	end

	act 'Train with Gustav':
		cla
		gt 'lab', 'jugo'
	end

	act 'Train with Tatiana':
		cla
		gt 'lab', 'Tatiana'
	end

	if judosparday ! daystart:
		act 'Sparring (Gustav, mutant power 600)':
			cla
			judosparday = daystart
			gs 'boyStat', 175
			!!stats
			strenV = 600
			speedV = 60
			agilV = 60
			reactV = 50
			vitalV = 200
			intelV = 50
			willV = 50
			!!skills
			magikV = 100
			boxingV = 100
			shootV = 100
			!!parameters
			healthV = vitalV * 10 + strenV * 5
			mannaV = intelV * 10 + magikV * 10
			willpowerV = willV * 10
			BonusAtakV = 0
			BonusDefV = 0
			!!Programme of Action
			program = 0
			jugoFight = 2
			gt 'fight', 'start'
		end
	end

	if karinsparday ! daystart:
		act 'Sparring (Tatiana, magician6)':
			cla
			karinsparday = daystart
			gs 'boyStat', 176
			!!stats
			strenV = 60
			speedV = 100
			agilV = 100
			reactV = 60
			vitalV = 100
			intelV = 100
			willV = 100
			!!skills
			magikV = 100
			boxingV = 100
			shootV = 100
			!!parameters
			healthV = vitalV * 10 + strenV * 5
			mannaV = intelV * 6 + magikV * 10
			willpowerV = willV * 10
			BonusAtakV = 0
			BonusDefV = 0
			!!Programme of Action
			program = 4
			karinFight = 1
			gt 'fight', 'start'
		end
	end
end

if $ARGS[0] = 'jugo':
	cla
	clr
	*clr
	minut += 5
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Gustav</font></b></center>'
	'<center><img src="images/picpre/jugopre.jpg"></center>'
	'Gustav is sitting on floor and staring off into space.'

	act 'Leave':gt 'lab', 'start'

	if jugoday ! daystart:
		act 'Develop strength (1:00)':
			cla
			stren_exp += rand(3, 6) + (steroid_dose - rand(0,steroid_dose)) & gs 'obj_din', 'steroids'
			minut += 60
			jugoday = daystart
			'You do exercises under the guidance of Gustav.'

			act 'Leave':gt 'lab', 'jugo'
		end

		act 'Develop speed (1:00)':
			cla
			speed += rand(3, 6)
			minut += 60
			jugoday = daystart
			'You do exercises under the guidance of Gustav.'

			act 'Leave':gt 'lab', 'jugo'
		end

		act 'Develop agility (1:00)':
			cla
			agil_exp += rand(3, 6)
			minut += 60
			jugoday = daystart
			'You do exercises under the guidance of Gustav.'

			act 'Leave':gt 'lab', 'jugo'
		end

		act 'Develop reactions (1:00)':
			cla
			react_exp += rand(3, 6)
			minut += 60
			jugoday = daystart
			'You do exercises under the guidance of Gustav.'

			act 'Leave':gt 'lab', 'jugo'
		end

		act 'Develop endurance (1:00)':
			cla
			vital_exp += rand(3, 6) + (steroid_dose - rand(0,steroid_dose)) & gs 'obj_din', 'steroids'
			minut += 60
			jugoday = daystart
			'You do exercises under the guidance of Gustav.'

			act 'Leave':gt 'lab', 'jugo'
		end
	end
end

if $ARGS[0] = 'Tatiana':
	cls
	$loc = 'lab'
	$metka = 'Tatiana'
	minut += 5
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Tatiana</font></b></center>'
	'<center><img src="images/picpre/karinpre.jpg"></center>'
	'Tatiana is always studying something.'

	if succubusflag = 1:
		if karinsucsex > 0 and sucinfoday ! 0 and sucinfoday <= daystart:
			'"Hey <<$pcs_nickname>>!'
			'"I''ve gotten some more information about Succubae!"'
			if sucpcinfo = 4 and succublvl >= 2:
				'"I heard from one of my mage contacts, in Sydney, Australia of all places, and he passed on some more details."'
				sucpcinfo = 5
				sucinfoday = daystart + 10 + rand(0,7)
				act 'Ask her to tell you': gt 'succubus', 'karinask', 1
				exit
			elseif sucpcinfo = 5:
				'"I heard from an old friend of mine who is now living in Morocco and she also has a Succubus for a lover. She said that after they had been together for some time, they discovered that with her help, her Succubus lover learned something new."'
				sucpcinfo = 6
				sucinfoday = daystart + 17 + rand(0,7)
				act 'Ask her to tell you': gt 'succubus', 'karinask', 2
				exit
			elseif sucpcinfo = 6:
				'"I heard from one of my contacts. He''s living in Las Vegas in America, which, apparently, is the Succubus capital of North America, and he passed along two pieces of information."'
				sucpcinfo = 7
!!				The +9000000 is so I can easily reset it when the next Skill upadtes are ready.
				sucinfoday = daystart + 9000000
				act 'Ask her to tell you': gt 'succubus', 'karinask', 3
				exit
			end
		end
		
		if karinsucsex ! 0 and karinsucsexask ! daystart: act 'Ask if she want''s to have sex': karinsucsexask = daystart & gt 'lab', 'Tatianasuctalk'

		if sucpcinfo >= 4: act 'Ask her about Succubae': gt 'lab', 'Tatianasuctalk'
	end

	act 'Leave':gt 'lab', 'start'

	act 'I''m too fat and do not want to get fat.':
		cla
		'(You) - Tatiana, I oily dibilka not able to watch their weight, wave your magic wand, what would not I grew fat.'
		'(Tatiana) - Ugh, that''s the same ponavylazyat downs of pussy, and then I vozis with them. Dick with you, take it. Just remember, this spell forever, you''ll be able to just come and change the waist and thighs, and since boobs are made of fat, I only supreme mercy 1st size you do, a little, shoved silicone. And the decision to reverse is or whether silicone doll or live as a man, I raskoldovyvat you will not. Since you have more fat will not be absorbed and body parameters are kept magically, marvel not at the post of dystrophy and not marvel that force will fall faster from malnutrition, you will no longer internal reserves.'

		act 'No no no, I changed my mind. Will continue smarter.':gt 'lab', 'Tatiana'

		act 'I would want that waist was ...':
			cla
			dounspell = 1
			TaliaDoun = input ("Waist in cm?")

			if TaliaDoun <= 0:TaliaDoun = 20

			act 'I would want that thighs ...':
				cla
				bedraDoun = input ("Hips in cm?")

				if bedraDoun <= 0:bedraDoun = 40
					act 'Enjoy your stupidity.':gt 'lab', 'Tatiana'
				end
			end
		end

		if IvanPodstavaQW = 2 and poverKAR = 0 and softKAR = 0:
			act 'Ask Tatiana for help with Ivan':
				cla
				gs 'stat'
				'You explained the situation and asked her to Tatiana assistance. Tatiana said thoughtfully. "I do not think there is any physical evidence of the guilt of Ivan. Necessary is achieved recognition. I think it would be possible to capture and interrogate. Or drink his cunning truth serum and interrogate. Anyway it is necessary to remove it all on video."'

				act 'Military solution':
					cls
					poverKAR = 1
					gs 'stat'
					'<center><img src="images/picpre/karinpre.jpg"></center>'
					'You have decided to achieve recognition Ivan force. Tatiana told you. You go to the apartment of Ivan. There vstretishsya with Gustav. It will help resolve the issue. Just see if he will go to the second level of the press, he was distraught. At the second level of the press he turns into a monster.'

					act 'Leave':gt 'lab', 'Tatiana'
				end

				act 'Tricky decision':
					cls
					softKAR = 1
					gs 'stat'
					'<center><img src="images/picpre/karinpre.jpg"></center>'
					'You have decided to achieve recognition Ivan cunning. Tatiana told you. You go to the apartment of Ivan. There we meet with you and obtyapaem owners.'

					act 'Leave':gt 'lab', 'Tatiana'
				end
			end
		elseif poverKAR = 2:
			act 'Approach to Tatiana about attacks apartments Ivan':
				cla
				poverKAR = 3
				'You came to Tatiana and she sighed. "Yes, failed. Gustav caught a bullet in his head and his strength went up to the next level, it has cured, made almost invulnerable, but finally deprived of his mind. Gustav not only gained recognition for Ivan, and not just kill him, he blew part of the entrance his attack. But there are pluses. Cops think it was a gas explosion. But now you have to either pay the debt or goes to jail. "'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if Tatianaday ! daystart:
			act 'Develop intelligence (1:00)':
				cla
				intel_exp += rand(3, 6)
				minut += 60
				Tatianaday = daystart
				'You study with Tatiana developing your intellect.'

				act 'Leave':gt 'lab', 'Tatiana'
			end

			act 'Will develop (1:00)':
				cla
				sprt_exp += rand(3, 6)
				minut += 60
				Tatianaday = daystart
				'You meditate with Tatiana developing your willpower.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spelltuman = 0 and pcs_magik >= 1:
			act 'Learn technique fog (1:00)':
				cla
				minut += 60
				spelltuman = 1
				'You learnt the technique of calling fog in battle.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spellklon = 0 and pcs_magik >= 1:
			act 'Learn technique protection cloning (1:00)':
				cla
				minut += 60
				spellklon = 1
				'You learnt the technique of cloning yourself to create decoys in battle.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spellstun = 0 and pcs_magik >= 2:
			act 'Learn technique paralysis (1:00)':
				cla
				minut += 60
				spellstun = 1
				'You learnt the technique of paralyzing the enemy.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spellwind = 0 and pcs_magik >= 2:
			act 'Learn mist blowing (1:00)':
				cla
				minut += 60
				spellwind = 1
				'You learnt the technique of blowing mist.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spellklon2 = 0 and pcs_magik >= 2:
			act 'Learn triple cloning (1:00)':
				cla
				minut += 60
				spellklon2 = 1
				'You learnt the technique triple cloning.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spellenergo = 0 and pcs_magik >= 3:
			act 'Learn energoschit (1:00)':
				cla
				minut += 60
				spellenergo = 1
				'You learnt the technique energoschita.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if spellinit = 0 and pcs_magik >= 3:
			act 'Learn technique deceleration time (1:00)':
				cla
				minut += 60
				spellinit = 1
				'You learnt the technique of time dilation.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

		if pcs_magik >= 4 and spellhel = 0:
			!!'With this level of magic I can not teach you anymore.'
				act 'Learn the technique of treatment (1:00)':
				cla
				minut += 60
				spellhel = 1
				'You learnt the technique of treatment.'

				act 'Leave':gt 'lab', 'Tatiana'
			end
		end

	if pcs_magik >= 5 and spellavtoklon = 0:
		act 'Learn technique preparation (1:00)':
			cla
			minut += 60
			spellavtoklon = 1
			'You learnt the technique preparation. This technique allows you to enter into battle with the already created three clones.'

			act 'Leave':gt 'lab', 'Tatiana'
		end
	end

	if pcs_magik >= 6 and spellbefshild = 0:
		act 'Learn technique pre-shield (1:00)':
			cla
			minut += 60
			spellbefshild = 1
			'You learned the technique of pre-shield. This technique allows you to enter into battle with a magical shield protecting you against physical impacts.'

			act 'Leave':gt 'lab', 'Tatiana'
		end
	end
!!	Succubus specific skill training.
	if succubusflag = 1:
		if sucpcinfo >= 4 and sucskill < 1:
			act 'Learn to monitor your Succubus Energies (may take some time)':
				cla
				minut += 30
				sucskill = 1
				gs 'stat'
				'You spend 30 minutes meditating, with Tatiana in a light link with you as she shows you how to tell what your Succubus energy levels are.'
				'You open your eyes and look at Tatiana sitting across from you.'
				'She is flushed, breathing hard, and her nipples are showing clearly through her blouse.'
				if 1 + (succublvl * 2) + karinsucsex < 20 and rand(0,100) < 90:
					'After a moment, she gives herself a shake and pulls herself together, before saying, "There you go!"'
					'She then stands up and goes back to her studying.'
					act 'Finish': gt 'lab', 'Tatiana'
				else
					xgt 'lab', 'suctrainsex'
				end
			end
		elseif sucpcinfo >= 5 and sucskill < 2:
			act 'Learn to increase your energy storage (may take some time)':
				cla
				minut += 5
				'You settle into a meditative state and link with Tatiana.'
				if succhungry > -2:
					gs 'stat'
					'After a few minutes, you feel Tatiana break the link and say, "<<$pcs_nickname>>, you need to build up <i>two</i> days of reserve before we do this training."'
					'She then stands up and goes back to her studying.'
					act 'Finish': gt 'lab', 'Tatiana'
					exit
				end
				minut += 55
				gs 'stat'
				sucskill = 2
				'Tatiana shows you how to build a storage reservoir that draws the excess energy in before your body uses it.'
				'Once you''re finished, Tatiana is again showing clear signs of arousal and she says, "You know, touching your power is a really, <i>really</i>, intense experience!"'
				'She then closes her eyes and visibly tries to get ahold of herself.'
				if karinsucsex >= 20 or rand(1,100) < 95:
					'After several moments, she pulls herself together, opens her eyes, smiles at you, and says, "There, I knew I could do it!"'
					'She then stands up and goes back to her studying.'
					act 'Finish': gt 'lab', 'Tatiana'
				else
					'Then her eyes snap open and you feel arousal suddenly flooding the link!'
					xgt 'lab', 'suctrainsex'
				end
			end
		elseif sucpcinfo >= 6 and sucskill < 3:
			if money >= 5000 and sctrainprep = 0:
				act 'Ask her about the preparations and training':
					cla
					gs 'stat'
					minut += 60
					'You ask her what''s involved in the training and preparations.'
					'She spends some time explaining the technical details of what you need to do during the "rital", then says,'
					'"The preparations will take 7 days, the money is to modify one of my devices to pull in free sexual energy from the adult businesses around here and to make several potions we''ll need, one of which is going to temporarily make me into a sexual energy "battery" and the others are so we can do the ritual without hurting ourselves.'
					'"Once I start, you''ll have 2 days to tell me to abort, after that I will have started building up the charge. We would not be able stop ourselves and premature sex could kill us, so I''ll be putting up a barrier to keep you out until 7 days have pasted and I''ll set it not to let you through unless you have 3 days of reserves and 100 units of stored energy.'
					'"Once I''ve built up to a full charge, I''ll only be able to hold it for a day, after that I''ll have to release it. The "battery" potion itself as well as the materials for it will not keep, so aborting after I start or fail to show up on time and 2000 <b>?</b> will have been wasted.'
					'"So, do you want me to start the preparations?"'
					act 'Yes':
						cla
						money -= 5000
						sctrainprep = 1
						Tatianasucsexday = daystart + 7
						'"Ok, I''ll get started! Be here next <<$week[week]>> with 3 days of reserves and 100 units of stored energy."'
						if karinsucsex > 0:
							'She then pulls you in for a quick kiss before adding, "Now get out of here, I can''t have you distracting me!"'
						else
							'She then surprises you with a peck on the cheek before adding, "Now get out of here, I can''t have you distracting me!"'
						end
						act 'Leave':
							minut += 5
							gt 'down'
						end
					end
					act 'Not Yet': gt 'lab', 'Tatiana'
				end
			elseif money >= 2000 and sctrainprep = -1:
				act 'Ask her to redo the preparations':
					cla
					'Are you sure? The same things from before apply; 2 days to abort, the barrier, 3 days of reserves and 100 units of stored energy, 8 to 10 hours once I''m fully charged... Another 2000 <b>?</b> wasted. Are you <i>really</i> sure?'
					act 'Yes':
						cla
						money -= 2000
						sctrainprep = 1
						Tatianasucsexday = daystart + 7
						'"Ok, I''ll get started! Be here next <<$week[week]>> with 3 days of reserves and 100 units of stored energy."'
						'"Now get out of here, I can''t have you distracting me!"'
						act 'Leave':
							minut += 5
							gt 'down'
						end
					end
					act 'Not Yet': gt 'lab', 'Tatiana'
				end
			end
		elseif sucpcinfo >= 7 and sucskill < 4 and maddildo = 1 and sucexcess >= 100:
			act 'Ask Tatiana about the accommodation training':
			cla
			'Tatiana asks, "Are you ready to do the accommodation training?"'
				act 'Yes, I''m ready. (can take a lot of time)':
					cls
					cla
					minut += 120
					gs 'stat'
					'<center><img src="images/qwest/selfplay/dildo.jpg"></center>'
					'She walks you through everything you need to do while leading you to the couch.'
					'Once there, as you as stripping, so is she! At your look, she says, "What? I don''t want to tear my clothes if one of us slips."'
					'You settle onto the couch then work the massive dildo into your snach. After working the dildo for a bit, with Tatiana in a light link guiding you, you switch to your ass. You work there for a while before switching back. You continue this way for nearly two hours, concentrating so hard you only have two orgasms, before you feel your body responding as it should. A quick test and you’re done.'
					sucskill = 4
					sucexcess -= 100
					act 'Continue':
						pcs_horny = 0
						'As you''re finishing, you notice Tatiana has her eyes closed and is visibly trying to get ahold of herself.'
						if Tatianasucsexday < daystart or rand(1,100) > 95:
							'Then her eyes snap open and you feel arousal suddenly flooding the link!'
							xgt 'lab', 'suctrainsex'
						else
							cla
							'After several moments, she pulls herself together, opens her eyes, smiles at you, and says, "There, I knew I could do it!"'
							'She then stands up and goes back to her studying.'
							act 'Finish': gt 'lab', 'Tatiana'
						end
					end
				end
				act 'Not Yet': gt 'lab', 'Tatiana'
			end
		end
	end
end

if $ARGS[0] = 'Tatianasuctalk':
	cla
	clr
	*clr
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Tatiana</font></b></center>'
	'<center><img src="images/picpre/karinpre.jpg"></center>'
	if sucpcinfo < 2:
		minut += 15
		'As you both settle onto the couch, Tatiana turns to you and says, "Ok, tell me what happened."'
		'You spend the next 15 minutes telling her about the Fairy, the odd dream, the energy you let loose the other night,'
		if succubusQW = 4:
			'and the felling you get when you''ve had sex.'
		elseif succubusQW > 4:
			'the felling you get when you''ve had sex, and the reaction you had to almost being raped.'
		end
		''
		'She thinks about it for a moment and then says, "Well, I have a couple of ideas, but no sense guessing when I can just magically examine you."'
		'She hops up and says, "Get undressed and lie down on the couch."'
		sucpcinfo = 2
		act 'Undress and lie down': gt 'succubus', 'karinask'
		exit
	end

	if Tatianasucsex = 0 and Tatianasucsexask ! daystart: act 'Ask Tatiana if she wants to try Succubus Sex': Tatianasucsexask = daystart & gt 'lab', 'Tatianasucsexask'

	act 'Ask her to repeat what she knows about Succubae': gt 'succubus', 'karinask'

	act 'Ask her if she has learned anything new about Succubae':
		cla
!!		Nothing after info level 6 here, because Tatiana will tell the PC automatically
		if sucinfoday ! 0 and sucinfoday <= daystart:
			if sucpcinfo = 4 and succublvl >= 2:
				'"Actually, I have gotten some more information about Succubae."'
				'"I heard from one of my mage contacts, in Sydney, Australia of all places, and he passed on some more details."'
				sucpcinfo = 5
				sucinfoday = daystart + 10 + rand(0,7)
				act 'Ask her to tell you': gt 'succubus', 'karinask', 1
			elseif sucpcinfo = 5:
				'"Actually, I have gotten some more information about Succubae."'
				'"I heard from an old friend of mine who is now living in Morocco and she actually has a Succubus for a lover. She said that after they had been together for some time, they discovered that with her help, her Succubus lover learned something new."'
				sucpcinfo = 6
				sucinfoday = daystart + 10 + rand(0,7)
				act 'Ask her to tell you': gt 'succubus', 'karinask', 2
			else
				'No, I havn''t.'
				act 'Continue': gt 'lab', 'Tatianasuctalk'
			end
		else
			'No, I havn''t.'
			act 'Continue': gt 'lab', 'Tatianasuctalk'
		end
	end

	act 'Change topics': gt 'lab', 'Tatiana'

end

if $ARGS[0] = 'Tatianasucsexask':
	cla
	clr
	*clr
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Tatiana</font></b></center>'
	'<center><img src="images/picpre/karinpre.jpg"></center>'
	If karinsucsex = 0:
		if TatianaSex = 1:
			'You give Tatiana what you hope is a "come hither" smile and ask,'
			'"So, you want to give Succubus sex a try?"'
		else
			'You give Tatiana a shy smile and ask,'
			'"Do you want to try Succubus sex?"'
		end
	else
		'You give Tatiana a bright smile and ask,'
		'Hey Tatiana, you up for some Succubus Sex?'
	end
	act 'She answers:':
		cla
		If karinsucsex = 0:
			'She gives you a wide eyed look before saying,'
			if succublvl + TatianaSex < rand(0,6):
				'"I''m sorry, <<$pcs_nickname>>, I just don''t have the time now."'
				act 'Move on to something else': gt 'lab', 'Tatiana'
			else
				'"I would love to!", with a wide smile.'
				'She leads you over to the couch and you both strip.'
				act 'Proceed': gt 'succubus', 'karinsex'
			end
		else
			If karinsucsexday <= daystart:
				if 1 + (succublvl * 2) + karinsucsex < rand(1,20):
					'"I''m sorry, <<$pcs_nickname>>, I just don''t have the time now."'
					act 'Move on to something else': gt 'lab', 'Tatiana'
				else
					'She gives you a "come hither" smile and says, "I would love to, <<$pcs_nickname>>!"'
					'You both head toward the couch, stripping as you go.'
					'Once there, you both sit down facing each other and she looks at you in anticipation.'
					act 'Proceed': gt 'succubus', 'karinsex'
				end
			else
				if karinsucsexday - daystart > 1:
					$scsextmp = 'days'
				else
					$scsextmp = 'day'
				end
				'She looks at you with a sad smile and says,'
				'"I''m sorry, <<$pcs_nickname>>, I need at least <<Tatianasucsexday - daystart>> more <<$scsextmp>>."'
				killvar '$scsextmp'
				act 'Move on to something else': gt 'lab', 'Tatiana'
			end
		end
	end
end

if $ARGS[0] = 'Tatianasexreject':
	cla
	clr
	*clr
	gs 'stat'
	'<center><b><font color="maroon">Tatiana</font></b></center>'
	'<center><img src="images/picpre/karinpre.jpg"></center>'
	if scpopt = 2:
		'I''m sorry, Tatiana, I just don''t have the time right now.'
		scpopt = 0
		killvar '$sclocrt' & killvar '$scargrt'
	end
	act 'Finish': gt 'lab', 'Tatiana'
end

if $ARGS[0] = 'suctrainsex':
	minut += 5
	'She suddenly lunges at you and starts kissing you! You''re so surprised it takes you a bit to respond and, before you can do anything, she is nibbling your ear and whispering, "Let it go..."'
!!	Hopefully this can be replaced by an 'arousal' call
	pcs_horny += 10
	if pcs_horny >= 100:
		pcs_horny = 0
		orgasm += 1
		'You''re so shocked at this; you suddenly feel a powerful orgasm rush through you, causing you to cry out even as it rushes down the link to Tatiana, giving her a powerful orgasm as well!'
		'Then, you feel your control slip...'
		act 'Continue': gt 'succubus', 'karinsex'
	else
		scfwon = 2
		scpopt = 1
		$sclocrt = 'lab'
		$scargrt = 'Tatianasexreject'
		'You only have moments to decide, do you give in and let <<sucself1>> go or do you reign it in?'
		act 'Continue': gt 'succubus', 'karinsex'
	end
end

if $ARGS[0] = 'suctraining':
	if sucpcinfo < 2:
		cla
		clr
		*clr
		'<center><b><font color="maroon">Tatiana</font></b></center>'
		'<center><img src="images/picpre/karinpre.jpg"></center>'
		'The moment you walked into her lab, Tatiana''s head jerked up and she hurried over to you.'
		'She stares at you for several seconds, then demands, "What the hell happened to you!?!?"'
		'You start to answer her when she holds up her hand and says, "Wait, come sit on the couch and tell me."'
		'She turns away from you and walks toward the couch.'

		act 'Follow her': gt 'lab', 'Tatianasuctalk'
		exit
	elseif sucpcinfo >= 6 and sucskill < 3 and sctrainprep = 1:
		if karinsucsexday > daystart and karinsucsexday - 5 >= daystart:
			cla
			clr
			*clr
			'<center><b><font color="maroon">Tatiana</font></b></center>'
			'<center><img src="images/picpre/karinpre.jpg"></center>'
			'You attempt to enter Tatiana''s lab but an invisible barrier stops you, but Tatiana apparently heard you as she rushes over and says, "What''s wrong? Do we need to cancel?"'
			act 'Yes, I need to cancel':
				cla
				'"Are you sure?"'
				act 'Yes, I''m sure':
					cla
					if karinsucsexday = daystart + 7:
						sctrainprep = 0
						money += 5000
						'"Ok, good thing I hadn''t bought anything yet." and she hands you back the 5000 <b>?</b> before going back to her studying.'
					else
						minut += 3
						sctrainprep = -1
						'"Ok, I''ll dump the "battery" potion."'
						'With that, she walks over to her workbench and dumps the contents of several beakers into a barrel that flairs with magic as she does so.'
					end
					act 'Continue': gt 'lab', 'start'
				end
				act 'No, never mind continue your preparations':
					cla
					'She gives a small shake of her head and says, "Then get out of here, I can''t have you distracting me!"'
					act 'Leave': gt 'down'
				end
			end
			act 'No...':
				cla
				'You say, "No, I just wanted to see you."'
				'She answers, "That''s sweet, but I can''t have you distracting me, come back all charged up in <<karinsucsexday - daystart>> days!"'
				act 'Leave':
					minut += 3
					gt 'down'
				end
			end
			exit
		elseif karinsucsexday > daystart and karinsucsexday - 5 < daystart:
			if karinsucsexday - daystart > 1:
				$scsextmp = 'days'
			else
				$scsextmp = 'day'
			end
			'You attempt to enter Tatiana''s lab but an invisible barrier stops you, but Tatiana apparently heard you as she shouts from across the lab, "I''ve already taken the first potion so I can''t come anywhere near you, come back all charged up in <<karinsucsexday - daystart>> <<$scsextmp>>!"'
			killvar '$scsextmp'
			act 'Leave':
				minut += 3
				gt 'down'
			end
			exit
		elseif karinsucsexday = daystart or karinsucsexday = daystart - 1:
			cla
			clr
			*clr
			gs 'stat'
			'<center><b><font color="maroon">Tatiana</font></b></center>'
			'<center><img src="images/picpre/karinpre.jpg"></center>'
			'The instant you walk into the lab, Tatiana''s head snaps up and she stares hard at you as you approach the barrier.'
			if sucexcess >= 100 and succhungry < -2:
				minut += 10
				'As you step through the barrier, Tatiana seems to teleport to you and start kissing you.'
				'She then starts pulling you toward her workbench while saying between kisses, "Thank (kiss) goodness (kiss) you''re (kiss) here (kiss) and ready (kiss)! You wouldn''t (kiss) believe (kiss) how (kiss) <i><b>horny</b></i> (kiss) carrying (kiss) all this (kiss) sexual (kiss) energy (kiss) has made me!"'
!!				Maybe add arousal call here
				'She suddenly turns away from you and you realize that you have reached her workbench. She grabs two smallish vails off the top, pops the tops off both, hands you one saying, "Drink this," before downing the other.'
				'It tastes like strawberry syrup.'
				'This time you''re ready when Tatiana lunges at you and you resume kissing as you lead her toward the couch while she is striping the clothes off both of you and you feel a large amount of your stored energy being released into your body.'
				'Once there, you both sit down facing each other, she looks at you with burning lust, and says, "Do it!"'
				act 'Proceed': gt 'succubus', 'karinsex'
				exit
			elseif sucexcess < 100 and succhungry > -2 and karinsucsexday = daystart:
				'She then says, "Damn! You don''t have enough reserve <i>or</i> stored energy! Run over to the Park and find some robbers or something, then get back here tomorrow!"'
			elseif succhungry > -2 and karinsucsexday = daystart:
				'She then says, Damn! You don''t have enough reserve energy! Run over to the Park and find some robbers or something, then get back here tomorrow!'
			elseif succhungry > -2 and karinsucsexday = daystart - 1:
				'She then says, "Damn! You don''t have enough reserve energy and there isn''t enough time for you to build it up." She then sighs and says, "Go ahead and take off, I need to bleed this energy off safely."'
				sctrainprep = -1
			else
				'She then says, "Damn! You don''t have enough stored energy! Run over to the Park and find some robbers or something, then get back here!"'
			end
			act 'Leave': minut += 5 & gt 'down'
			exit
		else
			'The barrier is down when you get to the lab and Tatiana calls from across the room, "You''re too late, I had to release the energy and we''ll need to start over."'
			sctrainprep = -1
			act 'Continue': gt 'lab', 'start'
			exit
		end
	end
!!	This is oops handling
	sucbypass = 1
	minut -= 5
	gt 'lab', 'start'
end

--- lab ---------------------------------