pornster/pornster.txt

#mod_pornster_setup

!input basic mod information here.
!this location must be the first one

$mod_info[0] = 'pornster'
!0=mod name, saved to $mod_name[i] array

$mod_info[1] = '00101'
!1=mod version
!this will be displayed as version 1.2, fix3.
!if you input 40500, will be showen as version 4.5

$mod_info[2] = 'KeyMasterOfGozer'
!2=mod author

$mod_info[3] = 'Micro-manage porn schedule.'
!3=mod description, input a short brief here.


if curloc = 'mod_<<$mod_info[0]>>_setup':
	usehtml = 1
	!this will be only showed if you exec mod file. This location should be only called by gs, so this line will not trigger on normal mod playing
	'<center><h1><font color=red>ACCESS DENIED</font></h1></center>'
	'<<$mod_info[0]>> is a mod for <b>Girl Life - English Community Version</b>, and can not be played individually.'
	''
	'You can find the main game in <a href="https://www.tfgamessite.com/index.php?module=viewgame&id=597">Tfgames site</a> (external link)'
	''
	'Our forum: <a href="https://tfgamessite.com/phpbb3/viewforum.php?f=70">Tfgames site</a> (external link)'
end

--- mod_pornster_setup ---------------------------------
#mod_pornster_readme

!input your mod detail readme here. you can use msg or detailed structure, just make sure to create act 'return': gt 'mod_setting'
*clr & cla
act 'Return': gt 'mod_setting'

'<center>Mod <b><font color=red> Pornster </font></b></center>'
'Mod is to allow fine-grained tweaking of the porn schedule.  This is mostly just for me to get my feet wet making a mod.
'

--- mod_ipornster_readme ---------------------------------
#mod_pornster

!input mod entry point here. this will be checked on every location, please keep it clean and brief to avoid game lag

!pornstudio
if $curloc = 'pornstudio':

	act "Hack the Schedule": gs 'mod_pornster_hack'

end

--- mod_pornster ---------------------------------
#mod_pornster_hack

$loc = 'mod_pornster_hack'
$location_type = 'public_indoors'
$menu_loc = 'mod_pornster_hack'
$menu_arg = 'start'
cls

act 'Back to Manager': gs 'pornstudio', 'manager'

$contracting = {
	*clr
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/studio/studia_0.jpg"></center>'
	''
	d1 = day
	w1 = week
	m1 = month
	counter = 1
	$pornofday = ''
	:pornopt
		killvar 'nh1'
		pcount[counter] = counter
		w1 += 1
		if w1 > 7:w1 = 1
		d1 += 1
		if monthsend[m1] < d1: m1 += 1 & d1 = 1
		if m1 > 12: m1 = 1

		if m1 = 1 and d1 >= 1 and d1 <= 8:nh1 = 1
		if m1 = 2 and d1 = 23:nh1 = 1
		if m1 = 3 and d1 = 8:nh1 = 1
		if m1 = 5 and (d1 = 1 or d1 = 2):nh1 = 1
		if m1 = 5 and d1 = 9:nh1 = 1
		if m1 = 6 and (d1 = 12 or d1 = 13):nh1 = 1
		if m1 = 11 and d1 = 4:nh1 = 1

		if (weekdayfilter = 1 and w1 >= 6) or (weekendfilter = 1 and w1 < 6) or (weekdayfilter = 0 and weekendfilter = 0) or nh1 = 1:
			if datefilter['<<selected[counter]>>'] = 0:
				if nh1 = 1:
					$pornofday = '<i><b>National holiday, no shootings!</b></i><br>'
				else
					porns = 0
					:pornplanloop
						dynamic $pornfilmdesc, pornplan['<<counter>>,<<porns>>']
						if (pfactor <= ppnum) or (ppnum = 0):
							$line_color = 'None'
							$line_cmnt = ''
							$line_button = 'Take'
							line_button_val = 2
							if porntaken['<<counter>>,<<porns>>'] = 2:
								$line_color = 'green'
								$line_cmnt =  '- <i>Already contracted by you</i>'
								$line_button = 'Drop'
								line_button_val = 0
							elseif porntaken['<<counter>>,<<porns>>'] = 1:
								$line_color = 'red'
								$line_cmnt =  '- <i>Taken by someone else</i>'
							end
							if $line_color = 'None':
								$line_deco_f = ''
								$line_deco_b = ''
							else
								$line_deco_f = '<font color="<<$line_color>>">'
								$line_deco_b = '</font>'
							end
							! Alter Button - Goes to picklist of Film Types
							$pornofday += '<a href="exec:gs ''mod_pornster_edit'', ''<<counter>>'', ''<<porns>>''">[Alter]</a> '
							! Ownership Button - Take or Drop
							$pornofday += '<a href="exec:pornstack += 1 & porntaken[''<<counter>>,<<porns>>''] = <<line_button_val>> & pfilmday[<<pcount[counter]>>] = pornplan[''<<counter>>,<<porns>>''] & gs ''stat'' & dynamic $contracting">[<<$line_button>>] </a>'
							! Description of this Film
							$pornofday += '<<$line_deco_f>><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>><<$line_cmnt>><<$line_deco_b>>'
							$pornofday += '<br>'
						end
					if porns < 3: porns += 1 & jump 'pornplanloop'
				end
				if $pornofday ! '':
					'<<$monthName[m1]>> <<d1>>, <<$week[w1]>>:'
					'<<$pornofday>>'
					$pornofday = ''
				end
			end
		end
	if counter < 49:
		counter += 1
		jump 'pornopt'
	end
}
dynamic $contracting

--- mod_pornster_hack ---------------------------------

#mod_pornster_edit

$loc = 'mod_pornster_edit'
$location_type = 'public_indoors'
$menu_loc = 'mod_pornster_edit'
$menu_arg = 'start'
cls

! Expected Parameters:
! 0) the numeric porn day number offset (zero is today)
! 1) the session number on the day
pdateoffset = $ARGS[0]
psessionnum = $ARGS[1]

act "Back to Schedule": gs 'mod_pornster_hack'

$picker = ''
counter = 1
num_porntypes = arrsize('$porndesc')

:pick

$picker += '<a href="exec:pornplan[''<<pdateoffset>>,<<psessionnum>>''] = <<counter>> & pfilmday[pdateoffset] = <<counter>> & gs ''stat'' & gs ''mod_pornster_hack''"><<$porndesc[counter]>></a><br>'

if counter <= num_porntypes:
	counter += 1
	jump 'pick'
end

*pl $picker

--- mod_pornster_edit ---------------------------------