glife/locations/city_center.qsrc

# city_center
! 14-09-22 Added Metro link to navigation line 130

$loc_arg = $ARGS[0]
$loc = 'city_center'
$region = 'city_center'
$menu_loc = 'city_center'
$menu_arg = ''
menu_off = 0
$location_type = 'public_outdoors'
killvar '$locclass'
CLOSE ALL
if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street_night_leto.mp3' & PLAY 'sound/street_night.mp3',30
	end
end

!!sets return location when visiting the bank or post office
bankloc = 1
gs 'stat'

!call random events from [street_events], and display them before show location.
if streetevent_hour ! hour:gt 'street_event','city_center', 'main'

'<center><h2>St. Petersburg</h2></center>'
'<center><b>City Center</b></center>'
if month >= 11 or month <= 3:
	if daystage = 2 or daystage = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/downw.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/downwn.jpg"></center>'
	end
else
	if daystage = 2 or daystage = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/down.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/down_night.jpg"></center>'
	end
end
*nl

'Day or night, the city centre is alive and bustling. So whether you''re looking to shop, hit the gym or get some cheap food, you''ll find it hard not to have your needs satisfied.'
*nl

gs'street_event','city_center', 'extras'

if nichWork = 2:act '<b>GO HOME</b> (Nicholas'' apartment)':gt 'nichApartment'

if shantpopala > 0:
	*clr & cla
	menu_off = 0
	minut += 480
	spafinloc = 14
	gs 'cum_manage'
	gs 'cum_manage'
	spafinloc = 4
	gs 'cum_manage'
	spafinloc = 12
	gs 'cum_manage'
	spafinloc = 11
	gs 'cum_manage'
	spafinloc = 7
	gs 'cum_manage'
	spafinloc = 3
	gs 'cum_manage'
	fingal += 1
	guy += 2
	rape += 1
	shantpopala -= 1
	'<center><img <<$set_imgh>> src="images/locations/city/shared/sex/rape.jpg"></center>'
	'A black jeep suddenly hit the brakes on the street close to you. You turn your head to see what''s happening and see two prominent men jump out of it and start running towards you. Before you can react and run away, they grab you and drag you into the car.'
	'"You''re doing this for a living? Taking pictures of naked people in the park?" one of them shouts while holding one of the pictures to your face you''ve made a while back and sent someone over a social network, hoping they would pay the ransom.'
	'"No... what? What the hell is going on? I don''t know what you''re talking about!" you try to explain.'
	'"Don''t lie to us, you stupid bitch." as he says that, he hits you on your head, and you pass out.'
	'You wake up somewhere out of town, tied up and naked. You look down on yourself and notice traces of cum on your body. It also seems like that cum is flowing from your ass and pussy.'
	'You notice that the blokes, who captured you, sit next to you and seem to have a break. Some of them are smoking.'
	'"Oh, she is finally awake, then the next fuck-cycle will be far more fun.", one of the men said as he noticed you moving. Some of them are starting to get evil grins on their face.'
	'They got up and came back at you. Barely a minute later, you wished you were still knocked out, as these jackasses had their ways with. You tried to resist, but the tape hindered you from moving. Not long after, everything faded black, and you lost consciousness again.'
	'You feel groggy as you wake up, but someone grabs you by the hair and shouts at you. "Let this be a lesson for you, bitch.", he yells, then kicks you in the stomach and leaves. As you collapse on the ground holding your stomach in pain, you glimpse the street and see the assholes driving away in their black jeep. The main road is about 200m away. You crawl most of the way there, but soon you can walk again, and eventually, you find your way back to one of the main streets.'
	gs 'arousal', 'bj', -60, 'sub', 'gangbang','humiliation', 'rough'
	gs 'arousal', 'vaginal', -60, 'sub', 'gangbang', 'humiliation', 'rough'
	gs 'arousal', 'anal', -60, 'sub', 'gangbang', 'humiliation', 'rough'
	gs 'arousal', 'end'
	gs 'stat'

	act 'Leave':gt $curloc

	exit
end

gs 'music_actions', 'music_icon'


if car > 0 and cardrive = 2:'In the parking stands your <a href="exec:GS ''carF'', ''start''"><<$car>></a>.'

