glife/locations/sewing.qsrc

# sewing

if $ARGS[0] = 'start':
	cla & *clr
	'<center><img <<$set_imgh>> src="images/pc/activities/sewing/kit.jpg"></center>'
	'You pull your sewing kit out from under your bed.'
	*nl
	if mc_inventory['sewing_fabric'] > 1:
		'You have <<mc_inventory[''sewing_fabric'']>> pieces of sewing fabric left.'
	elseif mc_inventory['sewing_fabric'] = 1:
		'You have 1 piece of sewing fabric left.'
	else
		'You have no fabric left to use as material.'
	end
	if pcs_sewng > 50 and mc_inventory['sewing_fabric'] >= 1: 'You can resize your own clothing when viewing items in the wardrobe list <a href="exec:gt ''clothing'', ''view_clothing_list'', ''wardrobe''">here</a>.'
	act 'Leave':gt $loc, $loc_arg
	act 'Practice sewing (0:30)':
		minut += 30
		gs 'stat'
		cla & *clr
		'<center><img <<$set_imgh>> src="images/pc/activities/sewing/practice.jpg"></center>'
		if pcs_sewng < 40:
			gs 'exp_gain', 'sewng', 2
			'You practice your sewing skills.'
		else
			'You spend some time practicing stitches and other sewing techniques, but you don''t feel like you''re getting any better.'
			*nl
			'You think you need real projects to work on to increase your skill, either in a class or on your own.'
		end
		act'Finish':gt 'sewing', 'start'
	end		

	
	act 'Sew trinkets (0:30)':
		minut += 30
		gs 'stat'
		cla & *clr
		act 'Finish':gt 'sewing', 'start'
		if mc_inventory['sewing_fabric'] < 1:
			'You do not have any material to sew anything. You should buy some from the supermarket.'
		elseif mc_inventory['trinkets_home'] = 30 and (YouCanGar = 0 or mc_inventory['trinkets_garage'] = 100):
			'You do not have any further storage space, you need to sell some trinkets to make room before sewing more of them.'
		else
			sew_trinket_success = rand(1,240)
			mc_inventory['sewing_fabric'] -= 1
			if pcs_sewng >= 40:gs 'exp_gain', 'sewng', rand(pcs_intel/20, pcs_intel/10)
			if pcs_sewng < 40:gs 'exp_gain', 'sewng', rand(pcs_intel/25, pcs_intel/15)

			if sew_trinket_success > pcs_sewng*4:
				'<center><img <<$set_imgh>> src="images/pc/activities/sewing/practice.jpg"></center>'
				'You do your best trying to sew together a trinket at a quality you can sell, but somewhere along the way, you mess it up. The material is ruined, and you''re frustrated as hell, but at least you feel like you learned something.'
			else
				if mc_inventory['trinkets_home'] >= 30 and (YouCanGar = 0 or mc_inventory['trinkets_garage'] >= 100):
					'<center><img <<$set_imgh>> src="images/pc/activities/sewing/kit.jpg"></center>'
					'You put together another trinket but then realize you have too many trinkets already. ' + iif(YouCanGar > 0, 'Even the space in your stepfather''s garage is full. ', '') + 'With a deep sense of regret, you throw it away, having no place to store it. At least you learned more about sewing...'
				else
					'<center><img <<$set_imgh>> src="images/pc/activities/sewing/trinket.jpg"></center>'
					*p 'You spend some time trying to sew something together. After a half hour, you find yourself rewarded for your effort with a small trinket that''s actually of decently high quality. '
					if mc_inventory['trinkets_home'] < 30:
						mc_inventory['trinkets_home'] += 1
						'Storing it away, you figure you ' + iif(mc_inventory['trinkets_home'] < 30, 'still have space for about <<30 - mc_inventory[''trinkets_home'']>>', 'probably don''t have room for any') + ' more of these in your room.' + iif(mc_inventory['trinkets_home'] >= 30 and YouCanGar > 0, ' If you make any more of these, you''ll need to start storing them in your stepfather''s garage.', '')
						*nl
						'You wonder if you can sell them somewhere.'
					else
						mc_inventory['trinkets_garage'] += 1
						'The storage space in your room is full, but you can still store it in your stepfather''s garage, ' + iif(mc_inventory['trinkets_garage'] < 100, 'along with probably another <<100 - mc_inventory['trinkets_garage']>>.', 'though it doesn''t look like there''s space for any more beyond that there either.')
						*nl
						'You wonder how many you can sell at the train station.'
					end
				end
			end
		end
	end
end
if $ARGS[0] = 'tapestry':
	if newgobelen = 0:
		*clr & cla
		menu_off = 1
		mc_inventory['sewing_fabric'] -= 1
		newgobelen = 1
		minut += 15
		gs 'stat'
		'You spend 15 minutes at the embroidery frame, preparing the fabric and outlining the pattern for the tapestry.'

		act 'Set the tapestry aside': gt $loc, $loc_arg
	else
		*clr & cla
		menu_off = 1
		minut+=60
		'<center><img <<$set_imgh>> src="images/pc/activities/sewing/practice.jpg"></center>'
		gs 'exp_gain', 'sewng', rand(pcs_intel/10, pcs_intel/5)
		gobramax = (pcs_sewng - 70) * 6
		gobramin = (pcs_sewng - 70) * 2
		newgobelen += rand(gobramin,gobramax)
		gs 'stat'
		if newgobelen < 1000:'You spend an hour working on your tapestry, which is now <<newgobelen/10>> percent finished.'
		if newgobelen >= 1000:
			killvar 'newgobelen'
			mc_inventory['tapestry'] += 1
			'Your work on the tapestry is done.'
		end
		act 'Set the tapestry aside': gt $loc, $loc_arg
	end
end			
--- sewing ---------------------------------