# Nord
$metka = $ARGS[0]
$loc = $CURLOC
$metkaStreet = $ARGS[0]
$locStreet = $CURLOC
CLOSE ALL
if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night_leto.mp3' & PLAY 'sound/street_night.mp3',30
	end
end

gs 'dinam'
clr
gs 'stat'
gs 'time'
'<center><b>Northern region</b></center>'
'<center><img src="images/etogame/nord.jpg"></center>'
!call random events from [street_events], and display them before show location.
gs'street_event','Nord' & if streetrand=-1:exit

if marudatestinterface = 1:
	!!!!!
	!!! Transportation

	'<center>'
	if hour >= 5 and hour <= 23: 
		*p '<a href="exec: GT ''metro'',''start''">Metro Station</a>'
			else *p 'Closed until 5 AM'
	end
	*p ' - '
	*p'<a href="exec:minut += 15 & GT ''vokzal''">Train Station</a>'
	*p ' - '
	*p '<a href="exec:GT ''zaprF'',''start''">Gas Station</a>'

	*nl
	*nl


	!!! General Content Locations / Activities


	*p '<a href="exec: set minut += 36 & GT ''park'',''start''">The Central Park</a>'
	*p ' - '
	*p'<a href="exec:GT ''casino''">"In Cash We Trust" Casino</a>'
	*p ' - '
	if hour >= 9 and hour <= 17 and week < 6: 
		*p '<a href="exec: GT ''dk'',''start''">Community Centre</a>'
			else *p 'Closed until 9 AM and on Weekends'
	end
	*p ' - '
	*p'<a href="exec:GT ''Terminal''">Storage Units</a>'

	*nl
	*nl

	!!! Shopping Locations

	if hour >= 8 and hour <= 22: 
		*p '<a href="exec: dynamic $kiosksig">Kiosk</a>'
			else *p 'Closed until 8 AM'
	end
	*p ' - '
	if hour >= 8 and hour <= 20: 
		*p '<a href="exec: GT ''shop'',''start''">Supermarket</a>'
			else *p 'Closed until 8 AM'
	end
	*p ' - '
	if hour >= 9 and hour <= 17 and week > 1: 
		*p '<a href="exec: GT ''autosalonF'',''start''">Car Dealership</a>'
			else *p 'Closed until 9 AM and on Mondays'
	end		
	*p ' - '
	if hour >= 9 and hour <= 17 and week > 1: 
		*p '<a href="exec: GT ''autotraidF'',''start''">Used-Car Dealership</a>'
			else *p 'Closed until 9 AM and on Mondays'
	end
	*p ' - '
	if hour >= 9 and hour <= 20 and week < 7: 
		*p '<a href="exec: GT ''autoservisF'',''start''">Repair Shop</a>'
			else *p 'Closed until 9 AM and on Sundays'
	end
	*p ' - '
	if hour >= 12 and hour < 20: 
		*p '<a href="exec: GT ''pirsingsalon''">Tatoo & Piercing Palor</a>'
			else *p 'Closed until 12 AM'
	end

	*nl
	*nl

	!!! Work Locations

	if hour >= 14 or hour < 4: 
		*p '<a href="exec: GT ''lakecafe'',''main''">Cafe & Restaurant</a>'
			else *p 'Closed until 2 PM'
	end
	*p ' - '
	if hour >= 9 and hour <= 17 and week < 6 and bumtolik > 3:
		*p '<a href="exec:gt ''buklinik'', ''start''">Mercy clinic</a>'
			elseif hour < 9 and hour > 17 and week > 6 and bumtolik > 3: *p 'Closed until 9 AM and on Weekends'
			elseif bumtolik <= 3: *p 'Location locked'
	end
	*nl
	*nl

	!!! Locations bound to Characters - Location Locked = Player does not meet requirements yet (obviously)

	if slavaQW >= 1: 
		*p '<a href="exec: GT ''qwBarPolet''">Bar "Flight"</a>'
			else *p 'Location locked'
	end
	*p ' - '
	if bumtolik > 3 and hour >= 9 and hour <= 17 and week < 6: 
		*p '<a href="exec: GT ''buklinik'',''start''">"Mercy" Clinic</a>'
			elseif hour > 17 or hour < 9: *p 'Closed until 9 AM and on Weekends'
				else *p 'Location locked'
	end
	*p ' - '
	if tobiQW >= 1: 
		*p 'The old mansion, home to <a href="exec: GT ''kakuzu'',''start''">Kakuzu</a>'
			else *p 'Location locked'
	end
	*p ' - '
	if jouryResult = 10: 
		*p 'In one of the building you can find <a href="exec: GT ''youry''">Georges flat</a>'
			else *p 'Location locked'
	end
	*p ' - '
	if IvanKvartira > 0: 
		*p 'In one of these building is  <a href="exec: GT ''ivanRoom''">Manager Ivans apartment</a>'
			else *p 'Location locked'
	end

	*nl
	*nl

