glife/locations/gad_forest_lost.qsrc

# gad_forest_lost

! this file holds all the current code and events for player when lost
! it is structured like the normal gad_forest file with similar actions and arguments but with unique events
if $ARGS[0] = 'forest_outskirts':
	*clr & cla

	gs 'shortgs', 'setloc', 'gad_forest_lost', 'forest_outskirts'
	$location_type = 'secluded'
	menu_off = 0

	$forest_args1 = 'forest_outskirts'

	CLOSE ALL
	gs 'gadukino_event', 'sound'
	gs 'stat'

	gs 'gad_forest_lost', 'gad_forest_lost_picture'

	! having a bonfire increases chances of being rescued and decreases chances of wolves attacking
	foresteventrand = rand(1,40)
	if foresteventrand <= (2+(bonfire*5)) and daystart >= forest_lostday and month >= 6 and month <= 9 and hour >= 8 and hour <= 16 and mushroom_pickersday ! daystart: mushroom_pickers = 2 & gt 'gad_forest_lost', 'rescue', 'pickers', 'forest_outskirts'
	if foresteventrand <= (4+(bonfire*5)) and daystart > forest_lostday and month >= 4 and month <= 10 and ((hour >= 8 and hour < 12) or (hour >= 14 and hour < 18)) and daystart > forest_lostday + 1: gt 'gad_forest_lost', 'rescue', 'hunters', 'forest_outskirts'
	if foresteventrand <= (6+(bonfire*5)) and daystart > forest_lostday: gt 'gad_forest_lost', 'rescue', 'ranger', 'forest_outskirts'
	if foresteventrand <= (8-(bonfire*5)) and (hour < 6 or hour > 22): gt 'gad_forest_lost', 'wolves', 'forest_outskirts'

	gs 'gad_forest_lost', 'wander'

	act 'Relax here for a bit': gt 'gad_forest_lost', 'relax'

	gs 'gad_forest_lost', 'picking'
end

if $ARGS[0] = 'forest_center':
	*clr & cla

	$loc = 'gad_forest_lost'
	$loc_arg = 'forest_center'
	$location_type = 'secluded'

	$menu_loc = 'gad_forest_lost'
	$menu_arg = 'forest_center'
	menu_off = 0

	$forest_args1 = 'forest_center'

	CLOSE ALL
	gs 'gadukino_event', 'sound'
	gs 'stat'

	gs 'gad_forest_lost', 'gad_forest_lost_picture'

	! having a bonfire increases chances of being rescued and decreases chances of wolves attacking
	foresteventrand = rand(1,40)
	if foresteventrand <= (1+(bonfire*2)) and daystart > forest_lostday and month >= 4 and month <= 10 and ((hour >= 8 and hour < 12) or (hour >= 14 and hour < 18)) and daystart > forest_lostday: gt 'gad_forest_lost', 'rescue', 'hunters', 'forest_center'
	if foresteventrand <= (3+(bonfire*2)) and daystart > forest_lostday + 1: gt 'gad_forest_lost', 'rescue', 'ranger', 'forest_center'
	if foresteventrand <= (8-(bonfire*2)) and (hour < 6 or hour > 22): gt 'gad_forest_lost', 'wolves', 'forest_center'

	gs 'gad_forest_lost', 'wander'

	act 'Relax here for a bit': gt 'gad_forest_lost', 'relax'

	gs 'gad_forest_lost', 'picking'
end

! this gs handles the bushcraft increases, clothing degradation, while lost in the forest
! $ARGS[1] - location of forest where this is called from
! Example: gs 'gad_forest_lost', 'bushcraft', 'forest_outskirts'
if $ARGS[0] = 'bushcraft':
	if $ARGS[1] = 'forest_outskirts':
		bushcraft_rand = 2
		bushcraft_lost = 20
		torncloth_high_bushcraft = 9
		torncloth_low_bushcraft = 7
	elseif $ARGS[1] = 'forest_center':
		bushcraft_rand = 3
		bushcraft_lost = 30
		torncloth_high_bushcraft = 8
		torncloth_low_bushcraft = 5
	end
	! No limit on earning bushcraft while lost but still random
	gs 'exp_gain', 'bushcraft', rand(0,bushcraft_rand)

	ripclothesrand = rand(1,10)
	if pcs_bushcraft < bushcraft_limit:
		if ripclothesrand >= torncloth_low_bushcraft: gs 'gad_forest', 'torncloth'
	else
		if ripclothesrand >= torncloth_high_bushcraft: gs 'gad_forest', 'torncloth'
	end
	gs 'stat'
