glife/locations/pav_shared_apt.qsrc

# pav_shared_apt

gs 'themes', 'indoors'
close all

if $ARGS[0] = 'update':
	rentWeekly = 2000
	if rentLeft <= 0:rentLeft = 0
	!how much of the unpaid weekly rent is left
	if orgB > 100:orgB = 100

	price_cook = 50
	price_clean = 50
	price_handjob = 50
	price_blowjob = 100
	price_vaginal = 150
	price_anal = 200
	price_special = 250

	! time calculations
	weekNum = (daystart - (daystart mod 7)) / 7

	! pcs setup
	$pcs_font = '990099'
		!pink

	! servitudeLvl = 0 - no service, pays rent
	! servitudeLvl = 1 - nonsexual service
	! servitudeLvl = 2 - sexual and nonsexual service


	$oleg_font = '0096FF'
		!blue
	oleg_leaves = 9
	oleg_comes = 18
	oleg_sleeps = 23
	oleg_wakes = 8


	$nestor_font = 'CC0000'
		!red
	nestor_leaves = 11
	nestor_comes = 19
	nestor_sleeps = 23
	nestor_wakes = 9


	$yakov_font = '009900'
		!green
	yakov_leaves = 7
	yakov_comes = 16
	yakov_sleeps = 22
	yakov_wakes = 5
		!flag if there was already a sex between him and Sveta
		!yakov_bj ; yakov_bjDeep ; yakov_swall ; yakov_vag ; yakov_vagCumInside ; yakov_vagCumInsideUnwanted ; yakov_anal ; yakov_analCumInside ; yakov_analCumInsideUnwanted

	!mood setup
	$oleg_mood = iif(oleg_mood = 1, 'great', '') + iif(oleg_mood = 2, 'good', '') + iif(oleg_mood = 3, 'nice', '') + iif(oleg_mood = 4, 'fine', '') + iif(oleg_mood = 5, 'neutral', '') + iif(oleg_mood = 6, 'okay', '') + iif(oleg_mood = 7, 'bad', '') + iif(oleg_mood = 8, 'terrible', '') + iif(oleg_mood = 9, 'awful', '') + iif(oleg_mood = 10, 'horrible', '')
	$nestor_mood = iif(nestor_mood = 1, 'great', '') + iif(nestor_mood = 2, 'good', '') + iif(nestor_mood = 3, 'nice', '') + iif(nestor_mood = 4, 'fine', '') + iif(nestor_mood = 5, 'neutral', '') + iif(nestor_mood = 6, 'okay', '') + iif(nestor_mood = 7, 'bad', '') + iif(nestor_mood = 8, 'terrible', '') + iif(nestor_mood = 9, 'awful', '') + iif(nestor_mood = 10, 'horrible', '')
	$yakov_mood = iif(yakov_mood = 1, 'great', '') + iif(yakov_mood = 2, 'good', '') + iif(yakov_mood = 3, 'nice', '') + iif(yakov_mood = 4, 'fine', '') + iif(yakov_mood = 5, 'neutral', '') + iif(yakov_mood = 6, 'okay', '') + iif(yakov_mood = 7, 'bad', '') + iif(yakov_mood = 8, 'terrible', '') + iif(yakov_mood = 9, 'awful', '') + iif(yakov_mood = 10, 'horrible', '')
	

	gs 'stat'

	if pavSharedAptDebug = 0:
	elseif pavSharedAptDebug = 1:
		'<a href="exec:pavSharedAptDebug=2">Debug</a>'
	elseif pavSharedAptDebug = 2:
		'<a href="exec:pavSharedAptDebug=1">Debug Close</a>'
		'<a href="exec:pavSharedAptDebug=0">Debug Disable</a>'
		$npc_firstname['A266']+' relationship: '+npc_rel['A266']
		$npc_firstname['A265']+' relationship: '+npc_rel['A265']
		$npc_firstname['A264']+' relationship: '+npc_rel['A264']
		'rentLeft: ' + rentLeft
		'weekNum: ' + weekNum
		'rentWeekNum: ' + rentWeekNum
		'servitudeLvl: ' + servitudeLvl
		'servicePaid: ' + servicePaid
		'cashPaid: ' + cashPaid
		'step: ' + step
		'subStep: ' + subStep
		'nestor_mood: ' + nestor_mood
		'oleg_mood: ' + oleg_mood
		'yakov_mood: ' + yakov_mood
		''
		oleg_served = 0
		oleg_mood = 1
		nestor_served = 0
		nestor_mood = 1
		yakov_mood = 1
		yakov_served = 0
	end
end

! accomodation advert
if $ARGS[0] = 'advertNo30':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'advertNo30'
	menu_off = 1
	minut += 2
	seenAd = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/stairs/pod_ob'+rand(1,2)+'.jpg"></center>'
	'<br>As you pass by the advertisements, you notice a sign - "сдаeтся в аренду комната" (Room for rent!). Some guys are looking for a roommate. They live in an apartment in one of the other buildings in the apartment complex.'
	act 'Continue':gt 'pod_ezd','etaj_1'
end

! door No 3 - shared
if $ARGS[0] = 'doorNo30':
	CLOSE ALL
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'doorNo30'
	menu_off = 1
	act 'Go back outside':gt 'pav_complex', 'start'
	if pavSharedAptEnabled = 1:
		'<center><img <<$set_imgh>> src="images/locations/shared/apartment/podezdhr.jpg"></center>'
		'<br>You stand before the entry door to apartment No 30, the apartment you share with three others'
		act 'Go inside':gt 'pav_shared_apt', 'start'
	else
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/aptno3door.jpg"></center>'
		'<br>You stand before the entry door to apartment No 30. There is a sign on the door saying - "сдаeтся в аренду комната" (Room for rent).'
		act 'Knock on the door':gt 'pav_shared_apt', 'intro'
	end
	
end

