glife/locations/Zvereva_events.qsrc

# Zvereva_events
!!22/06/01 - Alaratt

!!christinaQW['bully'] - earned if you stand up for yourself or not - less then 50 is you standing up, more then 50 is you being meek - at a certain point these unlock the below options
!!christinaQW['pre_fight'] - 1 means you are preparing to fight her
!!christinaQW['fight'] - 1 means you fought and won, -1 means you lost and are now her plaything
!!christinaQW['pre_bm'] - 1 means you are searching for the blackmail material to use against her
!!christinaQW['blackmail'] - 1 means you have the blackmail and need to talk to her to initiate, 2 means you have her blackmailed and are mostly safe from her bullying
!!christinaQW['submit'] - 1 means you willingly submitted, stays at 0 if you lose the fight, for reference on how you became her pet
!!christinaQW['subpath'] - 1 means you are looking to become her pet, 2 means you are her new pet, 3 means you have seen shower events, 4 is her home invite, 5 is you entered the home, 6 you push her into something...
!!slyQW['met'] - 1 means you are set to meet sly, 2 means you have met him
!!slyQW['trained'] - 1 means you have made it thru his sex intro
!!slyQW['foreplay'] - if not daystart, foreplay is allowed, but is set for every sex act, so will not go from anal/vag to a simple bj or hj
!!slyQW['virgin'] - 1 you protest you are a virgin, 2 you insist and no vag sex, even if no longer a virgin later on, because he wont know it changed at some point, 3 he took your virginity, 4 someone else did and you told him
!!slyQW['sex_stam'] - sex stamina, he will come when it reaches 6
!!slyQW['Chris_caught'] - increases when she spies on you, the higher it gets, the bolder she gets about doing it
!!slyQW['Chris_peeking'] - 0 she doesnt watch you that day, 1 she does, 2 just keeps Sveta from being surprised every change in sex acts
!!slyQW['Chris_peek_daystart'] - prevents more than one roll a day to see if Chris going to watch you and Sly


if $ARGS[0] = 'cikl':
	!!failsafe, should be used whenever adding or subtracting with bully events 
	if npc_rel['A18'] > 20:
		gs 'npc_relationship', 'set', 'A18', 20
	end
	if christinaQW['set_bully'] = 1:
		if christinaQW['bully'] < 1: christinaQW['bully'] = 1
		if christinaQW['bully'] > 99: christinaQW['bully'] = 99
	end
end

if $ARGS[0] = 'christina_bu_1':
	menu_off = 1
	!!Variable subtraction below keeps this number from being added twice when it returns you to the start point
	BeInSchool -= 1
	christinaQW['set_bully'] = 1
	christinaQW['bully'] = 50
	cla & *clr
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/school/events/nastymessage.jpg"></center>'
	'It''s your first day back to school, and Christina has decided to welcome you as only she could. As you approach your locker you find her writing graffiti on it.'
	act 'Say nothing':
		menu_off = 1
		pcs_mood -= 10
		christinaQW['bully'] += 1
		cla & *clr
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/school/events/nastymessage2.jpg"></center>'
		'As much as you want to say something, you know it won''t do any good.'
		'She gives you a sweet, and entirely fake, smile when she sees you coming. "Oh, hi <<$pcs_nickname>>. Don''t mind me, I was just giving your locker some much needed pop! We wouldn''t want anybody to think you were supposed to be treated normal, after all." Putting her marker away, she half waves and walks away.'
		'You try to rub it off, but have no luck. '+$OpenInnerThought+'Why does she always pick on me? I don''t understand what I did to deserve this.'+$CloseInnerThought
		act 'continue': gt 'gschool_grounds', 'bulding'
	end
	act 'Say something':
		menu_off = 1
		pcs_mood += 10
		christinaQW['bully'] -= 1
		cla & *clr
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/school/events/nastymessage2.jpg"></center>'
		'Though you know it won''t stop her, you cannot resist standing up for yourself. "What the fuck, Christina! Does my locker look like a coloring book to you? Why can''t you just leave my shit alone?"'
		'She gives you a sweet, and entirely fake, smile and says "Oh, hi <<$pcs_nickname>>. Don''t mind me, I was just giving your locker some much needed pop! We wouldn''t want anybody to think you were supposed to be treated normal, after all." Putting her marker away, she half waves and walks away.'
		'You try to rub it off, but have no luck. '+$OpenInnerThought+'Fucking bitch, someday I''ll get even, I swear!'+$CloseInnerThought
		act 'continue': gt 'gschool_grounds', 'bulding'
	end
end

