glife/locations/city_train.qsrc

# city_train

if $ARGS[0] = 'start':
	$loc_arg = 'start'
	$loc = 'city_train'
	$location_type = 'public_outdoors'
	$menu_loc = 'city_train'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla
	gs'stat'
	'<center><B>City center railway station</B></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/shared/trainstation/central_station_inside.jpg"></center>'
	'The grand old station in the city center is an impressive building. It is busy and has a number of shops and bars as well as all the platforms and trains. '
	*nl
	if car > 0 and cardrive = 2:
		'In the parking lot is <a href="exec:GS ''carF'',''start''">your <<$car>></a>.'
	end

	act 'Walk to the city center (0:05)':minut += 5 & gt 'city_center'
	if Trainpass_day > daystart:
		'You have <<Trainpass_day - daystart>> days left on your train pass.'
		act 'Go to the platforms': gt 'city_train', 'platform'
	else
		act 'Go to the ticket office': gt 'city_train', 'tickets'
	end
end

if $ARGS[0] = 'tickets':
	$menu_loc = 'city_train'
	$menu_arg = 'tickets'
	menu_off = 0
	*clr & cla
	gs 'stat'
	'<center><h4>Ticket office</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/kassa.jpg" ></center>'

	act 'Leave the ticket office':minut += 1 & gt 'city_train', 'start'
	
	act 'Buy a ticket':
		cla
		gs 'city_train', 'buy_ticket'
	end

	gs 'train_functions', 'buy_train_pass'
end

if $ARGS[0] = 'buy_ticket':
	$menu_loc = 'city_train'
	$menu_arg = 'buy_ticket'
	menu_off = 0
	
	act 'Leave the ticket office': minut += 1 & gt 'city_train', 'start'

	gs 'train_functions', 'buy_ticket', 'center'
end

if $ARGS[0] = 'platform':
	$location_type = 'public_outdoors'
	$menu_loc = 'city_train'
	$menu_arg = 'platform'
	menu_off = 0
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/indusplat.jpg" ></center>'
	'When you arrive at the platform, you can''t help but notice it bustling with activity. Lots of passengers are coming and going, all carrying shopping bags. It feels like it is always busy here, no matter at what time of the day it is.'

	act 'Return to the station hall':gt 'city_train', 'start'
	
	act 'Take a train to the city industrial area': gt 'city_train', 'ind'

	act 'Take a train to the old platform by the communal village': gt 'city_train', 'communal'

	act 'Take a train to the village of Gadukino': gt 'city_train', 'village'

	act 'Take a train to Pavlovsk': gt 'city_train', 'pavlovsk'
end

if $ARGS[0] = 'ind':
	$loc = 'city_industrial_train'
	$loc_arg = 'platform'
	menu_off = 1
	minut += 5
	gs 'stat'
	if rand(1, 100) < 15: gt 'train', 'private'
	if rand(1, 100) <= 10: gt 'train_incidental', 'events'
	if rand(1, 100) <= 20: gt 'train', 'events'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/indusplat.jpg" ></center>'
	'After 5 minutes, the train stops at the St. Petersburg city industrial area station.'
	act 'Get off the train':
		if train_event = 0 and rand(1, 100) <= 5: gt 'train_incidental', 'end'
		gt 'city_industrial_train', 'platform'
	end
end

if $ARGS[0] = 'communal':
	$loc = 'train'
	$loc_arg = 'communal'
	menu_off = 1
	minut += 15
	if rand(1, 100) <= 10: gt 'train_incidental', 'events'
	if rand(1, 100) <= 20: gt 'train', 'events'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/oldplat.jpg" ></center>'
	'After 15 minutes you arrive at an old railway platform near the communal village.'
	act 'Get off the train':
		if train_event = 0 and rand(1, 100) <= 5: gt 'train_incidental', 'end'
		gt 'train', 'communal'
	end
end

if $ARGS[0] = 'village':
	$loc = 'train'
	$loc_arg = 'village'
	menu_off = 1
	minut += 25
	if rand(1, 100) <= 10: gt 'train_incidental', 'events'
	if rand(1, 100) <= 20: gt 'train', 'events'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/gadplat.jpg" ></center>'
	'After 25 minutes, the train stops at the small station near the village of Gadukino.'
	act 'Get off the train':
		if train_event = 0 and rand(1, 100) <= 5: gt 'train_incidental', 'end'
		gt 'train', 'village'
	end
end

if $ARGS[0] = 'pavlovsk':
	$loc = 'pav_train_hall'
	$loc_arg = 'platform'
	menu_off = 1
	minut += 40
	if rand(1, 100) < 15: gt 'train', 'private'
	if rand(1, 100) < 30: gt 'train', 'Gopnik'
	if rand(1, 100) <= 10: gt 'train_incidental', 'events'
	if rand(1, 100) <= 20: gt 'train', 'events'
	gs 'stat'
	if train_event = 0 and rand(1, 100) < 20: gt 'train', 'events'
	'<center><img <<$set_imgh>> src="images/locations/shared/train/pavplat.jpg" ></center>'
	'After 40 minutes, you see the town of Pavlovsk approaching. Pavlovsk Castle is an impressive sight, even from a long distance. The train stops at its final destination, a platform in Pavlovsk station.'
	act 'Get off the train':
		if train_event = 0 and rand(1, 100) <= 5: gt 'train_incidental', 'end'
		gt 'pav_train_hall'
	end
end

--- city_train ---------------------------------