! apt hall
if $ARGS[0] = 'start':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'start'
	menu_off = 0
	$locM = 'pav_shared_apt'
	$locM_arg = 'start'
	$loc = 'pav_shared_apt'
	$loc_arg = 'start'
	$goBack = $loc_arg
	$location_type = 'private'
	killvar '$locclass'
	gs 'pav_shared_apt', 'update'
	if introDone = 0:gt 'pav_shared_apt', 'intro'
	minut += 2
	gs 'stat'
	
	gs 'courtletter'

	! do this once a day
	if daystart >= tomorrow:
		tomorrow = daystart + 1

		oleg_mood = rand(1, 10)
		oleg_cleaned = 0

		nestor_mood = rand(1, 10)
		nestor_cleaned = 0

		yakov_mood = rand(1, 10)
		yakov_cleaned = 0
	end

	! do this every time
	rentLeft = rentWeekly - servicePaid - cashPaid

	'<center><h3>Hallway</h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/hallway.jpg"></center>'
	'It is week number <<weekNum>>.'

	if weekNum < rentWeekNum:
		if rentLeft > 0:
			'You have <<rentLeft>> <b>₽</b> of rent left to pay for the next week.'
			if servitudeLvl >= 1:
				'You may still pay it in <a href="exec:gt ''pav_shared_apt'', ''payCash''">cash</a>, if you want.'
			else
				'Pay it in <a href="exec:gt ''pav_shared_apt'', ''payCash''">cash</a>.'
			end
		else
			'You have already paid the whole rent for the next week.'
			'You can end your rental agreement and leave the apartment if you don''t want to stay here anymore.'
		end
	elseif weekNum >= rentWeekNum:
		if rentLeft = 0:
			!rent was forepaid, everything OK, proceed to next week
			rentLeft += 2000
			cashPaid = 0
			servicePaid = 0			
			rentWeekNum = weekNum + 1
		elseif rentLeft > 0:
			!rent was not fully paid
			'You did not pay the whole rent for this week. You still have to pay <<rentLeft>> <b>₽</b>.'
			if money >= rentLeft:
				!not enough cash to pay it manually
				'You still can pay it in <a href="exec:gt ''pav_shared_apt'', ''payCash''">cash</a>, otwerwise you''ll be kicked out!'
			else
				!in future add some way to serve your way out
				'You do not have enough money to pay the rest of the rent in cash, even if you wanted to. Guess you''ll have to find a new living place...'
				rentPaid = 0
				pavSharedAptEnabled = 0
				gs 'homes_properties', 'block_access', 'shared_apartment', 0
			end
		end
	end

	act '<b>Leave and go outside</b>':
		if $clothingworntype ! 'nude':
			gt 'pav_complex', 'start'
		else
			msg'<b><font color = red>You need to get dressed.</font></b>'
			gt 'pav_shared_apt', 'start'
		end
	end
	
	if NatbelQW['QWstage'] >= 4 and week < 6 and hour = 7 and kanikuli = 0 and SchoolAtestat = 0 and SchoolBlock = 0 and (PCloStyle2 = 4 or Enable_sforma = 1):
		act 'Go pick up Natasha before school': gt 'natbelEv', 'carrybooks'
	end
	
	if rentPaid = 1:
		'A large apartment currently serves as shared living. As well as the normal living spaces, there are four bedrooms, one rented by you and three occupied by <a href="exec: gt ''pav_shared_oleg'', ''oleg_dick''"><font color=#<<$oleg_font>>><<$npc_firstname[''A266'']>></font></a>, <a href="exec: gt ''pav_shared_nestor'', ''nestor_Dick''"><font color=#<<$nestor_font>>><<$npc_firstname[''A265'']>></font></a>, <a href="exec: gt ''pav_shared_yakov'', ''yakov_Dick''"><font color=#<<$yakov_font>>><<$npc_firstname[''A264'']>></font></a>.'
		'You stand in the hallway.'
		*nl
		'From the hallway, several doors lead to <a href="exec:gt ''pav_shared_apt'', ''oleg_Room''"><<$npc_firstname[''A266'']>>''s</a>, <a href="exec:gt ''pav_shared_apt'', ''nestor_Room''"><<$npc_firstname[''A265'']>>''s</a>, and <a href="exec:gt ''pav_shared_apt'', ''yakov_Room''"><<$npc_firstname[''A264'']>>''s</a> rooms.'
		'The last doors lead to the <a href="exec:gt ''pav_shared_apt'', ''pcsRoom''">room</a> you have rented.'
		*nl
		!! Wardrobe is here because Sveta''s bedroom is actually the unused living room, with no wardrobe, so she is using the hall cupboard.
		'There are no cupboards in your living room cum bedroom, but there are several hall <a href="exec:gt ''wardrobe'', ''start''">closets</a> that you can use to store your clothes</a>, with a large tall <a href="exec:gt ''mirror'', ''start''">mirror</a> attached.'
		*nl
		if servitudeLvl >= 1:'A computer-printed <a href="exec:gt ''pav_shared_apt'', ''list''">list</a> hangs on the exit door.' & *nl
		act 'Go to your room':gt 'pav_shared_apt', 'pcsRoom'
		act 'Go to the bathroom':gt 'pav_shared_apt', 'bathroom'
		act 'Go to the kitchen':gt 'pav_shared_apt', 'kitchen'
		act '<font color=#<<$oleg_font>>><<$npc_firstname[''A266'']>>''s room</font>':gt 'pav_shared_apt', 'oleg_Room'
		act '<font color=#<<$nestor_font>>><<$npc_firstname[''A265'']>>''s room</font>':gt 'pav_shared_apt', 'nestor_Room'
		act '<font color=#<<$yakov_font>>><<$npc_firstname[''A264'']>>''s room</font>':gt 'pav_shared_apt', 'yakov_Room'
		if rentLeft = 0:
			act '<font color=red>End your rental agreement and move out</font>':gt 'pav_shared_apt', 'eoleg_agreement'
		end

		if func('homes_properties', 'is_current_home') = 0:
			act 'Set this apartment as your main home':gs 'homes_properties', 'set_home' & gt 'pav_shared_apt', 'start'
		end
	end

	!! NOTE:If Sveta has access to her parents home then she leaves the kids there
	if func('homes_properties', 'has_access', 'parents_home') = 0 and kid > 0:
		*clr & cla
		pavIntroStep = 0
		introDone = 0
		minut += 5
		!Need to have some actual story to this with NPC reactions.
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/boy/dimka/revenge/crying.jpg"></center>'
		'You''ve been kicked out of the apartment for having children.'
		pavSharedAptEnabled = 0
		gs 'homes_properties', 'block_access'
		act 'Leave':gt 'pav_complex', 'start'
	end
	if $clothingworntype = 'nude' and pavSharedAptEnabled = 0: gs 'clothing', 'wear_last_worn' & gs 'underwear', 'wear' & gs 'shoes', 'wear', 'last_worn' & gs 'stat'