if $ARGS[0] = 'christina_bu_2':
	menu_off = 1
	cla & *clr
	'You walk through the hallways until headiing outside. As you start down the path to home, you stumble and fall flat on your face. Stunned a bit, you lay there until you hear giggling and what sounds distinctly like a phone camera taking a picture. Climbing to your feet, you realize several of your classmates watched it happen and your face starts turning a bit red. Turning around, you realize who took a picture of you like that.'
	'"Smooth move," Christina says with her phone still aimed at you. "Hold on, I gotta make sure Lizaveta gets this."'
	if $pantyworntype ! 'none':
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/school/bully/fall_panties.jpg"></center>'
		act 'Say nothing':
			christinaQW['bully'] += 2
			cla
			'Your face burns as you imagine everybody in school looking at a picture of your panties, but she will do it no matter what you say, so you just quietly gather your fallen books and walk away.'

			act 'Leave': gt 'gschool_grounds', 'main'
		end
		act 'Say something':
			christinaQW['bully'] -= 2
			cla
			'Your face burns as you imagine everybody in school looking at a picture of your panties, and can''t stop yourself from saying "You pervert. Do you get off looking at girls panties?"'
			'Christina just shrugs and responds with "You''re the one showing them to the world. I bet you did it on purpose so people could see your'+iif($pantyworntype = 'gm', ' ugly',' cute')+' panties, slut." She finishes sending the picture, gives you a smirk, and walks away.'
			'All you can do at this point is gather your fallen stuff and head out.'

			act 'Leave': gt 'gschool_grounds', 'main'
		end
	else
		gs 'fame', 'pav', 'sex', 'tiny', 'local'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/school/bully/fall_nopanties.jpg"></center>'
		act 'Say nothing':
			christinaQW['bully'] += 3
			cla
			'Your face burns as you imagine everybody in school looking at a picture of your pussy on display, but she will do it no matter what you say, so you just quietly gather your fallen books and walk away.'

			act 'Leave': gt 'gschool_grounds', 'main'
		end
		act 'Say something':
			christinaQW['bully'] -= 3
			cla
			'Your face burns as you imagine everybody in school looking at a picture of your pussy on display, and can''t stop yourself from saying "You pervert. Do you get off taking upskirt pictures?"'
			'Christina just shrugs and responds with "You''re the one not wearing panties. I bet you did it on purpose so people could see your <<$pc_desc[''pubes'']>> pussy, slut." She finishes sending the picture, gives you a smirk, and walks away.'
			'All you can do at this point is gather your fallen stuff and head out.'

			act 'Leave': gt 'gschool_grounds', 'main'
		end
	end
end

if $ARGS[0] = 'christina_decide1':
	menu_off = 1
	cla & *clr
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
	'You can''t ever seem to decide how to deal with Christina. No matter how you treat her, she always seems to come off as cold or fake and has been this way for as long as you can remember. She''s such a bully to everybody except Albina, who seems to be the only person she''s seemingly wary of. She seems to especially hate you though, and bullies you every chance she gets.'
	*nl
	'You could try to fight her. She is reputedly one of the toughest girls in school though, so you better make sure you can actually do it before trying. Another option would be to find some dirt you could use against her. It would have to be something pretty embarressing to her to actually keep her from messing with you again.'
	act 'Leave it as is': gt 'gschool_lessons', 'short_break'
	act 'Pick a fight':
		menu_off = 1
		christinaQW['pre_fight'] = 1
		cla & *clr
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
		'You make your decision. You decide you''re going after her when school ends, when no teachers are around to stop it but everybody else will see.'

		act 'Return to break': gt 'gschool_lessons', 'short_break'
	end
	act 'Find something to blackmail her with':
		menu_off = 1
		christinaQW['pre_bm'] = 1
		cla & *clr
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
		'You make your decision. You need to keep your eyes and ears open to find something to use against her.'

		act 'Return to break': gt 'gschool_lessons', 'short_break'
	end
end

if $ARGS[0] = 'christina_decide2':
	menu_off = 1
	cla & *clr
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
	'You can''t ever seem to decide how to deal with Christina. No matter how you treat her, she always seems to come off as cold or fake and has been this way for as long as you can remember. She''s such a bully to everybody except Albina, who seems to be the only person she''s seemingly wary of. She seems to especially hate you though, and bullies you every chance she gets.'
	*nl
	'You could try and join Lina and Lariska, they both seem pretty happy to follow her orders and not having to think for themselves. The idea of being humiliated and treated as a possession strangely appeals to some dark part of you. It would be pretty easy to let her take control of your life too.'
	act 'Leave it as is': gt 'gschool_lessons', 'short_break'
	act 'Try and become her new pet':
		menu_off = 1
		christinaQW['subpath'] = 1
		cla & *clr
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big18.jpg"></center>'
		'You make your decision. You should head to the beach where she trains Lina on weekday afternoons and see what happens.'

		act 'Return to break': gt 'gschool_lessons', 'short_break'
	end
end

if $ARGS[0] = 'Chris_Lina_park':
	cla & *clr
	menu_off = 1
	socialchg['tChris_Lina_jog'] = daystart
	gs 'npc_relationship', 'modify', 'A19', 'like'
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/christina/Chris_Lina_park.jpg"></center>'
	if fame['pav_slut'] < 200:
		'You give a friendly wave to the girls as they get closer, but Christina just says something to Lina and they both laugh without slowing down.'
	else
		'You give a friendly wave to the girls as they get closer, but Christina just gives you a disgusted look and they continue running without slowing down.'
	end
	act 'Leave':gt 'pav_park', 'start'
end

if $ARGS[0] = 'KristinaFight':
	*clr & cla
	menu_off = 1
	$location_type = 'event_outdoors'
	gs 'stat'
	'<center><video autoplay loop src="images/characters/pavlovsk/school/girl/christina/school/fight.mp4"></video></center>'
	'You wait until you see Christina crossing the field heading home. Deciding you want to throw the first punch, you casually walk by like you were heading the same way. You know she cannot resist saying something nasty, and sure enough, she takes the bait. What she doesn''t expect is as soon as she tosses out an insult you whip towards her and punch her face, hard.'
	act 'Fight her':
		gs 'fight', 'initFight'
		gs 'fight_npcdata', 'christina'
		gt 'fight', 'start'
	end
end

--- Zvereva_events ---------------------------------