glife/locations/Zvereva_Sly_sex.qsrc

# Zvereva_Sly_sex
!!22/06/01 - Alaratt

!!christinaQW['bully'] - earned if you stand up for yourself or not - less then 50 is you standing up, more then 50 is you being meek - at a certain point these unlock the below options
!!christinaQW['pre_fight'] - 1 means you are preparing to fight her
!!christinaQW['fight'] - 1 means you fought and won, -1 means you lost and are now her plaything
!!christinaQW['pre_bm'] - 1 means you are searching for the blackmail material to use against her
!!christinaQW['blackmail'] - 1 means you have the blackmail and need to talk to her to initiate, 2 means you have her blackmailed and are mostly safe from her bullying
!!christinaQW['submit'] - 1 means you willingly submitted, stays at 0 if you lose the fight, for reference on how you became her pet
!!christinaQW['subpath'] - 1 means you are looking to become her pet, 2 means you are her new pet, 3 means you have seen shower events, 4 is her home invite, 5 is you entered the home, 6 you push her into something...
!!slyQW['met'] - 1 means you are set to meet sly, 2 means you have met him
!!slyQW['trained'] - 1 means you have made it thru his sex intro
!!slyQW['foreplay'] - if not daystart, foreplay is allowed, but is set for every sex act, so will not go from anal/vag to a simple bj or hj
!!slyQW['virgin'] - 1 you protest you are a virgin, 2 you insist and no vag sex, even if no longer a virgin later on, because he wont know it changed at some point, 3 he took your virginity, 4 someone else did and you told him
!!slyQW['sex_stam'] - sex stamina, he will come when it reaches 6
!!slyQW['Chris_caught'] - increases when she spies on you, the higher it gets, the bolder she gets about doing it
!!slyQW['Chris_peeking'] - 0 she doesnt watch you that day, 1 she does, 2 just keeps Sveta from being surprised every change in sex acts
!!slyQW['Chris_peek_daystart'] - prevents more than one roll a day to see if Chris going to watch you and Sly


!!Sex Mechanics
if $ARGS[0] = 'Sly_random_sex_acts':
	act 'Continue':
		gs 'boyStat', 'A248'
		slyQW['sex_stam'] += 1

		$pursepantytype = $pantyworntype
		pursepantynumber = pantywornnumber
		$pursebratype = $braworntype
		pursebranumber = brawornnumber
		gs 'clothing', 'strip'
		gs 'underwear', 'remove'

		if slyQW['Chris_peek_daystart'] ! daystart:
			slyQW['Chris_peek_daystart'] = daystart
			if slyQW['Chris_caught'] < 5:
				if rand(1, 4) = 1:
					slyQW['Chris_caught'] += 1
					slyQW['Chris_peeking'] = 1
				end
			elseif slyQW['Chris_caught'] < 10 and christinaQW['subpath'] >= 6:
				if rand(1, 2) = 1:
					slyQW['Chris_caught'] += 1
					slyQW['Chris_peeking'] = 1
				end
			elseif slyQW['Chris_caught'] = 10 and christinaQW['subpath'] >= 6:
				if christinaQW['subpath'] = 6: christinaQW['subpath'] = 7
				slyQW['Chris_peeking'] = 1
			end
		end

		if slyQW['sex_stam'] < 6:
			:sly_loop
			slyQW['sex_act'] = rand(1,8)
			if slyQW['sex_act'] = 1 and slyQW['foreplay'] ! daystart:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'hj_1'
			elseif slyQW['sex_act'] = 2 and slyQW['foreplay'] ! daystart:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'bj_1'
			elseif slyQW['sex_act'] = 3 and slyQW['virgin'] ! 2:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'vag_cow_1'
			elseif slyQW['sex_act'] = 4 and slyQW['virgin'] ! 2:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'vag_doggy_1'
			elseif slyQW['sex_act'] = 5 and slyQW['virgin'] ! 2:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'vag_stomach_1'
			elseif slyQW['sex_act'] = 6:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'anal_doggy_1'
			elseif slyQW['sex_act'] = 7:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'anal_stomach_1'
			elseif slyQW['sex_act'] = 8:
				slyQW['foreplay'] = daystart
				gt 'Zvereva_Sly_sex', 'anal_piledriver_1'
			else
				jump 'sly_loop'
			end
		else
			gt 'Zvereva_Sly_sex', 'cum_decide'
		end
	end
end