end

if $ARGS[0] = 'payCash':
	menu_off = 1
	minut += 2
	cash = rentLeft
	if money >= cash:
		'You have decided to pay the remainder of the weekly rent ('+cash+'<b>₽</b>) with cash.'
		cashPaid += cash
		money -= cash
		rentPaid = 1
		pavSharedAptEnabled = 1
		gs 'homes_properties', 'give_access'
	else
		'You do not have enough cash to pay for the rest of your rent.'
	end
	act 'Proceed':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'payService':
	menu_off = 1
	minut += 1
	'The amount '+price+' <b>₽</b> was taken off of your weekly rent.'
	servicePaid += price
	act 'Continue':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'rentSetup':
	menu_off = 1
	minut += 2
	'You get a list of paper, saying the weekly rent is <<rentWeekly>> rubles.'
	rentPaid = 1
	introDone = 1
	rentWeekNum = (daystart - (daystart mod 7)) / 7 + 1
	act 'Continue':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'intro':
	menu_off = 1
	gs 'pav_shared_apt', 'update'
	if step > 0:
		'<center><img border="5" bordercolor="<<$yakov_font>>" height="150" src="images/locations/pavlovsk/resident/sharedapt/sp/sp.jpg"> <img height="150" src="images/locations/pavlovsk/resident/sharedapt/gp/gp.jpg"> <img height="150" src="images/locations/pavlovsk/resident/sharedapt/nd/nd.jpg"></center>'
		''
	end

	if pavIntroStep = 0:
		minut += 2
		pavIntroStep = 1
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/sp/sp.jpg"></center>'
		''
		'The door is opened by a young, nice-looking athletic man.'
		'<font color=#<<$yakov_font>>>"Hi sweetie! What do you need?"</font>'
		'<font color=#<<$pcs_font>>>"Hello, my name is <<$pcs_firstname>> <<$pcs_lastname>>. I''ve seen the advert that someone here have a spare room for rent?"</font>'
		'<font color=#<<$yakov_font>>>"Yeah, that''s true. Come in, I''ll call the guys and we can talk about it. I''m <<$npc_firstname[''A264'']>> by the way."</font>'
		act 'Go in':gt 'pav_shared_apt', 'intro'
	elseif pavIntroStep = 1:
		minut += 3
		pavIntroStep = 2
		'You enter a hallway filled with coats and shoes, indicating that 3 or 4 people live here.'
		'The guy disappears into one of the rooms, and you overhear him talking to someone.'
		'They attempt to speak quietly, but you catch a sentence or two...:'
		''
		'"...a girl, I tell you..." "...nice one, really, with nice round features, man..." "...better than another guy, idiot..." "...ok, ok, just be done with it..."'
		''
		'After a while, three young men emerge in the hallway.'
		'<font color=#<<$yakov_font>>>"So, that''s her, guys. <<$pcs_firstname>>, could you introduce yourself to these guys?"</font>'
		'<font color=#<<$pcs_font>>>"Hello, I''m <<$pcs_firstname>> <<$pcs_lastname>>. I''d like to rent the empty room in your apartment."</font>'
		'<font color=#<<$nestor_font>>>"Well, now that''s what I like! Finally, this won''t be such a dull party!"</font>'
		'<font color=#<<$oleg_font>>>"<<$pcs_firstname>>, please excuse my friend, <<$npc_firstname[''A265'']>>. He can be quite rude. I''m <<$npc_firstname[''A266'']>>."</font>'
		'<font color=#<<$nestor_font>>>"Yup, I''m <<$npc_firstname[''A265'']>>."</font>'
		'<font color=#<<$oleg_font>>>"So, you want to live here with us?"</font>'
		'<font color=#<<$pcs_font>>>"Yes, I need a new place to stay."</font>'
		'<font color=#<<$nestor_font>>>"How old are you, girl?"</font>'
		'<font color=#<<$oleg_font>>>"<<$npc_firstname[''A265'']>>, not this again!"</font>'
		'<font color=#<<$pcs_font>>>"It''s okay. I''m actually <<age>> years old. Why do you ask?"</font>'
		'<font color=#<<$oleg_font>>>"He''s just an idiot; don''t listen to him."</font>'
			
		if age < 18:
			'(You can see <<$npc_firstname[''A265'']>> rub his crotch just a brief moment after you told him your age. What''s he up to?)'
		end
		if knowpreg = 1:
			act 'Ask about children':
				cla
				pavIntroStep = 50
				'<font color=#<<$pcs_font>>>"I thought I should tell you, I''m currently pregnant. How do you feel about having children in the apartment, will this be a problem?"</font>'
				act 'continue':gt 'pav_shared_apt', 'intro'
			end
		elseif kid > 0:
			act 'Ask about children':
				cla
				pavIntroStep = 50
				'<font color=#<<$pcs_font>>>"I thought I should tell, I''m a mother. How do you feel about having children in the apartment, will this be a problem?"</font>'
				act 'continue':gt 'pav_shared_apt', 'intro'
			end
		else
			act 'Continue':gt 'pav_shared_apt', 'intro'
		end
	elseif pavIntroStep = 2:
		minut += 3
		pavIntroStep = 3
		'<font color=#<<$pcs_font>>>"So what do you guys say, will you take me in?"</font>'
		'<font color=#<<$oleg_font>>>"We may. But first, do you have the money to pay the rent?"</font>'
		'<font color=#<<$pcs_font>>>"Well, of course I don''t expect to let me live here for free. But I hope the rent is reasonable..."</font>'
		'<font color=#<<$oleg_font>>>"It is indeed."</font>'
		'<font color=#<<$yakov_font>>>"<<rentWeekly>> rubles. Per week."</font>'
		'<font color=#<<$pcs_font>>>"Uhm. That''s quite a lot. I''m not sure if I''ll be able to afford this..."</font>'
		'<font color=#<<$nestor_font>>>"You can pay other ways if you''d like!"</font>'
		'<font color=#<<$oleg_font>>>"<<$npc_firstname[''A265'']>>!"</font>'
		'<font color=#<<$pcs_font>>>"What do you mean by other ways?"</font>'
		'<font color=#<<$yakov_font>>>"Well <<$pcs_firstname>>, since we are just guys here, and since we suck at these things, we could use someone as you, a girl I mean, to be something like our, let''s say, handmaiden. If you know what I mean."</font>'
		'<font color=#<<$pcs_font>>>"Like cooking and cleaning?"</font>'
		'<font color=#<<$yakov_font>>>"Yes, exactly."</font>'
		'<font color=#<<$nestor_font>>>"And more."</font>'
		'<font color=#<<$oleg_font>>>"Oh my... I give up."</font>'
		act 'More what?':gt 'pav_shared_apt', 'intro'
	elseif pavIntroStep = 3:
		minut += 3
		'<font color=#<<$nestor_font>>>"More services."</font>'
		'<font color=#<<$pcs_font>>>"What kind of "services"?"</font>'
		'<font color=#<<$yakov_font>>>"the adult kind of services."</font>'
		'<font color=#<<$pcs_font>>>"You mean to be a whore for you? Instead of paying the rent???"</font>'
		'<font color=#<<$oleg_font>>>"Please <<$pcs_firstname>>, don''t get mad. <<$npc_firstname[''A265'']>> is not just an idiot, he is a rude idiot. We are definitely not asking you to be our whore or something like that."</font>'
		'<font color=#<<$oleg_font>>>" As <<$npc_firstname[''A264'']>> told you, we could decrease your rent if you would do some housekeeping stuff we really suck at. But only if you want, of course."</font>'
		'<font color=#<<$yakov_font>>>"So what do you say <<$pcs_firstname>>?"</font>'
		act 'Say that you changed your mind about this':pavIntroStep = 40 & gt 'pav_shared_apt', 'intro'
		act 'Say you will pay the rent the normal way':pavSharedAptEnabled = 1 & gs 'homes_properties', 'give_access' & pavIntroStep = 10 & gt 'pav_shared_apt', 'intro'
		act 'Say you don''t mind doing the homekeeping stuff':pavSharedAptEnabled = 1 & gs 'homes_properties', 'give_access' & pavIntroStep = 20 & gt 'pav_shared_apt', 'intro'
		act 'Say you don''t mind anything':pavSharedAptEnabled = 1 & gs 'homes_properties', 'give_access' & pavIntroStep = 30 & gt 'pav_shared_apt', 'intro'
	elseif pavIntroStep = 10:
		minut += 2
		'<font color=#<<$yakov_font>>>"Fine. So the rest of this week you have free, but you need to prepay the next week. OK?"</font>'
		'<font color=#<<$pcs_font>>>"Yes, OK, I understand."</font>'
		'<font color=#<<$yakov_font>>>"So the room is over there.</font>'
		'<font color=#<<$pcs_font>>>"Wait, Isn''t that the living room?"</font>'
		'<font color=#<<$yakov_font>>>""Yes, it''s available, but we''re not using it, so we''re renting it out. It''s fully furnished with a bed, a table, and a chair. We''ve even added a curtain to separate the space. Feel free to move in whenever you''d like. See you later, <<$pcs_firstname>>!"'
		'<font color=#<<$oleg_font>>>"Have a nice day <<$pcs_firstname>>."</font>'
		'<font color=#<<$nestor_font>>>"See ya later girlie..."</font>'
		'<font color=#<<$pcs_font>>>"Later guys!"</font>'
		servitudeLvl = 0
		act 'Continue':pavIntroStep = 0 & gt 'pav_shared_apt', 'rentSetup'
	elseif pavIntroStep = 20:
		minut += 2
		'<font color=#<<$yakov_font>>>"Fine. So the rest of this week you have free, but you need to prepay the next week. OK?"</font>'
		'<font color=#<<$pcs_font>>>"Yes, OK, I understand."</font>'
		'<font color=#<<$oleg_font>>>"We will prepare a list of the charges for the housekeeping services you may want to do, so it''s clear how much will be deducted from your rent."</font>'
		'<font color=#<<$pcs_font>>>"Cool!"</font>'
		'<font color=#<<$yakov_font>>>"So the room is over there."</font>'
		'<font color=#<<$pcs_font>>>"Wait, Isn''t that the living room?"</font>'
		'<font color=#<<$yakov_font>>>"Yes, it''s available, but we''re not using it, so we''re renting it out. It''s fully furnished with a bed, a table, and a chair. We''ve even added a curtain to separate the space. Feel free to move in whenever you''d like. See you later, <<$pcs_firstname>>!"</font>'
		'<font color=#<<$oleg_font>>>"Have a nice day, <<$pcs_firstname>>."</font>'
		'<font color=#<<$nestor_font>>>"See ya later, girlie..."</font>'
		'<font color=#<<$pcs_font>>>"Later, guys!"</font>'
			
		servitudeLvl = 1
		act 'Continue':pavIntroStep = 0 & gt 'pav_shared_apt', 'rentSetup'
	elseif pavIntroStep = 30:
		minut += 2
		'<font color=#<<$yakov_font>>>"Fine. So, the rest of this week you have free, but you need to prepay the next week. OK?"</font>'
		'<font color=#<<$pcs_font>>>"Yes, OK, I understand."</font>'
		'<font color=#<<$oleg_font>>>"We will prepare a list of the charges for the housekeeping services you may want to do, so it''s clear how much will be deducted from your rent."</font>'
		'<font color=#<<$nestor_font>>>"The extra stuff services will be there too, girl."</font>'
		'<font color=#<<$pcs_font>>>"OK..."</font>'
		'<font color=#<<$yakov_font>>>"So, the room is over there."</font>'
		'<font color=#<<$pcs_font>>>"Wait, isn''t that the living room?"</font>'
		'<font color=#<<$yakov_font>>>"Yes, it is, but we don''t use it, so we are renting it out. There is all you need, a bed, a table with a chair, all this stuff. Just move in when you want, we even put a curtain over the doorway. See you later, <<$pcs_firstname>>!"</font>'
		'<font color=#<<$oleg_font>>>"Have a nice day, <<$pcs_firstname>>."</font>'
		'<font color=#<<$nestor_font>>>"See ya later, girlie..."</font>'
		'<font color=#<<$pcs_font>>>"Later, guys!"</font>'
		servitudeLvl = 2
		act 'Continue':pavIntroStep = 0 & gt 'pav_shared_apt', 'rentSetup'
	elseif pavIntroStep = 40:
		minut += 2
		'<font color=#<<$oleg_font>>>"I told you idiot not to scare her away!"</font>'
		'<font color=#<<$nestor_font>>>"Sorry man! We can still lock her to the radiator like I suggested in the first place..."</font>'
		'<font color=#<<$oleg_font>>>"Just shut up already!"</font>'
		''
		'<font color=#<<$yakov_font>>>"Sorry <<$pcs_firstname>>. We respect your decision. If you change your mind and the room is still empty, let us know and we can talk again. Goodbye!"</font>'
		act 'Tell them goodbye and leave':pavIntroStep = 0 & gt 'pav_complex', 'start'
	elseif pavIntroStep = 50:
		minut += 2
		!add dialogue for returning after being previously expelled from apartment
		'<font color=#<<$oleg_font>>>"I''m sorry <<$pcs_firstname>>, but we don''t want children or pets in the apartment!"</font>'
		'<font color=#<<$nestor_font>>>"If you get rid of the kid, come back and see us."</font>'
		'<font color=#<<$yakov_font>>>"Don''t mind him. There''s simply not enough room for 4 people, plus kids or pets. I hope you understand"</font>'
		if func('homes_properties', 'has_access', 'parents_home'):
			act 'Suggest a compromise':
				cla
				pavIntroStep = 2
				'<font color=#<<$pcs_font>>>"I can leave them with my parents for the time being, and keep them away from the apartment, how does this sound?'
				'<font color=#<<$yakov_font>>>"Are you certain you want to do this?"</font>'
				'<font color=#<<$nestor_font>>>"Sounds good to me!"</font>'
				'<font color=#<<$oleg_font>>>"hmmmm"</font>'
				act 'Continue':gt 'pav_shared_apt', 'intro'
			end
			act 'I won''t leave my children':
				cla
				pavIntroStep = 0
				'<font color=#<<$pcs_font>>>"OK, I will make do with my current accommodation.'
				'<font color=#<<$yakov_font>>>"We understand"</font>'
				'<font color=#<<$nestor_font>>>"Damn"</font>'
				'<font color=#<<$oleg_font>>>"No problem <<$pcs_firstname>>"</font>'
				act 'Continue':gt 'pav_shared_apt', 'intro'
			end
		else
			'<font color=#<<$pcs_font>>>OK, I understand.</font>'
			act 'Thank them and leave':pavIntroStep = 0 & gt 'pav_complex', 'start'
		end
	end