act 'Walk to the central park (0:35)': minut += 35 & gt 'city_park', 'start'
act 'Walk to the train station (0:05)': minut += 5 & gt 'city_train', 'start'
if hour = 4 and hour = 23:
	act 'Walk to the Metro':  minut += 5 & gt 'metro', 'start'
end


act 'Wait':gs 'obj_din', 'wait'

gs 'taxi'

if hour >= 4 and hour <= 23:
	$desc_txt1 = '<a href="exec: minut += 1 & gt ''metro'', ''start''">the metro</a>'
else
	$desc_txt1 = '<a href="exec:msg ''The metro is closed and will reopen at 4:00''">the metro</a>'
end

'You have easy access to the <a href="exec: minut += 5 & gs ''city_train'', ''start''">train station</a> and <<$desc_txt1>> is only a short walk from there. Both connect you quickly to other parts of St. Petersburg and the subway is great if you are tight on cash. If you can''t afford either, the <a href="exec:minut += 35 & gt ''city_park'', ''start''">central park</a> is a 35 minute walk from here and provides a more scenic route to the other city districts.'
*nl
if hour >= 8 and hour <= 22:
	$desc_txt1 = '<a href="exec: minut += 1 & gt ''kiosk'', ''start''">kiosk</a>'
else
	$desc_txt1 = '<a href="exec:msg ''The Ruch kiosk is closed and will reopen at 8:00''">kiosk</a>'
end
'The neon green sign of a <<$desc_txt1>> catches your eye. It''s open 8-10 selling magazines and cigarettes for cheap.'
*nl
if hour = 8 and minut >= 30:
	$desc_txt1 = '<a href="exec: minut += 1 & gt ''torgcentr''">The Galeria mall</a>'
	$desc_txt2 = '<a href="exec:msg ''The Havana Fitness Center is closed and will reopen at 9:00''">Havana Fitness Center</a>'
elseif hour >= 9 and hour <= 20:
	$desc_txt1 = '<a href="exec: minut += 1 & gt ''torgcentr''">The Galeria mall</a>'
	$desc_txt2 = '<a href="exec:gt ''fit'', ''start''">Havana Fitness Center</a>'
else
	$desc_txt1 = '<a href="exec:msg ''The Galeria mall is closed and will reopen at 8:30''">The Galeria mall</a>'
	$desc_txt2 = '<a href="exec:msg ''The Havana Fitness Center is closed and will reopen at 9:00''">Havana Fitness Center</a>'
end
'<<$desc_txt1>> is front and center in the commercial area. Nearby is a <<$desc_txt2>> which has a swimming pool that can be used for a small fee.'
if hour >= 6 and hour <= 23:
	$desc_txt1 = '<a href="exec: minut += 1 & gt ''foto'', ''start''">Aphrodite Photography</a>'
else
	$desc_txt1 = '<a href="exec:msg ''Aphrodite Photography is closed and will reopen at 6:00''">Aphrodite Photography</a>'
end
if hour >= 6 and hour <= 23:
	$desc_txt2 = '<a href="exec: minut += 1 & gt ''burger'', ''start''">Diner Bystroeshka</a>'
else
	$desc_txt2 = '<a href="exec:msg ''Diner Bystroeshka is closed and will reopen at 6:00''">Diner Bystroeshka</a>'
end
if hour >= 8 and hour <= 22:
	$desc_txt3 = '<a href="exec:gt ''restoran'', ''start''">Babel</a>'
else
	$desc_txt3 = '<a href="exec:msg ''Babel is closed and will reopen at 8:00''">Babel</a>'
end
'A few buildings away is <<$desc_txt1>> and <<$desc_txt2>>, a place for cheap fast food. For a more lavish dining experience, <<$desc_txt3>> is available.'
*nl
if week >= 4 and (hour >= 18 or hour <= 3):
	$desc_txt3 = '<a href="exec:gt ''city_nightclub'', ''start''">the nightclub</a>'
else
	$desc_txt3 = '<a href="exec:msg ''The nightclub is closed and will open from Friday to Sunday at 18:00''">The nightclub</a>'