if $ARGS[0] = 'sly_vibe':
	if vibratorIN = 1:
		vibratorIN = 0
		vibratorOUT = 1
		'You spread your legs and take the vibrator out of your pussy, letting out a slight moan as you do so. You feel somewhat empty now.'
	end
end

if $ARGS[0] = 'sly_plug':
	if analplugin = 1:
		if pcs_ass < 16:
			analplugout = 1
			analplugin = 0
			'Sly pulls the plug out of your tight asshole, making you give an involuntary gasp. You feel empty now.'
		else
			analplugout = 1
			analplugin = 0
			'Sly pulls the plug out of your asshole, making you give an involuntary moan. You feel empty now.'
		end
	end
end

if $ARGS[0] = 'Christina_peek':
	if slyQW['Chris_peeking'] = 1:
		if slyQW['Chris_caught'] <= 5:
			slyQW['Chris_peeking'] = 2
			*nl
			'You think you hear a moan that didn''t come from you, but you''re too busy to figure out where it''s coming from.'
			'Sly doesn''t seem to have heard anything and keeps thrusting into you.'
			*nl
		elseif slyQW['Chris_caught'] < 10:
			slyQW['Chris_peeking'] = 2
			*nl
			'You hear a moan coming from the doorway and sneak a look in that direction. Christina is peeking around the corner, obviously masturbating to the sight of her brother fucking you.'
			'Sly seems surprised to see her, but neither him nor her slow down.'
			*nl
		else
			slyQW['Chris_peeking'] = 2
			*nl
			'You hear a loud moan coming from the doorway again. Looking over, you see Christina boldly standing in the doorway naked and rubbing her clit, while watching the two of you fuck.'
			'Sly no longer seems to be surprised to see her watching and frequently looks in her direction to watch her masturbate.'
			*nl
		end
	elseif slyQW['Chris_peeking'] = 2:
		if slyQW['Chris_caught'] <= 5:
			*nl
			'You hear another moan but you ignore it.'
			'Sly doesn''t appear to have noticed anything seems off.'
			*nl
		elseif slyQW['Chris_caught'] < 10:
			*nl
			'You hear more moaning coming from Christina, as she masturbates to the sight of her brother fucking you.'
			'Sly''s attention keeps shifting from you to her. He seems unable to decide if he should be looking or not, judging by the war taking place on his face.'
			*nl
		else
			*nl
			'Looking towards the doorway, you see Christina has two fingers shoved up inside herself while rubbing her tits with her other hand.'
			'Sly doesn''t slow down his thrusts, but by the way he is staring at her and pretty much ignoring you, you imagine he is fucking her in his mind.'
			*nl
		end
	end
end

if $ARGS[0] = 'cum_decide':
	temp = rand(1, 10)
	if temp <= 2 and slyQW['virgin'] ! 2:
		gt 'Zvereva_Sly_sex', 'vag_doggy_cum_1'
	elseif temp <= 5:
		gt 'Zvereva_Sly_sex', 'anal_doggy_cum_1'
	else
		gt 'Zvereva_Sly_sex', 'swallow_cum_1'
	end
end

if $ARGS[0] = 'sex_end':
	act 'Clean up':
		slyQW['sex_act'] = 0
		slyQW['sex_stam'] = 0
		slyQW['trained'] += 1
		slyQW['Chris_peeking'] = 0

		gs 'panties', 'wear', $pursepantytype, pursepantynumber
		gs 'bras', 'wear', $pursebratype, pursebranumber
		killvar '$pursepantytype' & killvar 'pursepantynumber'
		killvar '$pursebratype' & killvar 'pursebranumber'
		gs 'clothing','wear_last_worn'

		if analplugout = 1: gs 'dinsex', 'after_anal'
		if vibratorOUT = 1:
			vibratorIN = 1
			vibratorOUT = 0
		end

		gs 'arousal', 'end'
		gs 'stat'

		gt 'Zvereva_house', 'hallw'
	end
end