end

! the pricelist
if $ARGS[0] = 'list':
	menu_off = 1
	$loc_arg = 'list'
	minut += 2
	$goBack = $loc_arg
	'<center><h3><<$pcs_firstname>>''s pricelist</h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/list.jpg"></center>'
	''
	'The basic weekly rent is <<rentWeekly>> rubles.'
	'It is possible to pay it in cash or offer services instead. The prices are following:'
	''
	'---------------'
	''
	'Cook a warm meal: '+price_cook
	'Clean the apartment: '+price_clean
	if servitudeLvl >= 2:
		''
		'---------------'
		''
		'Written in marker on the paper, are sexual favours you can offer as well.'
		''
		'---------------'
		'Rent discounts for the slut: '
		'Handjob: '+price_handjob
		'Blowjob: '+price_blowjob
		'Sex: '+price_vaginal
		'Anal sex: '+price_anal
		'Special treats: '+price_special
	end
	''
	'---------------'
	''
	'Not having paid the full weekly rent at the beginning of a new week will lead to termination of the accommodation services.'
	'Signed: <a href="exec: gt ''pav_shared_oleg'', ''oleg_Dick''"><font color=#<<$oleg_font>>><<$npc_firstname[''A266'']>></font></a>, <a href="exec: gt ''pav_shared_nestor'', ''nestor_Dick''"><font color=#<<$nestor_font>>><<$npc_firstname[''A265'']>></font></a>, <a href="exec: gt ''pav_shared_yakov'', ''yakov_Dick''"><font color=#<<$yakov_font>>><<$npc_firstname[''A264'']>></font></a>, <<$pcs_firstname>>.'
	''
	'---------------'
	act 'Continue':gt 'pav_shared_apt', 'start'