end

! this gs handles Sveta trying to find her way in the forest when lost
! $forest_args1 - location of forest where this is called from
! Example: gs 'gad_forest_lost', 'wander'
if $ARGS[0] = 'wander':
	if DayStage < 4:
		act 'Wander trying to get your bearings (1:30)':
			*clr & cla
			menu_off = 1
			minut += 90
			gs 'stat'

			gs 'gad_forest_lost', 'bushcraft', $forest_args1

			'<center><H4>Somewhere in the forest</H4></center>'
			if $clothingworntype = 'nude':'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestsearch_nude0.'+rand(1,4)+'.jpg"></center>'
			if $clothingworntype ! 'nude' and PCloSkirt = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestsearch0.'+rand(1,4)+'.jpg"></center>'
			if $clothingworntype ! 'nude' and PCloSkirt > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestsearch_ski0.'+rand(1,4)+'.jpg"></center>'
			*nl

			if pcs_bushcraft < bushcraft_lost:
				lostrand = rand(1,bushcraft_lost)
				if pcs_bushcraft > lostrand:
					gt 'gad_forest_lost','finish', $forest_args1
				else
					'After half an hour wandering around, you feel like all you''ve accomplished is walking in circles.'
					act 'Continue': gt 'gad_forest_lost', $forest_args1
				end
			else
				gt 'gad_forest_lost', 'finish', $forest_args1
			end
		end
	end
end