!!Sex Scenes
if $ARGS[0] = 'hj_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/handjob/hj2.mp4"></video></center>'
	'You wrap your hand around his dick and start jacking him off slowly '+iif(christinaQW['fight'] = -1, 'while trying not to look him in the eye.','and seductively, while staring into his eyes.')+''
	'He seems to enjoy it for a few minutes before saying "You can speed up a bit now."'
	'Pumping his cock harder draws a small groan from his lips, but he quickly stops you from continuing.'

	gs 'arousal', 'hj', 3, 'sub'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Blowjob': gt 'Zvereva_Sly_sex', 'bj_1'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'bj_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/blowjob/kotovbj'+rand(110, 114)+'.mp4"></video></center>'
	'He grabs his dick with one hand, the back of your head with his other hand, and lines the tip of it up with your lips.'
	if christinaQW['fight'] = -1:
		'You try to keep your lips pressed tightly shut, but he forces his way in, trying to fit the whole thing down your throat all at once! Almost immediately you find yourself unable to breathe, gagging and drooling all over his cock.'
	else
		'Submitting to him entirely, you open your mouth as wide as you can while staring straight into his eyes. Without any hesitation, he tries to shove it straight down your throat, making your eyes water as you drool all over his cock trying to breathe.'
	end
	'He finds a rythm pumping it down your throat for awhile before letting go of your head and pulling it out of your mouth.'

	if pcs_makeup > 1: pcs_makeup = 0
	gs 'arousal', 'bj', 5, 'sub', 'deepthroat', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		slyQW['Chris_caught'] += 1
		slyQW['Chris_peeking'] = 1
		if slyQW['virgin'] ! 2:
			act 'Continue': gt 'Zvereva_Sly_sex', 'vag_cow_1'
		else
			act 'Continue': gt 'Zvereva_Sly_sex', 'anal_doggy_1'
		end
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'vag_cow_1':
	if slyQW['virgin'] = 1: slyQW['virgin'] = 3
	gs 'cum_call', 'precum', 'A248', 1
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/vag/cowgirl/hard'+rand(1, 4)+'.mp4"></video></center>'
	gs 'Zvereva_Sly_sex', 'sly_vibe'
	'Sitting on his bed, he pulls you onto his lap, lines you up and shoves his cock in hard, without any attempt to be gentle. '+iif(pcs_vag = 0, 'You feel your hymen rip, you''re no longer a virgin. ','')+'"Start shaking those hips," he says, laying back with his arms behind his head.'
	if christinaQW['fight'] = -1:
		'You reluctantly move your hips back and forth until he seems to get annoyed at your pace. Grabbing your hips, he takes over, thrusting in and out as he pulls you forward and pushes you back.'
	else
		'You happily start bouncing up and down on his cock. You let out a few loud moans, partly because it feels good, but mostly to make him happy. Eventually he takes over, grabbing your hips and thrusting in and out as he pulls you forward and pushes you back.'
	end
	gs 'Zvereva_Sly_sex', 'Christina_peek'
	if christinaQW['fight'] = -1:
		'Feeling a bit like a fuck toy, you try to ignore the sloshing sounds coming from your pussy, telling yourself over and over how this isn''t exciting you.'
	else
		'You lose yourself in the feeling of his cock stretching you out, the sounds of wet slaps filling the room each time your crotch collides with his.'
	end

	gs 'arousal', 'vaginal', 5, 'sub', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Continue': gt 'Zvereva_Sly_sex', 'vag_doggy_1'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'vag_doggy_1':
	if slyQW['virgin'] = 1: slyQW['virgin'] = 3
	gs 'cum_call', 'precum', 'A248', 1
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/vag/doggy/kotovsex'+rand(10, 13)+'.mp4"></video></center>'
	gs 'Zvereva_Sly_sex', 'sly_vibe'
	'He flips you onto your hands and knees and just slams his cock inside without warning. '+iif(pcs_vag = 0, 'You feel your hymen rip, you''re no longer a virgin. ','')+'He presses your face into the bed and, finding his rythm, pounds away.'
	if christinaQW['fight'] = -1:
		'You grunt into the blankets with each thrust, annoyed at how your body reacts to the unwanted stimulus. Even with your face smashed into the blankets, you can hear the wet sounds your pussy makes as he plunges in and out of you.'
	else
		'You reach behind with both hands and spread yourself wide, to give him easier access. Even with your face smashed into the blankets, you can hear the wet sounds your pussy makes as he plunges in and out of you.'
	end
	gs 'Zvereva_Sly_sex', 'Christina_peek'
	'He spanks your ass several times while fucking you, leaving red handmarks all over your asscheeks. The rough treatment has you leaking like crazy, running down your thighs and onto the bed below.'

	gs 'pain', 2, 'asscheeks', 'spank'
	gs 'arousal', 'foreplay', -5
	gs 'arousal', 'vaginal', 5, 'sub', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Continue': gt 'Zvereva_Sly_sex', 'vag_stomach_1'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'vag_stomach_1':
	if slyQW['virgin'] = 1: slyQW['virgin'] = 3
	gs 'cum_call', 'precum', 'A248', 1
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/vag/facedown/kotovsex'+rand(40, 45)+'.mp4"></video></center>'
	gs 'Zvereva_Sly_sex', 'sly_vibe'
	if rand(1, 2) = 1:
		'Sly pushes you to your stomach and pushes his way inside. '+iif(pcs_vag = 0, 'You feel your hymen rip, you''re no longer a virgin. ','')+'He starts fucking you hard, giving you no chance to adjust to the speed of his thrusts.'
		'As you think he''s going to ease up, instead the pace picks up and Sly is now violently thrusting into you. The pain is making you teary-eyed as you''re not able to handle the pounding.'
	else
		if christinaQW['fight'] = -1:
			'"W-Wait..." you manage to yell out before as he grabs hold of the back of your head pushes you down onto your stomach, facefirst into the bed. "I-I..." You take too long to utter a word as he enters you without pardon. '+iif(pcs_vag = 0, 'You feel your hymen rip, you''re no longer a virgin, as ','')+ 'Sly plunges deep into your pussy, leaving you barely able to keep in control of yourself.'
		else
			'He grabs hold of you and throws you on the bed with ease. You try to squirm into a more pleasant position, but he''s got you firmly held on your stomach with your face down, not letting you move an inch in any direction.'
			'Without any hesitation, his cock plunges inside of you. '+iif(pcs_vag = 0, 'You feel your hymen rip, you''re no longer a virgin. ','')+'You let out a little screech, to let him know that he''s hurting you, but he''s not easing up as he continues to furiously thrust without any consideration.'
		end
	end
	gs 'Zvereva_Sly_sex', 'Christina_peek'
	'He smacks your ass a bit, then pulls on your hair as he pumps his cock in and out of you. Every time he does, you squeal out and tighten down on his dick. He seems to enjoy the feeling, as he does it on and off for several minutes.'

	gs 'pain', 2, 'asscheeks', 'spank'
	gs 'pain', 2, 'hair', 'pull'
	gs 'arousal', 'foreplay', -5
	gs 'arousal', 'vaginal', 5, 'sub', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Continue': gt 'Zvereva_Sly_sex', 'anal_doggy_1'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'anal_doggy_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/anal/doggy/kotovsexanal11.mp4"></video></center>'
	gs 'Zvereva_Sly_sex', 'sly_plug'
	if christinaQW['fight'] = -1:
		'Sly forces you on your hands and knees as he gets in position behind you, pushing his cock inside your ass. Within seconds he''s pounding you, disregarding your shrieks and even slapping your buttcheeks as your ass is getting stretched out.'
	else
		if rand(1, 2) = 1:
			'"Get down on your hands and knees," he orders you. You quickly comply and even tease him a little as you wiggle your ass in front of him. He gives your ass a few slaps, grabs his cock and enters you. Not expecting him to fuck you in the ass, at first you gasp, but as he picks up his pace you start wailing from his firm thrusts.'
		else
			'You present yourself wide for him, awaiting his cock and to give him easier access. To your surprise, instead of Sly fucking your wet pussy, he instead shoves his cock inside your anus and starts plunging in and out of you while giving your asscheeks a few slaps.'
		end
	end
	gs 'Zvereva_Sly_sex', 'Christina_peek'
	'You try to spread your cheeks wider, so it will hurt less, but he''s pounding you too hard and fast for it to make much difference.'

	gs 'pain', 2, 'asscheeks', 'spank'
	gs 'arousal', 'foreplay', -5
	gs 'arousal', 'anal', 5, 'sub', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Continue': gt 'Zvereva_Sly_sex', 'anal_stomach_1'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'anal_stomach_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/anal/facedown/kotovsexanal20.mp4"></video></center>'
	gs 'Zvereva_Sly_sex', 'sly_plug'
	'"I''m going to enjoy this," he grunts as he forces himself on top of you. He scoots forward, holding your head down with one hand while pushing his cock inside of you with his other. Without giving you a chance to adjust, he picks up his pace and before you know it he''s plowing you.'
	'Your shrieks are muffled by the blankets on the bed, which your face is smushed into. He seems to enjoy the noise, because he reaches around, underneath you, and starts pinching your nipples. It hurts, and your screams grow even louder.'
	gs 'Zvereva_Sly_sex', 'Christina_peek'
	if christinaQW['fight'] = -1:
		'You cry for it to stop, but he doesn''t pay you any attention, using you for as a human fleshlight for quite some time.'
	else
		'You beg for more, and he complies, more for his own pleasure than any need to please you. The humiliation of being treated as a human fleshlight only makes you more aroused.'
	end

	gs 'pain', 2, 'nipples', 'pinch'
	gs 'arousal', 'foreplay', -5
	gs 'arousal', 'anal', 5, 'sub', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Continue': gt 'Zvereva_Sly_sex', 'anal_piledriver_1'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end