end

! paying with money
if $ARGS[0] = 'payRent':
	menu_off = 1
	minut += 1
	'You decided to give the guys money, instead of serving them.'
	'You paid them <<paid_rent>> cash.'
	money -= paid_rent
	gs 'stat'
	act 'Continue': gs 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'bathroom':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'bathroom'
	menu_off = 0
	minut += 1
	$location_type = 'bathroom'
	$loc = 'pav_shared_apt'
	$loc_arg = 'bathroom'
	$locM_arg = 'bathroom'
	$locM = 'pav_shared_apt'

	'<center><h3>Bathroom</h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/vanrpar.jpg"></center>'
	*nl
	'This is a modest bathroom, containing everything that young people need for their daily life, such as:'
	'A shower, toilet, <a href="exec:gt ''mirror'',''start''">mirror</a>, where you can ' + iif(pcs_hairbsh < 1, '<a href="exec:gt ''mirror'',''brush''">brush</a>', 'brush') + ' your hair, a sink and even a bath tub.'
	*nl
	gs 'din_van', 'private'
	gs 'stat'
	act 'Leave':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'kitchen':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'kitchen'
	menu_off = 0
	*clr & cla
	minut += 2
	$loc = 'pav_shared_apt'
	$loc_arg = 'kitchen'
	$locclass = 'kitr'
	gs 'stat'
	gs 'kit_din'
	'<center><h3>Kitchen</h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/kuhrpar.jpg"></center>'
	'It''s a modest kitchen, but has all that is needed.'
	'You can cook breakfast for the guys between 6:00 and 7:00 and dinner for them between 18:00 and 19:00'

	! dishes
	if mc_inventory['dish_plates'] > 0:
		'Above the sink are <b><<mc_inventory[''dish_plates'']>></b> the clean plates'
	else
		'<b><font color = red>You have no clean dishes left.</font></b>'
	end
	if dirttarelka > 0:'The sink has <b><<dirttarelka>></b> dirty dishes. <a href="exec: dynamic $dirtarm">that need to be washed</a>.'
	if mc_inventory['dish_soap'] > 0:
		'Above the sink is some detergent to wash the dishes with. There is enough for <b><<mc_inventory[''dish_soap'']>></b> uses.'
	else
		'<b><font color = red>You do not have enough detergent, you should buy some from the supermarket.</font></b>'
	end

	! food
	if mc_inventory['food_basic'] > 0:
		if mc_inventory['dish_plates'] = 0 or edahot > 0:$edagot = ''
		if mc_inventory['dish_plates'] > 0 and edahot = 0:
			$edagot = '<a href="exec:dynamic $edagotd">Cook a meal  for yourself (0:30)</a>'
		end
		'In the refrigerator there''s enough (your own) food for <b><<mc_inventory[''food_basic'']>></b> servings. <<$edagot>>'
	end
	if edahot > 0:'<a href="exec: dynamic $edahotd ">On the table is ready meal (0:30).</a>'
	if mc_inventory['food_diet'] = 0 and mc_inventory['food_basic'] = 0:'<b><font color="red">You have nothing to eat, the refrigerator is empty!</font></b>'

	if hour = 6 or hour = 18:'<a href="exec: gt ''pav_shared_apt'', ''cookForGuys''">Cook meals for the guys (1:30)</a>'
	
	dynamic $edasnack
	dynamic $sandwich
	dynamic $driwater
	dynamic $dritea
	dynamic $fill_bottle
	dynamic $edaD
	dynamic $pranik
	dynamic $fatdel
	dynamic $lekarstvo
	dynamic $vitamin

	act 'Leave':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'cookForGuys':
	menu_off = 1
	cla
	*clr
	$loc = 'pav_shared_apt'
	$loc_arg = 'kitchen'
	minut += 90
	kuhdrova = 0
	pcs_mood -= 10
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/shared/home/kitchen/cook.jpg"></center>'
	'You prepare three meals, using what you can from the guys'' food. It''s not very healthy but you''re not planning to offer to do their shopping too.'
	price = price_cook

	act 'Leave the meal':gt 'pav_shared_apt', 'payService'