! $forest_args1 - location of forest where this is called from
! Example: gt 'gad_forest_lost', 'relax'
if $ARGS[0] = 'relax':
	*clr & cla

	gs 'shortgs', 'setloc', 'gad_forest_lost', 'relax'
	$location_type = 'secluded'
	menu_off = 0

	CLOSE ALL
	gs 'gadukino_event', 'sound'
	gs 'stat'

	if $forest_args1 = 'forest_outskirts':
		! having a bonfire increases chances of being rescued and decreases chances of wolves attacking
		foresteventrand = rand(1,30)
		if foresteventrand <= (2+(bonfire*5)) and daystart >= forest_lostday and month >= 6 and month <= 9 and hour >= 8 and hour <= 16 and mushroom_pickersday ! daystart: mushroom_pickers = 2 & gt 'gad_forest_lost', 'rescue', 'pickers', $forest_args1
		if foresteventrand <= (4+(bonfire*5)) and daystart > forest_lostday and month >= 4 and month <= 10 and ((hour >= 8 and hour < 12) or (hour >= 14 and hour < 18)): gt 'gad_forest_lost', 'rescue', 'hunters', $forest_args1
		if foresteventrand <= (6+(bonfire*5)) and daystart > forest_lostday+1: gt 'gad_forest_lost', 'rescue', 'ranger', $forest_args1
	elseif $forest_args1 = 'forest_center':
		! having a bonfire increases chances of being rescued and decreases chances of wolves attacking
		foresteventrand = rand(1,40)
		if foresteventrand <= (1+(bonfire*5)) and daystart > forest_lostday and month >= 4 and month <= 10 and ((hour >= 8 and hour < 12) or (hour >= 14 and hour < 18)): gt 'gad_forest_lost', 'rescue', 'hunters', $forest_args1
		if foresteventrand <= (3+(bonfire*5)) and daystart > forest_lostday + 1: gt 'gad_forest_lost', 'rescue', 'ranger', $forest_args1
	end

	'<center><H4>Somewhere in the forest</H4></center>'
	if $clothingworntype = 'nude':'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_nude'+ rand(1,3) +'.jpg"></center>'
	if $clothingworntype ! 'nude' and PCloSkirt = 0 and bonfire = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax1.jpg"></center>'
	if $clothingworntype ! 'nude' and PCloSkirt = 0 and bonfire = 1:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax2.jpg"></center>'
	if $clothingworntype ! 'nude' and PCloSkirt > 0 and bonfire = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_ski1.jpg"></center>'
	if $clothingworntype ! 'nude' and PCloSkirt > 0 and $pantyworntype ! 'none' and bonfire = 1:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_ski2.jpg"></center>'
	if $clothingworntype ! 'nude' and PCloSkirt > 0 and $pantyworntype = 'none' and bonfire = 1:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_ski3.jpg"></center>'
	*nl
	'You decide this is as good of place as any to stop and take a break.'
	if bonfire = 0:
		'<font color="red">You should build a bonfire to increase the chance of being rescued and decrease the chance of being attacked by wolves.</font>'
	else
		'<font color="green">Your bonfire burns bright, increasing the chance of being rescued and decreasing the chance of being attacked by wolves.</font>'
	end
	act 'Explore the forest': gt 'gad_forest_lost', $forest_args1

	if bonfire = 0:
		act 'Build a fire (0:30)':
			*clr & cla
			menu_off = 1
			minut += 30
			bonfire = 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_bonfire1.jpg"></center>'
			*nl
			'After a few minutes, you are able to get a nice sized fire started.'

			act 'Continue': gt 'gad_forest_lost', 'relax'
		end
		act 'Sit and relax (1:00)':
			*clr & cla
			menu_off = 1
			minut += 60
			gs 'stat'

			if $clothingworntype = 'nude':'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_nude' + rand(1, 2) + '.jpg"></center>'
			if $clothingworntype ! 'nude' and PCloSkirt = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax3.jpg"></center>'
			if $clothingworntype ! 'nude' and $pantyworntype ! 'none' and PCloSkirt > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_ski4.jpg"></center>'
			if $clothingworntype ! 'nude' and $pantyworntype = 'none' and PCloSkirt > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_ski5.jpg"></center>'
			*nl
			'You spend half an hour relaxing, trying to pretend this is just like any other walk in the woods you''ve done.'

			act 'Continue': gt 'gad_forest_lost', 'relax'
		end
		if pcs_sleep < 40:
			act 'Nap on the ground (2:00)':
				*clr & cla
				menu_off = 1
				pcs_mood += 10
				pcs_health -= 5
				gs 'sleep_simple', 'nap_base', 120

				if $clothingworntype = 'nude':'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_sleepnude1.' + rand(1, 2) + '.jpg"></center>'
				if $clothingworntype ! 'nude' and PCloSkirt = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_sleep.jpg"></center>'
				if $clothingworntype ! 'nude' and $pantyworntype ! 'none' and PCloSkirt > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_sleepski.jpg"></center>'
				if $clothingworntype ! 'nude' and $pantyworntype = 'none' and PCloSkirt > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_sleepski1.jpg"></center>'
				*nl
				'You are able to make youself fall asleep for about 2 hours, but that is it. If you want to get a full nights sleep you will have to find a way out of the forest.'
				'Even though you had to sleep on the ground, you do wake up feeling a bit more hopeful and rested.'

				act 'Continue': gt 'gad_forest_lost', 'relax'
			end
		end
	elseif bonfire = 1:
		act 'Warm up by the fire (1:00)':
			*clr & cla
			menu_off = 1
			minut += 60
			if frost > 0: frost -= 1
			gs 'stat'

			if hour >= 6 and hour < 21:
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_bonfire2.jpg"></center>'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_bonfire3.jpg"></center>'
			end
			*nl
			'You spend half an hour huddled by the flames'

			act 'Continue': gt 'gad_forest_lost', 'relax'
		end
		if pcs_sleep < 40:
			act 'Nap by the fire (2:00)':
				*clr & cla
				menu_off = 1
				pcs_mood += 20
				frost = 0
				gs 'sleep_simple', 'nap_base', 120

				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestrelax_bonfiresleep.jpg"></center>'
				*nl
				'You are able to make youself fall asleep for about 2 hours, but that is it. If you want to get a full nights sleep you will have to find a way out of the forest.'
				'Even though you had to sleep on the ground, you do wake up feeling a bit more hopeful and rested.'

				act 'Continue': gt 'gad_forest_lost', 'relax'
			end
		end
		if boletus > 0:
			act 'Cook some mushrooms in the fire (0:15)':
				*clr & cla
				menu_off = 1
				minut += 15
				boletus_cooked += 1
				boletus -= 1
				frost = 0
				gs'stat'

				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/boletushot.jpg"></center>'
				*nl
				'You spend 15 minutes grilling some mushrooms in the fire.'

				act 'Continue': gt 'gad_forest_lost', 'relax'
			end
		end
	end
	if boletus_cooked > 0:
		act 'Eat cooked mushrooms (0:15)':
			*clr & cla
			menu_off = 1
			minut += 15
			boletus_cooked -= 1
			pcs_health += 10
			pcs_mood += 10
			fat += 1
			pcs_energy += 20
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/boletuscook.jpg"></center>'
			*nl
			'You eat some cooked mushrooms. They are pretty tasty considering your circumstances.'

			act 'Continue': gt 'gad_forest_lost', 'relax'
		end
	end
	if bilberry > 0:
		act 'Eat berries (0:15)':
			*clr & cla
			menu_off = 1
			minut += 15
			bilberry -= 1
			pcs_health += 10
			pcs_mood += 10
			fat += 1
			pcs_energy += 10
			pcs_hydra += 10
			gs'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/bilberry.jpg"></center>'
			*nl
			'You eat some berries. These would be great to eat even if you weren''t lost.'

			act 'Continue': gt 'gad_forest_lost', 'relax'
		end
	end