end
'At night the only place open here is <<$desc_txt3>>.'
*nl
if (week < 6 and hour >= 8 and hour <= 16) or (week = 6 and hour >= 8 and hour <= 13):
	$desc_txt1 = '<a href="exec:gt ''office'', ''start''">Titran-Express</a>'
elseif (week = 5 or week = 6) and hour > 16:
	$desc_txt1 = '<a href="exec:msg ''Titran-Express is closed and will reopen at 8:00 on Monday''">Titran-Express</a>'
else
	$desc_txt1 = '<a href="exec:msg ''Titran-Express is closed and will reopen at 8:00''">Titran-Express</a>'
end
'Across the street is considered the business area. The large skyscraper there serves as the base of operations for <<$desc_txt1>>, an engineering company.'
*nl
if casting = 0:
	$desc_txt1 = 'Aurora talent agency'
elseif hour >= 7 and hour <= 20:
	$desc_txt1 = '<a href="exec:gt ''talent_agency'', ''start''">Aurora talent agency</a>'
else
	$desc_txt1 = '<a href="exec:msg ''Aurora talent agency is closed and will reopen at 7:00''">Aurora talent agency</a>'
end
if week < 6 and hour >= 9 and hour <= 18:
	$desc_txt2 = '<a href="exec:gt ''bank'', ''start''">VTB bank</a>'
elseif week < 5 and hour > 18:
	$desc_txt2 = '<a href="exec:msg ''VTB bank is closed and will reopen tomorrow at 9:00''">VTB bank</a>'
else
	$desc_txt2 = '<a href="exec:msg ''VTB bank is closed and will reopen on monday at 9:00''">VTB bank</a>'
end
if hour >= 8 and hour <= 22:
	$desc_txt3 = '<a href="exec: minut += 1 & gt ''agentned'', ''start''">Kirsanova Realty</a>'
else
	$desc_txt3 = '<a href="exec:msg ''Kirsanova Realty is closed and will reopen at 8:00''">Kirsanova Realty</a>'
end
if (week < 6 and hour >= 9 and hour <= 16) or (week = 6 and hour >= 9 and hour <= 13):
	$desc_txt4 = '<a href="exec: minut += 3 & gt ''post_office'', ''start''">post office</a>'
elseif (week = 5 or week = 6) and hour > 16:
	$desc_txt4 = '<a href="exec:msg ''The post office is closed and will reopen at 9:00 on Monday''">post office</a>'
else
	$desc_txt4 = '<a href="exec:msg ''The post office is closed and will reopen at 9:00''">post office</a>'
end
if hour >= 8 and hour <= 18:
	$desc_txt5 = '<a href="exec: minut += 1 & gt ''city_library''">National Library of Russia</a>'
else
	$desc_txt5 = '<a href="exec:msg ''The National Library of Russia is closed and will reopen at 8:00''">National Library of Russia</a>'
end
'Next door is the <<$desc_txt1>> followed by a <<$desc_txt2>> and <<$desc_txt3>> and the 5-star <a href="exec: minut += 1 & gt ''city_hotel'', ''start''">Hotel Indigo</a> for your housing needs. Lastly, the local <<$desc_txt4>> and <<$desc_txt5>> can be found at the end of the road.'
*nl
if week < 6 and hour >= 7 and hour <= 17:
	$desc_txt6 = '<a href="exec: minut += 1 & gt ''sentence'',''start''">The City Courthouse</a>'
elseif week < 5 and hour > 17:
	$desc_txt6 = '<a href="exec:msg ''The City Courthouse is closed and will reopen tomorrow at 7:00''">City Courthouse</a>'
else
	$desc_txt6 = '<a href="exec:msg ''The City Courthouse is closed and will reopen on Monday at 7:00''">City Courthouse</a>'