end

if $ARGS[0] = 'cleanForGuys':
	menu_off = 1
	cla
	*clr
	minut += 60
	mc_inventory['laundry_soap'] -= 3
	pcs_mood -= 10
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/stir.jpg"></center>'

	price = price_clean
	*nl
	'You collect piles of dirty clothes around the room, carry them into the bathroom, put them in a basin and then pour washing powder on them. You wash them until they are finally clean.'
	cumStainCh =  rand(0, 100)
	if servitudeLvl = 2 and cumStainCh <= 50:'<i>You notice bedsheets with what seems as dried out cum. Probably remainder of one of your "servings". Maybe it really is better to swallow every time...</i>'

	act 'Hang them to dry out and leave':gt 'pav_shared_apt', 'payService'
end

! living room & pc bedroom
if $ARGS[0] = 'pcsRoom':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'pcsRoom'
	menu_off = 0
	$loc = 'pav_shared_apt'
	$loc_arg = 'pcsRoom'
	$location_type = 'private'
	$locclass = 'bedr'
	minut += 2
	gs 'stat'
	gs 'pav_shared_apt', 'update'

	'<center><b><font color="maroon">Living Room</font></b></center>'
	'<center><img <<$set_imgh>> src="images/shared/home/bedroom/sofabed.jpg"></center>'
	*nl
	'The living room was never used by the other apartment occupants, so it''s now rented out as a bedroom. It''s sparsely decorated, with, a <a href="exec:gt ''bed'', ''start''">sofa bed</a>, against the back wall.'
	*nl
	'Beside the sofa bed is an old cabinet, with your <a href="exec:gt ''alarmclock'', ''start''">alarm clock</a> on top.'
	*nl
	'Your <a href="exec:gt ''alarmclock'', ''start''">alarm clock</a> is set to <<func(''alarmclock'', ''alarm_display'', alarmVars[''timerH''], alarmVars[''timerM''])>> during the week and <<func(''alarmclock'', ''alarm_display'', alarmVars[''timerEndH''], alarmVars[''timerEndM''])>> during the weekend. It is currently turned ' + iif(alarmVars['alarmOn'] = 0, '<a href="exec: alarmVars[''alarmOn''] = 1 & gt $loc, $loc_arg">OFF</a>.', '<a href="exec: alarmVars[''alarmOn''] = 0 & gt $loc, $loc_arg">ON</a>.')
	*nl
	if $ml_guitar['location'] = $loc: 'Your guitar rests on its stand next to your bed.'
	*nl
	if mc_inventory['tech_tv'] = 0 and mc_inventory['plasma_tv'] = 0: $TV = 'a great place for a TV, if you had one'
	if mc_inventory['tech_tv'] >= 1:$TV = 'an old CRT <a href="exec:gt ''TV'', ''start''">TV</a> sits on the shelf'
	'There is an wall unit at the other side of the room, <<$TV>>. Everyone in the household spends their time in their own rooms, so there was never a reason to use the living room for its intended purpose.'
	*nl
	if stol = 0:$stol = 'an old scratched <a href="exec:gt ''stol'', ''start''">table</a>'
	'In the corner there is <<$stol>>.'
	*nl
	'There is no door to the living room, instead there''s <a href="exec:view''images/shared/home/bedroom/curtain.jpg''">curtain</a> covering entry to the room, which gives you a modicum of privacy; not much better than the state of the non-existent window curtains.'

	act '<b>Leave the room</b>':gt 'pav_shared_apt', 'start'

	act 'Sit on the sofa bed':gt 'pav_shared_apt', 'sofabed'

	if mc_inventory['hula_hoop'] > 0: '<br>A hula hoop stands in corner of the room. '
	if mc_inventory['skipping_rope'] > 0: 'A jump rope lies on a shelf. '
	if mc_inventory['book_yoga'] > 0: 'A yoga mat is rolled up in a corner. '
	gs 'exercise', 'start'
	*nl

	if mc_inventory['tech_computer'] = 1:
		!! Sveta can''t do camshows unless she is blowing the guys for rent.
		gs 'internet_mobile', 'get_access', 'free', 'nocamshow'
		if servitudeLvl = 2: access['nocamshow'] = 0
		'Your <a href="exec:gorodokKomp = 1 & gt ''Komp'',''start''">computer</a> is sitting on small table.'
	end

	if vcard > 0: act 'View your vintage porn cards':card_deck = 0 & gt 'card'
	if card > 0: act 'View your new porn cards':card_deck = 1 & gt 'card'

	if mc_inventory['cocaine'] > 0:'You have <<mc_inventory[''cocaine'']>> doses of Pale Lady, hidden from the other housemates.'

	if mc_inventory['cocaine'] > 0 and drugVars['cocaine_day'] ! daystart:
		act 'Use some Pale Lady (0:05)':
			*clr & cla
			minut += 5
			gs 'drugs', 'cocaine'

			'<center><img <<$set_imgh>> src="images/shared/drugs/dur.jpg"></center>'
			'You snort some Pale Lady, feeling dizzy for just a moment. After that, you feel fantastic and incredibly horny.'

			act 'Continue':gt 'pav_shared_apt', 'pcsRoom'
		end
	end

	if gobelen>0:'You have <<gobelen>> completed tapestries.'
	if pcs_sewng >= 40 and mc_inventory['sewing_fabric'] > 0:'You have enough fabric for <<mc_inventory[''sewing_fabric'']>> lessons.'
	if pcs_sewng >= 40 and mc_inventory['sewing_fabric'] <= 0:'You do not have any fabric.'
	if pcs_sewng >= 80:
		if newgobelen = 0 and mc_inventory['sewing_fabric'] > 0:
			act'Start a new tapestry':
				cls
				mc_inventory['sewing_fabric'] -= 1
				newgobelen = 1
				minut += 15
				gs'stat'
				'You spend 15 minutes working on the embroidery frame, preparing the fabric and outlining the pattern for the tapestry.'
				act'Set the tapestry aside':gt 'pav_shared_apt', 'pcsRoom'
			end
		end
		if newgobelen>=1:
			'Your tapestry is <<newgobelen/10>> percent finished.'
			act'Work on the tapestry for an hour':
				cls
				minut+=60
				gs 'exp_gain', 'sewng', rand(pcs_intel/10, pcs_intel/5)
				gobramax = (pcs_sewng - 70) * 6
				gobramin = (pcs_sewng - 70) * 2
				newgobelen += rand(gobramin,gobramax)
				gs'stat'
				if newgobelen < 1000:'You spent an hour working on your tapestry, which is now <<newgobelen/10>> percent finished.'
					if newgobelen >= 1000:
					newgobelen = 0
					gobelen += 1
					'Your work on the tapestry is done.'
				end
				act'Set the tapestry aside':gt 'pav_shared_apt', 'pcsRoom'
			end
		end
	end

	if mc_inventory['contraceptive_pill'] > 0 and mc_inventory['equipped_condoms'] + mc_inventory['normal_condoms'] + mc_inventory['sabotaged_condoms'] > 0:
		'Your <a href="exec:gt ''stol'', ''bc''">birth control</a> tablets are in the cabinet next to your bed, along with some <a href="exec:gt ''stol'', ''bc''">condoms</a>.'
	elseif mc_inventory['contraceptive_pill'] > 0:
		'Your <a href="exec:gt ''stol'', ''bc''">birth control</a> tablets are in the cabinet next to your bed.'
	elseif mc_inventory['equipped_condoms'] + mc_inventory['normal_condoms'] + mc_inventory['sabotaged_condoms'] > 0:
		'Your <a href="exec:gt ''stol'', ''bc''">condoms</a> are in the cabinet next to your bed.'
	end
	''
	if mc_inventory['sewing_kit'] = 1:
		'Your <a href="exec:gt ''sewing'',''start''">sewing kit</a> is stored on a shelf.'
	end

	if tovarL > 0:'You currently have <<tovarL>> trinkets to sell at the station. The maximum you can carry with you is 30.'

	dynamic $wearpan
	dynamic $removepan
	!gs 'subkid'

	act 'Relax on your bed': gt 'bed', 'start'
	gs 'prostitution_functions', 'prostitute_outfit_at_home'
	gs 'music_actions', 'music_icon'