end
!!!!! End of marudatestinterface

!!act 'Exit to the northern highway':minut += 15 & nroad = 0 & gt 'road'
act 'Wait':
	cla
	waiting = input ("How long would you like to wait? (Not more than 120 minutes)")

	if waiting <= 0 or waiting > 120:
		minut += 15
	elseif waiting > 0 and waiting <= 120:
		minut += waiting
	end

	act 'Take a look at the clock':gt curloc
end

gs 'taxi'

if car > 0:
	if cardrive = 3 or cardrive >= 6 and cardrive <= 9:'In the parking stands your <a href="exec:GS ''carF'', ''start''"><<$car>></a>.'
end

if marudatestinterface = 0:

	'The towns <a href="exec:hour += 1 & gt ''park'', ''start''">central park</a> is an hours walk from here.'

	if hour >= 8 and hour <= 22:'A kiosk is selling <a href="exec:dynamic $kiosksig">cigarettes</a>.'

	'<a href="exec:minut += 15 & gt ''vokzal''">Train Station</a> to get to the small Town.'

	if slavaQW >= 1:'<a href="exec:gt ''qwBarPolet''">Bar "Flight"</a>.'

	litltown = 0
	'There is a <a href="exec:gt ''zaprF'', ''start''">Gas</a> Station near the street'

	if hour >= 5 and hour <= 23:'The <a href="exec:gt ''metro'', ''start''">Metro</a> Station is within a 5 minute walk from here.'
	if hour >= 9 and hour <= 17 and week > 1:'<a href="exec:gt ''autosalonF'', ''start''">Car Dealership</a>'
	if hour >= 9 and hour <= 20 and week < 7:'<a href="exec:gt ''autoservisF'', ''start''">Repair Shop</a>'
	if hour >= 9 and hour <= 17 and week > 1:'Used <a href="exec:gt ''autotraidF'', ''start''">Car Dealership</a>'
	if hour >= 9 and hour <= 17 and week < 6:'<a href="exec:gt ''dk'', ''start''">Community centre</a>'
	if hour >= 9 and hour <= 17 and week < 6 and bumtolik > 3:'<a href="exec:gt ''buklinik'', ''start''">Mercy clinic</a>'
	if hour >= 8 and hour <= 20:'The parking lot, which is engulfed in bright lights, belongs to a <a href="exec:gt ''shop'', ''start''">Supermarket</a>'
	if hour >= 12 and hour <= 19:'Above the door to a basement room is a bright neon sign for the <a href="exec:gt ''pirsingsalon''">Tatoo & Piercing parlor</a>'
	if tobiQW >= 1:'The old mansion, home to <a href="exec:gt ''kakuzu'', ''start''">Kakuzu</a>'

	'There is a huge building, with bright lights, which houses a <a href="exec:gt ''casino''">Casino</a> and a hotel.'

	if hour >= 14 or hour < 4:'Located far away from the buildings <a href="exec:gt ''lakecafe'', ''main''">barbecue</a>.'
	if jouryResult = 10:'In one of the building you can find <a href="exec:gt ''youry''">Georges</a> flat'
	if IvanKvartira > 0:'In one of these building is <a href="exec:gt ''ivanRoom''">Manager Ivans</a> apartment'

	'A long and high fence, which is build around the <a href="exec:gt ''Terminal''">storage terminal</a>'

end
!!!!! End of marudatestinterface

--- Nord ---------------------------------