end
$desc_txt7 = '<a href="exec: minut += 1 & gt ''police_station'',''start''">Main city police station</a>'
'Away from the shops is both <<$desc_txt6>> and the <<$desc_txt7>>.'
*nl
'<a href="exec: minut += 1 & gt ''city_church'', ''start''">Kazan Cathedral</a>, also known as the Cathedral of Our Lady of Kazan, sits at the very center of the city.'
*nl
if nichHotelReferral = 2:
	if hour >= 4 and hour < 16:
		'You could go to the apartment of a man named Nicholas to apply for a job as a live-in maid. But it is too early for that. You should come back between 16:00 and 20:59.'
	elseif hour < 4 or hour > 20:
		'You could go to the apartment of a man named Nicholas to apply for a job as a live-in maid. But it is too late for that. You should come back between 16:00 and 20:59.'
	else
		'You could go to the <a href="exec:gt ''nichApartment'', ''jobInterview''">apartment of a man named Nicholas</a> to apply for a job as a live-in maid.'
	end
end


if Enable_tablemap = 0:
	if nichTanyaRelationship = 1 and nichWork ! 2 and hour >= 16 and hour <= 21 and nichTanyaFuckLast ! daystart:'<a href="exec:gt ''nichApartment'', ''visitTanya''">Apartment where Tanya lives</a>.'
	if nichWork = 2:'<a href="exec:gt ''nichApartment''">Nicholas''s</a> apartment where you work as a live in maid.'
	if izoldaQW >= 1:'Your friend <a href="exec:gt ''qwIzoldaApp''">Isolde''s</a> apartment.'
	if mainQW >= 1:'<a href="exec:gt ''tatiana_lab'', ''start''">Tatiana''s</a> secret hideout.'
	if yaq = 1:'<a href="exec:gt ''yarik'', ''start''">Yaroslav</a> from the office''s apartment.'
	if peter > 0:'<a href="exec:gt ''peterroom'', ''start_door''">Peter</a> the sexshop owner''s apartment.'
else
	st_count=0 & $show_table=''
	if nichTanyaRelationship = 1 and nichWork ! 2 and hour >= 16 and hour <= 21 and nichTanyaFuckLast ! daystart:gs'show_table','<a href="exec:gt ''nichApartment'', ''visitTanya''">Apartment</a> where Tanya lives','3'
	if nichWork = 2:gs'show_table','<a href="exec:gt ''nichApartment''">Nicholas''s</a> apartment','3'
	if izoldaQW >= 1:gs'show_table','<a href="exec:gt ''qwIzoldaApp''">Isolde''s</a> apartment','3'
	if mainQW >= 1:gs'show_table','<a href="exec:gt ''tatiana_lab'', ''start''">Tatiana''s</a> secret hideout','3'
	if yaq = 1:gs'show_table','<a href="exec:gt ''yarik'', ''start''">Yaroslav''s</a> apartment','3'
	if peter > 0:gs'show_table','<a href="exec:gt ''peterroom'', ''start_door''">Peter''s</a> apartment','3'
	if st_count > 0 :'<TABLE BORDER=1><<$show_table>></TR></TABLE>'
end

if AlexandriaQW = 3 and hour >= 6 and hour <= 23:
    *nl
    act 'Call Tatiana to infiltrate the models agency': gt 'tatiana_missions','mission2B'
end

if hour >= 20 or hour <= 4:
	*nl
	'There are prostitutes working in places near here.'
	if pcs_makeup > 2 and PCloStyle = 4 and pcs_inhib >= 40 and (stat['vaginal'] >  0 or fame['pav_slut'] >= 100):
		act 'Prostitute yourself': gt 'street_walker', 'work'
	elseif pcs_inhib >= 40 and (stat['vaginal'] >  0 or fame['pav_slut'] >= 100):
		*nl
		'You could work as a prostitute, but you need to wear appropriate clothes and more than a little bit of makeup.'
	else
		*nl
		'You could work as a prostitute, but you aren''t comfortable with the idea.'
	end
end

gs 'camera', 'check_location'

if booty_call_time['A0'] = daystart:
	i=0
	*nl
	:loopBC
	if booty_call[$fuckbuddy[i]] = daystart and npc_residence[$fuckbuddy[i]] = 4:   
		dynamic(' ''<a href="exec: minut += 2 & gt ''''booty_call_start'''',''''start'''',''''<<$fuckbuddy[i]>>'''' "><<$npc_firstname[$fuckbuddy[i]]>>''''s</a> apartment is nearby.'' ')
	end
	 i +=1
	if i < arrsize('$fuckbuddy') : jump 'loopBC'
end

--- city_center ---------------------------------