end
	
if $ARGS[0] = 'sofabed':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'sofabed'
	menu_off = 0
	$loc = 'pav_shared_apt'
	$loc_arg = 'sofabed'
	*clr & cla
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/shared/home/bedroom/sofabed.jpg"></center>'
	'<center>A small sofa bed, when not unfolded, is just big enough for you to curl up on and take a nap.</center>'

	if mc_inventory['tech_tv'] = 1:
		act 'Watch some TV':gt 'TV', 'start'
	end

	if mc_inventory['mag_porn'] > 0:
		'<br>There is a porn magazine under the sofa cushions'
		gs 'events', 'read_porn'
	end

	gs 'events', 'read'

	if pcs_horny >= 50:
		act 'Masturbate':gt 'selfplay', 'start'
	end

	act 'Take a nap (1:00)':
		if pcs_sleep < 90:
			pcs_sleep += 10
			pcs_health += 5
			minut += 60
			gs 'stat'
			'You sleep about an hour.'
		else
			minut += 5
			gs 'stat'
			'You are not tired enough to sleep, even for a short nap.'
		end
	end
	act 'Get up':gt 'pav_shared_apt', 'pcsRoom'
end

if $ARGS[0] = 'oleg_Room':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'oleg_Room'
	menu_off = 0
	$loc = 'pav_shared_apt'
	$loc_arg = 'oleg_Room'
	minut += 2
	'<center><h3><font color=#<<$oleg_font>>><<$npc_firstname[''A266'']>>''s room</font></h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/nd/room.jpg"></center>'
	''
	'The room isn''t as messy as one might expect, given that <<$npc_firstname[''A266'']>> is an IT guy.'
	'There is one large window with a bed below it, but the entire room is dominated by a large table with several computers and monitors.'
	'At first glance, one might mistake this room for a hacker''s den.'
	
	if hour >= oleg_sleeps and hour < oleg_wakes:
		'<<$npc_firstname[''A266'']>> is sound asleep in his bed.'
	elseif hour >= oleg_wakes and hour < oleg_leaves:
		'<<$npc_firstname[''A266'']>> is already awake and getting ready to leave.'
		act 'Approach him': gt 'pav_shared_oleg', 'oleg'
	elseif hour >= oleg_leaves and hour < oleg_comes:
		'<<$npc_firstname[''A266'']>> is currently not here.'
	elseif hour >= oleg_comes and hour < oleg_sleeps:
		'<<$npc_firstname[''A266'']>> is behind his desk, engrossed in programming using an esoteric language.'
		act 'Approach him': gt 'pav_shared_oleg', 'oleg'
	end
	
	if servitudeLvl >= 1 and oleg_cleaned = 0:
		if mc_inventory['laundry_soap'] >= 1:
			act 'Clean the room':oleg_cleaned = 1 & gt 'pav_shared_apt', 'cleanForGuys'
		else
			'You don''t have enough laundry detergent to clean the room'
		end
	end
	act 'Leave':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'nestor_Room':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'nestor_Room'
	menu_off = 0
	$loc = 'pav_shared_apt'
	$loc_arg = 'nestor_Room'
	minut += 2
	'<center><h3><font color=#<<$nestor_font>>><<$npc_firstname[''A265'']>>''s room</font></h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/gp/room.jpg"></center>'
	''
	'This room is a messy disaster, with clothes scattered all over the floor.'

	if hour >= nestor_wakes and hour < nestor_leaves:
		'<<$npc_firstname[''A265'']>> is already awake, getting ready to leave.'
		act 'Approach him': gt 'pav_shared_nestor', 'nestor'
	elseif hour >= nestor_leaves and hour < nestor_comes:
		'<<$npc_firstname[''A265'']>> is not here.'
	elseif hour >= nestor_comes and hour < nestor_sleeps:
		'<<$npc_firstname[''A265'']>> is currently on his bed, listing through some magazines.'
		act 'Approach him': gt 'pav_shared_nestor', 'nestor'
	elseif hour >= nestor_sleeps or hour < nestor_wakes:
		'<<$npc_firstname[''A265'']>> is sleeping in his bed.'
	end
	if servitudeLvl >= 1 and nestor_cleaned = 0:
		if mc_inventory['laundry_soap'] >= 1:
			act 'Clean the room':nestor_cleaned = 1 & gt 'pav_shared_apt', 'cleanForGuys'
		else
			'You don''t have enough laundry detergent to clean the room'
		end
	end
	act 'Leave':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'yakov_Room':
	$menu_loc = 'pav_shared_apt'
	$menu_arg = 'yakov_Room'
	menu_off = 0
	$loc = 'pav_shared_apt'
	$loc_arg = 'yakov_Room'
	minut += 2
	'<center><h3><font color=#<<$yakov_font>>><<$npc_firstname[''A264'']>>''s room</font></h3></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/sharedapt/sp/room.jpg"></center>'
	''
	'This room is very neat and organized, filled with sporting gear such as dresses, equipment, and trophies. The walls are adorned with several posters of famous athletes and sports teams.'

	if hour >= yakov_wakes and hour < yakov_leaves:
		'<<$npc_firstname[''A264'']>> is already awake, packing his gym bags to leave.'
		act 'Approach him': gt 'pav_shared_yakov', 'yakov'
	elseif hour >= yakov_leaves and hour < yakov_comes:
		'<<$npc_firstname[''A264'']>> is not here.'
	elseif hour >= yakov_comes and hour < yakov_sleeps:
		doesStuff = rand(0, 100)
		if doesStuff < 50:'<<$npc_firstname[''A264'']>> is currently on his bed, listing through football magazines.'
		if doesStuff >= 50:'<<$npc_firstname[''A264'']>> is working out on the floor.'
		act 'Approach him': gt 'pav_shared_yakov', 'yakov'
	elseif hour >= yakov_sleeps or hour < yakov_wakes:
		'<<$npc_firstname[''A264'']>> is sleeping in his bed.'
	end
	if servitudeLvl >= 1 and yakov_cleaned = 0:
		if mc_inventory['laundry_soap'] >= 1:
			act 'Clean the room':yakov_cleaned = 1 & gt 'pav_shared_apt', 'cleanForGuys'
		else
			'You don''t have enough laundry detergent to clean the room'
		end
	end
	act 'Leave':gt 'pav_shared_apt', 'start'
end

if $ARGS[0] = 'eoleg_agreement':
	menu_off = 1
	'<center><img border="5" bordercolor="<<$yakov_font>>" height="150" src="images/locations/pavlovsk/resident/sharedapt/sp/sp.jpg"> <img height="150" src="images/locations/pavlovsk/resident/sharedapt/gp/gp.jpg"> <img height="150" src="images/locations/pavlovsk/resident/sharedapt/nd/nd.jpg"></center>'
	''

	'You gather the guys around and explain to them that you wish to move out.'
	'<font color=#<<$pcs_font>>><<$npc_firstname[''A264'']>> Looks disappointed as he addresses you. "That is a shame <<$pcs_firstname>> we''ve very much enjoyed having you stay here we us. Are you sure this is what you want?"</font>'
	act '"Yes." End agreement':
		pavSharedAptEnabled = 0
		gs 'homes_properties', 'block_access', 'shared_apartment', 0
		gt 'pav_complex', 'start'
	end
	act '"Maybe you are right, I''ll stay here with you guys"':gt 'pav_shared_apt', 'start'
end

--- pav_shared_apt ---------------------------------