end

! this gs handles mushroom and berry picking for Sveta in the various locations of the forest when she is lost
! $forest_args1 - location of forest where this is called from
! Example: gs 'gad_forest_lost', 'picking'
if $ARGS[0] = 'picking':
	if DayStage < 4 and month >= 6 and month <= 9 and boletus + boletus_cooked + bilberry < 5:
		act 'Look for mushrooms and berries (0:30)':
			*clr & cla
			menu_off = 1

			if $forest_args1 = 'forest_outskirts':
				outskirts_pickingday = daystart
				mushroom_pickers_check = 2
				max_boletus = 2
				max_bilberry = 2
			elseif $forest_args1 = 'forest_center':
				center_pickingday = daystart
				mushroom_pickers_check = 3
				max_boletus = 3
				max_bilberry = 3
			end

			minut += 30
			new_boletus = 0
			new_bilberry = 0
			gs 'gad_forest_lost', 'bushcraft', $forest_args1
			if $clothingworntype = 'nude' and pcs_inhib < 50:inhib_exp += rand(1,5)
			gs 'stat'

			if mushroom_pickers ! mushroom_pickers_check:
				new_boletus += max_boletus
				new_bilberry += max_bilberry
				boletus += new_boletus
				bilberry += new_bilberry
				pcs_mood += 10
				gs 'stat'

				gs 'gad_forest', 'picking_clothes', $forest_args1, 'berry'
				*nl
				'After searching for mushrooms and berries for half an hour you found <<new_boletus>> kg of mushrooms and <<new_bilberry>> kg of berries.'
			elseif mushroom_pickers = mushroom_pickers_check:
				new_boletus += rand(0,max_boletus)
				new_bilberry += rand(0,max_bilberry)
				boletus += new_boletus
				bilberry += new_bilberry
				gs 'stat'

				if new_boletus > 0 and new_bilberry > 0:
					pcs_mood += 10
					gs 'stat'

					gs 'gad_forest', 'picking_clothes', $forest_args1, 'berry'
					*nl
					'After searching for mushrooms and berries for half an hour you found <<new_boletus>> kg of mushrooms and <<new_bilberry>> kg of berries.'
				elseif new_boletus = 0 and new_bilberry > 0:
					pcs_mood += 5
					gs 'stat'

					gs 'gad_forest', 'picking_clothes', $forest_args1, 'berry'
					*nl
					'After searching for mushrooms and berries for half an hour you found <<new_bilberry>> kg of berries.'
				elseif new_boletus > 0 and new_bilberry = 0:
					pcs_mood += 5
					gs 'stat'

					gs 'gad_forest', 'picking_clothes', $forest_args1, 'mushroom'
					*nl
					'After searching for mushrooms and berries for half an hour you found <<new_boletus>> kg of mushrooms'
				elseif new_boletus = 0 and new_bilberry = 0:
					pcs_mood -= 5
					gs 'stat'

					gs 'gad_forest', 'picking_clothes_empty', $forest_args1
					*nl
					'After searching for mushrooms and berries for half an hour you found nothing.'
				end
			end
			act 'Continue': gt 'gad_forest_lost', $forest_args1
		end
	end
end

