glife/locations/unicoursework.qsrc

# unicoursework

$unicourseworkloc[0] = $ARGS[1]
$unicourseworkloc[1] = $ARGS[2]

if $ARGS[0] = 'start':
	if func('uniutil', 'student_status') > 0 and kursovik < 100:
		if $unicourseworkloc[0] = 'komp':
			'You should probably do some of your <a href="exec:gt ''unicoursework'',$unicourseworkloc[0],$unicourseworkloc[1],1">coursework</a>.'
		else:
			act 'Do some coursework (1:00)':
				gt 'unicoursework', 'do_coursework', $unicourseworkloc[0], $unicourseworkloc[1]
			end
		end
	end
end

if $ARGS[0] = 'do_coursework':
    *clr & cla
    menu_off = 1
    minut += 60

    if $ARGS[1] = 'komp':
    	elektro += 3
    	internet -= 1
    	compskl_exp += 1
    end

    kursovik += rand(pcs_intel / 20, pcs_intel / 10)
    if kursovik > 100:kursovik = 100

    pcs_mood -= 10
    gs 'stat'

    if $ARGS[1] = 'komp':
    	'<center><b>Coursework</b></center>'
    	'<center><img <<$set_imgh>> src="images/shared/accessories/computer/kursak.jpg"></center>'
    else:
    	'<center><img <<$set_imgh>> src="images/pc/activities/study.jpg"></center>'
    end

    if $ARGS[1] = 'komp':
    	'It may be boring, but it still needs doing! You spend an hour doing coursework, and '+kursovik+'% of it is now finished.'
    elseif $ARGS[1] = 'sitr2x':
    	'You sat and studied, and you managed to complete some of your coursework. You are now '+kursovik+' percent done.'
    elseif $ARGS[1] = 'sitr':
    	'You work on your course''s homework and are about '+kursovik+' percent done.'
    elseif $ARGS[1] = 'pav_shared_apt':
    	'You sit down on the sofa bed and do some of your coursework. You''ve finished '+kursovik+' percent of it.'
    elseif $ARGS[1] = 'nichBedroomServant':
    	'You work on your coursework and have now completed '+kursovik+' percent.'
    elseif $ARGS[1] = 'bedrPar':
    	'You sit down at your desk and do some of your coursework. You''ve finished '+kursovik+' percent of it.'
    else:
    	'You sit for an hour and do some of your work for class. You''ve finished '+kursovik+' percent of the work.'
    end

    if kursovik < 100:
    	act 'Do some more coursework (1:00)':
    		gt 'unicoursework', 'do_coursework', $unicourseworkloc[0], $unicourseworkloc[1]
    	end
    end

    act 'Stop':
    	gt $unicourseworkloc[0], $unicourseworkloc[1]
    end
end

--- unicoursework ---------------------------------