if $ARGS[0] = 'anal_piledriver_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/anal/piledriver/kotovsexanal36.mp4"></video></center>'
	gs 'Zvereva_Sly_sex', 'sly_plug'
	if christinaQW['fight'] = -1:
		'He pushes you onto your back, grabs your ankles, and pushes them behind your ears. Without hesitation, he plunges in full hilt. "S-Stop! It hurts," you cry out, but he pays no heed. Each time he slams down, he grunts, but draws a shriek out of you.'
	else
		'He pushes you onto your back, grabs your ankles, and pushes them behind your ears. Without hesitation, he plunges in full hilt. "Yes! More," you cry out. Each time he slams down, he grunts, but draws a shriek out of you.'
	end
	gs 'Zvereva_Sly_sex', 'Christina_peek'
	if christinaQW['fight'] = -1:
		'The sex is hard and fast. You hate it, but your body seems to respond to the pain by turning it into pleasure. Due to the awkward position your body is in, your own juices keeps splashing in your face until you''re soaked.'
	else
		'The sex is hard and fast. You love it, and your body seems to respond to the pain by turning it into pleasure. Due to the awkward position your body is in, your own juices keeps splashing in your face until you''re soaked.'
	end

	gs 'arousal', 'anal', 5, 'sub', 'rough'
	gs 'stat'

	if slyQW['trained'] = 0:
		act 'Continue': gt 'Zvereva_Sly_sex', 'cum_decide'
	else
		gs 'Zvereva_Sly_sex', 'Sly_random_sex_acts'
	end