! $ARGS[1] - location of forest where this is called from
if $ARGS[0] = 'finish':
	*clr & cla
	menu_off = 1
	bonfire = 0
	pcs_mood += 20
	gs 'exp_gain', 'bushcraft', rand(1,5)
	gs 'clothing', 'gad_swamp_clothes', 0
	gs 'stat'

	'<center><H4>Somewhere in the forest</H4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadjoy.jpg"></center>'
	*nl
	'After half an hour wandering around, you finally see some familiar sights.'

	if $clothingworntype = 'nude':
		if $ARGS[1] = 'forest_outskirts':
			act 'Continue':
				if gad_meadow_found = 1:
					foresteventrand = rand(1,3)
				else
					foresteventrand = rand(1,2)
				end
				if foresteventrand = 1: minut += 15 & gt 'gad_forest', 'forest_edge'
				if foresteventrand = 2: gt 'gad_forest', 'forest_outskirts'
				if foresteventrand = 3: minut += 35 & gt 'gad_meadow', 'start'
			end
		elseif $ARGS[1] = 'forest_center':
			act 'Continue':
				if hunterscabin = 1 and gad_meadow_found = 1:
					foresteventrand = rand(1,5)
				elseif gad_meadow_found = 1:
					foresteventrand = rand(1,4)
				else
					foresteventrand = rand(1,3)
				end
				if foresteventrand = 1: minut += 30 & gt 'gad_forest', 'forest_edge'
				if foresteventrand = 2: minut += 15 & gt 'gad_forest',' forest_outskirts'
				if foresteventrand = 3: gt 'gad_forest', 'forest_center'
				if foresteventrand = 4: minut += 50 & gt 'gad_meadow', 'start'
				if foresteventrand = 5: minut += 30 & gt 'gad_swamp_yard', 'start'
			end
		end
	else
		if $ARGS[1] = 'forest_outskirts':
			act 'Continue':
				if gad_meadow_found = 1:
					foresteventrand = rand(1,6)
				else
					foresteventrand = rand(1,5)
				end
				if foresteventrand = 1: minut += 15 & gt 'gad_forest', 'forest_edge'
				if foresteventrand = 2: gt 'gad_forest', 'forest_outskirts'
				if foresteventrand = 3: minut += 40 & gt 'gad_field', 'field'
				if foresteventrand = 4: minut += 30 & gt 'gad_road', 'start'
				if foresteventrand = 5: minut += 40 & gt 'gad_river', 'start'
				if foresteventrand = 6: minut += 35 & gt 'gad_meadow', 'start'
			end
		elseif $ARGS[1] = 'forest_center':
			act 'Continue':
				if hunterscabin = 1 and gad_meadow_found = 1:
					foresteventrand = rand(1,8)
				elseif gad_meadow_found = 1:
					foresteventrand = rand(1,7)
				else
					foresteventrand = rand(1,6)
				end
				if foresteventrand = 1: minut += 30 & gt 'gad_forest', 'forest_edge'
				if foresteventrand = 2: minut += 15 & gt 'gad_forest', 'forest_outskirts'
				if foresteventrand = 3: gt 'gad_forest', 'forest_center'
				if foresteventrand = 4: minut += 55 & gt 'gad_field', 'field'
				if foresteventrand = 5: minut += 45 & gt 'gad_road', 'start'
				if foresteventrand = 6: minut += 55 & gt 'gad_river', 'start'
				if foresteventrand = 7: minut += 50 & gt 'gad_meadow', 'start'
				if foresteventrand = 8: minut += 30 & gt 'gad_swamp_yard', 'start'
			end
		end
	end
end

