glife/locations/tryndin.qsrc

# tryndin
!2021/05/02
!!Xander Corvus 
!!Tryndin Maximovich

if $ARGS[0] = 'stairwell_chat':
	*clr & cla
	minut += 5
	trychat += 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big77.jpg"></center>'
	if trychat = 1:
		'Tryndin tells you that he''s a college student but he''s going to graduate soon.'
	elseif trychat = 2:
		'Tryndin tells you that he lives with his mother; his father filed for divorce a couple of years ago and now lives with a new wife and children.'
	elseif trychat = 3:
		'Tryndin tells you that he is working towards a law degree and his father promised to buy him a car if he succeeds.'
	elseif trychat = 4:
		'Tryndin tells you that he has been taking dance lessons since he could walk and, even today, he often practices dancing at the fitness center.'
	elseif trychat = 5:
		'Tryndin tells you that he spends most of his evenings repairing computers. It costs him most of his free time, but at least he doesn''t have to rely on his parents for money.'
	elseif trychat = 6:
		'Tryndin tells you that, after college, he wants to go to the university and study law; he''ll probably have to serve in the military first though.'
	elseif trychat >= 7:
		'Tryndin and you chat about life, computers and other things, cracking jokes and enjoying each other''s company.'
	else
		'You talk for a few minutes about random stuff before you say your goodbyes and go on your way.'
	end
	act 'Say goodbye and leave':gt 'city_apt_building', 'floor_4'
end

if $ARGS[0] = 'tryndinmetro':
	*clr & cla
	minut += 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big77.jpg"></center>'
	'Tryndin sees you and greets you, "Hello <<$pcs_nickname>>. How are you doing today?"'
	if trychat >= 1:
		if cumloc[6] = 1:
			'The two of you are having a great conversation before he suddenly notices semen on your clothes. As he comes to the realization, his eyes noticeably widen. "What''s that? Cum?" he asks suspiciously.'
			act 'Make an excuse':
				*clr & cla
				gs 'stat'
				'You begin making excuses, claiming that this is all a misunderstanding and that you''re are absolutely innocent. But Tryndin doesn''t believe you and only half pays attention to your explanation.'
				act 'Get out of the car':gt 'metro', 'start'
			end
		elseif cumloc[11] = 1:
			'He looks at your face puzzled. "<<$pcs_nickname>>, your face is smeared with something." He stares at you, and after a moment, he realizes that''s cum on your face. "What''s that? Cum?" he asks suspiciously.'
			act 'Make an excuse':
				*clr & cla
				gs 'stat'
				'You begin making excuses, claiming that this is all a misunderstanding and that you''re are absolutely innocent. But Tryndin doesn''t believe you and only half pays attention to your explanation.'
				act 'Get out of the car':gt 'metro', 'start'
			end
		else
			'You chat with Tryndin while riding the subway.'
		end
	end
	act 'Get out of the car':gt 'metro', 'start'
end

--- tryndin ---------------------------------