end



!!Cum Scenes
if $ARGS[0] = 'anal_doggy_cum_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/cum/analcreampie/cumanal'+rand(1, 2)+'.mp4"></video></center>'
	'You suddenly find yourself bent over, his dick in your asshole. You can feel it twitching inside you, and a warmth is spreading. He pulls out, and you feel his cum leaking out.'
	'"Now clean up and get the fuck out of my room." He starts getting dressed, so you gather your own clothes and leave.'

	gs 'cum_call', 'anus', 'A248', 1
	gs 'stat'

	gs 'Zvereva_Sly_sex', 'sex_end'
end

if $ARGS[0] = 'vag_doggy_cum_1':
	menu_off = 1
	*clr & cla
	'<center><video autoplay loop src="images/shared/sex/cum/vagcreampie/doggy'+rand(1, 3)+'.mp4"></video></center>'
	'You suddenly find yourself bent over, his dick shoved in your pussy. You can feel it twitching inside you, and a warmth is spreading. He pulls out, and you feel his cum leaking out.'
	'"Now clean up and get the fuck out of my room." He starts getting dressed, so you gather your own clothes and leave.'

	gs 'cum_call', '', 'A248', 1
	gs 'stat'

	gs 'Zvereva_Sly_sex', 'sex_end'
end

if $ARGS[0] = 'swallow_cum_1':
	menu_off = 1
	*clr & cla
	if christinaQW['fight'] = -1:
		'<center><video autoplay loop src="images/shared/sex/cum/mouth/yuck1.mp4"></video></center>'
		'Sly sits you up, puts the tip of his cock in your mouth, and says "Swallow it all."'
		'You give him an angry look, but before you can refuse, he is already pumping his seed into your mouth. You do your best to swallow his hateful seed without spitting it out, but cannot manage to keep the revulsion off your face.'
		'"Well, that wasn''t exactly enthusiastic, but we will work on that. Now clean up and get the fuck out of my room." He starts getting dressed, so you gather your own clothes and gladly leave.'
	else
		'<center><video autoplay loop src="images/shared/sex/cum/mouth/swallow3.mp4"></video></center>'
		'Sly sits you up, shoves his cock down your throat, and starts pumping his seed out. First he pumps your stomach, then partially pulls out and fills your mouth up too. "Show me you swallow it," he says.'
		'Dutifully, you open your mouth to show him his cum in your mouth, swallow it, then show him your mouth is empty.'
		'"Good girl. Now clean up and get the fuck out of my room." He starts getting dressed, so you gather your own clothes and leave.'
	end

	gs 'cum_call', 'mouth_swallow', 'A248', 1
	gs 'stat'

	gs 'Zvereva_Sly_sex', 'sex_end'
end

--- Zvereva_Sly_sex ---------------------------------