! $ARGS[1] - who is rescuing player
! $ARGS[2] - location of forest where this is called from
if $ARGS[0] = 'rescue':
	*clr & cla
	menu_off = 1
	bonfire = 0
	pcs_mood += 20
	gs 'exp_gain', 'bushcraft', rand(1,5)
	lost_girl = 0
	if swamp_clothes = 1:
		'You remove the terrible excuse for clothing the hunters gave you. You''re sure you can find something better to wear at your grandparents house.'
		gs 'clothing', 'strip', 'gad_forest'
		gs 'clothing', 'gad_swamp_clothes', 0
	end
	gs 'stat'

	if $ARGS[1] = 'pickers':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom_pickers2.jpg"></center>'
		*nl
		'Suddenly you hear the sounds of people approaching. A group of pickers from the village appear out of the bushes.'
		if bonfire = 1:'They notice your fire and praise you, "When lost, it''s very smart if you stay in one place and make a fire. It will keep you warm, and make you visible to others."'
		if grandmaQW['block'] = 0:
			'They walk up to you and say, "Your grandparents are very worried about you. They asked us to keep an eye out for you. Follow us, we will lead you back '+iif($clothingworntype ! 'nude','to their house."','to the edge of the forest."')
			if $clothingworntype ! 'nude':
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 45 & gt 'gad_gphouse', 'start'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 60 & gt 'gad_gphouse', 'start'
				end
			else
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 15 & gt 'gad_forest', 'forest_edge'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 30 & gt 'gad_forest', 'forest_edge'
				end
			end
		else
			'They walk up to you and say, "We heard there may have been a missing girl in the forest. Follow us, we will lead you back '+iif($clothingworntype ! 'nude','out of the forest."','to the edge of the forest."')
			if $clothingworntype ! 'nude':
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 30 & gt 'gad_road', 'start'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 45 & gt 'gad_road', 'start'
				end
			else
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 15 & gt 'gad_forest', 'forest_edge'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 30 & gt 'gad_forest', 'forest_edge'
				end
			end
		end
	elseif $ARGS[1] = 'hunters':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanters.jpg"></center>'
		*nl
		'Suddenly you hear the sounds of people approaching. '+iif(hunters_were_met=1,'The hunters from the swamp ','A group of hunters ')+'appear out of the bushes.'
		if bonfire = 1:'They notice your fire and praise you, "When lost, it''s very smart if you stay in one place and make a fire. It will keep you warm, and make you visible to others."'
		if grandmaQW['block'] = 0:
			'They walk up to you and say, "Your grandparents are very worried about you. They asked us to keep an eye out for you. Follow us, you can stay at our camp for the time being until someone can take you back."'
			if $ARGS[2] = 'forest_outskirts':
				act 'Continue': minut += 45 & gt 'hunter_interactions', 'meet_hunters_after_rescue'
			else
				act 'Continue': minut += 30 & gt 'hunter_interactions', 'meet_hunters_after_rescue'
			end
		else
			'They walk up to you and say, "We heard there may have been a missing girl in the forest. Follow us, you can stay at our camp for the time being until someone can take you back."'
			if $ARGS[2] = 'forest_outskirts':
				act 'Continue': minut += 45 & gt 'hunter_interactions', 'meet_hunters_after_rescue'
			else
				act 'Continue': minut += 30 & gt 'hunter_interactions', 'meet_hunters_after_rescue'
			end
		end
	elseif $ARGS[1] = 'ranger':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/forester.jpg"></center>'
		*nl
		'Suddenly you hear the sound of a person approaching. A man you vaguely recognize from the village appears out of the bushes.'
		if bonfire = 1:'They notice your fire and praise you, "When lost, it''s very smart if you stay in one place and make a fire. It will keep you warm, and make you visible to others."'
		if grandmaQW['block'] = 0:
			'He walks up to you and says, "Your grandparents are very worried about you. They asked me to keep an eye out for you. Follow me, I will lead you back '+iif($clothingworntype ! 'nude','to their house."','to the edge of the forest."')
			if $clothingworntype ! 'nude':
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 45 & gt 'gad_gphouse', 'start'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 60 & gt 'gad_gphouse', 'start'
				elseif $ARGS[2] = 'gad_swamp_yard':
					act 'Continue': minut += 90 & gt 'gad_gphouse', 'start'
				end
			else
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 15 & gt 'gad_forest', 'forest_edge'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 30 & gt 'gad_forest', 'forest_edge'
				elseif $ARGS[2] = 'gad_swamp_yard':
					act 'Continue': minut += 60 & gt 'gad_forest', 'forest_edge'
				end
			end
		else
			'He walks up to you and says, "I heard there may have been a missing girl in the forest. Follow me, I will lead you back '+iif($clothingworntype ! 'nude','out of the forest."','to the edge of the forest."')
			if $clothingworntype ! 'nude':
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 30 & gt 'gad_road', 'start'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 45 & gt 'gad_road', 'start'
				elseif $ARGS[2] = 'gad_swamp_yard':
					act 'Continue': minut += 75 & gt 'gad_road', 'start'
				end
			else
				if $ARGS[2] = 'forest_outskirts':
					act 'Continue': minut += 15 & gt 'gad_forest', 'forest_edge'
				elseif $ARGS[2] = 'forest_center':
					act 'Continue': minut += 30 & gt 'gad_forest', 'forest_edge'
				elseif $ARGS[2] = 'gad_swamp_yard':
					act 'Continue': minut += 60 & gt 'gad_forest', 'forest_edge'
				end
			end
		end
	end
end

! $ARGS[1] - location of forest where this is called from
if $ARGS[0] = 'wolves':
	*clr & cla
	menu_off = 1

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/howl.jpg"></center>'
	*nl
	'Suddenly your hear a terrifying howl nearby.'

	act 'Run away':
		*clr & cla
		gs 'exercise', 'tier4', 1, 'run'
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run.jpg"></center>'
		*nl
		'Instincts take over and you begin running without a second thought.'

		if $ARGS[1] = 'forest_edge':
			if pcs_bushcraft < 80 and pcs_agil < 70 and pcs_stren < 70:
				foresteventrand = rand(0, 19)
			else
				foresteventrand = rand(1, 19)
			end

			if foresteventrand = 0:
				gs 'exp_gain', 'bushcraft', rand(1, 2)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/horror.jpg"></center>'
				*nl
				'The wolves are simply too fast and you cannot lose them. Suddenly you feel a sharp pain as a wolf bites your leg.'
			elseif foresteventrand <= 10:
				gs 'exp_gain', 'bushcraft', rand(1, 3)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end2.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, but unfortunately are still in the forest.'
			else
				gs 'exp_gain', 'bushcraft', rand(1, 5)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end1.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, and also are no longer in the forest.'
			end

			act 'Continue':
				if foresteventrand = 0:
					gs 'gameover', 'check', 11
					msg '<font color=red><B>You should die in this forest, but Cheat Mode keeps you Alive.</B></font>'
					gt 'gad_forest_lost', 'forest_edge'
				elseif foresteventrand <= 10:
					gt 'gad_forest_lost', 'forest_edge'
				elseif foresteventrand <= 13:
					gt 'gad_forest_lost', 'forest_edge'
				elseif foresteventrand <= 15:
					gt 'gad_field', 'field'
				elseif foresteventrand <= 17:
					gt 'gad_road', 'start'
				else
					gt 'gad_river', 'start'
				end
			end

		elseif $ARGS[1] = 'forest_outskirts':
			if pcs_bushcraft < 80 and pcs_agil < 70 and pcs_stren < 70:
				foresteventrand = rand(0, 19)
			else
				foresteventrand = rand(1, 19)
			end

			if foresteventrand = 0:
				gs 'exp_gain', 'bushcraft', rand(1, 2)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/horror.jpg"></center>'
				*nl
				'The wolves are simply too fast and you cannot lose them. Suddenly you feel a sharp pain as a wolf bites your leg.'
			elseif foresteventrand <= 14:
				gs 'exp_gain', 'bushcraft', rand(1, 3)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end2.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, but unfortunately are still lost in the forest.'
			else
				gs 'exp_gain', 'bushcraft', rand(1, 5)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end1.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, and also are no longer lost as you recognize your surroundings.'
			end

			act 'Continue':
				if foresteventrand = 0:
					gt 'gameover', 'check', 11
					msg '<font color=red><B>You should die in this forest, but Cheat Mode keeps you Alive.</B></font>'
					gt 'gad_forest_lost', 'forest_outskirts'
				elseif foresteventrand <= 9:
					gt 'gad_forest_lost', 'forest_outskirts'
				elseif foresteventrand <= 14:
					gt 'gad_forest_lost', 'forest_edge'
				elseif foresteventrand = 15:
					gt 'gad_forest', 'forest_outskirts'
				elseif foresteventrand = 16:
					gt 'gad_forest', 'forest_edge'
				elseif foresteventrand = 17:
					gt 'gad_field', 'field'
				elseif foresteventrand = 18:
					gt 'gad_road', 'start'
				else
					gt 'gad_river', 'start'
				end
			end

		elseif $ARGS[1] = 'forest_center':
			if pcs_bushcraft < 80 and pcs_agil < 70 and pcs_stren < 70:
				foresteventrand = rand(0, 19)
			else
				foresteventrand = rand(1, 19)
			end

			if foresteventrand = 0:
				gs 'exp_gain', 'bushcraft', rand(1, 2)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/horror.jpg"></center>'
				*nl
				'The wolves are simply too fast and you cannot lose them. Suddenly you feel a sharp pain as a wolf bites your leg.'
			elseif foresteventrand <= 13:
				gs 'exp_gain', 'bushcraft', rand(1, 3)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end2.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, but unfortunately are still lost in the forest.'
			else
				gs 'exp_gain', 'bushcraft', rand(1, 5)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end1.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, and also are no longer lost as you recognize your surroundings.'
			end

			act 'Continue':
				if foresteventrand = 0:
					gt 'gameover', 'check', 11
					msg '<font color=red><B>You should die in this forest, but Cheat Mode keeps you Alive.</B></font>'
					gt 'gad_forest_lost', 'forest_center'
				elseif foresteventrand <= 8:
					gt 'gad_forest_lost', 'forest_center'
				elseif foresteventrand <= 11:
					gt 'gad_forest_lost', 'forest_outskirts'
				elseif foresteventrand <= 13:
					gt 'gad_forest_lost', 'forest_edge'
				elseif foresteventrand = 14:
					gt 'gad_forest', 'forest_center'
				elseif foresteventrand = 15:
					gt 'gad_forest', 'forest_outskirts'
				elseif foresteventrand = 16:
					gt 'gad_forest', 'forest_edge'
				elseif foresteventrand = 17:
					gt 'gad_field', 'field'
				elseif foresteventrand = 18:
					gt 'gad_road', 'start'
				else
					gt 'gad_river', 'start'
				end
			end

		elseif $ARGS[1] = 'swamp':
			if pcs_bushcraft < 80 and pcs_agil < 70 and pcs_stren < 70:
				foresteventrand = rand(0, 19)
			else
				foresteventrand = rand(1, 19)
			end

			if foresteventrand = 0:
				gs 'exp_gain', 'bushcraft', rand(1, 2)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/horror.jpg"></center>'
				*nl
				'The wolves are simply too fast and you cannot lose them. Suddenly you feel a sharp pain as a wolf bites your leg.'
			elseif foresteventrand <= 8:
				gs 'exp_gain', 'bushcraft', rand(1, 3)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end2.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, but unfortunately are still lost in the forest.'
			else
				gs 'exp_gain', 'bushcraft', rand(1, 5)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/run_end1.jpg"></center>'
				*nl
				'You are successful in escaping the wolves, and also are no longer in the forest.'
			end

			act 'Continue':
				if foresteventrand = 0:
					gt 'gameover', 'check', 11
					msg '<font color=red><B>You should die in this forest, but Cheat Mode keeps you Alive.</B></font>'
					gt 'gad_forest_lost', 'swamp'
				elseif foresteventrand <= 4:
					gt 'gad_forest_lost', 'swamp'
				elseif foresteventrand <= 6:
					gt 'gad_forest_lost', 'forest_center'
				elseif foresteventrand <= 8:
					gt 'gad_forest_lost', 'forest_outskirts'
				elseif foresteventrand <= 10:
					gt 'gad_forest_lost', 'forest_edge'
				elseif foresteventrand = 11:
					gt 'gad_forest', 'swamp'
				elseif foresteventrand = 12:
					gt 'gad_forest', 'forest_center'
				elseif foresteventrand = 13:
					gt 'gad_forest', 'forest_outskirts'
				elseif foresteventrand = 14:
					gt 'gad_forest', 'forest_edge'
				elseif foresteventrand = 15:
					gt 'gad_field', 'field'
				elseif foresteventrand = 16:
					gt 'gad_road', 'start'
				elseif foresteventrand = 17:
					gt 'gad_river', 'start'
				elseif foresteventrand = 18:
					gt 'gad_swamp_yard', 'start'
				else
					gt 'gad_swamp_woods', 'start'
				end
			end
		end
	end
end

! this gs handles images for generic forest locations while lost
! Example: gs 'gad_forest_lost', 'gad_forest_lost_picture'
if $ARGS[0] = 'gad_forest_lost_picture':
	'<center><H4>Somewhere in the forest</H4></center>'
	if month >= 4 and month <= 10:
		if DayStage < 4:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestlost0.'+rand(1,6)+'.jpg"></center>'
			*nl
			'You are lost in the woods. You don''t recognize any of your surroundings and there aren''t any good landmarks to help pinpoint where you are.'
			'You would normally consider the woods a relaxing and scenic place, but are too stressed to appreciate the beauty of nature right now.'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestlost_night0.'+rand(1,4)+'.jpg"></center>'
			*nl
			'You are lost in the woods. You don''t recognize any of your surroundings and there aren''t any good landmarks to help pinpoint where you are.'
			'<font color="red">With nightfall, your chances of finding your way are practically nothing. You should stop and rest until daylight.</font>'
		end
	else
		if DayStage < 4:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestlost_winter0.'+rand(1,5)+'.jpg"></center>'
			*nl
			'You are lost in the woods. You don''t recognize any of your surroundings and there aren''t any good landmarks to help pinpoint where you are.'
			'You would normally consider the woods a relaxing and scenic place, but are too stressed to appreciate the beauty of nature right now.'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/gadforestlost_winter_night0.'+rand(1,4)+'.jpg"></center>'
			*nl
			'You are lost in the woods. You don''t recognize any of your surroundings and there aren''t any good landmarks to help pinpoint where you are.'
			'<font color="red">With nightfall, your chances of finding your way are practically nothing. You should stop and rest until daylight.</font>'
		end
	end
end

--- gad_forest_lost ---------------------------------